arch/arm64/kernel/head.S

   1 /*
   2  * Low-level CPU initialisation
   3  * Based on arch/arm/kernel/head.S
   4  *
   5  * Copyright (C) 1994-2002 Russell King
   6  * Copyright (C) 2003-2012 ARM Ltd.
   7  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   8  *              Will Deacon <will.deacon@arm.com>
   9  *
  10  * This program is free software; you can redistribute it and/or modify
  11  * it under the terms of the GNU General Public License version 2 as
  12  * published by the Free Software Foundation.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21  */
  22
  23 #include <linux/linkage.h>
  24 #include <linux/init.h>
  25 #include <linux/irqchip/arm-gic-v3.h>
  26
  27 #include <asm/assembler.h>
  28 #include <asm/boot.h>
  29 #include <asm/ptrace.h>
  30 #include <asm/asm-offsets.h>
  31 #include <asm/cache.h>
  32 #include <asm/cputype.h>
  33 #include <asm/elf.h>
  34 #include <asm/kernel-pgtable.h>
  35 #include <asm/kvm_arm.h>
  36 #include <asm/memory.h>
  37 #include <asm/pgtable-hwdef.h>
  38 #include <asm/pgtable.h>
  39 #include <asm/page.h>
  40 #include <asm/smp.h>
  41 #include <asm/sysreg.h>
  42 #include <asm/thread_info.h>
  43 #include <asm/virt.h>
  44
  45 #define __PHYS_OFFSET   (KERNEL_START - TEXT_OFFSET)
  46
  47 #if (TEXT_OFFSET & 0xfff) != 0
  48 #error TEXT_OFFSET must be at least 4KB aligned
  49 #elif (PAGE_OFFSET & 0x1fffff) != 0
  50 #error PAGE_OFFSET must be at least 2MB aligned
  51 #elif TEXT_OFFSET > 0x1fffff
  52 #error TEXT_OFFSET must be less than 2MB
  53 #endif
  54
  55 /*
  56  * Kernel startup entry point.
  57  * ---------------------------
  58  *
  59  * The requirements are:
  60  *   MMU = off, D-cache = off, I-cache = on or off,
  61  *   x0 = physical address to the FDT blob.
  62  *
  63  * This code is mostly position independent so you call this at
  64  * __pa(PAGE_OFFSET + TEXT_OFFSET).
  65  *
  66  * Note that the callee-saved registers are used for storing variables
  67  * that are useful before the MMU is enabled. The allocations are described
  68  * in the entry routines.
  69  */
  70         __HEAD
  71 _head:
  72         /*
  73          * DO NOT MODIFY. Image header expected by Linux boot-loaders.
  74          */
  75 #ifdef CONFIG_EFI
  76         /*
  77          * This add instruction has no meaningful effect except that
  78          * its opcode forms the magic "MZ" signature required by UEFI.
  79          */
  80         add     x13, x18, #0x16
  81         b       stext
  82 #else
  83         b       stext                           // branch to kernel start, magic
  84         .long   0                               // reserved
  85 #endif
  86         le64sym _kernel_offset_le               // Image load offset from start of RAM, little-endian
  87         le64sym _kernel_size_le                 // Effective size of kernel image, little-endian
  88         le64sym _kernel_flags_le                // Informative flags, little-endian
  89         .quad   0                               // reserved
  90         .quad   0                               // reserved
  91         .quad   0                               // reserved
  92         .byte   0x41                            // Magic number, "ARM\x64"
  93         .byte   0x52
  94         .byte   0x4d
  95         .byte   0x64
  96 #ifdef CONFIG_EFI
  97         .long   pe_header - _head               // Offset to the PE header.
  98 #else
  99         .word   0                               // reserved
 100 #endif
 101
 102 #ifdef CONFIG_EFI
 103         .align 3
 104 pe_header:
 105         .ascii  "PE"
 106         .short  0
 107 coff_header:
 108         .short  0xaa64                          // AArch64
 109         .short  2                               // nr_sections
 110         .long   0                               // TimeDateStamp
 111         .long   0                               // PointerToSymbolTable
 112         .long   1                               // NumberOfSymbols
 113         .short  section_table - optional_header // SizeOfOptionalHeader
 114         .short  0x206                           // Characteristics.
 115                                                 // IMAGE_FILE_DEBUG_STRIPPED |
 116                                                 // IMAGE_FILE_EXECUTABLE_IMAGE |
 117                                                 // IMAGE_FILE_LINE_NUMS_STRIPPED
 118 optional_header:
 119         .short  0x20b                           // PE32+ format
 120         .byte   0x02                            // MajorLinkerVersion
 121         .byte   0x14                            // MinorLinkerVersion
 122         .long   _end - efi_header_end           // SizeOfCode
 123         .long   0                               // SizeOfInitializedData
 124         .long   0                               // SizeOfUninitializedData
 125         .long   __efistub_entry - _head         // AddressOfEntryPoint
 126         .long   efi_header_end - _head          // BaseOfCode
 127
 128 extra_header_fields:
 129         .quad   0                               // ImageBase
 130         .long   0x1000                          // SectionAlignment
 131         .long   PECOFF_FILE_ALIGNMENT           // FileAlignment
 132         .short  0                               // MajorOperatingSystemVersion
 133         .short  0                               // MinorOperatingSystemVersion
 134         .short  0                               // MajorImageVersion
 135         .short  0                               // MinorImageVersion
 136         .short  0                               // MajorSubsystemVersion
 137         .short  0                               // MinorSubsystemVersion
 138         .long   0                               // Win32VersionValue
 139
 140         .long   _end - _head                    // SizeOfImage
 141
 142         // Everything before the kernel image is considered part of the header
 143         .long   efi_header_end - _head          // SizeOfHeaders
 144         .long   0                               // CheckSum
 145         .short  0xa                             // Subsystem (EFI application)
 146         .short  0                               // DllCharacteristics
 147         .quad   0                               // SizeOfStackReserve
 148         .quad   0                               // SizeOfStackCommit
 149         .quad   0                               // SizeOfHeapReserve
 150         .quad   0                               // SizeOfHeapCommit
 151         .long   0                               // LoaderFlags
 152         .long   0x6                             // NumberOfRvaAndSizes
 153
 154         .quad   0                               // ExportTable
 155         .quad   0                               // ImportTable
 156         .quad   0                               // ResourceTable
 157         .quad   0                               // ExceptionTable
 158         .quad   0                               // CertificationTable
 159         .quad   0                               // BaseRelocationTable
 160
 161         // Section table
 162 section_table:
 163
 164         /*
 165          * The EFI application loader requires a relocation section
 166          * because EFI applications must be relocatable.  This is a
 167          * dummy section as far as we are concerned.
 168          */
 169         .ascii  ".reloc"
 170         .byte   0
 171         .byte   0                       // end of 0 padding of section name
 172         .long   0
 173         .long   0
 174         .long   0                       // SizeOfRawData
 175         .long   0                       // PointerToRawData
 176         .long   0                       // PointerToRelocations
 177         .long   0                       // PointerToLineNumbers
 178         .short  0                       // NumberOfRelocations
 179         .short  0                       // NumberOfLineNumbers
 180         .long   0x42100040              // Characteristics (section flags)
 181
 182
 183         .ascii  ".text"
 184         .byte   0
 185         .byte   0
 186         .byte   0                       // end of 0 padding of section name
 187         .long   _end - efi_header_end   // VirtualSize
 188         .long   efi_header_end - _head  // VirtualAddress
 189         .long   _edata - efi_header_end // SizeOfRawData
 190         .long   efi_header_end - _head  // PointerToRawData
 191
 192         .long   0               // PointerToRelocations (0 for executables)
 193         .long   0               // PointerToLineNumbers (0 for executables)
 194         .short  0               // NumberOfRelocations  (0 for executables)
 195         .short  0               // NumberOfLineNumbers  (0 for executables)
 196         .long   0xe0500020      // Characteristics (section flags)
 197
 198         /*
 199          * EFI will load .text onwards at the 4k section alignment
 200          * described in the PE/COFF header. To ensure that instruction
 201          * sequences using an adrp and a :lo12: immediate will function
 202          * correctly at this alignment, we must ensure that .text is
 203          * placed at a 4k boundary in the Image to begin with.
 204          */
 205         .align 12
 206 efi_header_end:
 207 #endif
 208
 209         __INIT
 210
 211 ENTRY(stext)
 212         bl      preserve_boot_args
 213         bl      el2_setup                       // Drop to EL1, w0=cpu_boot_mode
 214         adrp    x24, __PHYS_OFFSET
 215         and     x23, x24, MIN_KIMG_ALIGN - 1    // KASLR offset, defaults to 0
 216         bl      set_cpu_boot_mode_flag
 217         bl      __create_page_tables
 218         /*
 219          * The following calls CPU setup code, see arch/arm64/mm/proc.S for
 220          * details.
 221          * On return, the CPU will be ready for the MMU to be turned on and
 222          * the TCR will have been set.
 223          */
 224         bl      __cpu_setup                     // initialise processor
 225         b       __primary_switch
 226 ENDPROC(stext)
 227
 228 /*
 229  * Preserve the arguments passed by the bootloader in x0 .. x3
 230  */
 231 preserve_boot_args:
 232         mov     x21, x0                         // x21=FDT
 233
 234         adr_l   x0, boot_args                   // record the contents of
 235         stp     x21, x1, [x0]                   // x0 .. x3 at kernel entry
 236         stp     x2, x3, [x0, #16]
 237
 238         dmb     sy                              // needed before dc ivac with
 239                                                 // MMU off
 240
 241         add     x1, x0, #0x20                   // 4 x 8 bytes
 242         b       __inval_cache_range             // tail call
 243 ENDPROC(preserve_boot_args)
 244
 245 /*
 246  * Macro to create a table entry to the next page.
 247  *
 248  *      tbl:    page table address
 249  *      virt:   virtual address
 250  *      shift:  #imm page table shift
 251  *      ptrs:   #imm pointers per table page
 252  *
 253  * Preserves:   virt
 254  * Corrupts:    tmp1, tmp2
 255  * Returns:     tbl -> next level table page address
 256  */
 257         .macro  create_table_entry, tbl, virt, shift, ptrs, tmp1, tmp2
 258         lsr     \tmp1, \virt, #\shift
 259         and     \tmp1, \tmp1, #\ptrs - 1        // table index
 260         add     \tmp2, \tbl, #PAGE_SIZE
 261         orr     \tmp2, \tmp2, #PMD_TYPE_TABLE   // address of next table and entry type
 262         str     \tmp2, [\tbl, \tmp1, lsl #3]
 263         add     \tbl, \tbl, #PAGE_SIZE          // next level table page
 264         .endm
 265
 266 /*
 267  * Macro to populate the PGD (and possibily PUD) for the corresponding
 268  * block entry in the next level (tbl) for the given virtual address.
 269  *
 270  * Preserves:   tbl, next, virt
 271  * Corrupts:    tmp1, tmp2
 272  */
 273         .macro  create_pgd_entry, tbl, virt, tmp1, tmp2
 274         create_table_entry \tbl, \virt, PGDIR_SHIFT, PTRS_PER_PGD, \tmp1, \tmp2
 275 #if SWAPPER_PGTABLE_LEVELS > 3
 276         create_table_entry \tbl, \virt, PUD_SHIFT, PTRS_PER_PUD, \tmp1, \tmp2
 277 #endif
 278 #if SWAPPER_PGTABLE_LEVELS > 2
 279         create_table_entry \tbl, \virt, SWAPPER_TABLE_SHIFT, PTRS_PER_PTE, \tmp1, \tmp2
 280 #endif
 281         .endm
 282
 283 /*
 284  * Macro to populate block entries in the page table for the start..end
 285  * virtual range (inclusive).
 286  *
 287  * Preserves:   tbl, flags
 288  * Corrupts:    phys, start, end, pstate
 289  */
 290         .macro  create_block_map, tbl, flags, phys, start, end
 291         lsr     \phys, \phys, #SWAPPER_BLOCK_SHIFT
 292         lsr     \start, \start, #SWAPPER_BLOCK_SHIFT
 293         and     \start, \start, #PTRS_PER_PTE - 1       // table index
 294         orr     \phys, \flags, \phys, lsl #SWAPPER_BLOCK_SHIFT  // table entry
 295         lsr     \end, \end, #SWAPPER_BLOCK_SHIFT
 296         and     \end, \end, #PTRS_PER_PTE - 1           // table end index
 297 9999:   str     \phys, [\tbl, \start, lsl #3]           // store the entry
 298         add     \start, \start, #1                      // next entry
 299         add     \phys, \phys, #SWAPPER_BLOCK_SIZE               // next block
 300         cmp     \start, \end
 301         b.ls    9999b
 302         .endm
 303
 304 /*
 305  * Setup the initial page tables. We only setup the barest amount which is
 306  * required to get the kernel running. The following sections are required:
 307  *   - identity mapping to enable the MMU (low address, TTBR0)
 308  *   - first few MB of the kernel linear mapping to jump to once the MMU has
 309  *     been enabled
 310  */
 311 __create_page_tables:
 312         mov     x28, lr
 313
 314         /*
 315          * Invalidate the idmap and swapper page tables to avoid potential
 316          * dirty cache lines being evicted.
 317          */
 318         adrp    x0, idmap_pg_dir
 319         adrp    x1, swapper_pg_dir + SWAPPER_DIR_SIZE
 320         bl      __inval_cache_range
 321
 322         /*
 323          * Clear the idmap and swapper page tables.
 324          */
 325         adrp    x0, idmap_pg_dir
 326         adrp    x6, swapper_pg_dir + SWAPPER_DIR_SIZE
 327 1:      stp     xzr, xzr, [x0], #16
 328         stp     xzr, xzr, [x0], #16
 329         stp     xzr, xzr, [x0], #16
 330         stp     xzr, xzr, [x0], #16
 331         cmp     x0, x6
 332         b.lo    1b
 333
 334         mov     x7, SWAPPER_MM_MMUFLAGS
 335
 336         /*
 337          * Create the identity mapping.
 338          */
 339         adrp    x0, idmap_pg_dir
 340         adrp    x3, __idmap_text_start          // __pa(__idmap_text_start)
 341
 342 #ifndef CONFIG_ARM64_VA_BITS_48
 343 #define EXTRA_SHIFT     (PGDIR_SHIFT + PAGE_SHIFT - 3)
 344 #define EXTRA_PTRS      (1 << (48 - EXTRA_SHIFT))
 345
 346         /*
 347          * If VA_BITS < 48, it may be too small to allow for an ID mapping to be
 348          * created that covers system RAM if that is located sufficiently high
 349          * in the physical address space. So for the ID map, use an extended
 350          * virtual range in that case, by configuring an additional translation
 351          * level.
 352          * First, we have to verify our assumption that the current value of
 353          * VA_BITS was chosen such that all translation levels are fully
 354          * utilised, and that lowering T0SZ will always result in an additional
 355          * translation level to be configured.
 356          */
 357 #if VA_BITS != EXTRA_SHIFT
 358 #error "Mismatch between VA_BITS and page size/number of translation levels"
 359 #endif
 360
 361         /*
 362          * Calculate the maximum allowed value for TCR_EL1.T0SZ so that the
 363          * entire ID map region can be mapped. As T0SZ == (64 - #bits used),
 364          * this number conveniently equals the number of leading zeroes in
 365          * the physical address of __idmap_text_end.
 366          */
 367         adrp    x5, __idmap_text_end
 368         clz     x5, x5
 369         cmp     x5, TCR_T0SZ(VA_BITS)   // default T0SZ small enough?
 370         b.ge    1f                      // .. then skip additional level
 371
 372         adr_l   x6, idmap_t0sz
 373         str     x5, [x6]
 374         dmb     sy
 375         dc      ivac, x6                // Invalidate potentially stale cache line
 376
 377         create_table_entry x0, x3, EXTRA_SHIFT, EXTRA_PTRS, x5, x6
 378 1:
 379 #endif
 380
 381         create_pgd_entry x0, x3, x5, x6
 382         mov     x5, x3                          // __pa(__idmap_text_start)
 383         adr_l   x6, __idmap_text_end            // __pa(__idmap_text_end)
 384         create_block_map x0, x7, x3, x5, x6
 385
 386         /*
 387          * Map the kernel image (starting with PHYS_OFFSET).
 388          */
 389         adrp    x0, swapper_pg_dir
 390         mov_q   x5, KIMAGE_VADDR + TEXT_OFFSET  // compile time __va(_text)
 391         add     x5, x5, x23                     // add KASLR displacement
 392         create_pgd_entry x0, x5, x3, x6
 393         adrp    x6, _end                        // runtime __pa(_end)
 394         adrp    x3, _text                       // runtime __pa(_text)
 395         sub     x6, x6, x3                      // _end - _text
 396         add     x6, x6, x5                      // runtime __va(_end)
 397         create_block_map x0, x7, x3, x5, x6
 398
 399         /*
 400          * Since the page tables have been populated with non-cacheable
 401          * accesses (MMU disabled), invalidate the idmap and swapper page
 402          * tables again to remove any speculatively loaded cache lines.
 403          */
 404         adrp    x0, idmap_pg_dir
 405         adrp    x1, swapper_pg_dir + SWAPPER_DIR_SIZE
 406         dmb     sy
 407         bl      __inval_cache_range
 408
 409         ret     x28
 410 ENDPROC(__create_page_tables)
 411         .ltorg
 412
 413 /*
 414  * The following fragment of code is executed with the MMU enabled.
 415  */
 416         .set    initial_sp, init_thread_union + THREAD_START_SP
 417 __primary_switched:
 418         mov     x28, lr                         // preserve LR
 419         adr_l   x8, vectors                     // load VBAR_EL1 with virtual
 420         msr     vbar_el1, x8                    // vector table address
 421         isb
 422
 423         // Clear BSS
 424         adr_l   x0, __bss_start
 425         mov     x1, xzr
 426         adr_l   x2, __bss_stop
 427         sub     x2, x2, x0
 428         bl      __pi_memset
 429         dsb     ishst                           // Make zero page visible to PTW
 430
 431         adr_l   sp, initial_sp, x4
 432         mov     x4, sp
 433         and     x4, x4, #~(THREAD_SIZE - 1)
 434         msr     sp_el0, x4                      // Save thread_info
 435         str_l   x21, __fdt_pointer, x5          // Save FDT pointer
 436
 437         ldr_l   x4, kimage_vaddr                // Save the offset between
 438         sub     x4, x4, x24                     // the kernel virtual and
 439         str_l   x4, kimage_voffset, x5          // physical mappings
 440
 441         mov     x29, #0
 442 #ifdef CONFIG_KASAN
 443         bl      kasan_early_init
 444 #endif
 445 #ifdef CONFIG_RANDOMIZE_BASE
 446         tst     x23, ~(MIN_KIMG_ALIGN - 1)      // already running randomized?
 447         b.ne    0f
 448         mov     x0, x21                         // pass FDT address in x0
 449         mov     x1, x23                         // pass modulo offset in x1
 450         bl      kaslr_early_init                // parse FDT for KASLR options
 451         cbz     x0, 0f                          // KASLR disabled? just proceed
 452         orr     x23, x23, x0                    // record KASLR offset
 453         ret     x28                             // we must enable KASLR, return
 454                                                 // to __primary_switch()
 455 0:
 456 #endif
 457         b       start_kernel
 458 ENDPROC(__primary_switched)
 459
 460 /*
 461  * end early head section, begin head code that is also used for
 462  * hotplug and needs to have the same protections as the text region
 463  */
 464         .section ".idmap.text","ax"
 465
 466 ENTRY(kimage_vaddr)
 467         .quad           _text - TEXT_OFFSET
 468
 469 /*
 470  * If we're fortunate enough to boot at EL2, ensure that the world is
 471  * sane before dropping to EL1.
 472  *
 473  * Returns either BOOT_CPU_MODE_EL1 or BOOT_CPU_MODE_EL2 in x20 if
 474  * booted in EL1 or EL2 respectively.
 475  */
 476 ENTRY(el2_setup)
 477         mrs     x0, CurrentEL
 478         cmp     x0, #CurrentEL_EL2
 479         b.ne    1f
 480         mrs     x0, sctlr_el2
 481 CPU_BE( orr     x0, x0, #(1 << 25)      )       // Set the EE bit for EL2
 482 CPU_LE( bic     x0, x0, #(1 << 25)      )       // Clear the EE bit for EL2
 483         msr     sctlr_el2, x0
 484         b       2f
 485 1:      mrs     x0, sctlr_el1
 486 CPU_BE( orr     x0, x0, #(3 << 24)      )       // Set the EE and E0E bits for EL1
 487 CPU_LE( bic     x0, x0, #(3 << 24)      )       // Clear the EE and E0E bits for EL1
 488         msr     sctlr_el1, x0
 489         mov     w0, #BOOT_CPU_MODE_EL1          // This cpu booted in EL1
 490         isb
 491         ret
 492
 493 2:
 494 #ifdef CONFIG_ARM64_VHE
 495         /*
 496          * Check for VHE being present. For the rest of the EL2 setup,
 497          * x2 being non-zero indicates that we do have VHE, and that the
 498          * kernel is intended to run at EL2.
 499          */
 500         mrs     x2, id_aa64mmfr1_el1
 501         ubfx    x2, x2, #8, #4
 502 #else
 503         mov     x2, xzr
 504 #endif
 505
 506         /* Hyp configuration. */
 507         mov     x0, #HCR_RW                     // 64-bit EL1
 508         cbz     x2, set_hcr
 509         orr     x0, x0, #HCR_TGE                // Enable Host Extensions
 510         orr     x0, x0, #HCR_E2H
 511 set_hcr:
 512         msr     hcr_el2, x0
 513         isb
 514
 515         /* Generic timers. */
 516         mrs     x0, cnthctl_el2
 517         orr     x0, x0, #3                      // Enable EL1 physical timers
 518         msr     cnthctl_el2, x0
 519         msr     cntvoff_el2, xzr                // Clear virtual offset
 520
 521 #ifdef CONFIG_ARM_GIC_V3
 522         /* GICv3 system register access */
 523         mrs     x0, id_aa64pfr0_el1
 524         ubfx    x0, x0, #24, #4
 525         cmp     x0, #1
 526         b.ne    3f
 527
 528         mrs_s   x0, ICC_SRE_EL2
 529         orr     x0, x0, #ICC_SRE_EL2_SRE        // Set ICC_SRE_EL2.SRE==1
 530         orr     x0, x0, #ICC_SRE_EL2_ENABLE     // Set ICC_SRE_EL2.Enable==1
 531         msr_s   ICC_SRE_EL2, x0
 532         isb                                     // Make sure SRE is now set
 533         mrs_s   x0, ICC_SRE_EL2                 // Read SRE back,
 534         tbz     x0, #0, 3f                      // and check that it sticks
 535         msr_s   ICH_HCR_EL2, xzr                // Reset ICC_HCR_EL2 to defaults
 536
 537 3:
 538 #endif
 539
 540         /* Populate ID registers. */
 541         mrs     x0, midr_el1
 542         mrs     x1, mpidr_el1
 543         msr     vpidr_el2, x0
 544         msr     vmpidr_el2, x1
 545
 546         /*
 547          * When VHE is not in use, early init of EL2 and EL1 needs to be
 548          * done here.
 549          * When VHE _is_ in use, EL1 will not be used in the host and
 550          * requires no configuration, and all non-hyp-specific EL2 setup
 551          * will be done via the _EL1 system register aliases in __cpu_setup.
 552          */
 553         cbnz    x2, 1f
 554
 555         /* sctlr_el1 */
 556         mov     x0, #0x0800                     // Set/clear RES{1,0} bits
 557 CPU_BE( movk    x0, #0x33d0, lsl #16    )       // Set EE and E0E on BE systems
 558 CPU_LE( movk    x0, #0x30d0, lsl #16    )       // Clear EE and E0E on LE systems
 559         msr     sctlr_el1, x0
 560
 561         /* Coprocessor traps. */
 562         mov     x0, #0x33ff
 563         msr     cptr_el2, x0                    // Disable copro. traps to EL2
 564 1:
 565
 566 #ifdef CONFIG_COMPAT
 567         msr     hstr_el2, xzr                   // Disable CP15 traps to EL2
 568 #endif
 569
 570         /* EL2 debug */
 571         mrs     x0, id_aa64dfr0_el1             // Check ID_AA64DFR0_EL1 PMUVer
 572         sbfx    x0, x0, #8, #4
 573         cmp     x0, #1
 574         b.lt    4f                              // Skip if no PMU present
 575         mrs     x0, pmcr_el0                    // Disable debug access traps
 576         ubfx    x0, x0, #11, #5                 // to EL2 and allow access to
 577         msr     mdcr_el2, x0                    // all PMU counters from EL1
 578 4:
 579
 580         /* Stage-2 translation */
 581         msr     vttbr_el2, xzr
 582
 583         cbz     x2, install_el2_stub
 584
 585         mov     w0, #BOOT_CPU_MODE_EL2          // This CPU booted in EL2
 586         isb
 587         ret
 588
 589 install_el2_stub:
 590         /* Hypervisor stub */
 591         adrp    x0, __hyp_stub_vectors
 592         add     x0, x0, #:lo12:__hyp_stub_vectors
 593         msr     vbar_el2, x0
 594
 595         /* spsr */
 596         mov     x0, #(PSR_F_BIT | PSR_I_BIT | PSR_A_BIT | PSR_D_BIT |\
 597                       PSR_MODE_EL1h)
 598         msr     spsr_el2, x0
 599         msr     elr_el2, lr
 600         mov     w0, #BOOT_CPU_MODE_EL2          // This CPU booted in EL2
 601         eret
 602 ENDPROC(el2_setup)
 603
 604 /*
 605  * Sets the __boot_cpu_mode flag depending on the CPU boot mode passed
 606  * in x20. See arch/arm64/include/asm/virt.h for more info.
 607  */
 608 set_cpu_boot_mode_flag:
 609         adr_l   x1, __boot_cpu_mode
 610         cmp     w0, #BOOT_CPU_MODE_EL2
 611         b.ne    1f
 612         add     x1, x1, #4
 613 1:      str     w0, [x1]                        // This CPU has booted in EL1
 614         dmb     sy
 615         dc      ivac, x1                        // Invalidate potentially stale cache line
 616         ret
 617 ENDPROC(set_cpu_boot_mode_flag)
 618
 619 /*
 620  * These values are written with the MMU off, but read with the MMU on.
 621  * Writers will invalidate the corresponding address, discarding up to a
 622  * 'Cache Writeback Granule' (CWG) worth of data. The linker script ensures
 623  * sufficient alignment that the CWG doesn't overlap another section.
 624  */
 625         .pushsection ".mmuoff.data.write", "aw"
 626 /*
 627  * We need to find out the CPU boot mode long after boot, so we need to
 628  * store it in a writable variable.
 629  *
 630  * This is not in .bss, because we set it sufficiently early that the boot-time
 631  * zeroing of .bss would clobber it.
 632  */
 633 ENTRY(__boot_cpu_mode)
 634         .long   BOOT_CPU_MODE_EL2
 635         .long   BOOT_CPU_MODE_EL1
 636 /*
 637  * The booting CPU updates the failed status @__early_cpu_boot_status,
 638  * with MMU turned off.
 639  */
 640 ENTRY(__early_cpu_boot_status)
 641         .long   0
 642
 643         .popsection
 644
 645         /*
 646          * This provides a "holding pen" for platforms to hold all secondary
 647          * cores are held until we're ready for them to initialise.
 648          */
 649 ENTRY(secondary_holding_pen)
 650         bl      el2_setup                       // Drop to EL1, w0=cpu_boot_mode
 651         bl      set_cpu_boot_mode_flag
 652         mrs     x0, mpidr_el1
 653         mov_q   x1, MPIDR_HWID_BITMASK
 654         and     x0, x0, x1
 655         adr_l   x3, secondary_holding_pen_release
 656 pen:    ldr     x4, [x3]
 657         cmp     x4, x0
 658         b.eq    secondary_startup
 659         wfe
 660         b       pen
 661 ENDPROC(secondary_holding_pen)
 662
 663         /*
 664          * Secondary entry point that jumps straight into the kernel. Only to
 665          * be used where CPUs are brought online dynamically by the kernel.
 666          */
 667 ENTRY(secondary_entry)
 668         bl      el2_setup                       // Drop to EL1
 669         bl      set_cpu_boot_mode_flag
 670         b       secondary_startup
 671 ENDPROC(secondary_entry)
 672
 673 secondary_startup:
 674         /*
 675          * Common entry point for secondary CPUs.
 676          */
 677         bl      __cpu_setup                     // initialise processor
 678
 679         adr_l   x27, __secondary_switch         // address to jump to after enabling the MMU
 680         b       __enable_mmu
 681 ENDPROC(secondary_startup)
 682
 683 __secondary_switched:
 684         adr_l   x5, vectors
 685         msr     vbar_el1, x5
 686         isb
 687
 688         adr_l   x0, secondary_data
 689         ldr     x0, [x0, #CPU_BOOT_STACK]       // get secondary_data.stack
 690         mov     sp, x0
 691         and     x0, x0, #~(THREAD_SIZE - 1)
 692         msr     sp_el0, x0                      // save thread_info
 693         mov     x29, #0
 694         b       secondary_start_kernel
 695 ENDPROC(__secondary_switched)
 696
 697 /*
 698  * The booting CPU updates the failed status @__early_cpu_boot_status,
 699  * with MMU turned off.
 700  *
 701  * update_early_cpu_boot_status tmp, status
 702  *  - Corrupts tmp1, tmp2
 703  *  - Writes 'status' to __early_cpu_boot_status and makes sure
 704  *    it is committed to memory.
 705  */
 706
 707         .macro  update_early_cpu_boot_status status, tmp1, tmp2
 708         mov     \tmp2, #\status
 709         adr_l   \tmp1, __early_cpu_boot_status
 710         str     \tmp2, [\tmp1]
 711         dmb     sy
 712         dc      ivac, \tmp1                     // Invalidate potentially stale cache line
 713         .endm
 714
 715 /*
 716  * Enable the MMU.
 717  *
 718  *  x0  = SCTLR_EL1 value for turning on the MMU.
 719  *  x27 = *virtual* address to jump to upon completion
 720  *
 721  * Other registers depend on the function called upon completion.
 722  *
 723  * Checks if the selected granule size is supported by the CPU.
 724  * If it isn't, park the CPU
 725  */
 726 ENTRY(__enable_mmu)
 727         mrs     x1, ID_AA64MMFR0_EL1
 728         ubfx    x2, x1, #ID_AA64MMFR0_TGRAN_SHIFT, 4
 729         cmp     x2, #ID_AA64MMFR0_TGRAN_SUPPORTED
 730         b.ne    __no_granule_support
 731         update_early_cpu_boot_status 0, x1, x2
 732         adrp    x1, idmap_pg_dir
 733         adrp    x2, swapper_pg_dir
 734         msr     ttbr0_el1, x1                   // load TTBR0
 735         msr     ttbr1_el1, x2                   // load TTBR1
 736         isb
 737         msr     sctlr_el1, x0
 738         isb
 739         /*
 740          * Invalidate the local I-cache so that any instructions fetched
 741          * speculatively from the PoC are discarded, since they may have
 742          * been dynamically patched at the PoU.
 743          */
 744         ic      iallu
 745         dsb     nsh
 746         isb
 747         br      x27
 748 ENDPROC(__enable_mmu)
 749
 750 __no_granule_support:
 751         /* Indicate that this CPU can't boot and is stuck in the kernel */
 752         update_early_cpu_boot_status CPU_STUCK_IN_KERNEL, x1, x2
 753 1:
 754         wfe
 755         wfi
 756         b       1b
 757 ENDPROC(__no_granule_support)
 758
 759 #ifdef CONFIG_RELOCATABLE
 760 __relocate_kernel:
 761         /*
 762          * Iterate over each entry in the relocation table, and apply the
 763          * relocations in place.
 764          */
 765         ldr     w9, =__rela_offset              // offset to reloc table
 766         ldr     w10, =__rela_size               // size of reloc table
 767
 768         mov_q   x11, KIMAGE_VADDR               // default virtual offset
 769         add     x11, x11, x23                   // actual virtual offset
 770         add     x9, x9, x11                     // __va(.rela)
 771         add     x10, x9, x10                    // __va(.rela) + sizeof(.rela)
 772
 773 0:      cmp     x9, x10
 774         b.hs    1f
 775         ldp     x11, x12, [x9], #24
 776         ldr     x13, [x9, #-8]
 777         cmp     w12, #R_AARCH64_RELATIVE
 778         b.ne    0b
 779         add     x13, x13, x23                   // relocate
 780         str     x13, [x11, x23]
 781         b       0b
 782 1:      ret
 783 ENDPROC(__relocate_kernel)
 784 #endif
 785
 786 __primary_switch:
 787 #ifdef CONFIG_RANDOMIZE_BASE
 788         mov     x19, x0                         // preserve new SCTLR_EL1 value
 789         mrs     x20, sctlr_el1                  // preserve old SCTLR_EL1 value
 790 #endif
 791
 792         adr     x27, 0f
 793         b       __enable_mmu
 794 0:
 795 #ifdef CONFIG_RELOCATABLE
 796         bl      __relocate_kernel
 797 #ifdef CONFIG_RANDOMIZE_BASE
 798         ldr     x8, =__primary_switched
 799         blr     x8
 800
 801         /*
 802          * If we return here, we have a KASLR displacement in x23 which we need
 803          * to take into account by discarding the current kernel mapping and
 804          * creating a new one.
 805          */
 806         msr     sctlr_el1, x20                  // disable the MMU
 807         isb
 808         bl      __create_page_tables            // recreate kernel mapping
 809
 810         tlbi    vmalle1                         // Remove any stale TLB entries
 811         dsb     nsh
 812
 813         msr     sctlr_el1, x19                  // re-enable the MMU
 814         isb
 815         ic      iallu                           // flush instructions fetched
 816         dsb     nsh                             // via old mapping
 817         isb
 818
 819         bl      __relocate_kernel
 820 #endif
 821 #endif
 822         ldr     x8, =__primary_switched
 823         br      x8
 824 ENDPROC(__primary_switch)
 825
 826 __secondary_switch:
 827         ldr     x8, =__secondary_switched
 828         br      x8
 829 ENDPROC(__secondary_switch)