arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <asm/context_tracking.h>
  60 #include <asm/smap.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72 #ifdef CONFIG_FUNCTION_TRACER
  73
  74 #ifdef CC_USING_FENTRY
  75 # define function_hook  __fentry__
  76 #else
  77 # define function_hook  mcount
  78 #endif
  79
  80 #ifdef CONFIG_DYNAMIC_FTRACE
  81
  82 ENTRY(function_hook)
  83         retq
  84 END(function_hook)
  85
  86 /* skip is set if stack has been adjusted */
  87 .macro ftrace_caller_setup skip=0
  88         MCOUNT_SAVE_FRAME \skip
  89
  90         /* Load the ftrace_ops into the 3rd parameter */
  91         movq function_trace_op(%rip), %rdx
  92
  93         /* Load ip into the first parameter */
  94         movq RIP(%rsp), %rdi
  95         subq $MCOUNT_INSN_SIZE, %rdi
  96         /* Load the parent_ip into the second parameter */
  97 #ifdef CC_USING_FENTRY
  98         movq SS+16(%rsp), %rsi
  99 #else
 100         movq 8(%rbp), %rsi
 101 #endif
 102 .endm
 103
 104 ENTRY(ftrace_caller)
 105         /* Check if tracing was disabled (quick check) */
 106         cmpl $0, function_trace_stop
 107         jne  ftrace_stub
 108
 109         ftrace_caller_setup
 110         /* regs go into 4th parameter (but make it NULL) */
 111         movq $0, %rcx
 112
 113 GLOBAL(ftrace_call)
 114         call ftrace_stub
 115
 116         MCOUNT_RESTORE_FRAME
 117 ftrace_return:
 118
 119 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 120 GLOBAL(ftrace_graph_call)
 121         jmp ftrace_stub
 122 #endif
 123
 124 GLOBAL(ftrace_stub)
 125         retq
 126 END(ftrace_caller)
 127
 128 ENTRY(ftrace_regs_caller)
 129         /* Save the current flags before compare (in SS location)*/
 130         pushfq
 131
 132         /* Check if tracing was disabled (quick check) */
 133         cmpl $0, function_trace_stop
 134         jne  ftrace_restore_flags
 135
 136         /* skip=8 to skip flags saved in SS */
 137         ftrace_caller_setup 8
 138
 139         /* Save the rest of pt_regs */
 140         movq %r15, R15(%rsp)
 141         movq %r14, R14(%rsp)
 142         movq %r13, R13(%rsp)
 143         movq %r12, R12(%rsp)
 144         movq %r11, R11(%rsp)
 145         movq %r10, R10(%rsp)
 146         movq %rbp, RBP(%rsp)
 147         movq %rbx, RBX(%rsp)
 148         /* Copy saved flags */
 149         movq SS(%rsp), %rcx
 150         movq %rcx, EFLAGS(%rsp)
 151         /* Kernel segments */
 152         movq $__KERNEL_DS, %rcx
 153         movq %rcx, SS(%rsp)
 154         movq $__KERNEL_CS, %rcx
 155         movq %rcx, CS(%rsp)
 156         /* Stack - skipping return address */
 157         leaq SS+16(%rsp), %rcx
 158         movq %rcx, RSP(%rsp)
 159
 160         /* regs go into 4th parameter */
 161         leaq (%rsp), %rcx
 162
 163 GLOBAL(ftrace_regs_call)
 164         call ftrace_stub
 165
 166         /* Copy flags back to SS, to restore them */
 167         movq EFLAGS(%rsp), %rax
 168         movq %rax, SS(%rsp)
 169
 170         /* Handlers can change the RIP */
 171         movq RIP(%rsp), %rax
 172         movq %rax, SS+8(%rsp)
 173
 174         /* restore the rest of pt_regs */
 175         movq R15(%rsp), %r15
 176         movq R14(%rsp), %r14
 177         movq R13(%rsp), %r13
 178         movq R12(%rsp), %r12
 179         movq R10(%rsp), %r10
 180         movq RBP(%rsp), %rbp
 181         movq RBX(%rsp), %rbx
 182
 183         /* skip=8 to skip flags saved in SS */
 184         MCOUNT_RESTORE_FRAME 8
 185
 186         /* Restore flags */
 187         popfq
 188
 189         jmp ftrace_return
 190 ftrace_restore_flags:
 191         popfq
 192         jmp  ftrace_stub
 193
 194 END(ftrace_regs_caller)
 195
 196
 197 #else /* ! CONFIG_DYNAMIC_FTRACE */
 198
 199 ENTRY(function_hook)
 200         cmpl $0, function_trace_stop
 201         jne  ftrace_stub
 202
 203         cmpq $ftrace_stub, ftrace_trace_function
 204         jnz trace
 205
 206 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 207         cmpq $ftrace_stub, ftrace_graph_return
 208         jnz ftrace_graph_caller
 209
 210         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 211         jnz ftrace_graph_caller
 212 #endif
 213
 214 GLOBAL(ftrace_stub)
 215         retq
 216
 217 trace:
 218         MCOUNT_SAVE_FRAME
 219
 220         movq RIP(%rsp), %rdi
 221 #ifdef CC_USING_FENTRY
 222         movq SS+16(%rsp), %rsi
 223 #else
 224         movq 8(%rbp), %rsi
 225 #endif
 226         subq $MCOUNT_INSN_SIZE, %rdi
 227
 228         call   *ftrace_trace_function
 229
 230         MCOUNT_RESTORE_FRAME
 231
 232         jmp ftrace_stub
 233 END(function_hook)
 234 #endif /* CONFIG_DYNAMIC_FTRACE */
 235 #endif /* CONFIG_FUNCTION_TRACER */
 236
 237 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 238 ENTRY(ftrace_graph_caller)
 239         MCOUNT_SAVE_FRAME
 240
 241 #ifdef CC_USING_FENTRY
 242         leaq SS+16(%rsp), %rdi
 243         movq $0, %rdx   /* No framepointers needed */
 244 #else
 245         leaq 8(%rbp), %rdi
 246         movq (%rbp), %rdx
 247 #endif
 248         movq RIP(%rsp), %rsi
 249         subq $MCOUNT_INSN_SIZE, %rsi
 250
 251         call    prepare_ftrace_return
 252
 253         MCOUNT_RESTORE_FRAME
 254
 255         retq
 256 END(ftrace_graph_caller)
 257
 258 GLOBAL(return_to_handler)
 259         subq  $24, %rsp
 260
 261         /* Save the return values */
 262         movq %rax, (%rsp)
 263         movq %rdx, 8(%rsp)
 264         movq %rbp, %rdi
 265
 266         call ftrace_return_to_handler
 267
 268         movq %rax, %rdi
 269         movq 8(%rsp), %rdx
 270         movq (%rsp), %rax
 271         addq $24, %rsp
 272         jmp *%rdi
 273 #endif
 274
 275
 276 #ifndef CONFIG_PREEMPT
 277 #define retint_kernel retint_restore_args
 278 #endif
 279
 280 #ifdef CONFIG_PARAVIRT
 281 ENTRY(native_usergs_sysret64)
 282         swapgs
 283         sysretq
 284 ENDPROC(native_usergs_sysret64)
 285 #endif /* CONFIG_PARAVIRT */
 286
 287
 288 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 289 #ifdef CONFIG_TRACE_IRQFLAGS
 290         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 291         jnc  1f
 292         TRACE_IRQS_ON
 293 1:
 294 #endif
 295 .endm
 296
 297 /*
 298  * When dynamic function tracer is enabled it will add a breakpoint
 299  * to all locations that it is about to modify, sync CPUs, update
 300  * all the code, sync CPUs, then remove the breakpoints. In this time
 301  * if lockdep is enabled, it might jump back into the debug handler
 302  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 303  *
 304  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 305  * make sure the stack pointer does not get reset back to the top
 306  * of the debug stack, and instead just reuses the current stack.
 307  */
 308 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 309
 310 .macro TRACE_IRQS_OFF_DEBUG
 311         call debug_stack_set_zero
 312         TRACE_IRQS_OFF
 313         call debug_stack_reset
 314 .endm
 315
 316 .macro TRACE_IRQS_ON_DEBUG
 317         call debug_stack_set_zero
 318         TRACE_IRQS_ON
 319         call debug_stack_reset
 320 .endm
 321
 322 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 323         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 324         jnc  1f
 325         TRACE_IRQS_ON_DEBUG
 326 1:
 327 .endm
 328
 329 #else
 330 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 331 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 332 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 333 #endif
 334
 335 /*
 336  * C code is not supposed to know about undefined top of stack. Every time
 337  * a C function with an pt_regs argument is called from the SYSCALL based
 338  * fast path FIXUP_TOP_OF_STACK is needed.
 339  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 340  * manipulation.
 341  */
 342
 343         /* %rsp:at FRAMEEND */
 344         .macro FIXUP_TOP_OF_STACK tmp offset=0
 345         movq PER_CPU_VAR(old_rsp),\tmp
 346         movq \tmp,RSP+\offset(%rsp)
 347         movq $__USER_DS,SS+\offset(%rsp)
 348         movq $__USER_CS,CS+\offset(%rsp)
 349         movq $-1,RCX+\offset(%rsp)
 350         movq R11+\offset(%rsp),\tmp  /* get eflags */
 351         movq \tmp,EFLAGS+\offset(%rsp)
 352         .endm
 353
 354         .macro RESTORE_TOP_OF_STACK tmp offset=0
 355         movq RSP+\offset(%rsp),\tmp
 356         movq \tmp,PER_CPU_VAR(old_rsp)
 357         movq EFLAGS+\offset(%rsp),\tmp
 358         movq \tmp,R11+\offset(%rsp)
 359         .endm
 360
 361         .macro FAKE_STACK_FRAME child_rip
 362         /* push in order ss, rsp, eflags, cs, rip */
 363         xorl %eax, %eax
 364         pushq_cfi $__KERNEL_DS /* ss */
 365         /*CFI_REL_OFFSET        ss,0*/
 366         pushq_cfi %rax /* rsp */
 367         CFI_REL_OFFSET  rsp,0
 368         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 369         /*CFI_REL_OFFSET        rflags,0*/
 370         pushq_cfi $__KERNEL_CS /* cs */
 371         /*CFI_REL_OFFSET        cs,0*/
 372         pushq_cfi \child_rip /* rip */
 373         CFI_REL_OFFSET  rip,0
 374         pushq_cfi %rax /* orig rax */
 375         .endm
 376
 377         .macro UNFAKE_STACK_FRAME
 378         addq $8*6, %rsp
 379         CFI_ADJUST_CFA_OFFSET   -(6*8)
 380         .endm
 381
 382 /*
 383  * initial frame state for interrupts (and exceptions without error code)
 384  */
 385         .macro EMPTY_FRAME start=1 offset=0
 386         .if \start
 387         CFI_STARTPROC simple
 388         CFI_SIGNAL_FRAME
 389         CFI_DEF_CFA rsp,8+\offset
 390         .else
 391         CFI_DEF_CFA_OFFSET 8+\offset
 392         .endif
 393         .endm
 394
 395 /*
 396  * initial frame state for interrupts (and exceptions without error code)
 397  */
 398         .macro INTR_FRAME start=1 offset=0
 399         EMPTY_FRAME \start, SS+8+\offset-RIP
 400         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 401         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 402         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 403         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 404         CFI_REL_OFFSET rip, RIP+\offset-RIP
 405         .endm
 406
 407 /*
 408  * initial frame state for exceptions with error code (and interrupts
 409  * with vector already pushed)
 410  */
 411         .macro XCPT_FRAME start=1 offset=0
 412         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 413         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 414         .endm
 415
 416 /*
 417  * frame that enables calling into C.
 418  */
 419         .macro PARTIAL_FRAME start=1 offset=0
 420         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 421         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 422         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 423         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 424         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 425         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 426         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 427         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 428         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 429         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 430         .endm
 431
 432 /*
 433  * frame that enables passing a complete pt_regs to a C function.
 434  */
 435         .macro DEFAULT_FRAME start=1 offset=0
 436         PARTIAL_FRAME \start, R11+\offset-R15
 437         CFI_REL_OFFSET rbx, RBX+\offset
 438         CFI_REL_OFFSET rbp, RBP+\offset
 439         CFI_REL_OFFSET r12, R12+\offset
 440         CFI_REL_OFFSET r13, R13+\offset
 441         CFI_REL_OFFSET r14, R14+\offset
 442         CFI_REL_OFFSET r15, R15+\offset
 443         .endm
 444
 445 /* save partial stack frame */
 446         .macro SAVE_ARGS_IRQ
 447         cld
 448         /* start from rbp in pt_regs and jump over */
 449         movq_cfi rdi, (RDI-RBP)
 450         movq_cfi rsi, (RSI-RBP)
 451         movq_cfi rdx, (RDX-RBP)
 452         movq_cfi rcx, (RCX-RBP)
 453         movq_cfi rax, (RAX-RBP)
 454         movq_cfi  r8,  (R8-RBP)
 455         movq_cfi  r9,  (R9-RBP)
 456         movq_cfi r10, (R10-RBP)
 457         movq_cfi r11, (R11-RBP)
 458
 459         /* Save rbp so that we can unwind from get_irq_regs() */
 460         movq_cfi rbp, 0
 461
 462         /* Save previous stack value */
 463         movq %rsp, %rsi
 464
 465         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 466         testl $3, CS-RBP(%rsi)
 467         je 1f
 468         SWAPGS
 469         /*
 470          * irq_count is used to check if a CPU is already on an interrupt stack
 471          * or not. While this is essentially redundant with preempt_count it is
 472          * a little cheaper to use a separate counter in the PDA (short of
 473          * moving irq_enter into assembly, which would be too much work)
 474          */
 475 1:      incl PER_CPU_VAR(irq_count)
 476         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 477         CFI_DEF_CFA_REGISTER    rsi
 478
 479         /* Store previous stack value */
 480         pushq %rsi
 481         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 482                         0x77 /* DW_OP_breg7 */, 0, \
 483                         0x06 /* DW_OP_deref */, \
 484                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 485                         0x22 /* DW_OP_plus */
 486         /* We entered an interrupt context - irqs are off: */
 487         TRACE_IRQS_OFF
 488         .endm
 489
 490 ENTRY(save_paranoid)
 491         XCPT_FRAME 1 RDI+8
 492         cld
 493         movq_cfi rdi, RDI+8
 494         movq_cfi rsi, RSI+8
 495         movq_cfi rdx, RDX+8
 496         movq_cfi rcx, RCX+8
 497         movq_cfi rax, RAX+8
 498         movq_cfi r8, R8+8
 499         movq_cfi r9, R9+8
 500         movq_cfi r10, R10+8
 501         movq_cfi r11, R11+8
 502         movq_cfi rbx, RBX+8
 503         movq_cfi rbp, RBP+8
 504         movq_cfi r12, R12+8
 505         movq_cfi r13, R13+8
 506         movq_cfi r14, R14+8
 507         movq_cfi r15, R15+8
 508         movl $1,%ebx
 509         movl $MSR_GS_BASE,%ecx
 510         rdmsr
 511         testl %edx,%edx
 512         js 1f   /* negative -> in kernel */
 513         SWAPGS
 514         xorl %ebx,%ebx
 515 1:      ret
 516         CFI_ENDPROC
 517 END(save_paranoid)
 518
 519 /*
 520  * A newly forked process directly context switches into this address.
 521  *
 522  * rdi: prev task we switched from
 523  */
 524 ENTRY(ret_from_fork)
 525         DEFAULT_FRAME
 526
 527         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 528
 529         pushq_cfi $0x0002
 530         popfq_cfi                               # reset kernel eflags
 531
 532         call schedule_tail                      # rdi: 'prev' task parameter
 533
 534         GET_THREAD_INFO(%rcx)
 535
 536         RESTORE_REST
 537
 538         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 539         jz   1f
 540
 541         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 542         jnz  int_ret_from_sys_call
 543
 544         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 545         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 546
 547 1:
 548         subq $REST_SKIP, %rsp   # leave space for volatiles
 549         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 550         movq %rbp, %rdi
 551         call *%rbx
 552         movl $0, RAX(%rsp)
 553         RESTORE_REST
 554         jmp int_ret_from_sys_call
 555         CFI_ENDPROC
 556 END(ret_from_fork)
 557
 558 /*
 559  * System call entry. Up to 6 arguments in registers are supported.
 560  *
 561  * SYSCALL does not save anything on the stack and does not change the
 562  * stack pointer.  However, it does mask the flags register for us, so
 563  * CLD and CLAC are not needed.
 564  */
 565
 566 /*
 567  * Register setup:
 568  * rax  system call number
 569  * rdi  arg0
 570  * rcx  return address for syscall/sysret, C arg3
 571  * rsi  arg1
 572  * rdx  arg2
 573  * r10  arg3    (--> moved to rcx for C)
 574  * r8   arg4
 575  * r9   arg5
 576  * r11  eflags for syscall/sysret, temporary for C
 577  * r12-r15,rbp,rbx saved by C code, not touched.
 578  *
 579  * Interrupts are off on entry.
 580  * Only called from user space.
 581  *
 582  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 583  *      and report it properly in ps. Unfortunately we haven't.
 584  *
 585  * When user can change the frames always force IRET. That is because
 586  * it deals with uncanonical addresses better. SYSRET has trouble
 587  * with them due to bugs in both AMD and Intel CPUs.
 588  */
 589
 590 ENTRY(system_call)
 591         CFI_STARTPROC   simple
 592         CFI_SIGNAL_FRAME
 593         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 594         CFI_REGISTER    rip,rcx
 595         /*CFI_REGISTER  rflags,r11*/
 596         SWAPGS_UNSAFE_STACK
 597         /*
 598          * A hypervisor implementation might want to use a label
 599          * after the swapgs, so that it can do the swapgs
 600          * for the guest and jump here on syscall.
 601          */
 602 GLOBAL(system_call_after_swapgs)
 603
 604         movq    %rsp,PER_CPU_VAR(old_rsp)
 605         movq    PER_CPU_VAR(kernel_stack),%rsp
 606         /*
 607          * No need to follow this irqs off/on section - it's straight
 608          * and short:
 609          */
 610         ENABLE_INTERRUPTS(CLBR_NONE)
 611         SAVE_ARGS 8,0
 612         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 613         movq  %rcx,RIP-ARGOFFSET(%rsp)
 614         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 615         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 616         jnz tracesys
 617 system_call_fastpath:
 618 #if __SYSCALL_MASK == ~0
 619         cmpq $__NR_syscall_max,%rax
 620 #else
 621         andl $__SYSCALL_MASK,%eax
 622         cmpl $__NR_syscall_max,%eax
 623 #endif
 624         ja badsys
 625         movq %r10,%rcx
 626         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 627         movq %rax,RAX-ARGOFFSET(%rsp)
 628 /*
 629  * Syscall return path ending with SYSRET (fast path)
 630  * Has incomplete stack frame and undefined top of stack.
 631  */
 632 ret_from_sys_call:
 633         movl $_TIF_ALLWORK_MASK,%edi
 634         /* edi: flagmask */
 635 sysret_check:
 636         LOCKDEP_SYS_EXIT
 637         DISABLE_INTERRUPTS(CLBR_NONE)
 638         TRACE_IRQS_OFF
 639         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 640         andl %edi,%edx
 641         jnz  sysret_careful
 642         CFI_REMEMBER_STATE
 643         /*
 644          * sysretq will re-enable interrupts:
 645          */
 646         TRACE_IRQS_ON
 647         movq RIP-ARGOFFSET(%rsp),%rcx
 648         CFI_REGISTER    rip,rcx
 649         RESTORE_ARGS 1,-ARG_SKIP,0
 650         /*CFI_REGISTER  rflags,r11*/
 651         movq    PER_CPU_VAR(old_rsp), %rsp
 652         USERGS_SYSRET64
 653
 654         CFI_RESTORE_STATE
 655         /* Handle reschedules */
 656         /* edx: work, edi: workmask */
 657 sysret_careful:
 658         bt $TIF_NEED_RESCHED,%edx
 659         jnc sysret_signal
 660         TRACE_IRQS_ON
 661         ENABLE_INTERRUPTS(CLBR_NONE)
 662         pushq_cfi %rdi
 663         SCHEDULE_USER
 664         popq_cfi %rdi
 665         jmp sysret_check
 666
 667         /* Handle a signal */
 668 sysret_signal:
 669         TRACE_IRQS_ON
 670         ENABLE_INTERRUPTS(CLBR_NONE)
 671 #ifdef CONFIG_AUDITSYSCALL
 672         bt $TIF_SYSCALL_AUDIT,%edx
 673         jc sysret_audit
 674 #endif
 675         /*
 676          * We have a signal, or exit tracing or single-step.
 677          * These all wind up with the iret return path anyway,
 678          * so just join that path right now.
 679          */
 680         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 681         jmp int_check_syscall_exit_work
 682
 683 badsys:
 684         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 685         jmp ret_from_sys_call
 686
 687 #ifdef CONFIG_AUDITSYSCALL
 688         /*
 689          * Fast path for syscall audit without full syscall trace.
 690          * We just call __audit_syscall_entry() directly, and then
 691          * jump back to the normal fast path.
 692          */
 693 auditsys:
 694         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 695         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 696         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 697         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 698         movq %rax,%rsi                  /* 2nd arg: syscall number */
 699         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 700         call __audit_syscall_entry
 701         LOAD_ARGS 0             /* reload call-clobbered registers */
 702         jmp system_call_fastpath
 703
 704         /*
 705          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 706          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 707          * masked off.
 708          */
 709 sysret_audit:
 710         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 711         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 712         setbe %al               /* 1 if so, 0 if not */
 713         movzbl %al,%edi         /* zero-extend that into %edi */
 714         call __audit_syscall_exit
 715         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 716         jmp sysret_check
 717 #endif  /* CONFIG_AUDITSYSCALL */
 718
 719         /* Do syscall tracing */
 720 tracesys:
 721 #ifdef CONFIG_AUDITSYSCALL
 722         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 723         jz auditsys
 724 #endif
 725         SAVE_REST
 726         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 727         FIXUP_TOP_OF_STACK %rdi
 728         movq %rsp,%rdi
 729         call syscall_trace_enter
 730         /*
 731          * Reload arg registers from stack in case ptrace changed them.
 732          * We don't reload %rax because syscall_trace_enter() returned
 733          * the value it wants us to use in the table lookup.
 734          */
 735         LOAD_ARGS ARGOFFSET, 1
 736         RESTORE_REST
 737 #if __SYSCALL_MASK == ~0
 738         cmpq $__NR_syscall_max,%rax
 739 #else
 740         andl $__SYSCALL_MASK,%eax
 741         cmpl $__NR_syscall_max,%eax
 742 #endif
 743         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 744         movq %r10,%rcx  /* fixup for C */
 745         call *sys_call_table(,%rax,8)
 746         movq %rax,RAX-ARGOFFSET(%rsp)
 747         /* Use IRET because user could have changed frame */
 748
 749 /*
 750  * Syscall return path ending with IRET.
 751  * Has correct top of stack, but partial stack frame.
 752  */
 753 GLOBAL(int_ret_from_sys_call)
 754         DISABLE_INTERRUPTS(CLBR_NONE)
 755         TRACE_IRQS_OFF
 756         movl $_TIF_ALLWORK_MASK,%edi
 757         /* edi: mask to check */
 758 GLOBAL(int_with_check)
 759         LOCKDEP_SYS_EXIT_IRQ
 760         GET_THREAD_INFO(%rcx)
 761         movl TI_flags(%rcx),%edx
 762         andl %edi,%edx
 763         jnz   int_careful
 764         andl    $~TS_COMPAT,TI_status(%rcx)
 765         jmp   retint_swapgs
 766
 767         /* Either reschedule or signal or syscall exit tracking needed. */
 768         /* First do a reschedule test. */
 769         /* edx: work, edi: workmask */
 770 int_careful:
 771         bt $TIF_NEED_RESCHED,%edx
 772         jnc  int_very_careful
 773         TRACE_IRQS_ON
 774         ENABLE_INTERRUPTS(CLBR_NONE)
 775         pushq_cfi %rdi
 776         SCHEDULE_USER
 777         popq_cfi %rdi
 778         DISABLE_INTERRUPTS(CLBR_NONE)
 779         TRACE_IRQS_OFF
 780         jmp int_with_check
 781
 782         /* handle signals and tracing -- both require a full stack frame */
 783 int_very_careful:
 784         TRACE_IRQS_ON
 785         ENABLE_INTERRUPTS(CLBR_NONE)
 786 int_check_syscall_exit_work:
 787         SAVE_REST
 788         /* Check for syscall exit trace */
 789         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 790         jz int_signal
 791         pushq_cfi %rdi
 792         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 793         call syscall_trace_leave
 794         popq_cfi %rdi
 795         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 796         jmp int_restore_rest
 797
 798 int_signal:
 799         testl $_TIF_DO_NOTIFY_MASK,%edx
 800         jz 1f
 801         movq %rsp,%rdi          # &ptregs -> arg1
 802         xorl %esi,%esi          # oldset -> arg2
 803         call do_notify_resume
 804 1:      movl $_TIF_WORK_MASK,%edi
 805 int_restore_rest:
 806         RESTORE_REST
 807         DISABLE_INTERRUPTS(CLBR_NONE)
 808         TRACE_IRQS_OFF
 809         jmp int_with_check
 810         CFI_ENDPROC
 811 END(system_call)
 812
 813         .macro FORK_LIKE func
 814 ENTRY(stub_\func)
 815         CFI_STARTPROC
 816         popq    %r11                    /* save return address */
 817         PARTIAL_FRAME 0
 818         SAVE_REST
 819         pushq   %r11                    /* put it back on stack */
 820         FIXUP_TOP_OF_STACK %r11, 8
 821         DEFAULT_FRAME 0 8               /* offset 8: return address */
 822         call sys_\func
 823         RESTORE_TOP_OF_STACK %r11, 8
 824         ret $REST_SKIP          /* pop extended registers */
 825         CFI_ENDPROC
 826 END(stub_\func)
 827         .endm
 828
 829         .macro FIXED_FRAME label,func
 830 ENTRY(\label)
 831         CFI_STARTPROC
 832         PARTIAL_FRAME 0 8               /* offset 8: return address */
 833         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 834         call \func
 835         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 836         ret
 837         CFI_ENDPROC
 838 END(\label)
 839         .endm
 840
 841         FORK_LIKE  clone
 842         FORK_LIKE  fork
 843         FORK_LIKE  vfork
 844         FIXED_FRAME stub_iopl, sys_iopl
 845
 846 ENTRY(ptregscall_common)
 847         DEFAULT_FRAME 1 8       /* offset 8: return address */
 848         RESTORE_TOP_OF_STACK %r11, 8
 849         movq_cfi_restore R15+8, r15
 850         movq_cfi_restore R14+8, r14
 851         movq_cfi_restore R13+8, r13
 852         movq_cfi_restore R12+8, r12
 853         movq_cfi_restore RBP+8, rbp
 854         movq_cfi_restore RBX+8, rbx
 855         ret $REST_SKIP          /* pop extended registers */
 856         CFI_ENDPROC
 857 END(ptregscall_common)
 858
 859 ENTRY(stub_execve)
 860         CFI_STARTPROC
 861         addq $8, %rsp
 862         PARTIAL_FRAME 0
 863         SAVE_REST
 864         FIXUP_TOP_OF_STACK %r11
 865         call sys_execve
 866         movq %rax,RAX(%rsp)
 867         RESTORE_REST
 868         jmp int_ret_from_sys_call
 869         CFI_ENDPROC
 870 END(stub_execve)
 871
 872 /*
 873  * sigreturn is special because it needs to restore all registers on return.
 874  * This cannot be done with SYSRET, so use the IRET return path instead.
 875  */
 876 ENTRY(stub_rt_sigreturn)
 877         CFI_STARTPROC
 878         addq $8, %rsp
 879         PARTIAL_FRAME 0
 880         SAVE_REST
 881         FIXUP_TOP_OF_STACK %r11
 882         call sys_rt_sigreturn
 883         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 884         RESTORE_REST
 885         jmp int_ret_from_sys_call
 886         CFI_ENDPROC
 887 END(stub_rt_sigreturn)
 888
 889 #ifdef CONFIG_X86_X32_ABI
 890 ENTRY(stub_x32_rt_sigreturn)
 891         CFI_STARTPROC
 892         addq $8, %rsp
 893         PARTIAL_FRAME 0
 894         SAVE_REST
 895         FIXUP_TOP_OF_STACK %r11
 896         call sys32_x32_rt_sigreturn
 897         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 898         RESTORE_REST
 899         jmp int_ret_from_sys_call
 900         CFI_ENDPROC
 901 END(stub_x32_rt_sigreturn)
 902
 903 ENTRY(stub_x32_execve)
 904         CFI_STARTPROC
 905         addq $8, %rsp
 906         PARTIAL_FRAME 0
 907         SAVE_REST
 908         FIXUP_TOP_OF_STACK %r11
 909         call compat_sys_execve
 910         RESTORE_TOP_OF_STACK %r11
 911         movq %rax,RAX(%rsp)
 912         RESTORE_REST
 913         jmp int_ret_from_sys_call
 914         CFI_ENDPROC
 915 END(stub_x32_execve)
 916
 917 #endif
 918
 919 /*
 920  * Build the entry stubs and pointer table with some assembler magic.
 921  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 922  * single cache line on all modern x86 implementations.
 923  */
 924         .section .init.rodata,"a"
 925 ENTRY(interrupt)
 926         .section .entry.text
 927         .p2align 5
 928         .p2align CONFIG_X86_L1_CACHE_SHIFT
 929 ENTRY(irq_entries_start)
 930         INTR_FRAME
 931 vector=FIRST_EXTERNAL_VECTOR
 932 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 933         .balign 32
 934   .rept 7
 935     .if vector < NR_VECTORS
 936       .if vector <> FIRST_EXTERNAL_VECTOR
 937         CFI_ADJUST_CFA_OFFSET -8
 938       .endif
 939 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 940       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 941         jmp 2f
 942       .endif
 943       .previous
 944         .quad 1b
 945       .section .entry.text
 946 vector=vector+1
 947     .endif
 948   .endr
 949 2:      jmp common_interrupt
 950 .endr
 951         CFI_ENDPROC
 952 END(irq_entries_start)
 953
 954 .previous
 955 END(interrupt)
 956 .previous
 957
 958 /*
 959  * Interrupt entry/exit.
 960  *
 961  * Interrupt entry points save only callee clobbered registers in fast path.
 962  *
 963  * Entry runs with interrupts off.
 964  */
 965
 966 /* 0(%rsp): ~(interrupt number) */
 967         .macro interrupt func
 968         /* reserve pt_regs for scratch regs and rbp */
 969         subq $ORIG_RAX-RBP, %rsp
 970         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 971         SAVE_ARGS_IRQ
 972         call \func
 973         .endm
 974
 975         /*
 976          * The interrupt stubs push (~vector+0x80) onto the stack and
 977          * then jump to common_interrupt.
 978          */
 979         .p2align CONFIG_X86_L1_CACHE_SHIFT
 980 common_interrupt:
 981         XCPT_FRAME
 982         ASM_CLAC
 983         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 984         interrupt do_IRQ
 985         /* 0(%rsp): old_rsp-ARGOFFSET */
 986 ret_from_intr:
 987         DISABLE_INTERRUPTS(CLBR_NONE)
 988         TRACE_IRQS_OFF
 989         decl PER_CPU_VAR(irq_count)
 990
 991         /* Restore saved previous stack */
 992         popq %rsi
 993         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 994         leaq ARGOFFSET-RBP(%rsi), %rsp
 995         CFI_DEF_CFA_REGISTER    rsp
 996         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 997
 998 exit_intr:
 999         GET_THREAD_INFO(%rcx)
1000         testl $3,CS-ARGOFFSET(%rsp)
1001         je retint_kernel
1002
1003         /* Interrupt came from user space */
1004         /*
1005          * Has a correct top of stack, but a partial stack frame
1006          * %rcx: thread info. Interrupts off.
1007          */
1008 retint_with_reschedule:
1009         movl $_TIF_WORK_MASK,%edi
1010 retint_check:
1011         LOCKDEP_SYS_EXIT_IRQ
1012         movl TI_flags(%rcx),%edx
1013         andl %edi,%edx
1014         CFI_REMEMBER_STATE
1015         jnz  retint_careful
1016
1017 retint_swapgs:          /* return to user-space */
1018         /*
1019          * The iretq could re-enable interrupts:
1020          */
1021         DISABLE_INTERRUPTS(CLBR_ANY)
1022         TRACE_IRQS_IRETQ
1023         SWAPGS
1024         jmp restore_args
1025
1026 retint_restore_args:    /* return to kernel space */
1027         DISABLE_INTERRUPTS(CLBR_ANY)
1028         /*
1029          * The iretq could re-enable interrupts:
1030          */
1031         TRACE_IRQS_IRETQ
1032 restore_args:
1033         RESTORE_ARGS 1,8,1
1034
1035 irq_return:
1036         INTERRUPT_RETURN
1037         _ASM_EXTABLE(irq_return, bad_iret)
1038
1039 #ifdef CONFIG_PARAVIRT
1040 ENTRY(native_iret)
1041         iretq
1042         _ASM_EXTABLE(native_iret, bad_iret)
1043 #endif
1044
1045         .section .fixup,"ax"
1046 bad_iret:
1047         /*
1048          * The iret traps when the %cs or %ss being restored is bogus.
1049          * We've lost the original trap vector and error code.
1050          * #GPF is the most likely one to get for an invalid selector.
1051          * So pretend we completed the iret and took the #GPF in user mode.
1052          *
1053          * We are now running with the kernel GS after exception recovery.
1054          * But error_entry expects us to have user GS to match the user %cs,
1055          * so swap back.
1056          */
1057         pushq $0
1058
1059         SWAPGS
1060         jmp general_protection
1061
1062         .previous
1063
1064         /* edi: workmask, edx: work */
1065 retint_careful:
1066         CFI_RESTORE_STATE
1067         bt    $TIF_NEED_RESCHED,%edx
1068         jnc   retint_signal
1069         TRACE_IRQS_ON
1070         ENABLE_INTERRUPTS(CLBR_NONE)
1071         pushq_cfi %rdi
1072         SCHEDULE_USER
1073         popq_cfi %rdi
1074         GET_THREAD_INFO(%rcx)
1075         DISABLE_INTERRUPTS(CLBR_NONE)
1076         TRACE_IRQS_OFF
1077         jmp retint_check
1078
1079 retint_signal:
1080         testl $_TIF_DO_NOTIFY_MASK,%edx
1081         jz    retint_swapgs
1082         TRACE_IRQS_ON
1083         ENABLE_INTERRUPTS(CLBR_NONE)
1084         SAVE_REST
1085         movq $-1,ORIG_RAX(%rsp)
1086         xorl %esi,%esi          # oldset
1087         movq %rsp,%rdi          # &pt_regs
1088         call do_notify_resume
1089         RESTORE_REST
1090         DISABLE_INTERRUPTS(CLBR_NONE)
1091         TRACE_IRQS_OFF
1092         GET_THREAD_INFO(%rcx)
1093         jmp retint_with_reschedule
1094
1095 #ifdef CONFIG_PREEMPT
1096         /* Returning to kernel space. Check if we need preemption */
1097         /* rcx:  threadinfo. interrupts off. */
1098 ENTRY(retint_kernel)
1099         cmpl $0,PER_CPU_VAR(__preempt_count)
1100         jnz  retint_restore_args
1101         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1102         jnc  retint_restore_args
1103         call preempt_schedule_irq
1104         jmp exit_intr
1105 #endif
1106
1107         CFI_ENDPROC
1108 END(common_interrupt)
1109
1110 /*
1111  * APIC interrupts.
1112  */
1113 .macro apicinterrupt3 num sym do_sym
1114 ENTRY(\sym)
1115         INTR_FRAME
1116         ASM_CLAC
1117         pushq_cfi $~(\num)
1118 .Lcommon_\sym:
1119         interrupt \do_sym
1120         jmp ret_from_intr
1121         CFI_ENDPROC
1122 END(\sym)
1123 .endm
1124
1125 #ifdef CONFIG_TRACING
1126 #define trace(sym) trace_##sym
1127 #define smp_trace(sym) smp_trace_##sym
1128
1129 .macro trace_apicinterrupt num sym
1130 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
1131 .endm
1132 #else
1133 .macro trace_apicinterrupt num sym do_sym
1134 .endm
1135 #endif
1136
1137 .macro apicinterrupt num sym do_sym
1138 apicinterrupt3 \num \sym \do_sym
1139 trace_apicinterrupt \num \sym
1140 .endm
1141
1142 #ifdef CONFIG_SMP
1143 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
1144         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1145 apicinterrupt3 REBOOT_VECTOR \
1146         reboot_interrupt smp_reboot_interrupt
1147 #endif
1148
1149 #ifdef CONFIG_X86_UV
1150 apicinterrupt3 UV_BAU_MESSAGE \
1151         uv_bau_message_intr1 uv_bau_message_interrupt
1152 #endif
1153 apicinterrupt LOCAL_TIMER_VECTOR \
1154         apic_timer_interrupt smp_apic_timer_interrupt
1155 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1156         x86_platform_ipi smp_x86_platform_ipi
1157
1158 #ifdef CONFIG_HAVE_KVM
1159 apicinterrupt3 POSTED_INTR_VECTOR \
1160         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1161 #endif
1162
1163 #ifdef CONFIG_X86_MCE_THRESHOLD
1164 apicinterrupt THRESHOLD_APIC_VECTOR \
1165         threshold_interrupt smp_threshold_interrupt
1166 #endif
1167
1168 #ifdef CONFIG_X86_THERMAL_VECTOR
1169 apicinterrupt THERMAL_APIC_VECTOR \
1170         thermal_interrupt smp_thermal_interrupt
1171 #endif
1172
1173 #ifdef CONFIG_SMP
1174 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1175         call_function_single_interrupt smp_call_function_single_interrupt
1176 apicinterrupt CALL_FUNCTION_VECTOR \
1177         call_function_interrupt smp_call_function_interrupt
1178 apicinterrupt RESCHEDULE_VECTOR \
1179         reschedule_interrupt smp_reschedule_interrupt
1180 #endif
1181
1182 apicinterrupt ERROR_APIC_VECTOR \
1183         error_interrupt smp_error_interrupt
1184 apicinterrupt SPURIOUS_APIC_VECTOR \
1185         spurious_interrupt smp_spurious_interrupt
1186
1187 #ifdef CONFIG_IRQ_WORK
1188 apicinterrupt IRQ_WORK_VECTOR \
1189         irq_work_interrupt smp_irq_work_interrupt
1190 #endif
1191
1192 /*
1193  * Exception entry points.
1194  */
1195 .macro zeroentry sym do_sym
1196 ENTRY(\sym)
1197         INTR_FRAME
1198         ASM_CLAC
1199         PARAVIRT_ADJUST_EXCEPTION_FRAME
1200         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1201         subq $ORIG_RAX-R15, %rsp
1202         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1203         call error_entry
1204         DEFAULT_FRAME 0
1205         movq %rsp,%rdi          /* pt_regs pointer */
1206         xorl %esi,%esi          /* no error code */
1207         call \do_sym
1208         jmp error_exit          /* %ebx: no swapgs flag */
1209         CFI_ENDPROC
1210 END(\sym)
1211 .endm
1212
1213 .macro paranoidzeroentry sym do_sym
1214 ENTRY(\sym)
1215         INTR_FRAME
1216         ASM_CLAC
1217         PARAVIRT_ADJUST_EXCEPTION_FRAME
1218         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1219         subq $ORIG_RAX-R15, %rsp
1220         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1221         call save_paranoid
1222         TRACE_IRQS_OFF
1223         movq %rsp,%rdi          /* pt_regs pointer */
1224         xorl %esi,%esi          /* no error code */
1225         call \do_sym
1226         jmp paranoid_exit       /* %ebx: no swapgs flag */
1227         CFI_ENDPROC
1228 END(\sym)
1229 .endm
1230
1231 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1232 .macro paranoidzeroentry_ist sym do_sym ist
1233 ENTRY(\sym)
1234         INTR_FRAME
1235         ASM_CLAC
1236         PARAVIRT_ADJUST_EXCEPTION_FRAME
1237         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1238         subq $ORIG_RAX-R15, %rsp
1239         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1240         call save_paranoid
1241         TRACE_IRQS_OFF_DEBUG
1242         movq %rsp,%rdi          /* pt_regs pointer */
1243         xorl %esi,%esi          /* no error code */
1244         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1245         call \do_sym
1246         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1247         jmp paranoid_exit       /* %ebx: no swapgs flag */
1248         CFI_ENDPROC
1249 END(\sym)
1250 .endm
1251
1252 .macro errorentry sym do_sym
1253 ENTRY(\sym)
1254         XCPT_FRAME
1255         ASM_CLAC
1256         PARAVIRT_ADJUST_EXCEPTION_FRAME
1257         subq $ORIG_RAX-R15, %rsp
1258         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1259         call error_entry
1260         DEFAULT_FRAME 0
1261         movq %rsp,%rdi                  /* pt_regs pointer */
1262         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1263         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1264         call \do_sym
1265         jmp error_exit                  /* %ebx: no swapgs flag */
1266         CFI_ENDPROC
1267 END(\sym)
1268 .endm
1269
1270 #ifdef CONFIG_TRACING
1271 .macro trace_errorentry sym do_sym
1272 errorentry trace(\sym) trace(\do_sym)
1273 errorentry \sym \do_sym
1274 .endm
1275 #else
1276 .macro trace_errorentry sym do_sym
1277 errorentry \sym \do_sym
1278 .endm
1279 #endif
1280
1281         /* error code is on the stack already */
1282 .macro paranoiderrorentry sym do_sym
1283 ENTRY(\sym)
1284         XCPT_FRAME
1285         ASM_CLAC
1286         PARAVIRT_ADJUST_EXCEPTION_FRAME
1287         subq $ORIG_RAX-R15, %rsp
1288         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1289         call save_paranoid
1290         DEFAULT_FRAME 0
1291         TRACE_IRQS_OFF
1292         movq %rsp,%rdi                  /* pt_regs pointer */
1293         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1294         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1295         call \do_sym
1296         jmp paranoid_exit               /* %ebx: no swapgs flag */
1297         CFI_ENDPROC
1298 END(\sym)
1299 .endm
1300
1301 zeroentry divide_error do_divide_error
1302 zeroentry overflow do_overflow
1303 zeroentry bounds do_bounds
1304 zeroentry invalid_op do_invalid_op
1305 zeroentry device_not_available do_device_not_available
1306 paranoiderrorentry double_fault do_double_fault
1307 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1308 errorentry invalid_TSS do_invalid_TSS
1309 errorentry segment_not_present do_segment_not_present
1310 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1311 zeroentry coprocessor_error do_coprocessor_error
1312 errorentry alignment_check do_alignment_check
1313 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1314
1315
1316         /* Reload gs selector with exception handling */
1317         /* edi:  new selector */
1318 ENTRY(native_load_gs_index)
1319         CFI_STARTPROC
1320         pushfq_cfi
1321         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1322         SWAPGS
1323 gs_change:
1324         movl %edi,%gs
1325 2:      mfence          /* workaround */
1326         SWAPGS
1327         popfq_cfi
1328         ret
1329         CFI_ENDPROC
1330 END(native_load_gs_index)
1331
1332         _ASM_EXTABLE(gs_change,bad_gs)
1333         .section .fixup,"ax"
1334         /* running with kernelgs */
1335 bad_gs:
1336         SWAPGS                  /* switch back to user gs */
1337         xorl %eax,%eax
1338         movl %eax,%gs
1339         jmp  2b
1340         .previous
1341
1342 /* Call softirq on interrupt stack. Interrupts are off. */
1343 ENTRY(do_softirq_own_stack)
1344         CFI_STARTPROC
1345         pushq_cfi %rbp
1346         CFI_REL_OFFSET rbp,0
1347         mov  %rsp,%rbp
1348         CFI_DEF_CFA_REGISTER rbp
1349         incl PER_CPU_VAR(irq_count)
1350         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1351         push  %rbp                      # backlink for old unwinder
1352         call __do_softirq
1353         leaveq
1354         CFI_RESTORE             rbp
1355         CFI_DEF_CFA_REGISTER    rsp
1356         CFI_ADJUST_CFA_OFFSET   -8
1357         decl PER_CPU_VAR(irq_count)
1358         ret
1359         CFI_ENDPROC
1360 END(do_softirq_own_stack)
1361
1362 #ifdef CONFIG_XEN
1363 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1364
1365 /*
1366  * A note on the "critical region" in our callback handler.
1367  * We want to avoid stacking callback handlers due to events occurring
1368  * during handling of the last event. To do this, we keep events disabled
1369  * until we've done all processing. HOWEVER, we must enable events before
1370  * popping the stack frame (can't be done atomically) and so it would still
1371  * be possible to get enough handler activations to overflow the stack.
1372  * Although unlikely, bugs of that kind are hard to track down, so we'd
1373  * like to avoid the possibility.
1374  * So, on entry to the handler we detect whether we interrupted an
1375  * existing activation in its critical region -- if so, we pop the current
1376  * activation and restart the handler using the previous one.
1377  */
1378 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1379         CFI_STARTPROC
1380 /*
1381  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1382  * see the correct pointer to the pt_regs
1383  */
1384         movq %rdi, %rsp            # we don't return, adjust the stack frame
1385         CFI_ENDPROC
1386         DEFAULT_FRAME
1387 11:     incl PER_CPU_VAR(irq_count)
1388         movq %rsp,%rbp
1389         CFI_DEF_CFA_REGISTER rbp
1390         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1391         pushq %rbp                      # backlink for old unwinder
1392         call xen_evtchn_do_upcall
1393         popq %rsp
1394         CFI_DEF_CFA_REGISTER rsp
1395         decl PER_CPU_VAR(irq_count)
1396         jmp  error_exit
1397         CFI_ENDPROC
1398 END(xen_do_hypervisor_callback)
1399
1400 /*
1401  * Hypervisor uses this for application faults while it executes.
1402  * We get here for two reasons:
1403  *  1. Fault while reloading DS, ES, FS or GS
1404  *  2. Fault while executing IRET
1405  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1406  * registers that could be reloaded and zeroed the others.
1407  * Category 2 we fix up by killing the current process. We cannot use the
1408  * normal Linux return path in this case because if we use the IRET hypercall
1409  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1410  * We distinguish between categories by comparing each saved segment register
1411  * with its current contents: any discrepancy means we in category 1.
1412  */
1413 ENTRY(xen_failsafe_callback)
1414         INTR_FRAME 1 (6*8)
1415         /*CFI_REL_OFFSET gs,GS*/
1416         /*CFI_REL_OFFSET fs,FS*/
1417         /*CFI_REL_OFFSET es,ES*/
1418         /*CFI_REL_OFFSET ds,DS*/
1419         CFI_REL_OFFSET r11,8
1420         CFI_REL_OFFSET rcx,0
1421         movw %ds,%cx
1422         cmpw %cx,0x10(%rsp)
1423         CFI_REMEMBER_STATE
1424         jne 1f
1425         movw %es,%cx
1426         cmpw %cx,0x18(%rsp)
1427         jne 1f
1428         movw %fs,%cx
1429         cmpw %cx,0x20(%rsp)
1430         jne 1f
1431         movw %gs,%cx
1432         cmpw %cx,0x28(%rsp)
1433         jne 1f
1434         /* All segments match their saved values => Category 2 (Bad IRET). */
1435         movq (%rsp),%rcx
1436         CFI_RESTORE rcx
1437         movq 8(%rsp),%r11
1438         CFI_RESTORE r11
1439         addq $0x30,%rsp
1440         CFI_ADJUST_CFA_OFFSET -0x30
1441         pushq_cfi $0    /* RIP */
1442         pushq_cfi %r11
1443         pushq_cfi %rcx
1444         jmp general_protection
1445         CFI_RESTORE_STATE
1446 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1447         movq (%rsp),%rcx
1448         CFI_RESTORE rcx
1449         movq 8(%rsp),%r11
1450         CFI_RESTORE r11
1451         addq $0x30,%rsp
1452         CFI_ADJUST_CFA_OFFSET -0x30
1453         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1454         SAVE_ALL
1455         jmp error_exit
1456         CFI_ENDPROC
1457 END(xen_failsafe_callback)
1458
1459 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1460         xen_hvm_callback_vector xen_evtchn_do_upcall
1461
1462 #endif /* CONFIG_XEN */
1463
1464 #if IS_ENABLED(CONFIG_HYPERV)
1465 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1466         hyperv_callback_vector hyperv_vector_handler
1467 #endif /* CONFIG_HYPERV */
1468
1469 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1470 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1471 paranoiderrorentry stack_segment do_stack_segment
1472 #ifdef CONFIG_XEN
1473 zeroentry xen_debug do_debug
1474 zeroentry xen_int3 do_int3
1475 errorentry xen_stack_segment do_stack_segment
1476 #endif
1477 errorentry general_protection do_general_protection
1478 trace_errorentry page_fault do_page_fault
1479 #ifdef CONFIG_KVM_GUEST
1480 errorentry async_page_fault do_async_page_fault
1481 #endif
1482 #ifdef CONFIG_X86_MCE
1483 paranoidzeroentry machine_check *machine_check_vector(%rip)
1484 #endif
1485
1486         /*
1487          * "Paranoid" exit path from exception stack.
1488          * Paranoid because this is used by NMIs and cannot take
1489          * any kernel state for granted.
1490          * We don't do kernel preemption checks here, because only
1491          * NMI should be common and it does not enable IRQs and
1492          * cannot get reschedule ticks.
1493          *
1494          * "trace" is 0 for the NMI handler only, because irq-tracing
1495          * is fundamentally NMI-unsafe. (we cannot change the soft and
1496          * hard flags at once, atomically)
1497          */
1498
1499         /* ebx: no swapgs flag */
1500 ENTRY(paranoid_exit)
1501         DEFAULT_FRAME
1502         DISABLE_INTERRUPTS(CLBR_NONE)
1503         TRACE_IRQS_OFF_DEBUG
1504         testl %ebx,%ebx                         /* swapgs needed? */
1505         jnz paranoid_restore
1506         testl $3,CS(%rsp)
1507         jnz   paranoid_userspace
1508 paranoid_swapgs:
1509         TRACE_IRQS_IRETQ 0
1510         SWAPGS_UNSAFE_STACK
1511         RESTORE_ALL 8
1512         jmp irq_return
1513 paranoid_restore:
1514         TRACE_IRQS_IRETQ_DEBUG 0
1515         RESTORE_ALL 8
1516         jmp irq_return
1517 paranoid_userspace:
1518         GET_THREAD_INFO(%rcx)
1519         movl TI_flags(%rcx),%ebx
1520         andl $_TIF_WORK_MASK,%ebx
1521         jz paranoid_swapgs
1522         movq %rsp,%rdi                  /* &pt_regs */
1523         call sync_regs
1524         movq %rax,%rsp                  /* switch stack for scheduling */
1525         testl $_TIF_NEED_RESCHED,%ebx
1526         jnz paranoid_schedule
1527         movl %ebx,%edx                  /* arg3: thread flags */
1528         TRACE_IRQS_ON
1529         ENABLE_INTERRUPTS(CLBR_NONE)
1530         xorl %esi,%esi                  /* arg2: oldset */
1531         movq %rsp,%rdi                  /* arg1: &pt_regs */
1532         call do_notify_resume
1533         DISABLE_INTERRUPTS(CLBR_NONE)
1534         TRACE_IRQS_OFF
1535         jmp paranoid_userspace
1536 paranoid_schedule:
1537         TRACE_IRQS_ON
1538         ENABLE_INTERRUPTS(CLBR_ANY)
1539         SCHEDULE_USER
1540         DISABLE_INTERRUPTS(CLBR_ANY)
1541         TRACE_IRQS_OFF
1542         jmp paranoid_userspace
1543         CFI_ENDPROC
1544 END(paranoid_exit)
1545
1546 /*
1547  * Exception entry point. This expects an error code/orig_rax on the stack.
1548  * returns in "no swapgs flag" in %ebx.
1549  */
1550 ENTRY(error_entry)
1551         XCPT_FRAME
1552         CFI_ADJUST_CFA_OFFSET 15*8
1553         /* oldrax contains error code */
1554         cld
1555         movq_cfi rdi, RDI+8
1556         movq_cfi rsi, RSI+8
1557         movq_cfi rdx, RDX+8
1558         movq_cfi rcx, RCX+8
1559         movq_cfi rax, RAX+8
1560         movq_cfi  r8,  R8+8
1561         movq_cfi  r9,  R9+8
1562         movq_cfi r10, R10+8
1563         movq_cfi r11, R11+8
1564         movq_cfi rbx, RBX+8
1565         movq_cfi rbp, RBP+8
1566         movq_cfi r12, R12+8
1567         movq_cfi r13, R13+8
1568         movq_cfi r14, R14+8
1569         movq_cfi r15, R15+8
1570         xorl %ebx,%ebx
1571         testl $3,CS+8(%rsp)
1572         je error_kernelspace
1573 error_swapgs:
1574         SWAPGS
1575 error_sti:
1576         TRACE_IRQS_OFF
1577         ret
1578
1579 /*
1580  * There are two places in the kernel that can potentially fault with
1581  * usergs. Handle them here. The exception handlers after iret run with
1582  * kernel gs again, so don't set the user space flag. B stepping K8s
1583  * sometimes report an truncated RIP for IRET exceptions returning to
1584  * compat mode. Check for these here too.
1585  */
1586 error_kernelspace:
1587         incl %ebx
1588         leaq irq_return(%rip),%rcx
1589         cmpq %rcx,RIP+8(%rsp)
1590         je error_swapgs
1591         movl %ecx,%eax  /* zero extend */
1592         cmpq %rax,RIP+8(%rsp)
1593         je bstep_iret
1594         cmpq $gs_change,RIP+8(%rsp)
1595         je error_swapgs
1596         jmp error_sti
1597
1598 bstep_iret:
1599         /* Fix truncated RIP */
1600         movq %rcx,RIP+8(%rsp)
1601         jmp error_swapgs
1602         CFI_ENDPROC
1603 END(error_entry)
1604
1605
1606 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1607 ENTRY(error_exit)
1608         DEFAULT_FRAME
1609         movl %ebx,%eax
1610         RESTORE_REST
1611         DISABLE_INTERRUPTS(CLBR_NONE)
1612         TRACE_IRQS_OFF
1613         GET_THREAD_INFO(%rcx)
1614         testl %eax,%eax
1615         jne retint_kernel
1616         LOCKDEP_SYS_EXIT_IRQ
1617         movl TI_flags(%rcx),%edx
1618         movl $_TIF_WORK_MASK,%edi
1619         andl %edi,%edx
1620         jnz retint_careful
1621         jmp retint_swapgs
1622         CFI_ENDPROC
1623 END(error_exit)
1624
1625 /*
1626  * Test if a given stack is an NMI stack or not.
1627  */
1628         .macro test_in_nmi reg stack nmi_ret normal_ret
1629         cmpq %\reg, \stack
1630         ja \normal_ret
1631         subq $EXCEPTION_STKSZ, %\reg
1632         cmpq %\reg, \stack
1633         jb \normal_ret
1634         jmp \nmi_ret
1635         .endm
1636
1637         /* runs on exception stack */
1638 ENTRY(nmi)
1639         INTR_FRAME
1640         PARAVIRT_ADJUST_EXCEPTION_FRAME
1641         /*
1642          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1643          * the iretq it performs will take us out of NMI context.
1644          * This means that we can have nested NMIs where the next
1645          * NMI is using the top of the stack of the previous NMI. We
1646          * can't let it execute because the nested NMI will corrupt the
1647          * stack of the previous NMI. NMI handlers are not re-entrant
1648          * anyway.
1649          *
1650          * To handle this case we do the following:
1651          *  Check the a special location on the stack that contains
1652          *  a variable that is set when NMIs are executing.
1653          *  The interrupted task's stack is also checked to see if it
1654          *  is an NMI stack.
1655          *  If the variable is not set and the stack is not the NMI
1656          *  stack then:
1657          *    o Set the special variable on the stack
1658          *    o Copy the interrupt frame into a "saved" location on the stack
1659          *    o Copy the interrupt frame into a "copy" location on the stack
1660          *    o Continue processing the NMI
1661          *  If the variable is set or the previous stack is the NMI stack:
1662          *    o Modify the "copy" location to jump to the repeate_nmi
1663          *    o return back to the first NMI
1664          *
1665          * Now on exit of the first NMI, we first clear the stack variable
1666          * The NMI stack will tell any nested NMIs at that point that it is
1667          * nested. Then we pop the stack normally with iret, and if there was
1668          * a nested NMI that updated the copy interrupt stack frame, a
1669          * jump will be made to the repeat_nmi code that will handle the second
1670          * NMI.
1671          */
1672
1673         /* Use %rdx as out temp variable throughout */
1674         pushq_cfi %rdx
1675         CFI_REL_OFFSET rdx, 0
1676
1677         /*
1678          * If %cs was not the kernel segment, then the NMI triggered in user
1679          * space, which means it is definitely not nested.
1680          */
1681         cmpl $__KERNEL_CS, 16(%rsp)
1682         jne first_nmi
1683
1684         /*
1685          * Check the special variable on the stack to see if NMIs are
1686          * executing.
1687          */
1688         cmpl $1, -8(%rsp)
1689         je nested_nmi
1690
1691         /*
1692          * Now test if the previous stack was an NMI stack.
1693          * We need the double check. We check the NMI stack to satisfy the
1694          * race when the first NMI clears the variable before returning.
1695          * We check the variable because the first NMI could be in a
1696          * breakpoint routine using a breakpoint stack.
1697          */
1698         lea 6*8(%rsp), %rdx
1699         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1700         CFI_REMEMBER_STATE
1701
1702 nested_nmi:
1703         /*
1704          * Do nothing if we interrupted the fixup in repeat_nmi.
1705          * It's about to repeat the NMI handler, so we are fine
1706          * with ignoring this one.
1707          */
1708         movq $repeat_nmi, %rdx
1709         cmpq 8(%rsp), %rdx
1710         ja 1f
1711         movq $end_repeat_nmi, %rdx
1712         cmpq 8(%rsp), %rdx
1713         ja nested_nmi_out
1714
1715 1:
1716         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1717         leaq -1*8(%rsp), %rdx
1718         movq %rdx, %rsp
1719         CFI_ADJUST_CFA_OFFSET 1*8
1720         leaq -10*8(%rsp), %rdx
1721         pushq_cfi $__KERNEL_DS
1722         pushq_cfi %rdx
1723         pushfq_cfi
1724         pushq_cfi $__KERNEL_CS
1725         pushq_cfi $repeat_nmi
1726
1727         /* Put stack back */
1728         addq $(6*8), %rsp
1729         CFI_ADJUST_CFA_OFFSET -6*8
1730
1731 nested_nmi_out:
1732         popq_cfi %rdx
1733         CFI_RESTORE rdx
1734
1735         /* No need to check faults here */
1736         INTERRUPT_RETURN
1737
1738         CFI_RESTORE_STATE
1739 first_nmi:
1740         /*
1741          * Because nested NMIs will use the pushed location that we
1742          * stored in rdx, we must keep that space available.
1743          * Here's what our stack frame will look like:
1744          * +-------------------------+
1745          * | original SS             |
1746          * | original Return RSP     |
1747          * | original RFLAGS         |
1748          * | original CS             |
1749          * | original RIP            |
1750          * +-------------------------+
1751          * | temp storage for rdx    |
1752          * +-------------------------+
1753          * | NMI executing variable  |
1754          * +-------------------------+
1755          * | copied SS               |
1756          * | copied Return RSP       |
1757          * | copied RFLAGS           |
1758          * | copied CS               |
1759          * | copied RIP              |
1760          * +-------------------------+
1761          * | Saved SS                |
1762          * | Saved Return RSP        |
1763          * | Saved RFLAGS            |
1764          * | Saved CS                |
1765          * | Saved RIP               |
1766          * +-------------------------+
1767          * | pt_regs                 |
1768          * +-------------------------+
1769          *
1770          * The saved stack frame is used to fix up the copied stack frame
1771          * that a nested NMI may change to make the interrupted NMI iret jump
1772          * to the repeat_nmi. The original stack frame and the temp storage
1773          * is also used by nested NMIs and can not be trusted on exit.
1774          */
1775         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1776         movq (%rsp), %rdx
1777         CFI_RESTORE rdx
1778
1779         /* Set the NMI executing variable on the stack. */
1780         pushq_cfi $1
1781
1782         /*
1783          * Leave room for the "copied" frame
1784          */
1785         subq $(5*8), %rsp
1786         CFI_ADJUST_CFA_OFFSET 5*8
1787
1788         /* Copy the stack frame to the Saved frame */
1789         .rept 5
1790         pushq_cfi 11*8(%rsp)
1791         .endr
1792         CFI_DEF_CFA_OFFSET SS+8-RIP
1793
1794         /* Everything up to here is safe from nested NMIs */
1795
1796         /*
1797          * If there was a nested NMI, the first NMI's iret will return
1798          * here. But NMIs are still enabled and we can take another
1799          * nested NMI. The nested NMI checks the interrupted RIP to see
1800          * if it is between repeat_nmi and end_repeat_nmi, and if so
1801          * it will just return, as we are about to repeat an NMI anyway.
1802          * This makes it safe to copy to the stack frame that a nested
1803          * NMI will update.
1804          */
1805 repeat_nmi:
1806         /*
1807          * Update the stack variable to say we are still in NMI (the update
1808          * is benign for the non-repeat case, where 1 was pushed just above
1809          * to this very stack slot).
1810          */
1811         movq $1, 10*8(%rsp)
1812
1813         /* Make another copy, this one may be modified by nested NMIs */
1814         addq $(10*8), %rsp
1815         CFI_ADJUST_CFA_OFFSET -10*8
1816         .rept 5
1817         pushq_cfi -6*8(%rsp)
1818         .endr
1819         subq $(5*8), %rsp
1820         CFI_DEF_CFA_OFFSET SS+8-RIP
1821 end_repeat_nmi:
1822
1823         /*
1824          * Everything below this point can be preempted by a nested
1825          * NMI if the first NMI took an exception and reset our iret stack
1826          * so that we repeat another NMI.
1827          */
1828         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1829         subq $ORIG_RAX-R15, %rsp
1830         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1831         /*
1832          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1833          * as we should not be calling schedule in NMI context.
1834          * Even with normal interrupts enabled. An NMI should not be
1835          * setting NEED_RESCHED or anything that normal interrupts and
1836          * exceptions might do.
1837          */
1838         call save_paranoid
1839         DEFAULT_FRAME 0
1840
1841         /*
1842          * Save off the CR2 register. If we take a page fault in the NMI then
1843          * it could corrupt the CR2 value. If the NMI preempts a page fault
1844          * handler before it was able to read the CR2 register, and then the
1845          * NMI itself takes a page fault, the page fault that was preempted
1846          * will read the information from the NMI page fault and not the
1847          * origin fault. Save it off and restore it if it changes.
1848          * Use the r12 callee-saved register.
1849          */
1850         movq %cr2, %r12
1851
1852         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1853         movq %rsp,%rdi
1854         movq $-1,%rsi
1855         call do_nmi
1856
1857         /* Did the NMI take a page fault? Restore cr2 if it did */
1858         movq %cr2, %rcx
1859         cmpq %rcx, %r12
1860         je 1f
1861         movq %r12, %cr2
1862 1:
1863
1864         testl %ebx,%ebx                         /* swapgs needed? */
1865         jnz nmi_restore
1866 nmi_swapgs:
1867         SWAPGS_UNSAFE_STACK
1868 nmi_restore:
1869         /* Pop the extra iret frame at once */
1870         RESTORE_ALL 6*8
1871
1872         /* Clear the NMI executing stack variable */
1873         movq $0, 5*8(%rsp)
1874         jmp irq_return
1875         CFI_ENDPROC
1876 END(nmi)
1877
1878 ENTRY(ignore_sysret)
1879         CFI_STARTPROC
1880         mov $-ENOSYS,%eax
1881         sysret
1882         CFI_ENDPROC
1883 END(ignore_sysret)
1884