arch/x86/entry/calling.h

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #include <linux/jump_label.h>
   3 #include <asm/unwind_hints.h>
   4
   5 /*
   6
   7  x86 function call convention, 64-bit:
   8  -------------------------------------
   9   arguments           |  callee-saved      | extra caller-saved | return
  10  [callee-clobbered]   |                    | [callee-clobbered] |
  11  ---------------------------------------------------------------------------
  12  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
  13
  14  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  15    functions when it sees tail-call optimization possibilities) rflags is
  16    clobbered. Leftover arguments are passed over the stack frame.)
  17
  18  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  19
  20  [**] for struct return values wider than 64 bits the return convention is a
  21       bit more complex: up to 128 bits width we return small structures
  22       straight in rax, rdx. For structures larger than that (3 words or
  23       larger) the caller puts a pointer to an on-stack return struct
  24       [allocated in the caller's stack frame] into the first argument - i.e.
  25       into rdi. All other arguments shift up by one in this case.
  26       Fortunately this case is rare in the kernel.
  27
  28 For 32-bit we have the following conventions - kernel is built with
  29 -mregparm=3 and -freg-struct-return:
  30
  31  x86 function calling convention, 32-bit:
  32  ----------------------------------------
  33   arguments         | callee-saved        | extra caller-saved | return
  34  [callee-clobbered] |                     | [callee-clobbered] |
  35  -------------------------------------------------------------------------
  36  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  37
  38  ( here too esp is obviously invariant across normal function calls. eflags
  39    is clobbered. Leftover arguments are passed over the stack frame. )
  40
  41  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  42
  43  [**] We build with -freg-struct-return, which on 32-bit means similar
  44       semantics as on 64-bit: edx can be used for a second return value
  45       (i.e. covering integer and structure sizes up to 64 bits) - after that
  46       it gets more complex and more expensive: 3-word or larger struct returns
  47       get done in the caller's frame and the pointer to the return struct goes
  48       into regparm0, i.e. eax - the other arguments shift up and the
  49       function's register parameters degenerate to regparm=2 in essence.
  50
  51 */
  52
  53 #ifdef CONFIG_X86_64
  54
  55 /*
  56  * 64-bit system call stack frame layout defines and helpers,
  57  * for assembly code:
  58  */
  59
  60 /* The layout forms the "struct pt_regs" on the stack: */
  61 /*
  62  * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
  63  * unless syscall needs a complete, fully filled "struct pt_regs".
  64  */
  65 #define R15             0*8
  66 #define R14             1*8
  67 #define R13             2*8
  68 #define R12             3*8
  69 #define RBP             4*8
  70 #define RBX             5*8
  71 /* These regs are callee-clobbered. Always saved on kernel entry. */
  72 #define R11             6*8
  73 #define R10             7*8
  74 #define R9              8*8
  75 #define R8              9*8
  76 #define RAX             10*8
  77 #define RCX             11*8
  78 #define RDX             12*8
  79 #define RSI             13*8
  80 #define RDI             14*8
  81 /*
  82  * On syscall entry, this is syscall#. On CPU exception, this is error code.
  83  * On hw interrupt, it's IRQ number:
  84  */
  85 #define ORIG_RAX        15*8
  86 /* Return frame for iretq */
  87 #define RIP             16*8
  88 #define CS              17*8
  89 #define EFLAGS          18*8
  90 #define RSP             19*8
  91 #define SS              20*8
  92
  93 #define SIZEOF_PTREGS   21*8
  94
  95         .macro ALLOC_PT_GPREGS_ON_STACK
  96         addq    $-(15*8), %rsp
  97         .endm
  98
  99         .macro SAVE_C_REGS_HELPER offset=0 rax=1 rcx=1 r8910=1 r11=1
 100         .if \r11
 101         movq %r11, 6*8+\offset(%rsp)
 102         .endif
 103         .if \r8910
 104         movq %r10, 7*8+\offset(%rsp)
 105         movq %r9,  8*8+\offset(%rsp)
 106         movq %r8,  9*8+\offset(%rsp)
 107         .endif
 108         .if \rax
 109         movq %rax, 10*8+\offset(%rsp)
 110         .endif
 111         .if \rcx
 112         movq %rcx, 11*8+\offset(%rsp)
 113         .endif
 114         movq %rdx, 12*8+\offset(%rsp)
 115         movq %rsi, 13*8+\offset(%rsp)
 116         movq %rdi, 14*8+\offset(%rsp)
 117         UNWIND_HINT_REGS offset=\offset extra=0
 118         .endm
 119         .macro SAVE_C_REGS offset=0
 120         SAVE_C_REGS_HELPER \offset, 1, 1, 1, 1
 121         .endm
 122         .macro SAVE_C_REGS_EXCEPT_RAX_RCX offset=0
 123         SAVE_C_REGS_HELPER \offset, 0, 0, 1, 1
 124         .endm
 125         .macro SAVE_C_REGS_EXCEPT_R891011
 126         SAVE_C_REGS_HELPER 0, 1, 1, 0, 0
 127         .endm
 128         .macro SAVE_C_REGS_EXCEPT_RCX_R891011
 129         SAVE_C_REGS_HELPER 0, 1, 0, 0, 0
 130         .endm
 131         .macro SAVE_C_REGS_EXCEPT_RAX_RCX_R11
 132         SAVE_C_REGS_HELPER 0, 0, 0, 1, 0
 133         .endm
 134
 135         .macro SAVE_EXTRA_REGS offset=0
 136         movq %r15, 0*8+\offset(%rsp)
 137         movq %r14, 1*8+\offset(%rsp)
 138         movq %r13, 2*8+\offset(%rsp)
 139         movq %r12, 3*8+\offset(%rsp)
 140         movq %rbp, 4*8+\offset(%rsp)
 141         movq %rbx, 5*8+\offset(%rsp)
 142         UNWIND_HINT_REGS offset=\offset
 143         .endm
 144
 145         .macro RESTORE_EXTRA_REGS offset=0
 146         movq 0*8+\offset(%rsp), %r15
 147         movq 1*8+\offset(%rsp), %r14
 148         movq 2*8+\offset(%rsp), %r13
 149         movq 3*8+\offset(%rsp), %r12
 150         movq 4*8+\offset(%rsp), %rbp
 151         movq 5*8+\offset(%rsp), %rbx
 152         UNWIND_HINT_REGS offset=\offset extra=0
 153         .endm
 154
 155         .macro RESTORE_C_REGS_HELPER rstor_rax=1, rstor_rcx=1, rstor_r11=1, rstor_r8910=1, rstor_rdx=1
 156         .if \rstor_r11
 157         movq 6*8(%rsp), %r11
 158         .endif
 159         .if \rstor_r8910
 160         movq 7*8(%rsp), %r10
 161         movq 8*8(%rsp), %r9
 162         movq 9*8(%rsp), %r8
 163         .endif
 164         .if \rstor_rax
 165         movq 10*8(%rsp), %rax
 166         .endif
 167         .if \rstor_rcx
 168         movq 11*8(%rsp), %rcx
 169         .endif
 170         .if \rstor_rdx
 171         movq 12*8(%rsp), %rdx
 172         .endif
 173         movq 13*8(%rsp), %rsi
 174         movq 14*8(%rsp), %rdi
 175         UNWIND_HINT_IRET_REGS offset=16*8
 176         .endm
 177         .macro RESTORE_C_REGS
 178         RESTORE_C_REGS_HELPER 1,1,1,1,1
 179         .endm
 180         .macro RESTORE_C_REGS_EXCEPT_RAX
 181         RESTORE_C_REGS_HELPER 0,1,1,1,1
 182         .endm
 183         .macro RESTORE_C_REGS_EXCEPT_RCX
 184         RESTORE_C_REGS_HELPER 1,0,1,1,1
 185         .endm
 186         .macro RESTORE_C_REGS_EXCEPT_R11
 187         RESTORE_C_REGS_HELPER 1,1,0,1,1
 188         .endm
 189         .macro RESTORE_C_REGS_EXCEPT_RCX_R11
 190         RESTORE_C_REGS_HELPER 1,0,0,1,1
 191         .endm
 192
 193         .macro REMOVE_PT_GPREGS_FROM_STACK addskip=0
 194         subq $-(15*8+\addskip), %rsp
 195         .endm
 196
 197         .macro icebp
 198         .byte 0xf1
 199         .endm
 200
 201 /*
 202  * This is a sneaky trick to help the unwinder find pt_regs on the stack.  The
 203  * frame pointer is replaced with an encoded pointer to pt_regs.  The encoding
 204  * is just setting the LSB, which makes it an invalid stack address and is also
 205  * a signal to the unwinder that it's a pt_regs pointer in disguise.
 206  *
 207  * NOTE: This macro must be used *after* SAVE_EXTRA_REGS because it corrupts
 208  * the original rbp.
 209  */
 210 .macro ENCODE_FRAME_POINTER ptregs_offset=0
 211 #ifdef CONFIG_FRAME_POINTER
 212         .if \ptregs_offset
 213                 leaq \ptregs_offset(%rsp), %rbp
 214         .else
 215                 mov %rsp, %rbp
 216         .endif
 217         orq     $0x1, %rbp
 218 #endif
 219 .endm
 220
 221 #endif /* CONFIG_X86_64 */
 222
 223 /*
 224  * This does 'call enter_from_user_mode' unless we can avoid it based on
 225  * kernel config or using the static jump infrastructure.
 226  */
 227 .macro CALL_enter_from_user_mode
 228 #ifdef CONFIG_CONTEXT_TRACKING
 229 #ifdef HAVE_JUMP_LABEL
 230         STATIC_JUMP_IF_FALSE .Lafter_call_\@, context_tracking_enabled, def=0
 231 #endif
 232         call enter_from_user_mode
 233 .Lafter_call_\@:
 234 #endif
 235 .endm