arch/openrisc/kernel/vmlinux.lds.S

   1 /*
   2  * OpenRISC vmlinux.lds.S
   3  *
   4  * Linux architectural port borrowing liberally from similar works of
   5  * others.  All original copyrights apply as per the original source
   6  * declaration.
   7  *
   8  * Modifications for the OpenRISC architecture:
   9  * Copyright (C) 2003 Matjaz Breskvar <phoenix@bsemi.com>
  10  * Copyright (C) 2010-2011 Jonas Bonn <jonas@southpole.se>
  11  *
  12  *      This program is free software; you can redistribute it and/or
  13  *      modify it under the terms of the GNU General Public License
  14  *      as published by the Free Software Foundation; either version
  15  *      2 of the License, or (at your option) any later version.
  16  *
  17  * ld script for OpenRISC architecture
  18  */
  19
  20 /* TODO
  21  *              - clean up __offset & stuff
  22  *              - change all 8192 aligment to PAGE !!!
  23  *              - recheck if all aligments are really needed
  24  */
  25
  26 #  define LOAD_OFFSET  PAGE_OFFSET
  27 #  define LOAD_BASE    PAGE_OFFSET
  28
  29 #include <asm/page.h>
  30 #include <asm/cache.h>
  31 #include <asm-generic/vmlinux.lds.h>
  32
  33 #ifdef __OR1K__
  34 #define __OUTPUT_FORMAT        "elf32-or1k"
  35 #else
  36 #define __OUTPUT_FORMAT        "elf32-or32"
  37 #endif
  38
  39 OUTPUT_FORMAT(__OUTPUT_FORMAT, __OUTPUT_FORMAT, __OUTPUT_FORMAT)
  40 jiffies = jiffies_64 + 4;
  41
  42 SECTIONS
  43 {
  44         /* Read-only sections, merged into text segment: */
  45         . = LOAD_BASE ;
  46
  47         /* _s_kernel_ro must be page aligned */
  48         . = ALIGN(PAGE_SIZE);
  49         _s_kernel_ro = .;
  50
  51         .text                   : AT(ADDR(.text) - LOAD_OFFSET)
  52         {
  53           _stext = .;
  54           TEXT_TEXT
  55           SCHED_TEXT
  56           CPUIDLE_TEXT
  57           LOCK_TEXT
  58           KPROBES_TEXT
  59           IRQENTRY_TEXT
  60           SOFTIRQENTRY_TEXT
  61           *(.fixup)
  62           *(.text.__*)
  63           _etext = .;
  64         }
  65         /* TODO: Check if fixup and text.__* are really necessary
  66          * fixup is definitely necessary
  67          */
  68
  69         _sdata = .;
  70
  71         /* Page alignment required for RO_DATA_SECTION */
  72         RO_DATA_SECTION(PAGE_SIZE)
  73         _e_kernel_ro = .;
  74
  75         /* Whatever comes after _e_kernel_ro had better be page-aligend, too */
  76
  77         /* 32 here is cacheline size... recheck this */
  78         RW_DATA_SECTION(32, PAGE_SIZE, PAGE_SIZE)
  79
  80         _edata  =  .;
  81
  82         EXCEPTION_TABLE(4)
  83         NOTES
  84
  85         /* Init code and data */
  86         . = ALIGN(PAGE_SIZE);
  87         __init_begin = .;
  88
  89         HEAD_TEXT_SECTION
  90
  91         /* Page aligned */
  92         INIT_TEXT_SECTION(PAGE_SIZE)
  93
  94         /* Align __setup_start on 16 byte boundary */
  95         INIT_DATA_SECTION(16)
  96
  97         PERCPU_SECTION(L1_CACHE_BYTES)
  98
  99         __init_end = .;
 100
 101         . = ALIGN(PAGE_SIZE);
 102         .initrd                 : AT(ADDR(.initrd) - LOAD_OFFSET)
 103         {
 104                 __initrd_start = .;
 105                 *(.initrd)
 106                 __initrd_end = .;
 107                 FILL (0);
 108                 . = ALIGN (PAGE_SIZE);
 109         }
 110
 111         __vmlinux_end = .;            /* last address of the physical file */
 112
 113         BSS_SECTION(0, 0, 0x20)
 114
 115         _end = .;
 116
 117         /* Throw in the debugging sections */
 118         STABS_DEBUG
 119         DWARF_DEBUG
 120
 121         /* Sections to be discarded -- must be last */
 122         DISCARDS
 123 }