arch/x86/entry/calling.h

   1 #include <linux/jump_label.h>
   2 #include <asm/unwind_hints.h>
   3
   4 /*
   5
   6  x86 function call convention, 64-bit:
   7  -------------------------------------
   8   arguments           |  callee-saved      | extra caller-saved | return
   9  [callee-clobbered]   |                    | [callee-clobbered] |
  10  ---------------------------------------------------------------------------
  11  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
  12
  13  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  14    functions when it sees tail-call optimization possibilities) rflags is
  15    clobbered. Leftover arguments are passed over the stack frame.)
  16
  17  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  18
  19  [**] for struct return values wider than 64 bits the return convention is a
  20       bit more complex: up to 128 bits width we return small structures
  21       straight in rax, rdx. For structures larger than that (3 words or
  22       larger) the caller puts a pointer to an on-stack return struct
  23       [allocated in the caller's stack frame] into the first argument - i.e.
  24       into rdi. All other arguments shift up by one in this case.
  25       Fortunately this case is rare in the kernel.
  26
  27 For 32-bit we have the following conventions - kernel is built with
  28 -mregparm=3 and -freg-struct-return:
  29
  30  x86 function calling convention, 32-bit:
  31  ----------------------------------------
  32   arguments         | callee-saved        | extra caller-saved | return
  33  [callee-clobbered] |                     | [callee-clobbered] |
  34  -------------------------------------------------------------------------
  35  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  36
  37  ( here too esp is obviously invariant across normal function calls. eflags
  38    is clobbered. Leftover arguments are passed over the stack frame. )
  39
  40  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  41
  42  [**] We build with -freg-struct-return, which on 32-bit means similar
  43       semantics as on 64-bit: edx can be used for a second return value
  44       (i.e. covering integer and structure sizes up to 64 bits) - after that
  45       it gets more complex and more expensive: 3-word or larger struct returns
  46       get done in the caller's frame and the pointer to the return struct goes
  47       into regparm0, i.e. eax - the other arguments shift up and the
  48       function's register parameters degenerate to regparm=2 in essence.
  49
  50 */
  51
  52 #ifdef CONFIG_X86_64
  53
  54 /*
  55  * 64-bit system call stack frame layout defines and helpers,
  56  * for assembly code:
  57  */
  58
  59 /* The layout forms the "struct pt_regs" on the stack: */
  60 /*
  61  * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
  62  * unless syscall needs a complete, fully filled "struct pt_regs".
  63  */
  64 #define R15             0*8
  65 #define R14             1*8
  66 #define R13             2*8
  67 #define R12             3*8
  68 #define RBP             4*8
  69 #define RBX             5*8
  70 /* These regs are callee-clobbered. Always saved on kernel entry. */
  71 #define R11             6*8
  72 #define R10             7*8
  73 #define R9              8*8
  74 #define R8              9*8
  75 #define RAX             10*8
  76 #define RCX             11*8
  77 #define RDX             12*8
  78 #define RSI             13*8
  79 #define RDI             14*8
  80 /*
  81  * On syscall entry, this is syscall#. On CPU exception, this is error code.
  82  * On hw interrupt, it's IRQ number:
  83  */
  84 #define ORIG_RAX        15*8
  85 /* Return frame for iretq */
  86 #define RIP             16*8
  87 #define CS              17*8
  88 #define EFLAGS          18*8
  89 #define RSP             19*8
  90 #define SS              20*8
  91
  92 #define SIZEOF_PTREGS   21*8
  93
  94         .macro ALLOC_PT_GPREGS_ON_STACK
  95         addq    $-(15*8), %rsp
  96         .endm
  97
  98         .macro SAVE_C_REGS_HELPER offset=0 rax=1 rcx=1 r8910=1 r11=1
  99         .if \r11
 100         movq %r11, 6*8+\offset(%rsp)
 101         .endif
 102         .if \r8910
 103         movq %r10, 7*8+\offset(%rsp)
 104         movq %r9,  8*8+\offset(%rsp)
 105         movq %r8,  9*8+\offset(%rsp)
 106         .endif
 107         .if \rax
 108         movq %rax, 10*8+\offset(%rsp)
 109         .endif
 110         .if \rcx
 111         movq %rcx, 11*8+\offset(%rsp)
 112         .endif
 113         movq %rdx, 12*8+\offset(%rsp)
 114         movq %rsi, 13*8+\offset(%rsp)
 115         movq %rdi, 14*8+\offset(%rsp)
 116         UNWIND_HINT_REGS offset=\offset extra=0
 117         .endm
 118         .macro SAVE_C_REGS offset=0
 119         SAVE_C_REGS_HELPER \offset, 1, 1, 1, 1
 120         .endm
 121         .macro SAVE_C_REGS_EXCEPT_RAX_RCX offset=0
 122         SAVE_C_REGS_HELPER \offset, 0, 0, 1, 1
 123         .endm
 124         .macro SAVE_C_REGS_EXCEPT_R891011
 125         SAVE_C_REGS_HELPER 0, 1, 1, 0, 0
 126         .endm
 127         .macro SAVE_C_REGS_EXCEPT_RCX_R891011
 128         SAVE_C_REGS_HELPER 0, 1, 0, 0, 0
 129         .endm
 130         .macro SAVE_C_REGS_EXCEPT_RAX_RCX_R11
 131         SAVE_C_REGS_HELPER 0, 0, 0, 1, 0
 132         .endm
 133
 134         .macro SAVE_EXTRA_REGS offset=0
 135         movq %r15, 0*8+\offset(%rsp)
 136         movq %r14, 1*8+\offset(%rsp)
 137         movq %r13, 2*8+\offset(%rsp)
 138         movq %r12, 3*8+\offset(%rsp)
 139         movq %rbp, 4*8+\offset(%rsp)
 140         movq %rbx, 5*8+\offset(%rsp)
 141         UNWIND_HINT_REGS offset=\offset
 142         .endm
 143
 144         .macro POP_EXTRA_REGS
 145         popq %r15
 146         popq %r14
 147         popq %r13
 148         popq %r12
 149         popq %rbp
 150         popq %rbx
 151         .endm
 152
 153         .macro POP_C_REGS
 154         popq %r11
 155         popq %r10
 156         popq %r9
 157         popq %r8
 158         popq %rax
 159         popq %rcx
 160         popq %rdx
 161         popq %rsi
 162         popq %rdi
 163         .endm
 164
 165         .macro icebp
 166         .byte 0xf1
 167         .endm
 168
 169 /*
 170  * This is a sneaky trick to help the unwinder find pt_regs on the stack.  The
 171  * frame pointer is replaced with an encoded pointer to pt_regs.  The encoding
 172  * is just setting the LSB, which makes it an invalid stack address and is also
 173  * a signal to the unwinder that it's a pt_regs pointer in disguise.
 174  *
 175  * NOTE: This macro must be used *after* SAVE_EXTRA_REGS because it corrupts
 176  * the original rbp.
 177  */
 178 .macro ENCODE_FRAME_POINTER ptregs_offset=0
 179 #ifdef CONFIG_FRAME_POINTER
 180         .if \ptregs_offset
 181                 leaq \ptregs_offset(%rsp), %rbp
 182         .else
 183                 mov %rsp, %rbp
 184         .endif
 185         orq     $0x1, %rbp
 186 #endif
 187 .endm
 188
 189 #endif /* CONFIG_X86_64 */
 190
 191 /*
 192  * This does 'call enter_from_user_mode' unless we can avoid it based on
 193  * kernel config or using the static jump infrastructure.
 194  */
 195 .macro CALL_enter_from_user_mode
 196 #ifdef CONFIG_CONTEXT_TRACKING
 197 #ifdef HAVE_JUMP_LABEL
 198         STATIC_JUMP_IF_FALSE .Lafter_call_\@, context_tracking_enabled, def=0
 199 #endif
 200         call enter_from_user_mode
 201 .Lafter_call_\@:
 202 #endif
 203 .endm