arch/x86/boot/header.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *      header.S
   4  *
   5  *      Copyright (C) 1991, 1992 Linus Torvalds
   6  *
   7  *      Based on bootsect.S and setup.S
   8  *      modified by more people than can be counted
   9  *
  10  *      Rewritten as a common file by H. Peter Anvin (Apr 2007)
  11  *
  12  * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
  13  * addresses must be multiplied by 16 to obtain their respective linear
  14  * addresses. To avoid confusion, linear addresses are written using leading
  15  * hex while segment addresses are written as segment:offset.
  16  *
  17  */
  18 #include <linux/pe.h>
  19 #include <asm/segment.h>
  20 #include <asm/boot.h>
  21 #include <asm/page_types.h>
  22 #include <asm/setup.h>
  23 #include <asm/bootparam.h>
  24 #include "boot.h"
  25 #include "voffset.h"
  26 #include "zoffset.h"
  27
  28 BOOTSEG         = 0x07C0                /* original address of boot-sector */
  29 SYSSEG          = 0x1000                /* historical load address >> 4 */
  30
  31 #ifndef SVGA_MODE
  32 #define SVGA_MODE ASK_VGA
  33 #endif
  34
  35 #ifndef ROOT_RDONLY
  36 #define ROOT_RDONLY 1
  37 #endif
  38
  39         .code16
  40         .section ".bstext", "ax"
  41
  42         .global bootsect_start
  43 bootsect_start:
  44 #ifdef CONFIG_EFI_STUB
  45         # "MZ", MS-DOS header
  46         .word   MZ_MAGIC
  47 #endif
  48
  49         # Normalize the start address
  50         ljmp    $BOOTSEG, $start2
  51
  52 start2:
  53         movw    %cs, %ax
  54         movw    %ax, %ds
  55         movw    %ax, %es
  56         movw    %ax, %ss
  57         xorw    %sp, %sp
  58         sti
  59         cld
  60
  61         movw    $bugger_off_msg, %si
  62
  63 msg_loop:
  64         lodsb
  65         andb    %al, %al
  66         jz      bs_die
  67         movb    $0xe, %ah
  68         movw    $7, %bx
  69         int     $0x10
  70         jmp     msg_loop
  71
  72 bs_die:
  73         # Allow the user to press a key, then reboot
  74         xorw    %ax, %ax
  75         int     $0x16
  76         int     $0x19
  77
  78         # int 0x19 should never return.  In case it does anyway,
  79         # invoke the BIOS reset code...
  80         ljmp    $0xf000,$0xfff0
  81
  82 #ifdef CONFIG_EFI_STUB
  83         .org    0x3c
  84         #
  85         # Offset to the PE header.
  86         #
  87         .long   pe_header
  88 #endif /* CONFIG_EFI_STUB */
  89
  90         .section ".bsdata", "a"
  91 bugger_off_msg:
  92         .ascii  "Use a boot loader.\r\n"
  93         .ascii  "\n"
  94         .ascii  "Remove disk and press any key to reboot...\r\n"
  95         .byte   0
  96
  97 #ifdef CONFIG_EFI_STUB
  98 pe_header:
  99         .long   PE_MAGIC
 100
 101 coff_header:
 102 #ifdef CONFIG_X86_32
 103         .set    image_file_add_flags, IMAGE_FILE_32BIT_MACHINE
 104         .set    pe_opt_magic, PE_OPT_MAGIC_PE32
 105         .word   IMAGE_FILE_MACHINE_I386
 106 #else
 107         .set    image_file_add_flags, 0
 108         .set    pe_opt_magic, PE_OPT_MAGIC_PE32PLUS
 109         .word   IMAGE_FILE_MACHINE_AMD64
 110 #endif
 111         .word   section_count                   # nr_sections
 112         .long   0                               # TimeDateStamp
 113         .long   0                               # PointerToSymbolTable
 114         .long   1                               # NumberOfSymbols
 115         .word   section_table - optional_header # SizeOfOptionalHeader
 116         .word   IMAGE_FILE_EXECUTABLE_IMAGE     | \
 117                 image_file_add_flags            | \
 118                 IMAGE_FILE_DEBUG_STRIPPED       | \
 119                 IMAGE_FILE_LINE_NUMS_STRIPPED   # Characteristics
 120
 121 optional_header:
 122         .word   pe_opt_magic
 123         .byte   0x02                            # MajorLinkerVersion
 124         .byte   0x14                            # MinorLinkerVersion
 125
 126         # Filled in by build.c
 127         .long   0                               # SizeOfCode
 128
 129         .long   0                               # SizeOfInitializedData
 130         .long   0                               # SizeOfUninitializedData
 131
 132         # Filled in by build.c
 133         .long   0x0000                          # AddressOfEntryPoint
 134
 135         .long   0x0200                          # BaseOfCode
 136 #ifdef CONFIG_X86_32
 137         .long   0                               # data
 138 #endif
 139
 140 extra_header_fields:
 141 #ifdef CONFIG_X86_32
 142         .long   0                               # ImageBase
 143 #else
 144         .quad   0                               # ImageBase
 145 #endif
 146         .long   0x20                            # SectionAlignment
 147         .long   0x20                            # FileAlignment
 148         .word   0                               # MajorOperatingSystemVersion
 149         .word   0                               # MinorOperatingSystemVersion
 150         .word   0                               # MajorImageVersion
 151         .word   0                               # MinorImageVersion
 152         .word   0                               # MajorSubsystemVersion
 153         .word   0                               # MinorSubsystemVersion
 154         .long   0                               # Win32VersionValue
 155
 156         #
 157         # The size of the bzImage is written in tools/build.c
 158         #
 159         .long   0                               # SizeOfImage
 160
 161         .long   0x200                           # SizeOfHeaders
 162         .long   0                               # CheckSum
 163         .word   IMAGE_SUBSYSTEM_EFI_APPLICATION # Subsystem (EFI application)
 164         .word   0                               # DllCharacteristics
 165 #ifdef CONFIG_X86_32
 166         .long   0                               # SizeOfStackReserve
 167         .long   0                               # SizeOfStackCommit
 168         .long   0                               # SizeOfHeapReserve
 169         .long   0                               # SizeOfHeapCommit
 170 #else
 171         .quad   0                               # SizeOfStackReserve
 172         .quad   0                               # SizeOfStackCommit
 173         .quad   0                               # SizeOfHeapReserve
 174         .quad   0                               # SizeOfHeapCommit
 175 #endif
 176         .long   0                               # LoaderFlags
 177         .long   (section_table - .) / 8         # NumberOfRvaAndSizes
 178
 179         .quad   0                               # ExportTable
 180         .quad   0                               # ImportTable
 181         .quad   0                               # ResourceTable
 182         .quad   0                               # ExceptionTable
 183         .quad   0                               # CertificationTable
 184         .quad   0                               # BaseRelocationTable
 185
 186         # Section table
 187 section_table:
 188         #
 189         # The offset & size fields are filled in by build.c.
 190         #
 191         .ascii  ".setup"
 192         .byte   0
 193         .byte   0
 194         .long   0
 195         .long   0x0                             # startup_{32,64}
 196         .long   0                               # Size of initialized data
 197                                                 # on disk
 198         .long   0x0                             # startup_{32,64}
 199         .long   0                               # PointerToRelocations
 200         .long   0                               # PointerToLineNumbers
 201         .word   0                               # NumberOfRelocations
 202         .word   0                               # NumberOfLineNumbers
 203         .long   IMAGE_SCN_CNT_CODE              | \
 204                 IMAGE_SCN_MEM_READ              | \
 205                 IMAGE_SCN_MEM_EXECUTE           | \
 206                 IMAGE_SCN_ALIGN_16BYTES         # Characteristics
 207
 208         #
 209         # The EFI application loader requires a relocation section
 210         # because EFI applications must be relocatable. The .reloc
 211         # offset & size fields are filled in by build.c.
 212         #
 213         .ascii  ".reloc"
 214         .byte   0
 215         .byte   0
 216         .long   0
 217         .long   0
 218         .long   0                               # SizeOfRawData
 219         .long   0                               # PointerToRawData
 220         .long   0                               # PointerToRelocations
 221         .long   0                               # PointerToLineNumbers
 222         .word   0                               # NumberOfRelocations
 223         .word   0                               # NumberOfLineNumbers
 224         .long   IMAGE_SCN_CNT_INITIALIZED_DATA  | \
 225                 IMAGE_SCN_MEM_READ              | \
 226                 IMAGE_SCN_MEM_DISCARDABLE       | \
 227                 IMAGE_SCN_ALIGN_1BYTES          # Characteristics
 228
 229 #ifdef CONFIG_EFI_MIXED
 230         #
 231         # The offset & size fields are filled in by build.c.
 232         #
 233         .asciz  ".compat"
 234         .long   0
 235         .long   0x0
 236         .long   0                               # Size of initialized data
 237                                                 # on disk
 238         .long   0x0
 239         .long   0                               # PointerToRelocations
 240         .long   0                               # PointerToLineNumbers
 241         .word   0                               # NumberOfRelocations
 242         .word   0                               # NumberOfLineNumbers
 243         .long   IMAGE_SCN_CNT_INITIALIZED_DATA  | \
 244                 IMAGE_SCN_MEM_READ              | \
 245                 IMAGE_SCN_MEM_DISCARDABLE       | \
 246                 IMAGE_SCN_ALIGN_1BYTES          # Characteristics
 247 #endif
 248
 249         #
 250         # The offset & size fields are filled in by build.c.
 251         #
 252         .ascii  ".text"
 253         .byte   0
 254         .byte   0
 255         .byte   0
 256         .long   0
 257         .long   0x0                             # startup_{32,64}
 258         .long   0                               # Size of initialized data
 259                                                 # on disk
 260         .long   0x0                             # startup_{32,64}
 261         .long   0                               # PointerToRelocations
 262         .long   0                               # PointerToLineNumbers
 263         .word   0                               # NumberOfRelocations
 264         .word   0                               # NumberOfLineNumbers
 265         .long   IMAGE_SCN_CNT_CODE              | \
 266                 IMAGE_SCN_MEM_READ              | \
 267                 IMAGE_SCN_MEM_EXECUTE           | \
 268                 IMAGE_SCN_ALIGN_16BYTES         # Characteristics
 269
 270         .set    section_count, (. - section_table) / 40
 271 #endif /* CONFIG_EFI_STUB */
 272
 273         # Kernel attributes; used by setup.  This is part 1 of the
 274         # header, from the old boot sector.
 275
 276         .section ".header", "a"
 277         .globl  sentinel
 278 sentinel:       .byte 0xff, 0xff        /* Used to detect broken loaders */
 279
 280         .globl  hdr
 281 hdr:
 282 setup_sects:    .byte 0                 /* Filled in by build.c */
 283 root_flags:     .word ROOT_RDONLY
 284 syssize:        .long 0                 /* Filled in by build.c */
 285 ram_size:       .word 0                 /* Obsolete */
 286 vid_mode:       .word SVGA_MODE
 287 root_dev:       .word 0                 /* Filled in by build.c */
 288 boot_flag:      .word 0xAA55
 289
 290         # offset 512, entry point
 291
 292         .globl  _start
 293 _start:
 294                 # Explicitly enter this as bytes, or the assembler
 295                 # tries to generate a 3-byte jump here, which causes
 296                 # everything else to push off to the wrong offset.
 297                 .byte   0xeb            # short (2-byte) jump
 298                 .byte   start_of_setup-1f
 299 1:
 300
 301         # Part 2 of the header, from the old setup.S
 302
 303                 .ascii  "HdrS"          # header signature
 304                 .word   0x020f          # header version number (>= 0x0105)
 305                                         # or else old loadlin-1.5 will fail)
 306                 .globl realmode_swtch
 307 realmode_swtch: .word   0, 0            # default_switch, SETUPSEG
 308 start_sys_seg:  .word   SYSSEG          # obsolete and meaningless, but just
 309                                         # in case something decided to "use" it
 310                 .word   kernel_version-512 # pointing to kernel version string
 311                                         # above section of header is compatible
 312                                         # with loadlin-1.5 (header v1.5). Don't
 313                                         # change it.
 314
 315 type_of_loader: .byte   0               # 0 means ancient bootloader, newer
 316                                         # bootloaders know to change this.
 317                                         # See Documentation/x86/boot.rst for
 318                                         # assigned ids
 319
 320 # flags, unused bits must be zero (RFU) bit within loadflags
 321 loadflags:
 322                 .byte   LOADED_HIGH     # The kernel is to be loaded high
 323
 324 setup_move_size: .word  0x8000          # size to move, when setup is not
 325                                         # loaded at 0x90000. We will move setup
 326                                         # to 0x90000 then just before jumping
 327                                         # into the kernel. However, only the
 328                                         # loader knows how much data behind
 329                                         # us also needs to be loaded.
 330
 331 code32_start:                           # here loaders can put a different
 332                                         # start address for 32-bit code.
 333                 .long   0x100000        # 0x100000 = default for big kernel
 334
 335 ramdisk_image:  .long   0               # address of loaded ramdisk image
 336                                         # Here the loader puts the 32-bit
 337                                         # address where it loaded the image.
 338                                         # This only will be read by the kernel.
 339
 340 ramdisk_size:   .long   0               # its size in bytes
 341
 342 bootsect_kludge:
 343                 .long   0               # obsolete
 344
 345 heap_end_ptr:   .word   _end+STACK_SIZE-512
 346                                         # (Header version 0x0201 or later)
 347                                         # space from here (exclusive) down to
 348                                         # end of setup code can be used by setup
 349                                         # for local heap purposes.
 350
 351 ext_loader_ver:
 352                 .byte   0               # Extended boot loader version
 353 ext_loader_type:
 354                 .byte   0               # Extended boot loader type
 355
 356 cmd_line_ptr:   .long   0               # (Header version 0x0202 or later)
 357                                         # If nonzero, a 32-bit pointer
 358                                         # to the kernel command line.
 359                                         # The command line should be
 360                                         # located between the start of
 361                                         # setup and the end of low
 362                                         # memory (0xa0000), or it may
 363                                         # get overwritten before it
 364                                         # gets read.  If this field is
 365                                         # used, there is no longer
 366                                         # anything magical about the
 367                                         # 0x90000 segment; the setup
 368                                         # can be located anywhere in
 369                                         # low memory 0x10000 or higher.
 370
 371 initrd_addr_max: .long 0x7fffffff
 372                                         # (Header version 0x0203 or later)
 373                                         # The highest safe address for
 374                                         # the contents of an initrd
 375                                         # The current kernel allows up to 4 GB,
 376                                         # but leave it at 2 GB to avoid
 377                                         # possible bootloader bugs.
 378
 379 kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN  #physical addr alignment
 380                                                 #required for protected mode
 381                                                 #kernel
 382 #ifdef CONFIG_RELOCATABLE
 383 relocatable_kernel:    .byte 1
 384 #else
 385 relocatable_kernel:    .byte 0
 386 #endif
 387 min_alignment:          .byte MIN_KERNEL_ALIGN_LG2      # minimum alignment
 388
 389 xloadflags:
 390 #ifdef CONFIG_X86_64
 391 # define XLF0 XLF_KERNEL_64                     /* 64-bit kernel */
 392 #else
 393 # define XLF0 0
 394 #endif
 395
 396 #if defined(CONFIG_RELOCATABLE) && defined(CONFIG_X86_64)
 397    /* kernel/boot_param/ramdisk could be loaded above 4g */
 398 # define XLF1 XLF_CAN_BE_LOADED_ABOVE_4G
 399 #else
 400 # define XLF1 0
 401 #endif
 402
 403 #ifdef CONFIG_EFI_STUB
 404 # ifdef CONFIG_EFI_MIXED
 405 #  define XLF23 (XLF_EFI_HANDOVER_32|XLF_EFI_HANDOVER_64)
 406 # else
 407 #  ifdef CONFIG_X86_64
 408 #   define XLF23 XLF_EFI_HANDOVER_64            /* 64-bit EFI handover ok */
 409 #  else
 410 #   define XLF23 XLF_EFI_HANDOVER_32            /* 32-bit EFI handover ok */
 411 #  endif
 412 # endif
 413 #else
 414 # define XLF23 0
 415 #endif
 416
 417 #if defined(CONFIG_X86_64) && defined(CONFIG_EFI) && defined(CONFIG_KEXEC_CORE)
 418 # define XLF4 XLF_EFI_KEXEC
 419 #else
 420 # define XLF4 0
 421 #endif
 422
 423 #ifdef CONFIG_X86_64
 424 #ifdef CONFIG_X86_5LEVEL
 425 #define XLF56 (XLF_5LEVEL|XLF_5LEVEL_ENABLED)
 426 #else
 427 #define XLF56 XLF_5LEVEL
 428 #endif
 429 #else
 430 #define XLF56 0
 431 #endif
 432
 433                         .word XLF0 | XLF1 | XLF23 | XLF4 | XLF56
 434
 435 cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
 436                                                 #added with boot protocol
 437                                                 #version 2.06
 438
 439 hardware_subarch:       .long 0                 # subarchitecture, added with 2.07
 440                                                 # default to 0 for normal x86 PC
 441
 442 hardware_subarch_data:  .quad 0
 443
 444 payload_offset:         .long ZO_input_data
 445 payload_length:         .long ZO_z_input_len
 446
 447 setup_data:             .quad 0                 # 64-bit physical pointer to
 448                                                 # single linked list of
 449                                                 # struct setup_data
 450
 451 pref_address:           .quad LOAD_PHYSICAL_ADDR        # preferred load addr
 452
 453 #
 454 # Getting to provably safe in-place decompression is hard. Worst case
 455 # behaviours need to be analyzed. Here let's take the decompression of
 456 # a gzip-compressed kernel as example, to illustrate it:
 457 #
 458 # The file layout of gzip compressed kernel is:
 459 #
 460 #    magic[2]
 461 #    method[1]
 462 #    flags[1]
 463 #    timestamp[4]
 464 #    extraflags[1]
 465 #    os[1]
 466 #    compressed data blocks[N]
 467 #    crc[4] orig_len[4]
 468 #
 469 # ... resulting in +18 bytes overhead of uncompressed data.
 470 #
 471 # (For more information, please refer to RFC 1951 and RFC 1952.)
 472 #
 473 # Files divided into blocks
 474 # 1 bit (last block flag)
 475 # 2 bits (block type)
 476 #
 477 # 1 block occurs every 32K -1 bytes or when there 50% compression
 478 # has been achieved. The smallest block type encoding is always used.
 479 #
 480 # stored:
 481 #    32 bits length in bytes.
 482 #
 483 # fixed:
 484 #    magic fixed tree.
 485 #    symbols.
 486 #
 487 # dynamic:
 488 #    dynamic tree encoding.
 489 #    symbols.
 490 #
 491 #
 492 # The buffer for decompression in place is the length of the uncompressed
 493 # data, plus a small amount extra to keep the algorithm safe. The
 494 # compressed data is placed at the end of the buffer.  The output pointer
 495 # is placed at the start of the buffer and the input pointer is placed
 496 # where the compressed data starts. Problems will occur when the output
 497 # pointer overruns the input pointer.
 498 #
 499 # The output pointer can only overrun the input pointer if the input
 500 # pointer is moving faster than the output pointer.  A condition only
 501 # triggered by data whose compressed form is larger than the uncompressed
 502 # form.
 503 #
 504 # The worst case at the block level is a growth of the compressed data
 505 # of 5 bytes per 32767 bytes.
 506 #
 507 # The worst case internal to a compressed block is very hard to figure.
 508 # The worst case can at least be bounded by having one bit that represents
 509 # 32764 bytes and then all of the rest of the bytes representing the very
 510 # very last byte.
 511 #
 512 # All of which is enough to compute an amount of extra data that is required
 513 # to be safe.  To avoid problems at the block level allocating 5 extra bytes
 514 # per 32767 bytes of data is sufficient.  To avoid problems internal to a
 515 # block adding an extra 32767 bytes (the worst case uncompressed block size)
 516 # is sufficient, to ensure that in the worst case the decompressed data for
 517 # block will stop the byte before the compressed data for a block begins.
 518 # To avoid problems with the compressed data's meta information an extra 18
 519 # bytes are needed.  Leading to the formula:
 520 #
 521 # extra_bytes = (uncompressed_size >> 12) + 32768 + 18
 522 #
 523 # Adding 8 bytes per 32K is a bit excessive but much easier to calculate.
 524 # Adding 32768 instead of 32767 just makes for round numbers.
 525 #
 526 # Above analysis is for decompressing gzip compressed kernel only. Up to
 527 # now 6 different decompressor are supported all together. And among them
 528 # xz stores data in chunks and has maximum chunk of 64K. Hence safety
 529 # margin should be updated to cover all decompressors so that we don't
 530 # need to deal with each of them separately. Please check
 531 # the description in lib/decompressor_xxx.c for specific information.
 532 #
 533 # extra_bytes = (uncompressed_size >> 12) + 65536 + 128
 534 #
 535 # LZ4 is even worse: data that cannot be further compressed grows by 0.4%,
 536 # or one byte per 256 bytes. OTOH, we can safely get rid of the +128 as
 537 # the size-dependent part now grows so fast.
 538 #
 539 # extra_bytes = (uncompressed_size >> 8) + 65536
 540
 541 #define ZO_z_extra_bytes        ((ZO_z_output_len >> 8) + 65536)
 542 #if ZO_z_output_len > ZO_z_input_len
 543 # define ZO_z_extract_offset    (ZO_z_output_len + ZO_z_extra_bytes - \
 544                                  ZO_z_input_len)
 545 #else
 546 # define ZO_z_extract_offset    ZO_z_extra_bytes
 547 #endif
 548
 549 /*
 550  * The extract_offset has to be bigger than ZO head section. Otherwise when
 551  * the head code is running to move ZO to the end of the buffer, it will
 552  * overwrite the head code itself.
 553  */
 554 #if (ZO__ehead - ZO_startup_32) > ZO_z_extract_offset
 555 # define ZO_z_min_extract_offset ((ZO__ehead - ZO_startup_32 + 4095) & ~4095)
 556 #else
 557 # define ZO_z_min_extract_offset ((ZO_z_extract_offset + 4095) & ~4095)
 558 #endif
 559
 560 #define ZO_INIT_SIZE    (ZO__end - ZO_startup_32 + ZO_z_min_extract_offset)
 561
 562 #define VO_INIT_SIZE    (VO__end - VO__text)
 563 #if ZO_INIT_SIZE > VO_INIT_SIZE
 564 # define INIT_SIZE ZO_INIT_SIZE
 565 #else
 566 # define INIT_SIZE VO_INIT_SIZE
 567 #endif
 568
 569 init_size:              .long INIT_SIZE         # kernel initialization size
 570 handover_offset:        .long 0                 # Filled in by build.c
 571 kernel_info_offset:     .long 0                 # Filled in by build.c
 572
 573 # End of setup header #####################################################
 574
 575         .section ".entrytext", "ax"
 576 start_of_setup:
 577 # Force %es = %ds
 578         movw    %ds, %ax
 579         movw    %ax, %es
 580         cld
 581
 582 # Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
 583 # which happened to work by accident for the old code.  Recalculate the stack
 584 # pointer if %ss is invalid.  Otherwise leave it alone, LOADLIN sets up the
 585 # stack behind its own code, so we can't blindly put it directly past the heap.
 586
 587         movw    %ss, %dx
 588         cmpw    %ax, %dx        # %ds == %ss?
 589         movw    %sp, %dx
 590         je      2f              # -> assume %sp is reasonably set
 591
 592         # Invalid %ss, make up a new stack
 593         movw    $_end, %dx
 594         testb   $CAN_USE_HEAP, loadflags
 595         jz      1f
 596         movw    heap_end_ptr, %dx
 597 1:      addw    $STACK_SIZE, %dx
 598         jnc     2f
 599         xorw    %dx, %dx        # Prevent wraparound
 600
 601 2:      # Now %dx should point to the end of our stack space
 602         andw    $~3, %dx        # dword align (might as well...)
 603         jnz     3f
 604         movw    $0xfffc, %dx    # Make sure we're not zero
 605 3:      movw    %ax, %ss
 606         movzwl  %dx, %esp       # Clear upper half of %esp
 607         sti                     # Now we should have a working stack
 608
 609 # We will have entered with %cs = %ds+0x20, normalize %cs so
 610 # it is on par with the other segments.
 611         pushw   %ds
 612         pushw   $6f
 613         lretw
 614 6:
 615
 616 # Check signature at end of setup
 617         cmpl    $0x5a5aaa55, setup_sig
 618         jne     setup_bad
 619
 620 # Zero the bss
 621         movw    $__bss_start, %di
 622         movw    $_end+3, %cx
 623         xorl    %eax, %eax
 624         subw    %di, %cx
 625         shrw    $2, %cx
 626         rep; stosl
 627
 628 # Jump to C code (should not return)
 629         calll   main
 630
 631 # Setup corrupt somehow...
 632 setup_bad:
 633         movl    $setup_corrupt, %eax
 634         calll   puts
 635         # Fall through...
 636
 637         .globl  die
 638         .type   die, @function
 639 die:
 640         hlt
 641         jmp     die
 642
 643         .size   die, .-die
 644
 645         .section ".initdata", "a"
 646 setup_corrupt:
 647         .byte   7
 648         .string "No setup signature found...\n"