arch/powerpc/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #ifdef CONFIG_PPC64
   3 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   4 #else
   5 #define PROVIDE32(x)    PROVIDE(x)
   6 #endif
   7
   8 #define BSS_FIRST_SECTIONS *(.bss.prominit)
   9 #define EMITS_PT_NOTE
  10 #define RO_EXCEPTION_TABLE_ALIGN        0
  11
  12 #include <asm/page.h>
  13 #include <asm-generic/vmlinux.lds.h>
  14 #include <asm/cache.h>
  15 #include <asm/thread_info.h>
  16
  17 #define STRICT_ALIGN_SIZE       (1 << CONFIG_DATA_SHIFT)
  18
  19 ENTRY(_stext)
  20
  21 PHDRS {
  22         text PT_LOAD FLAGS(7); /* RWX */
  23         note PT_NOTE FLAGS(0);
  24 }
  25
  26 #ifdef CONFIG_PPC64
  27 OUTPUT_ARCH(powerpc:common64)
  28 jiffies = jiffies_64;
  29 #else
  30 OUTPUT_ARCH(powerpc:common)
  31 jiffies = jiffies_64 + 4;
  32 #endif
  33 SECTIONS
  34 {
  35         . = KERNELBASE;
  36
  37 /*
  38  * Text, read only data and other permanent read-only sections
  39  */
  40
  41         _text = .;
  42         _stext = .;
  43
  44         /*
  45          * Head text.
  46          * This needs to be in its own output section to avoid ld placing
  47          * branch trampoline stubs randomly throughout the fixed sections,
  48          * which it will do (even if the branch comes from another section)
  49          * in order to optimize stub generation.
  50          */
  51         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
  52 #ifdef CONFIG_PPC64
  53                 KEEP(*(.head.text.first_256B));
  54 #ifdef CONFIG_PPC_BOOK3E
  55 #else
  56                 KEEP(*(.head.text.real_vectors));
  57                 *(.head.text.real_trampolines);
  58                 KEEP(*(.head.text.virt_vectors));
  59                 *(.head.text.virt_trampolines);
  60 # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  61                 KEEP(*(.head.data.fwnmi_page));
  62 # endif
  63 #endif
  64 #else /* !CONFIG_PPC64 */
  65                 HEAD_TEXT
  66 #endif
  67         } :text
  68
  69         __head_end = .;
  70
  71 #ifdef CONFIG_PPC64
  72         /*
  73          * ALIGN(0) overrides the default output section alignment because
  74          * this needs to start right after .head.text in order for fixed
  75          * section placement to work.
  76          */
  77         .text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
  78 #ifdef CONFIG_LD_HEAD_STUB_CATCH
  79                 KEEP(*(.linker_stub_catch));
  80                 . = . ;
  81 #endif
  82
  83 #else
  84         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  85                 ALIGN_FUNCTION();
  86 #endif
  87                 /* careful! __ftr_alt_* sections need to be close to .text */
  88                 *(.text.hot .text.hot.* TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text);
  89 #ifdef CONFIG_PPC64
  90                 *(.tramp.ftrace.text);
  91 #endif
  92                 NOINSTR_TEXT
  93                 SCHED_TEXT
  94                 CPUIDLE_TEXT
  95                 LOCK_TEXT
  96                 KPROBES_TEXT
  97                 IRQENTRY_TEXT
  98                 SOFTIRQENTRY_TEXT
  99                 /*
 100                  * -Os builds call FP save/restore functions. The powerpc64
 101                  * linker generates those on demand in the .sfpr section.
 102                  * .sfpr gets placed at the beginning of a group of input
 103                  * sections, which can break start-of-text offset if it is
 104                  * included with the main text sections, so put it by itself.
 105                  */
 106                 *(.sfpr);
 107                 MEM_KEEP(init.text)
 108                 MEM_KEEP(exit.text)
 109
 110 #ifdef CONFIG_PPC32
 111                 *(.got1)
 112                 __got2_start = .;
 113                 *(.got2)
 114                 __got2_end = .;
 115 #endif /* CONFIG_PPC32 */
 116
 117         } :text
 118
 119         . = ALIGN(PAGE_SIZE);
 120         _etext = .;
 121         PROVIDE32 (etext = .);
 122
 123         /* Read-only data */
 124         RO_DATA(PAGE_SIZE)
 125
 126 #ifdef CONFIG_PPC64
 127         . = ALIGN(8);
 128         __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
 129                 __start___stf_entry_barrier_fixup = .;
 130                 *(__stf_entry_barrier_fixup)
 131                 __stop___stf_entry_barrier_fixup = .;
 132         }
 133
 134         . = ALIGN(8);
 135         __uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
 136                 __start___uaccess_flush_fixup = .;
 137                 *(__uaccess_flush_fixup)
 138                 __stop___uaccess_flush_fixup = .;
 139         }
 140
 141         . = ALIGN(8);
 142         __entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
 143                 __start___entry_flush_fixup = .;
 144                 *(__entry_flush_fixup)
 145                 __stop___entry_flush_fixup = .;
 146         }
 147
 148         . = ALIGN(8);
 149         __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
 150                 __start___stf_exit_barrier_fixup = .;
 151                 *(__stf_exit_barrier_fixup)
 152                 __stop___stf_exit_barrier_fixup = .;
 153         }
 154
 155         . = ALIGN(8);
 156         __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
 157                 __start___rfi_flush_fixup = .;
 158                 *(__rfi_flush_fixup)
 159                 __stop___rfi_flush_fixup = .;
 160         }
 161 #endif /* CONFIG_PPC64 */
 162
 163 #ifdef CONFIG_PPC_BARRIER_NOSPEC
 164         . = ALIGN(8);
 165         __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
 166                 __start___barrier_nospec_fixup = .;
 167                 *(__barrier_nospec_fixup)
 168                 __stop___barrier_nospec_fixup = .;
 169         }
 170 #endif /* CONFIG_PPC_BARRIER_NOSPEC */
 171
 172 #ifdef CONFIG_PPC_FSL_BOOK3E
 173         . = ALIGN(8);
 174         __spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
 175                 __start__btb_flush_fixup = .;
 176                 *(__btb_flush_fixup)
 177                 __stop__btb_flush_fixup = .;
 178         }
 179 #endif
 180
 181 /*
 182  * Init sections discarded at runtime
 183  */
 184         . = ALIGN(STRICT_ALIGN_SIZE);
 185         __init_begin = .;
 186         . = ALIGN(PAGE_SIZE);
 187         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 188                 _sinittext = .;
 189                 INIT_TEXT
 190
 191                 /*
 192                  *.init.text might be RO so we must ensure this section ends on
 193                  * a page boundary.
 194                  */
 195                 . = ALIGN(PAGE_SIZE);
 196                 _einittext = .;
 197 #ifdef CONFIG_PPC64
 198                 *(.tramp.ftrace.init);
 199 #endif
 200         } :text
 201
 202         /* .exit.text is discarded at runtime, not link time,
 203          * to deal with references from __bug_table
 204          */
 205         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 206                 EXIT_TEXT
 207         }
 208
 209         . = ALIGN(PAGE_SIZE);
 210
 211         INIT_DATA_SECTION(16)
 212
 213         . = ALIGN(8);
 214         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 215                 __start___ftr_fixup = .;
 216                 KEEP(*(__ftr_fixup))
 217                 __stop___ftr_fixup = .;
 218         }
 219         . = ALIGN(8);
 220         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
 221                 __start___mmu_ftr_fixup = .;
 222                 KEEP(*(__mmu_ftr_fixup))
 223                 __stop___mmu_ftr_fixup = .;
 224         }
 225         . = ALIGN(8);
 226         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
 227                 __start___lwsync_fixup = .;
 228                 KEEP(*(__lwsync_fixup))
 229                 __stop___lwsync_fixup = .;
 230         }
 231 #ifdef CONFIG_PPC64
 232         . = ALIGN(8);
 233         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 234                 __start___fw_ftr_fixup = .;
 235                 KEEP(*(__fw_ftr_fixup))
 236                 __stop___fw_ftr_fixup = .;
 237         }
 238 #endif
 239
 240         PERCPU_SECTION(L1_CACHE_BYTES)
 241
 242         . = ALIGN(8);
 243         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 244                 __machine_desc_start = . ;
 245                 KEEP(*(.machine.desc))
 246                 __machine_desc_end = . ;
 247         }
 248 #ifdef CONFIG_RELOCATABLE
 249         . = ALIGN(8);
 250         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
 251         {
 252 #ifdef CONFIG_PPC32
 253                 __dynamic_symtab = .;
 254 #endif
 255                 *(.dynsym)
 256         }
 257         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
 258         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
 259         {
 260                 __dynamic_start = .;
 261                 *(.dynamic)
 262         }
 263         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
 264         .gnu.hash : AT(ADDR(.gnu.hash) - LOAD_OFFSET) { *(.gnu.hash) }
 265         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
 266         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
 267         {
 268                 __rela_dyn_start = .;
 269                 *(.rela*)
 270         }
 271 #endif
 272         /* .exit.data is discarded at runtime, not link time,
 273          * to deal with references from .exit.text
 274          */
 275         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 276                 EXIT_DATA
 277         }
 278
 279         /* freed after init ends here */
 280         . = ALIGN(PAGE_SIZE);
 281         __init_end = .;
 282
 283 /*
 284  * And now the various read/write data
 285  */
 286
 287         . = ALIGN(PAGE_SIZE);
 288         _sdata = .;
 289
 290 #ifdef CONFIG_PPC32
 291         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 292                 DATA_DATA
 293 #ifdef CONFIG_UBSAN
 294                 *(.data..Lubsan_data*)
 295                 *(.data..Lubsan_type*)
 296 #endif
 297                 *(.data.rel*)
 298                 *(SDATA_MAIN)
 299                 *(.sdata2)
 300                 *(.got.plt) *(.got)
 301                 *(.plt)
 302                 *(.branch_lt)
 303         }
 304 #else
 305         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 306                 DATA_DATA
 307 #ifdef CONFIG_UBSAN
 308                 *(.data..Lubsan_data*)
 309                 *(.data..Lubsan_type*)
 310 #endif
 311                 *(.data.rel*)
 312                 *(.toc1)
 313                 *(.branch_lt)
 314         }
 315
 316         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 317                 __start_opd = .;
 318                 KEEP(*(.opd))
 319                 __end_opd = .;
 320         }
 321
 322         . = ALIGN(256);
 323         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 324                 __toc_start = .;
 325 #ifndef CONFIG_RELOCATABLE
 326                 __prom_init_toc_start = .;
 327                 arch/powerpc/kernel/prom_init.o*(.toc .got)
 328                 __prom_init_toc_end = .;
 329 #endif
 330                 *(.got)
 331                 *(.toc)
 332         }
 333 #endif
 334
 335         /* The initial task and kernel stack */
 336         INIT_TASK_DATA_SECTION(THREAD_ALIGN)
 337
 338         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
 339                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 340         }
 341
 342         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
 343                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 344         }
 345
 346         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
 347                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 348         }
 349
 350         . = ALIGN(PAGE_SIZE);
 351         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 352                 NOSAVE_DATA
 353         }
 354
 355         BUG_TABLE
 356
 357         . = ALIGN(PAGE_SIZE);
 358         _edata  =  .;
 359         PROVIDE32 (edata = .);
 360
 361 /*
 362  * And finally the bss
 363  */
 364
 365         BSS_SECTION(0, 0, 0)
 366
 367         . = ALIGN(PAGE_SIZE);
 368         _end = . ;
 369         PROVIDE32 (end = .);
 370
 371         STABS_DEBUG
 372         DWARF_DEBUG
 373         ELF_DETAILS
 374
 375         DISCARDS
 376         /DISCARD/ : {
 377                 *(*.EMB.apuinfo)
 378                 *(.glink .iplt .plt .rela* .comment)
 379                 *(.gnu.version*)
 380                 *(.gnu.attributes)
 381                 *(.eh_frame)
 382         }
 383 }