1 /* SPDX-License-Identifier: GPL-2.0 */
3 * linux/arch/x86_64/entry.S
5 * Copyright (C) 1991, 1992 Linus Torvalds
6 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
7 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
9 * entry.S contains the system-call and fault low-level handling routines.
11 * Some of this is documented in Documentation/x86/entry_64.txt
13 * A note on terminology:
14 * - iret frame: Architecture defined interrupt frame from SS to RIP
15 * at the top of the kernel process stack.
18 * - ENTRY/END: Define functions in the symbol table.
19 * - TRACE_IRQ_*: Trace hardirq state for lock debugging.
20 * - idtentry: Define exception entry points.
22 #include <linux/linkage.h>
23 #include <asm/segment.h>
24 #include <asm/cache.h>
25 #include <asm/errno.h>
26 #include <asm/asm-offsets.h>
28 #include <asm/unistd.h>
29 #include <asm/thread_info.h>
30 #include <asm/hw_irq.h>
31 #include <asm/page_types.h>
32 #include <asm/irqflags.h>
33 #include <asm/paravirt.h>
34 #include <asm/percpu.h>
37 #include <asm/pgtable_types.h>
38 #include <asm/export.h>
39 #include <asm/frame.h>
40 #include <asm/nospec-branch.h>
41 #include <linux/err.h>
46 .section .entry.text, "ax"
48 #ifdef CONFIG_PARAVIRT
49 ENTRY(native_usergs_sysret64)
53 END(native_usergs_sysret64)
54 #endif /* CONFIG_PARAVIRT */
56 .macro TRACE_IRQS_FLAGS flags:req
57 #ifdef CONFIG_TRACE_IRQFLAGS
58 bt $9, \flags /* interrupts off? */
65 .macro TRACE_IRQS_IRETQ
66 TRACE_IRQS_FLAGS EFLAGS(%rsp)
70 * When dynamic function tracer is enabled it will add a breakpoint
71 * to all locations that it is about to modify, sync CPUs, update
72 * all the code, sync CPUs, then remove the breakpoints. In this time
73 * if lockdep is enabled, it might jump back into the debug handler
74 * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
76 * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
77 * make sure the stack pointer does not get reset back to the top
78 * of the debug stack, and instead just reuses the current stack.
80 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
82 .macro TRACE_IRQS_OFF_DEBUG
83 call debug_stack_set_zero
85 call debug_stack_reset
88 .macro TRACE_IRQS_ON_DEBUG
89 call debug_stack_set_zero
91 call debug_stack_reset
94 .macro TRACE_IRQS_IRETQ_DEBUG
95 bt $9, EFLAGS(%rsp) /* interrupts off? */
102 # define TRACE_IRQS_OFF_DEBUG TRACE_IRQS_OFF
103 # define TRACE_IRQS_ON_DEBUG TRACE_IRQS_ON
104 # define TRACE_IRQS_IRETQ_DEBUG TRACE_IRQS_IRETQ
108 * 64-bit SYSCALL instruction entry. Up to 6 arguments in registers.
110 * This is the only entry point used for 64-bit system calls. The
111 * hardware interface is reasonably well designed and the register to
112 * argument mapping Linux uses fits well with the registers that are
113 * available when SYSCALL is used.
115 * SYSCALL instructions can be found inlined in libc implementations as
116 * well as some other programs and libraries. There are also a handful
117 * of SYSCALL instructions in the vDSO used, for example, as a
118 * clock_gettimeofday fallback.
120 * 64-bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
121 * then loads new ss, cs, and rip from previously programmed MSRs.
122 * rflags gets masked by a value from another MSR (so CLD and CLAC
123 * are not needed). SYSCALL does not save anything on the stack
124 * and does not change rsp.
126 * Registers on entry:
127 * rax system call number
129 * r11 saved rflags (note: r11 is callee-clobbered register in C ABI)
133 * r10 arg3 (needs to be moved to rcx to conform to C ABI)
136 * (note: r12-r15, rbp, rbx are callee-preserved in C ABI)
138 * Only called from user space.
140 * When user can change pt_regs->foo always force IRET. That is because
141 * it deals with uncanonical addresses better. SYSRET has trouble
142 * with them due to bugs in both AMD and Intel CPUs.
145 .pushsection .entry_trampoline, "ax"
148 * The code in here gets remapped into cpu_entry_area's trampoline. This means
149 * that the assembler and linker have the wrong idea as to where this code
150 * lives (and, in fact, it's mapped more than once, so it's not even at a
151 * fixed address). So we can't reference any symbols outside the entry
152 * trampoline and expect it to work.
154 * Instead, we carefully abuse %rip-relative addressing.
155 * _entry_trampoline(%rip) refers to the start of the remapped) entry
156 * trampoline. We can thus find cpu_entry_area with this macro:
159 #define CPU_ENTRY_AREA \
160 _entry_trampoline - CPU_ENTRY_AREA_entry_trampoline(%rip)
162 /* The top word of the SYSENTER stack is hot and is usable as scratch space. */
163 #define RSP_SCRATCH CPU_ENTRY_AREA_entry_stack + \
164 SIZEOF_entry_stack - 8 + CPU_ENTRY_AREA
166 ENTRY(entry_SYSCALL_64_trampoline)
170 /* Stash the user RSP. */
171 movq %rsp, RSP_SCRATCH
173 /* Note: using %rsp as a scratch reg. */
174 SWITCH_TO_KERNEL_CR3 scratch_reg=%rsp
176 /* Load the top of the task stack into RSP */
177 movq CPU_ENTRY_AREA_tss + TSS_sp1 + CPU_ENTRY_AREA, %rsp
179 /* Start building the simulated IRET frame. */
180 pushq $__USER_DS /* pt_regs->ss */
181 pushq RSP_SCRATCH /* pt_regs->sp */
182 pushq %r11 /* pt_regs->flags */
183 pushq $__USER_CS /* pt_regs->cs */
184 pushq %rcx /* pt_regs->ip */
187 * x86 lacks a near absolute jump, and we can't jump to the real
188 * entry text with a relative jump. We could push the target
189 * address and then use retq, but this destroys the pipeline on
190 * many CPUs (wasting over 20 cycles on Sandy Bridge). Instead,
191 * spill RDI and restore it in a second-stage trampoline.
194 movq $entry_SYSCALL_64_stage2, %rdi
196 END(entry_SYSCALL_64_trampoline)
200 ENTRY(entry_SYSCALL_64_stage2)
203 jmp entry_SYSCALL_64_after_hwframe
204 END(entry_SYSCALL_64_stage2)
206 ENTRY(entry_SYSCALL_64)
209 * Interrupts are off on entry.
210 * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
211 * it is too small to ever cause noticeable irq latency.
216 * This path is not taken when PAGE_TABLE_ISOLATION is disabled so it
217 * is not required to switch CR3.
219 movq %rsp, PER_CPU_VAR(rsp_scratch)
220 movq PER_CPU_VAR(cpu_current_top_of_stack), %rsp
222 /* Construct struct pt_regs on stack */
223 pushq $__USER_DS /* pt_regs->ss */
224 pushq PER_CPU_VAR(rsp_scratch) /* pt_regs->sp */
225 pushq %r11 /* pt_regs->flags */
226 pushq $__USER_CS /* pt_regs->cs */
227 pushq %rcx /* pt_regs->ip */
228 GLOBAL(entry_SYSCALL_64_after_hwframe)
229 pushq %rax /* pt_regs->orig_ax */
230 pushq %rdi /* pt_regs->di */
231 pushq %rsi /* pt_regs->si */
232 pushq %rdx /* pt_regs->dx */
233 pushq %rcx /* pt_regs->cx */
234 pushq $-ENOSYS /* pt_regs->ax */
235 pushq %r8 /* pt_regs->r8 */
236 pushq %r9 /* pt_regs->r9 */
237 pushq %r10 /* pt_regs->r10 */
238 pushq %r11 /* pt_regs->r11 */
239 sub $(6*8), %rsp /* pt_regs->bp, bx, r12-15 not saved */
240 UNWIND_HINT_REGS extra=0
245 * If we need to do entry work or if we guess we'll need to do
246 * exit work, go straight to the slow path.
248 movq PER_CPU_VAR(current_task), %r11
249 testl $_TIF_WORK_SYSCALL_ENTRY|_TIF_ALLWORK_MASK, TASK_TI_flags(%r11)
250 jnz entry_SYSCALL64_slow_path
252 entry_SYSCALL_64_fastpath:
254 * Easy case: enable interrupts and issue the syscall. If the syscall
255 * needs pt_regs, we'll call a stub that disables interrupts again
256 * and jumps to the slow path.
259 ENABLE_INTERRUPTS(CLBR_NONE)
260 #if __SYSCALL_MASK == ~0
261 cmpq $__NR_syscall_max, %rax
263 andl $__SYSCALL_MASK, %eax
264 cmpl $__NR_syscall_max, %eax
266 ja 1f /* return -ENOSYS (already in pt_regs->ax) */
270 * This call instruction is handled specially in stub_ptregs_64.
271 * It might end up jumping to the slow path. If it jumps, RAX
272 * and all argument registers are clobbered.
274 #ifdef CONFIG_RETPOLINE
275 movq sys_call_table(, %rax, 8), %rax
276 call __x86_indirect_thunk_rax
278 call *sys_call_table(, %rax, 8)
280 .Lentry_SYSCALL_64_after_fastpath_call:
286 * If we get here, then we know that pt_regs is clean for SYSRET64.
287 * If we see that no exit work is required (which we are required
288 * to check with IRQs off), then we can go straight to SYSRET64.
290 DISABLE_INTERRUPTS(CLBR_ANY)
292 movq PER_CPU_VAR(current_task), %r11
293 testl $_TIF_ALLWORK_MASK, TASK_TI_flags(%r11)
297 TRACE_IRQS_ON /* user mode is traced as IRQs on */
299 movq EFLAGS(%rsp), %r11
300 addq $6*8, %rsp /* skip extra regs -- they were preserved */
302 jmp .Lpop_c_regs_except_rcx_r11_and_sysret
306 * The fast path looked good when we started, but something changed
307 * along the way and we need to switch to the slow path. Calling
308 * raise(3) will trigger this, for example. IRQs are off.
311 ENABLE_INTERRUPTS(CLBR_ANY)
314 call syscall_return_slowpath /* returns with IRQs disabled */
315 jmp return_from_SYSCALL_64
317 entry_SYSCALL64_slow_path:
321 call do_syscall_64 /* returns with IRQs disabled */
323 return_from_SYSCALL_64:
324 TRACE_IRQS_IRETQ /* we're about to change IF */
327 * Try to use SYSRET instead of IRET if we're returning to
328 * a completely clean 64-bit userspace context. If we're not,
329 * go to the slow exit path.
334 cmpq %rcx, %r11 /* SYSRET requires RCX == RIP */
335 jne swapgs_restore_regs_and_return_to_usermode
338 * On Intel CPUs, SYSRET with non-canonical RCX/RIP will #GP
339 * in kernel space. This essentially lets the user take over
340 * the kernel, since userspace controls RSP.
342 * If width of "canonical tail" ever becomes variable, this will need
343 * to be updated to remain correct on both old and new CPUs.
345 * Change top bits to match most significant bit (47th or 56th bit
346 * depending on paging mode) in the address.
348 shl $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
349 sar $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
351 /* If this changed %rcx, it was not canonical */
353 jne swapgs_restore_regs_and_return_to_usermode
355 cmpq $__USER_CS, CS(%rsp) /* CS must match SYSRET */
356 jne swapgs_restore_regs_and_return_to_usermode
359 cmpq %r11, EFLAGS(%rsp) /* R11 == RFLAGS */
360 jne swapgs_restore_regs_and_return_to_usermode
363 * SYSCALL clears RF when it saves RFLAGS in R11 and SYSRET cannot
364 * restore RF properly. If the slowpath sets it for whatever reason, we
365 * need to restore it correctly.
367 * SYSRET can restore TF, but unlike IRET, restoring TF results in a
368 * trap from userspace immediately after SYSRET. This would cause an
369 * infinite loop whenever #DB happens with register state that satisfies
370 * the opportunistic SYSRET conditions. For example, single-stepping
373 * movq $stuck_here, %rcx
378 * would never get past 'stuck_here'.
380 testq $(X86_EFLAGS_RF|X86_EFLAGS_TF), %r11
381 jnz swapgs_restore_regs_and_return_to_usermode
383 /* nothing to check for RSP */
385 cmpq $__USER_DS, SS(%rsp) /* SS must match SYSRET */
386 jne swapgs_restore_regs_and_return_to_usermode
389 * We win! This label is here just for ease of understanding
390 * perf profiles. Nothing jumps here.
392 syscall_return_via_sysret:
393 /* rcx and r11 are already restored (see code above) */
396 .Lpop_c_regs_except_rcx_r11_and_sysret:
397 popq %rsi /* skip r11 */
402 popq %rsi /* skip rcx */
407 * Now all regs are restored except RSP and RDI.
408 * Save old stack pointer and switch to trampoline stack.
411 movq PER_CPU_VAR(cpu_tss_rw + TSS_sp0), %rsp
413 pushq RSP-RDI(%rdi) /* RSP */
414 pushq (%rdi) /* RDI */
417 * We are on the trampoline stack. All regs except RDI are live.
418 * We can do future final exit work right here.
420 SWITCH_TO_USER_CR3_STACK scratch_reg=%rdi
425 END(entry_SYSCALL_64)
427 ENTRY(stub_ptregs_64)
429 * Syscalls marked as needing ptregs land here.
430 * If we are on the fast path, we need to save the extra regs,
431 * which we achieve by trying again on the slow path. If we are on
432 * the slow path, the extra regs are already saved.
434 * RAX stores a pointer to the C function implementing the syscall.
437 cmpq $.Lentry_SYSCALL_64_after_fastpath_call, (%rsp)
441 * Called from fast path -- disable IRQs again, pop return address
442 * and jump to slow path
444 DISABLE_INTERRUPTS(CLBR_ANY)
447 UNWIND_HINT_REGS extra=0
448 jmp entry_SYSCALL64_slow_path
451 JMP_NOSPEC %rax /* Called from C */
454 .macro ptregs_stub func
457 leaq \func(%rip), %rax
462 /* Instantiate ptregs_stub for each ptregs-using syscall */
463 #define __SYSCALL_64_QUAL_(sym)
464 #define __SYSCALL_64_QUAL_ptregs(sym) ptregs_stub sym
465 #define __SYSCALL_64(nr, sym, qual) __SYSCALL_64_QUAL_##qual(sym)
466 #include <asm/syscalls_64.h>
472 ENTRY(__switch_to_asm)
475 * Save callee-saved registers
476 * This must match the order in inactive_task_frame
486 movq %rsp, TASK_threadsp(%rdi)
487 movq TASK_threadsp(%rsi), %rsp
489 #ifdef CONFIG_CC_STACKPROTECTOR
490 movq TASK_stack_canary(%rsi), %rbx
491 movq %rbx, PER_CPU_VAR(irq_stack_union)+stack_canary_offset
494 #ifdef CONFIG_RETPOLINE
496 * When switching from a shallower to a deeper call stack
497 * the RSB may either underflow or use entries populated
498 * with userspace addresses. On CPUs where those concerns
499 * exist, overwrite the RSB with entries which capture
500 * speculative execution to prevent attack.
503 FILL_RETURN_BUFFER RSB_CLEAR_LOOPS, X86_FEATURE_RSB_CTXSW
506 /* restore callee-saved registers */
518 * A newly forked process directly context switches into this address.
520 * rax: prev task we switched from
521 * rbx: kernel thread func (NULL for user thread)
522 * r12: kernel thread arg
527 call schedule_tail /* rdi: 'prev' task parameter */
529 testq %rbx, %rbx /* from kernel_thread? */
530 jnz 1f /* kernel threads are uncommon */
535 call syscall_return_slowpath /* returns with IRQs disabled */
536 TRACE_IRQS_ON /* user mode is traced as IRQS on */
537 jmp swapgs_restore_regs_and_return_to_usermode
544 * A kernel thread is allowed to return here after successfully
545 * calling do_execve(). Exit to userspace to complete the execve()
553 * Build the entry stubs with some assembler magic.
554 * We pack 1 stub into every 8-byte block.
557 ENTRY(irq_entries_start)
558 vector=FIRST_EXTERNAL_VECTOR
559 .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
560 UNWIND_HINT_IRET_REGS
561 pushq $(~vector+0x80) /* Note: always in signed byte range */
566 END(irq_entries_start)
568 .macro DEBUG_ENTRY_ASSERT_IRQS_OFF
569 #ifdef CONFIG_DEBUG_ENTRY
572 testl $X86_EFLAGS_IF, %eax
581 * Enters the IRQ stack if we're not already using it. NMI-safe. Clobbers
582 * flags and puts old RSP into old_rsp, and leaves all other GPRs alone.
583 * Requires kernel GSBASE.
585 * The invariant is that, if irq_count != -1, then the IRQ stack is in use.
587 .macro ENTER_IRQ_STACK regs=1 old_rsp
588 DEBUG_ENTRY_ASSERT_IRQS_OFF
592 UNWIND_HINT_REGS base=\old_rsp
595 incl PER_CPU_VAR(irq_count)
596 jnz .Lirq_stack_push_old_rsp_\@
599 * Right now, if we just incremented irq_count to zero, we've
600 * claimed the IRQ stack but we haven't switched to it yet.
602 * If anything is added that can interrupt us here without using IST,
603 * it must be *extremely* careful to limit its stack usage. This
604 * could include kprobes and a hypothetical future IST-less #DB
607 * The OOPS unwinder relies on the word at the top of the IRQ
608 * stack linking back to the previous RSP for the entire time we're
609 * on the IRQ stack. For this to work reliably, we need to write
610 * it before we actually move ourselves to the IRQ stack.
613 movq \old_rsp, PER_CPU_VAR(irq_stack_union + IRQ_STACK_SIZE - 8)
614 movq PER_CPU_VAR(irq_stack_ptr), %rsp
616 #ifdef CONFIG_DEBUG_ENTRY
618 * If the first movq above becomes wrong due to IRQ stack layout
619 * changes, the only way we'll notice is if we try to unwind right
620 * here. Assert that we set up the stack right to catch this type
623 cmpq -8(%rsp), \old_rsp
624 je .Lirq_stack_okay\@
629 .Lirq_stack_push_old_rsp_\@:
633 UNWIND_HINT_REGS indirect=1
638 * Undoes ENTER_IRQ_STACK.
640 .macro LEAVE_IRQ_STACK regs=1
641 DEBUG_ENTRY_ASSERT_IRQS_OFF
642 /* We need to be off the IRQ stack before decrementing irq_count. */
650 * As in ENTER_IRQ_STACK, irq_count == 0, we are still claiming
651 * the irq stack but we're not on it.
654 decl PER_CPU_VAR(irq_count)
658 * Interrupt entry/exit.
660 * Interrupt entry points save only callee clobbered registers in fast path.
662 * Entry runs with interrupts off.
665 /* 0(%rsp): ~(interrupt number) */
666 .macro interrupt func
669 testb $3, CS-ORIG_RAX(%rsp)
672 call switch_to_thread_stack
675 ALLOC_PT_GPREGS_ON_STACK
684 * IRQ from user mode.
686 * We need to tell lockdep that IRQs are off. We can't do this until
687 * we fix gsbase, and we should do it before enter_from_user_mode
688 * (which can take locks). Since TRACE_IRQS_OFF idempotent,
689 * the simplest way to handle it is to just call it twice if
690 * we enter from user mode. There's no reason to optimize this since
691 * TRACE_IRQS_OFF is a no-op if lockdep is off.
695 CALL_enter_from_user_mode
698 ENTER_IRQ_STACK old_rsp=%rdi
699 /* We entered an interrupt context - irqs are off: */
702 call \func /* rdi points to pt_regs */
706 * The interrupt stubs push (~vector+0x80) onto the stack and
707 * then jump to common_interrupt.
709 .p2align CONFIG_X86_L1_CACHE_SHIFT
712 addq $-0x80, (%rsp) /* Adjust vector to [-256, -1] range */
714 /* 0(%rsp): old RSP */
716 DISABLE_INTERRUPTS(CLBR_ANY)
724 /* Interrupt came from user space */
727 call prepare_exit_to_usermode
730 GLOBAL(swapgs_restore_regs_and_return_to_usermode)
731 #ifdef CONFIG_DEBUG_ENTRY
732 /* Assert that pt_regs indicates user mode. */
749 * The stack is now user RDI, orig_ax, RIP, CS, EFLAGS, RSP, SS.
750 * Save old stack pointer and switch to trampoline stack.
753 movq PER_CPU_VAR(cpu_tss_rw + TSS_sp0), %rsp
755 /* Copy the IRET frame to the trampoline stack. */
756 pushq 6*8(%rdi) /* SS */
757 pushq 5*8(%rdi) /* RSP */
758 pushq 4*8(%rdi) /* EFLAGS */
759 pushq 3*8(%rdi) /* CS */
760 pushq 2*8(%rdi) /* RIP */
762 /* Push user RDI on the trampoline stack. */
766 * We are on the trampoline stack. All regs except RDI are live.
767 * We can do future final exit work right here.
770 SWITCH_TO_USER_CR3_STACK scratch_reg=%rdi
778 /* Returning to kernel space */
780 #ifdef CONFIG_PREEMPT
781 /* Interrupts are off */
782 /* Check if we need preemption */
783 bt $9, EFLAGS(%rsp) /* were interrupts off? */
785 0: cmpl $0, PER_CPU_VAR(__preempt_count)
787 call preempt_schedule_irq
792 * The iretq could re-enable interrupts:
796 GLOBAL(restore_regs_and_return_to_kernel)
797 #ifdef CONFIG_DEBUG_ENTRY
798 /* Assert that pt_regs indicates kernel mode. */
806 addq $8, %rsp /* skip regs->orig_ax */
810 UNWIND_HINT_IRET_REGS
812 * Are we returning to a stack segment from the LDT? Note: in
813 * 64-bit mode SS:RSP on the exception stack is always valid.
815 #ifdef CONFIG_X86_ESPFIX64
816 testb $4, (SS-RIP)(%rsp)
817 jnz native_irq_return_ldt
820 .global native_irq_return_iret
821 native_irq_return_iret:
823 * This may fault. Non-paranoid faults on return to userspace are
824 * handled by fixup_bad_iret. These include #SS, #GP, and #NP.
825 * Double-faults due to espfix64 are handled in do_double_fault.
826 * Other faults here are fatal.
830 #ifdef CONFIG_X86_ESPFIX64
831 native_irq_return_ldt:
833 * We are running with user GSBASE. All GPRs contain their user
834 * values. We have a percpu ESPFIX stack that is eight slots
835 * long (see ESPFIX_STACK_SIZE). espfix_waddr points to the bottom
836 * of the ESPFIX stack.
838 * We clobber RAX and RDI in this code. We stash RDI on the
839 * normal stack and RAX on the ESPFIX stack.
841 * The ESPFIX stack layout we set up looks like this:
843 * --- top of ESPFIX stack ---
848 * RIP <-- RSP points here when we're done
849 * RAX <-- espfix_waddr points here
850 * --- bottom of ESPFIX stack ---
853 pushq %rdi /* Stash user RDI */
854 SWAPGS /* to kernel GS */
855 SWITCH_TO_KERNEL_CR3 scratch_reg=%rdi /* to kernel CR3 */
857 movq PER_CPU_VAR(espfix_waddr), %rdi
858 movq %rax, (0*8)(%rdi) /* user RAX */
859 movq (1*8)(%rsp), %rax /* user RIP */
860 movq %rax, (1*8)(%rdi)
861 movq (2*8)(%rsp), %rax /* user CS */
862 movq %rax, (2*8)(%rdi)
863 movq (3*8)(%rsp), %rax /* user RFLAGS */
864 movq %rax, (3*8)(%rdi)
865 movq (5*8)(%rsp), %rax /* user SS */
866 movq %rax, (5*8)(%rdi)
867 movq (4*8)(%rsp), %rax /* user RSP */
868 movq %rax, (4*8)(%rdi)
869 /* Now RAX == RSP. */
871 andl $0xffff0000, %eax /* RAX = (RSP & 0xffff0000) */
874 * espfix_stack[31:16] == 0. The page tables are set up such that
875 * (espfix_stack | (X & 0xffff0000)) points to a read-only alias of
876 * espfix_waddr for any X. That is, there are 65536 RO aliases of
877 * the same page. Set up RSP so that RSP[31:16] contains the
878 * respective 16 bits of the /userspace/ RSP and RSP nonetheless
879 * still points to an RO alias of the ESPFIX stack.
881 orq PER_CPU_VAR(espfix_stack), %rax
883 SWITCH_TO_USER_CR3_STACK scratch_reg=%rdi
884 SWAPGS /* to user GS */
885 popq %rdi /* Restore user RDI */
888 UNWIND_HINT_IRET_REGS offset=8
891 * At this point, we cannot write to the stack any more, but we can
894 popq %rax /* Restore user RAX */
897 * RSP now points to an ordinary IRET frame, except that the page
898 * is read-only and RSP[31:16] are preloaded with the userspace
899 * values. We can now IRET back to userspace.
901 jmp native_irq_return_iret
903 END(common_interrupt)
908 .macro apicinterrupt3 num sym do_sym
910 UNWIND_HINT_IRET_REGS
919 /* Make sure APIC interrupt handlers end up in the irqentry section: */
920 #define PUSH_SECTION_IRQENTRY .pushsection .irqentry.text, "ax"
921 #define POP_SECTION_IRQENTRY .popsection
923 .macro apicinterrupt num sym do_sym
924 PUSH_SECTION_IRQENTRY
925 apicinterrupt3 \num \sym \do_sym
930 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
931 apicinterrupt3 REBOOT_VECTOR reboot_interrupt smp_reboot_interrupt
935 apicinterrupt3 UV_BAU_MESSAGE uv_bau_message_intr1 uv_bau_message_interrupt
938 apicinterrupt LOCAL_TIMER_VECTOR apic_timer_interrupt smp_apic_timer_interrupt
939 apicinterrupt X86_PLATFORM_IPI_VECTOR x86_platform_ipi smp_x86_platform_ipi
941 #ifdef CONFIG_HAVE_KVM
942 apicinterrupt3 POSTED_INTR_VECTOR kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
943 apicinterrupt3 POSTED_INTR_WAKEUP_VECTOR kvm_posted_intr_wakeup_ipi smp_kvm_posted_intr_wakeup_ipi
944 apicinterrupt3 POSTED_INTR_NESTED_VECTOR kvm_posted_intr_nested_ipi smp_kvm_posted_intr_nested_ipi
947 #ifdef CONFIG_X86_MCE_THRESHOLD
948 apicinterrupt THRESHOLD_APIC_VECTOR threshold_interrupt smp_threshold_interrupt
951 #ifdef CONFIG_X86_MCE_AMD
952 apicinterrupt DEFERRED_ERROR_VECTOR deferred_error_interrupt smp_deferred_error_interrupt
955 #ifdef CONFIG_X86_THERMAL_VECTOR
956 apicinterrupt THERMAL_APIC_VECTOR thermal_interrupt smp_thermal_interrupt
960 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR call_function_single_interrupt smp_call_function_single_interrupt
961 apicinterrupt CALL_FUNCTION_VECTOR call_function_interrupt smp_call_function_interrupt
962 apicinterrupt RESCHEDULE_VECTOR reschedule_interrupt smp_reschedule_interrupt
965 apicinterrupt ERROR_APIC_VECTOR error_interrupt smp_error_interrupt
966 apicinterrupt SPURIOUS_APIC_VECTOR spurious_interrupt smp_spurious_interrupt
968 #ifdef CONFIG_IRQ_WORK
969 apicinterrupt IRQ_WORK_VECTOR irq_work_interrupt smp_irq_work_interrupt
973 * Exception entry points.
975 #define CPU_TSS_IST(x) PER_CPU_VAR(cpu_tss_rw) + (TSS_ist + ((x) - 1) * 8)
978 * Switch to the thread stack. This is called with the IRET frame and
979 * orig_ax on the stack. (That is, RDI..R12 are not on the stack and
980 * space has not been allocated for them.)
982 ENTRY(switch_to_thread_stack)
986 /* Need to switch before accessing the thread stack. */
987 SWITCH_TO_KERNEL_CR3 scratch_reg=%rdi
989 movq PER_CPU_VAR(cpu_current_top_of_stack), %rsp
990 UNWIND_HINT sp_offset=16 sp_reg=ORC_REG_DI
992 pushq 7*8(%rdi) /* regs->ss */
993 pushq 6*8(%rdi) /* regs->rsp */
994 pushq 5*8(%rdi) /* regs->eflags */
995 pushq 4*8(%rdi) /* regs->cs */
996 pushq 3*8(%rdi) /* regs->ip */
997 pushq 2*8(%rdi) /* regs->orig_ax */
998 pushq 8(%rdi) /* return address */
1003 END(switch_to_thread_stack)
1005 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
1007 UNWIND_HINT_IRET_REGS offset=\has_error_code*8
1010 .if \shift_ist != -1 && \paranoid == 0
1011 .error "using shift_ist requires paranoid=1"
1016 .if \has_error_code == 0
1017 pushq $-1 /* ORIG_RAX: no syscall to restart */
1020 ALLOC_PT_GPREGS_ON_STACK
1023 testb $3, CS(%rsp) /* If coming from userspace, switch stacks */
1024 jnz .Lfrom_usermode_switch_stack_\@
1033 /* returned flag: ebx=0: need swapgs on exit, ebx=1: don't need it */
1036 .if \shift_ist != -1
1037 TRACE_IRQS_OFF_DEBUG /* reload IDT in case of recursion */
1043 movq %rsp, %rdi /* pt_regs pointer */
1046 movq ORIG_RAX(%rsp), %rsi /* get error code */
1047 movq $-1, ORIG_RAX(%rsp) /* no syscall to restart */
1049 xorl %esi, %esi /* no error code */
1052 .if \shift_ist != -1
1053 subq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
1058 .if \shift_ist != -1
1059 addq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
1062 /* these procedures expect "no swapgs" flag in ebx */
1071 * Entry from userspace. Switch stacks and treat it
1072 * as a normal entry. This means that paranoid handlers
1073 * run in real process context if user_mode(regs).
1075 .Lfrom_usermode_switch_stack_\@:
1078 movq %rsp, %rdi /* pt_regs pointer */
1081 movq ORIG_RAX(%rsp), %rsi /* get error code */
1082 movq $-1, ORIG_RAX(%rsp) /* no syscall to restart */
1084 xorl %esi, %esi /* no error code */
1089 jmp error_exit /* %ebx: no swapgs flag */
1094 idtentry divide_error do_divide_error has_error_code=0
1095 idtentry overflow do_overflow has_error_code=0
1096 idtentry bounds do_bounds has_error_code=0
1097 idtentry invalid_op do_invalid_op has_error_code=0
1098 idtentry device_not_available do_device_not_available has_error_code=0
1099 idtentry double_fault do_double_fault has_error_code=1 paranoid=2
1100 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
1101 idtentry invalid_TSS do_invalid_TSS has_error_code=1
1102 idtentry segment_not_present do_segment_not_present has_error_code=1
1103 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
1104 idtentry coprocessor_error do_coprocessor_error has_error_code=0
1105 idtentry alignment_check do_alignment_check has_error_code=1
1106 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
1110 * Reload gs selector with exception handling
1113 ENTRY(native_load_gs_index)
1116 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1121 2: ALTERNATIVE "", "mfence", X86_BUG_SWAPGS_FENCE
1123 TRACE_IRQS_FLAGS (%rsp)
1127 ENDPROC(native_load_gs_index)
1128 EXPORT_SYMBOL(native_load_gs_index)
1130 _ASM_EXTABLE(.Lgs_change, bad_gs)
1131 .section .fixup, "ax"
1132 /* running with kernelgs */
1134 SWAPGS /* switch back to user gs */
1136 /* This can't be a string because the preprocessor needs to see it. */
1137 movl $__USER_DS, %eax
1140 ALTERNATIVE "", "ZAP_GS", X86_BUG_NULL_SEG
1146 /* Call softirq on interrupt stack. Interrupts are off. */
1147 ENTRY(do_softirq_own_stack)
1150 ENTER_IRQ_STACK regs=0 old_rsp=%r11
1152 LEAVE_IRQ_STACK regs=0
1155 ENDPROC(do_softirq_own_stack)
1158 idtentry hypervisor_callback xen_do_hypervisor_callback has_error_code=0
1161 * A note on the "critical region" in our callback handler.
1162 * We want to avoid stacking callback handlers due to events occurring
1163 * during handling of the last event. To do this, we keep events disabled
1164 * until we've done all processing. HOWEVER, we must enable events before
1165 * popping the stack frame (can't be done atomically) and so it would still
1166 * be possible to get enough handler activations to overflow the stack.
1167 * Although unlikely, bugs of that kind are hard to track down, so we'd
1168 * like to avoid the possibility.
1169 * So, on entry to the handler we detect whether we interrupted an
1170 * existing activation in its critical region -- if so, we pop the current
1171 * activation and restart the handler using the previous one.
1173 ENTRY(xen_do_hypervisor_callback) /* do_hypervisor_callback(struct *pt_regs) */
1176 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1177 * see the correct pointer to the pt_regs
1180 movq %rdi, %rsp /* we don't return, adjust the stack frame */
1183 ENTER_IRQ_STACK old_rsp=%r10
1184 call xen_evtchn_do_upcall
1187 #ifndef CONFIG_PREEMPT
1188 call xen_maybe_preempt_hcall
1191 END(xen_do_hypervisor_callback)
1194 * Hypervisor uses this for application faults while it executes.
1195 * We get here for two reasons:
1196 * 1. Fault while reloading DS, ES, FS or GS
1197 * 2. Fault while executing IRET
1198 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1199 * registers that could be reloaded and zeroed the others.
1200 * Category 2 we fix up by killing the current process. We cannot use the
1201 * normal Linux return path in this case because if we use the IRET hypercall
1202 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1203 * We distinguish between categories by comparing each saved segment register
1204 * with its current contents: any discrepancy means we in category 1.
1206 ENTRY(xen_failsafe_callback)
1209 cmpw %cx, 0x10(%rsp)
1212 cmpw %cx, 0x18(%rsp)
1215 cmpw %cx, 0x20(%rsp)
1218 cmpw %cx, 0x28(%rsp)
1220 /* All segments match their saved values => Category 2 (Bad IRET). */
1225 UNWIND_HINT_IRET_REGS offset=8
1226 jmp general_protection
1227 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1231 UNWIND_HINT_IRET_REGS
1232 pushq $-1 /* orig_ax = -1 => not a system call */
1233 ALLOC_PT_GPREGS_ON_STACK
1236 ENCODE_FRAME_POINTER
1238 END(xen_failsafe_callback)
1240 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1241 xen_hvm_callback_vector xen_evtchn_do_upcall
1243 #endif /* CONFIG_XEN */
1245 #if IS_ENABLED(CONFIG_HYPERV)
1246 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1247 hyperv_callback_vector hyperv_vector_handler
1248 #endif /* CONFIG_HYPERV */
1250 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1251 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1252 idtentry stack_segment do_stack_segment has_error_code=1
1255 idtentry xennmi do_nmi has_error_code=0
1256 idtentry xendebug do_debug has_error_code=0
1257 idtentry xenint3 do_int3 has_error_code=0
1260 idtentry general_protection do_general_protection has_error_code=1
1261 idtentry page_fault do_page_fault has_error_code=1
1263 #ifdef CONFIG_KVM_GUEST
1264 idtentry async_page_fault do_async_page_fault has_error_code=1
1267 #ifdef CONFIG_X86_MCE
1268 idtentry machine_check do_mce has_error_code=0 paranoid=1
1272 * Save all registers in pt_regs, and switch gs if needed.
1273 * Use slow, but surefire "are we in kernel?" check.
1274 * Return: ebx=0: need swapgs on exit, ebx=1: otherwise
1276 ENTRY(paranoid_entry)
1281 ENCODE_FRAME_POINTER 8
1283 movl $MSR_GS_BASE, %ecx
1286 js 1f /* negative -> in kernel */
1291 SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg=%rax save_reg=%r14
1297 * "Paranoid" exit path from exception stack. This is invoked
1298 * only on return from non-NMI IST interrupts that came
1299 * from kernel space.
1301 * We may be returning to very strange contexts (e.g. very early
1302 * in syscall entry), so checking for preemption here would
1303 * be complicated. Fortunately, we there's no good reason
1304 * to try to handle preemption here.
1306 * On entry, ebx is "no swapgs" flag (1: don't need swapgs, 0: need it)
1308 ENTRY(paranoid_exit)
1310 DISABLE_INTERRUPTS(CLBR_ANY)
1311 TRACE_IRQS_OFF_DEBUG
1312 testl %ebx, %ebx /* swapgs needed? */
1313 jnz .Lparanoid_exit_no_swapgs
1315 RESTORE_CR3 scratch_reg=%rbx save_reg=%r14
1317 jmp .Lparanoid_exit_restore
1318 .Lparanoid_exit_no_swapgs:
1319 TRACE_IRQS_IRETQ_DEBUG
1320 .Lparanoid_exit_restore:
1321 jmp restore_regs_and_return_to_kernel
1325 * Save all registers in pt_regs, and switch gs if needed.
1326 * Return: EBX=0: came from user mode; EBX=1: otherwise
1333 ENCODE_FRAME_POINTER 8
1335 testb $3, CS+8(%rsp)
1336 jz .Lerror_kernelspace
1339 * We entered from user mode or we're pretending to have entered
1340 * from user mode due to an IRET fault.
1343 /* We have user CR3. Change to kernel CR3. */
1344 SWITCH_TO_KERNEL_CR3 scratch_reg=%rax
1346 .Lerror_entry_from_usermode_after_swapgs:
1347 /* Put us onto the real thread stack. */
1348 popq %r12 /* save return addr in %12 */
1349 movq %rsp, %rdi /* arg0 = pt_regs pointer */
1351 movq %rax, %rsp /* switch stack */
1352 ENCODE_FRAME_POINTER
1356 * We need to tell lockdep that IRQs are off. We can't do this until
1357 * we fix gsbase, and we should do it before enter_from_user_mode
1358 * (which can take locks).
1361 CALL_enter_from_user_mode
1369 * There are two places in the kernel that can potentially fault with
1370 * usergs. Handle them here. B stepping K8s sometimes report a
1371 * truncated RIP for IRET exceptions returning to compat mode. Check
1372 * for these here too.
1374 .Lerror_kernelspace:
1376 leaq native_irq_return_iret(%rip), %rcx
1377 cmpq %rcx, RIP+8(%rsp)
1379 movl %ecx, %eax /* zero extend */
1380 cmpq %rax, RIP+8(%rsp)
1382 cmpq $.Lgs_change, RIP+8(%rsp)
1383 jne .Lerror_entry_done
1386 * hack: .Lgs_change can fail with user gsbase. If this happens, fix up
1387 * gsbase and proceed. We'll fix up the exception and land in
1388 * .Lgs_change's error handler with kernel gsbase.
1391 SWITCH_TO_KERNEL_CR3 scratch_reg=%rax
1392 jmp .Lerror_entry_done
1395 /* Fix truncated RIP */
1396 movq %rcx, RIP+8(%rsp)
1401 * We came from an IRET to user mode, so we have user
1402 * gsbase and CR3. Switch to kernel gsbase and CR3:
1405 SWITCH_TO_KERNEL_CR3 scratch_reg=%rax
1408 * Pretend that the exception came from user mode: set up pt_regs
1409 * as if we faulted immediately after IRET and clear EBX so that
1410 * error_exit knows that we will be returning to user mode.
1416 jmp .Lerror_entry_from_usermode_after_swapgs
1421 * On entry, EBX is a "return to kernel mode" flag:
1422 * 1: already in kernel mode, don't need SWAPGS
1423 * 0: user gsbase is loaded, we need SWAPGS and standard preparation for return to usermode
1427 DISABLE_INTERRUPTS(CLBR_ANY)
1435 * Runs on exception stack. Xen PV does not go through this path at all,
1436 * so we can use real assembly here.
1439 * %r14: Used to save/restore the CR3 of the interrupted context
1440 * when PAGE_TABLE_ISOLATION is in use. Do not clobber.
1443 UNWIND_HINT_IRET_REGS
1446 * We allow breakpoints in NMIs. If a breakpoint occurs, then
1447 * the iretq it performs will take us out of NMI context.
1448 * This means that we can have nested NMIs where the next
1449 * NMI is using the top of the stack of the previous NMI. We
1450 * can't let it execute because the nested NMI will corrupt the
1451 * stack of the previous NMI. NMI handlers are not re-entrant
1454 * To handle this case we do the following:
1455 * Check the a special location on the stack that contains
1456 * a variable that is set when NMIs are executing.
1457 * The interrupted task's stack is also checked to see if it
1459 * If the variable is not set and the stack is not the NMI
1461 * o Set the special variable on the stack
1462 * o Copy the interrupt frame into an "outermost" location on the
1464 * o Copy the interrupt frame into an "iret" location on the stack
1465 * o Continue processing the NMI
1466 * If the variable is set or the previous stack is the NMI stack:
1467 * o Modify the "iret" location to jump to the repeat_nmi
1468 * o return back to the first NMI
1470 * Now on exit of the first NMI, we first clear the stack variable
1471 * The NMI stack will tell any nested NMIs at that point that it is
1472 * nested. Then we pop the stack normally with iret, and if there was
1473 * a nested NMI that updated the copy interrupt stack frame, a
1474 * jump will be made to the repeat_nmi code that will handle the second
1477 * However, espfix prevents us from directly returning to userspace
1478 * with a single IRET instruction. Similarly, IRET to user mode
1479 * can fault. We therefore handle NMIs from user space like
1480 * other IST entries.
1485 /* Use %rdx as our temp variable throughout */
1488 testb $3, CS-RIP+8(%rsp)
1489 jz .Lnmi_from_kernel
1492 * NMI from user mode. We need to run on the thread stack, but we
1493 * can't go through the normal entry paths: NMIs are masked, and
1494 * we don't want to enable interrupts, because then we'll end
1495 * up in an awkward situation in which IRQs are on but NMIs
1498 * We also must not push anything to the stack before switching
1499 * stacks lest we corrupt the "NMI executing" variable.
1504 SWITCH_TO_KERNEL_CR3 scratch_reg=%rdx
1506 movq PER_CPU_VAR(cpu_current_top_of_stack), %rsp
1507 UNWIND_HINT_IRET_REGS base=%rdx offset=8
1508 pushq 5*8(%rdx) /* pt_regs->ss */
1509 pushq 4*8(%rdx) /* pt_regs->rsp */
1510 pushq 3*8(%rdx) /* pt_regs->flags */
1511 pushq 2*8(%rdx) /* pt_regs->cs */
1512 pushq 1*8(%rdx) /* pt_regs->rip */
1513 UNWIND_HINT_IRET_REGS
1514 pushq $-1 /* pt_regs->orig_ax */
1515 pushq %rdi /* pt_regs->di */
1516 pushq %rsi /* pt_regs->si */
1517 pushq (%rdx) /* pt_regs->dx */
1518 pushq %rcx /* pt_regs->cx */
1519 pushq %rax /* pt_regs->ax */
1520 pushq %r8 /* pt_regs->r8 */
1521 pushq %r9 /* pt_regs->r9 */
1522 pushq %r10 /* pt_regs->r10 */
1523 pushq %r11 /* pt_regs->r11 */
1524 pushq %rbx /* pt_regs->rbx */
1525 pushq %rbp /* pt_regs->rbp */
1526 pushq %r12 /* pt_regs->r12 */
1527 pushq %r13 /* pt_regs->r13 */
1528 pushq %r14 /* pt_regs->r14 */
1529 pushq %r15 /* pt_regs->r15 */
1531 ENCODE_FRAME_POINTER
1534 * At this point we no longer need to worry about stack damage
1535 * due to nesting -- we're on the normal thread stack and we're
1536 * done with the NMI stack.
1544 * Return back to user mode. We must *not* do the normal exit
1545 * work, because we don't want to enable interrupts.
1547 jmp swapgs_restore_regs_and_return_to_usermode
1551 * Here's what our stack frame will look like:
1552 * +---------------------------------------------------------+
1554 * | original Return RSP |
1555 * | original RFLAGS |
1558 * +---------------------------------------------------------+
1559 * | temp storage for rdx |
1560 * +---------------------------------------------------------+
1561 * | "NMI executing" variable |
1562 * +---------------------------------------------------------+
1563 * | iret SS } Copied from "outermost" frame |
1564 * | iret Return RSP } on each loop iteration; overwritten |
1565 * | iret RFLAGS } by a nested NMI to force another |
1566 * | iret CS } iteration if needed. |
1568 * +---------------------------------------------------------+
1569 * | outermost SS } initialized in first_nmi; |
1570 * | outermost Return RSP } will not be changed before |
1571 * | outermost RFLAGS } NMI processing is done. |
1572 * | outermost CS } Copied to "iret" frame on each |
1573 * | outermost RIP } iteration. |
1574 * +---------------------------------------------------------+
1576 * +---------------------------------------------------------+
1578 * The "original" frame is used by hardware. Before re-enabling
1579 * NMIs, we need to be done with it, and we need to leave enough
1580 * space for the asm code here.
1582 * We return by executing IRET while RSP points to the "iret" frame.
1583 * That will either return for real or it will loop back into NMI
1586 * The "outermost" frame is copied to the "iret" frame on each
1587 * iteration of the loop, so each iteration starts with the "iret"
1588 * frame pointing to the final return target.
1592 * Determine whether we're a nested NMI.
1594 * If we interrupted kernel code between repeat_nmi and
1595 * end_repeat_nmi, then we are a nested NMI. We must not
1596 * modify the "iret" frame because it's being written by
1597 * the outer NMI. That's okay; the outer NMI handler is
1598 * about to about to call do_nmi anyway, so we can just
1599 * resume the outer NMI.
1602 movq $repeat_nmi, %rdx
1605 movq $end_repeat_nmi, %rdx
1611 * Now check "NMI executing". If it's set, then we're nested.
1612 * This will not detect if we interrupted an outer NMI just
1619 * Now test if the previous stack was an NMI stack. This covers
1620 * the case where we interrupt an outer NMI after it clears
1621 * "NMI executing" but before IRET. We need to be careful, though:
1622 * there is one case in which RSP could point to the NMI stack
1623 * despite there being no NMI active: naughty userspace controls
1624 * RSP at the very beginning of the SYSCALL targets. We can
1625 * pull a fast one on naughty userspace, though: we program
1626 * SYSCALL to mask DF, so userspace cannot cause DF to be set
1627 * if it controls the kernel's RSP. We set DF before we clear
1631 /* Compare the NMI stack (rdx) with the stack we came from (4*8(%rsp)) */
1632 cmpq %rdx, 4*8(%rsp)
1633 /* If the stack pointer is above the NMI stack, this is a normal NMI */
1636 subq $EXCEPTION_STKSZ, %rdx
1637 cmpq %rdx, 4*8(%rsp)
1638 /* If it is below the NMI stack, it is a normal NMI */
1641 /* Ah, it is within the NMI stack. */
1643 testb $(X86_EFLAGS_DF >> 8), (3*8 + 1)(%rsp)
1644 jz first_nmi /* RSP was user controlled. */
1646 /* This is a nested NMI. */
1650 * Modify the "iret" frame to point to repeat_nmi, forcing another
1651 * iteration of NMI handling.
1654 leaq -10*8(%rsp), %rdx
1661 /* Put stack back */
1667 /* We are returning to kernel mode, so this cannot result in a fault. */
1674 /* Make room for "NMI executing". */
1677 /* Leave room for the "iret" frame */
1680 /* Copy the "original" frame to the "outermost" frame */
1684 UNWIND_HINT_IRET_REGS
1686 /* Everything up to here is safe from nested NMIs */
1688 #ifdef CONFIG_DEBUG_ENTRY
1690 * For ease of testing, unmask NMIs right away. Disabled by
1691 * default because IRET is very expensive.
1694 pushq %rsp /* RSP (minus 8 because of the previous push) */
1695 addq $8, (%rsp) /* Fix up RSP */
1697 pushq $__KERNEL_CS /* CS */
1699 iretq /* continues at repeat_nmi below */
1700 UNWIND_HINT_IRET_REGS
1706 * If there was a nested NMI, the first NMI's iret will return
1707 * here. But NMIs are still enabled and we can take another
1708 * nested NMI. The nested NMI checks the interrupted RIP to see
1709 * if it is between repeat_nmi and end_repeat_nmi, and if so
1710 * it will just return, as we are about to repeat an NMI anyway.
1711 * This makes it safe to copy to the stack frame that a nested
1714 * RSP is pointing to "outermost RIP". gsbase is unknown, but, if
1715 * we're repeating an NMI, gsbase has the same value that it had on
1716 * the first iteration. paranoid_entry will load the kernel
1717 * gsbase if needed before we call do_nmi. "NMI executing"
1720 movq $1, 10*8(%rsp) /* Set "NMI executing". */
1723 * Copy the "outermost" frame to the "iret" frame. NMIs that nest
1724 * here must not modify the "iret" frame while we're writing to
1725 * it or it will end up containing garbage.
1735 * Everything below this point can be preempted by a nested NMI.
1736 * If this happens, then the inner NMI will change the "iret"
1737 * frame to point back to repeat_nmi.
1739 pushq $-1 /* ORIG_RAX: no syscall to restart */
1740 ALLOC_PT_GPREGS_ON_STACK
1743 * Use paranoid_entry to handle SWAPGS, but no need to use paranoid_exit
1744 * as we should not be calling schedule in NMI context.
1745 * Even with normal interrupts enabled. An NMI should not be
1746 * setting NEED_RESCHED or anything that normal interrupts and
1747 * exceptions might do.
1752 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1757 RESTORE_CR3 scratch_reg=%r15 save_reg=%r14
1759 testl %ebx, %ebx /* swapgs needed? */
1768 * Skip orig_ax and the "outermost" frame to point RSP at the "iret"
1769 * at the "iret" frame.
1774 * Clear "NMI executing". Set DF first so that we can easily
1775 * distinguish the remaining code between here and IRET from
1776 * the SYSCALL entry and exit paths.
1778 * We arguably should just inspect RIP instead, but I (Andy) wrote
1779 * this code when I had the misapprehension that Xen PV supported
1780 * NMIs, and Xen PV would break that approach.
1783 movq $0, 5*8(%rsp) /* clear "NMI executing" */
1786 * iretq reads the "iret" frame and exits the NMI stack in a
1787 * single instruction. We are returning to kernel mode, so this
1788 * cannot result in a fault. Similarly, we don't need to worry
1789 * about espfix64 on the way back to kernel mode.
1794 ENTRY(ignore_sysret)
1800 ENTRY(rewind_stack_do_exit)
1802 /* Prevent any naive code from trying to unwind to our caller. */
1805 movq PER_CPU_VAR(cpu_current_top_of_stack), %rax
1806 leaq -PTREGS_SIZE(%rax), %rsp
1807 UNWIND_HINT_FUNC sp_offset=PTREGS_SIZE
1810 END(rewind_stack_do_exit)