1 /* SPDX-License-Identifier: GPL-2.0-only */
3 * linux/arch/arm/boot/compressed/head.S
5 * Copyright (C) 1996-2002 Russell King
6 * Copyright (C) 2004 Hyok S. Choi (MPU support)
8 #include <linux/linkage.h>
9 #include <asm/assembler.h>
12 #include "efi-header.S"
14 AR_CLASS( .arch armv7-a )
15 M_CLASS( .arch armv7-m )
20 * Note that these macros must not contain any code which is not
21 * 100% relocatable. Any attempt to do so will result in a crash.
22 * Please select one of the following when turning on debugging.
26 #if defined(CONFIG_DEBUG_ICEDCC)
28 #if defined(CONFIG_CPU_V6) || defined(CONFIG_CPU_V6K) || defined(CONFIG_CPU_V7)
29 .macro loadsp, rb, tmp1, tmp2
32 mcr p14, 0, \ch, c0, c5, 0
34 #elif defined(CONFIG_CPU_XSCALE)
35 .macro loadsp, rb, tmp1, tmp2
38 mcr p14, 0, \ch, c8, c0, 0
41 .macro loadsp, rb, tmp1, tmp2
44 mcr p14, 0, \ch, c1, c0, 0
50 #include CONFIG_DEBUG_LL_INCLUDE
56 #if defined(CONFIG_ARCH_SA1100)
57 .macro loadsp, rb, tmp1, tmp2
58 mov \rb, #0x80000000 @ physical base address
59 #ifdef CONFIG_DEBUG_LL_SER3
60 add \rb, \rb, #0x00050000 @ Ser3
62 add \rb, \rb, #0x00010000 @ Ser1
66 .macro loadsp, rb, tmp1, tmp2
67 addruart \rb, \tmp1, \tmp2
84 .macro debug_reloc_start
87 kphex r6, 8 /* processor id */
89 kphex r7, 8 /* architecture id */
90 #ifdef CONFIG_CPU_CP15
92 mrc p15, 0, r0, c1, c0
93 kphex r0, 8 /* control reg */
96 kphex r5, 8 /* decompressed kernel start */
98 kphex r9, 8 /* decompressed kernel end */
100 kphex r4, 8 /* kernel execution address */
105 .macro debug_reloc_end
107 kphex r5, 8 /* end of kernel */
110 bl memdump /* dump 256 bytes at start of kernel */
115 * Debug kernel copy by printing the memory addresses involved
117 .macro dbgkc, begin, end, cbegin, cend
124 kphex \begin, 8 /* Start of compressed kernel */
128 kphex \end, 8 /* End of compressed kernel */
133 kphex \cbegin, 8 /* Start of kernel copy */
137 kphex \cend, 8 /* End of kernel copy */
143 .macro enable_cp15_barriers, reg
144 mrc p15, 0, \reg, c1, c0, 0 @ read SCTLR
145 tst \reg, #(1 << 5) @ CP15BEN bit set?
147 orr \reg, \reg, #(1 << 5) @ CP15 barrier instructions
148 mcr p15, 0, \reg, c1, c0, 0 @ write SCTLR
149 ARM( .inst 0xf57ff06f @ v7+ isb )
155 * The kernel build system appends the size of the
156 * decompressed kernel at the end of the compressed data
157 * in little-endian form.
159 .macro get_inflated_image_size, res:req, tmp1:req, tmp2:req
160 adr \res, .Linflated_image_size_offset
162 add \tmp1, \tmp1, \res @ address of inflated image size
164 ldrb \res, [\tmp1] @ get_unaligned_le32
165 ldrb \tmp2, [\tmp1, #1]
166 orr \res, \res, \tmp2, lsl #8
167 ldrb \tmp2, [\tmp1, #2]
168 ldrb \tmp1, [\tmp1, #3]
169 orr \res, \res, \tmp2, lsl #16
170 orr \res, \res, \tmp1, lsl #24
173 .section ".start", "ax"
175 * sort out different calling conventions
179 * Always enter in ARM state for CPUs that support the ARM ISA.
180 * As of today (2014) that's exactly the members of the A and R
185 .type start,#function
187 * These 7 nops along with the 1 nop immediately below for
188 * !THUMB2 form 8 nops that make the compressed kernel bootable
189 * on legacy ARM systems that were assuming the kernel in a.out
190 * binary format. The boot loaders on these systems would
191 * jump 32 bytes into the image to skip the a.out header.
192 * with these 8 nops filling exactly 32 bytes, things still
193 * work as expected on these legacy systems. Thumb2 mode keeps
194 * 7 of the nops as it turns out that some boot loaders
195 * were patching the initial instructions of the kernel, i.e
196 * had started to exploit this "patch area".
201 #ifndef CONFIG_THUMB2_KERNEL
204 AR_CLASS( sub pc, pc, #3 ) @ A/R: switch to Thumb2 mode
205 M_CLASS( nop.w ) @ M: already in Thumb2 mode
210 .word _magic_sig @ Magic numbers to help the loader
211 .word _magic_start @ absolute load/run zImage address
212 .word _magic_end @ zImage end address
213 .word 0x04030201 @ endianness flag
214 .word 0x45454545 @ another magic number to indicate
215 .word _magic_table @ additional data table
219 ARM_BE8( setend be ) @ go BE8 if compiled for BE8
220 AR_CLASS( mrs r9, cpsr )
221 #ifdef CONFIG_ARM_VIRT_EXT
222 bl __hyp_stub_install @ get into SVC mode, reversibly
224 mov r7, r1 @ save architecture ID
225 mov r8, r2 @ save atags pointer
227 #ifndef CONFIG_CPU_V7M
229 * Booting from Angel - need to enter SVC mode and disable
230 * FIQs/IRQs (numeric definitions from angel arm.h source).
231 * We only do this if we were in user mode on entry.
233 mrs r2, cpsr @ get current mode
234 tst r2, #3 @ not user?
236 mov r0, #0x17 @ angel_SWIreason_EnterSVC
237 ARM( swi 0x123456 ) @ angel_SWI_ARM
238 THUMB( svc 0xab ) @ angel_SWI_THUMB
240 safe_svcmode_maskall r0
241 msr spsr_cxsf, r9 @ Save the CPU boot mode in
245 * Note that some cache flushing and other stuff may
246 * be needed here - is there an Angel SWI call for this?
250 * some architecture specific code can be inserted
251 * by the linker here, but it should preserve r7, r8, and r9.
256 #ifdef CONFIG_AUTO_ZRELADDR
258 * Find the start of physical memory. As we are executing
259 * without the MMU on, we are in the physical address space.
260 * We just need to get rid of any offset by aligning the
263 * This alignment is a balance between the requirements of
264 * different platforms - we have chosen 128MB to allow
265 * platforms which align the start of their physical memory
266 * to 128MB to use this feature, while allowing the zImage
267 * to be placed within the first 128MB of memory on other
268 * platforms. Increasing the alignment means we place
269 * stricter alignment requirements on the start of physical
270 * memory, but relaxing it means that we break people who
271 * are already placing their zImage in (eg) the top 64MB
275 and r4, r4, #0xf8000000
276 /* Determine final kernel image address. */
277 add r4, r4, #TEXT_OFFSET
283 * Set up a page table only if it won't overwrite ourself.
284 * That means r4 < pc || r4 - 16k page directory > &_end.
285 * Given that r4 > &_end is most unfrequent, we add a rough
286 * additional 1MB of room for a possible appended DTB.
293 orrcc r4, r4, #1 @ remember we skipped cache_on
302 get_inflated_image_size r9, r10, lr
304 #ifndef CONFIG_ZBOOT_ROM
305 /* malloc space is above the relocated stack (64k max) */
306 add r10, sp, #0x10000
309 * With ZBOOT_ROM the bss/stack is non relocatable,
310 * but someone could still run this code from RAM,
311 * in which case our reference is _edata.
316 mov r5, #0 @ init dtb size to 0
317 #ifdef CONFIG_ARM_APPENDED_DTB
319 * r4 = final kernel address (possibly with LSB set)
320 * r5 = appended dtb size (still unknown)
322 * r7 = architecture ID
323 * r8 = atags/device tree pointer
324 * r9 = size of decompressed image
325 * r10 = end of this image, including bss/stack/malloc space if non XIP
328 * if there are device trees (dtb) appended to zImage, advance r10 so that the
329 * dtb data will get relocated along with the kernel if necessary.
334 ldr r1, =0xedfe0dd0 @ sig is 0xd00dfeed big endian
339 bne dtb_check_done @ not found
341 #ifdef CONFIG_ARM_ATAG_DTB_COMPAT
343 * OK... Let's do some funky business here.
344 * If we do have a DTB appended to zImage, and we do have
345 * an ATAG list around, we want the later to be translated
346 * and folded into the former here. No GOT fixup has occurred
347 * yet, but none of the code we're about to call uses any
351 /* Get the initial DTB size */
354 /* convert to little endian */
355 eor r1, r5, r5, ror #16
356 bic r1, r1, #0x00ff0000
358 eor r5, r5, r1, lsr #8
360 /* 50% DTB growth should be good enough */
361 add r5, r5, r5, lsr #1
362 /* preserve 64-bit alignment */
365 /* clamp to 32KB min and 1MB max */
370 /* temporarily relocate the stack past the DTB work space */
379 * If returned value is 1, there is no ATAG at the location
380 * pointed by r8. Try the typical 0x100 offset from start
381 * of RAM and hope for the best.
384 sub r0, r4, #TEXT_OFFSET
394 mov r8, r6 @ use the appended device tree
397 * Make sure that the DTB doesn't end up in the final
398 * kernel's .bss area. To do so, we adjust the decompressed
399 * kernel size to compensate if that .bss size is larger
400 * than the relocated code.
402 ldr r5, =_kernel_bss_size
403 adr r1, wont_overwrite
408 /* Get the current DTB size */
411 /* convert r5 (dtb size) to little endian */
412 eor r1, r5, r5, ror #16
413 bic r1, r1, #0x00ff0000
415 eor r5, r5, r1, lsr #8
418 /* preserve 64-bit alignment */
422 /* relocate some pointers past the appended dtb */
430 * Check to see if we will overwrite ourselves.
431 * r4 = final kernel address (possibly with LSB set)
432 * r9 = size of decompressed image
433 * r10 = end of this image, including bss/stack/malloc space if non XIP
435 * r4 - 16k page directory >= r10 -> OK
436 * r4 + image length <= address of wont_overwrite -> OK
437 * Note: the possible LSB in r4 is harmless here.
443 adr r9, wont_overwrite
448 * Relocate ourselves past the end of the decompressed kernel.
450 * r10 = end of the decompressed kernel
451 * Because we always copy ahead, we need to do it from the end and go
452 * backward in case the source and destination overlap.
455 * Bump to the next 256-byte boundary with the size of
456 * the relocation code added. This avoids overwriting
457 * ourself when the offset is small.
459 add r10, r10, #((reloc_code_end - restart + 256) & ~255)
462 /* Get start of code we want to copy and align it down. */
466 /* Relocate the hyp vector base if necessary */
467 #ifdef CONFIG_ARM_VIRT_EXT
469 and r0, r0, #MODE_MASK
474 * Compute the address of the hyp vectors after relocation.
475 * This requires some arithmetic since we cannot directly
476 * reference __hyp_stub_vectors in a PC-relative way.
477 * Call __hyp_set_vectors with the new address so that we
478 * can HVC again after the copy.
481 movw r1, #:lower16:__hyp_stub_vectors - 0b
482 movt r1, #:upper16:__hyp_stub_vectors - 0b
490 sub r9, r6, r5 @ size to copy
491 add r9, r9, #31 @ rounded up to a multiple
492 bic r9, r9, #31 @ ... of 32 bytes
500 * We are about to copy the kernel to a new memory area.
501 * The boundaries of the new memory area can be found in
502 * r10 and r9, whilst r5 and r6 contain the boundaries
503 * of the memory we are going to copy.
504 * Calling dbgkc will help with the printing of this
507 dbgkc r5, r6, r10, r9
510 1: ldmdb r6!, {r0 - r3, r10 - r12, lr}
512 stmdb r9!, {r0 - r3, r10 - r12, lr}
515 /* Preserve offset to relocated code. */
518 mov r0, r9 @ start of relocated zImage
519 add r1, sp, r6 @ end of relocated zImage
528 ldmia r0, {r1, r2, r3, r11, r12}
529 sub r0, r0, r1 @ calculate the delta offset
532 * If delta is zero, we are running at the address we were linked at.
536 * r4 = kernel execution address (possibly with LSB set)
537 * r5 = appended dtb size (0 if not present)
538 * r7 = architecture ID
550 #ifndef CONFIG_ZBOOT_ROM
552 * If we're running fully PIC === CONFIG_ZBOOT_ROM = n,
553 * we need to fix up pointers into the BSS region.
554 * Note that the stack pointer has already been fixed up.
560 * Relocate all entries in the GOT table.
561 * Bump bss entries to _edata + dtb size
563 1: ldr r1, [r11, #0] @ relocate entries in the GOT
564 add r1, r1, r0 @ This fixes up C references
565 cmp r1, r2 @ if entry >= bss_start &&
566 cmphs r3, r1 @ bss_end > entry
567 addhi r1, r1, r5 @ entry += dtb size
568 str r1, [r11], #4 @ next entry
572 /* bump our bss pointers too */
579 * Relocate entries in the GOT table. We only relocate
580 * the entries that are outside the (relocated) BSS region.
582 1: ldr r1, [r11, #0] @ relocate entries in the GOT
583 cmp r1, r2 @ entry < bss_start ||
584 cmphs r3, r1 @ _end < entry
585 addlo r1, r1, r0 @ table. This fixes up the
586 str r1, [r11], #4 @ C references.
591 not_relocated: mov r0, #0
592 1: str r0, [r2], #4 @ clear bss
600 * Did we skip the cache setup earlier?
601 * That is indicated by the LSB in r4.
609 * The C runtime environment should now be setup sufficiently.
610 * Set up some pointers, and start decompressing.
611 * r4 = kernel execution address
612 * r7 = architecture ID
616 mov r1, sp @ malloc space above stack
617 add r2, sp, #0x10000 @ 64k max
621 get_inflated_image_size r1, r2, r3
623 mov r0, r4 @ start of inflated image
624 add r1, r1, r0 @ end of inflated image
628 #ifdef CONFIG_ARM_VIRT_EXT
629 mrs r0, spsr @ Get saved CPU boot mode
630 and r0, r0, #MODE_MASK
631 cmp r0, #HYP_MODE @ if not booted in HYP mode...
632 bne __enter_kernel @ boot kernel directly
634 adr r12, .L__hyp_reentry_vectors_offset
639 __HVC(0) @ otherwise bounce to hyp mode
641 b . @ should never be reached
644 .L__hyp_reentry_vectors_offset: .long __hyp_reentry_vectors - .
652 .word __bss_start @ r2
654 .word _got_start @ r11
659 LC1: .word .L_user_stack_end - LC1 @ sp
660 .word _edata - LC1 @ r6
664 .word _end - restart + 16384 + 1024*1024
666 .Linflated_image_size_offset:
667 .long (input_data_end - 4) - .
669 #ifdef CONFIG_ARCH_RPC
671 params: ldr r0, =0x10000100 @ params_phys for RPC
678 * dcache_line_size - get the minimum D-cache line size from the CTR register
681 .macro dcache_line_size, reg, tmp
682 #ifdef CONFIG_CPU_V7M
683 movw \tmp, #:lower16:BASEADDR_V7M_SCB + V7M_SCB_CTR
684 movt \tmp, #:upper16:BASEADDR_V7M_SCB + V7M_SCB_CTR
687 mrc p15, 0, \tmp, c0, c0, 1 @ read ctr
690 and \tmp, \tmp, #0xf @ cache line size encoding
691 mov \reg, #4 @ bytes per word
692 mov \reg, \reg, lsl \tmp @ actual cache line size
696 * Turn on the cache. We need to setup some page tables so that we
697 * can have both the I and D caches on.
699 * We place the page tables 16k down from the kernel execution address,
700 * and we hope that nothing else is using it. If we're using it, we
704 * r4 = kernel execution address
705 * r7 = architecture number
708 * r0, r1, r2, r3, r9, r10, r12 corrupted
709 * This routine must preserve:
713 cache_on: mov r3, #8 @ cache_on function
717 * Initialize the highest priority protection region, PR7
718 * to cover all 32bit address and cacheable and bufferable.
720 __armv4_mpu_cache_on:
721 mov r0, #0x3f @ 4G, the whole
722 mcr p15, 0, r0, c6, c7, 0 @ PR7 Area Setting
723 mcr p15, 0, r0, c6, c7, 1
726 mcr p15, 0, r0, c2, c0, 0 @ D-cache on
727 mcr p15, 0, r0, c2, c0, 1 @ I-cache on
728 mcr p15, 0, r0, c3, c0, 0 @ write-buffer on
731 mcr p15, 0, r0, c5, c0, 1 @ I-access permission
732 mcr p15, 0, r0, c5, c0, 0 @ D-access permission
735 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
736 mcr p15, 0, r0, c7, c5, 0 @ flush(inval) I-Cache
737 mcr p15, 0, r0, c7, c6, 0 @ flush(inval) D-Cache
738 mrc p15, 0, r0, c1, c0, 0 @ read control reg
739 @ ...I .... ..D. WC.M
740 orr r0, r0, #0x002d @ .... .... ..1. 11.1
741 orr r0, r0, #0x1000 @ ...1 .... .... ....
743 mcr p15, 0, r0, c1, c0, 0 @ write control reg
746 mcr p15, 0, r0, c7, c5, 0 @ flush(inval) I-Cache
747 mcr p15, 0, r0, c7, c6, 0 @ flush(inval) D-Cache
750 __armv3_mpu_cache_on:
751 mov r0, #0x3f @ 4G, the whole
752 mcr p15, 0, r0, c6, c7, 0 @ PR7 Area Setting
755 mcr p15, 0, r0, c2, c0, 0 @ cache on
756 mcr p15, 0, r0, c3, c0, 0 @ write-buffer on
759 mcr p15, 0, r0, c5, c0, 0 @ access permission
762 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
764 * ?? ARMv3 MMU does not allow reading the control register,
765 * does this really work on ARMv3 MPU?
767 mrc p15, 0, r0, c1, c0, 0 @ read control reg
768 @ .... .... .... WC.M
769 orr r0, r0, #0x000d @ .... .... .... 11.1
770 /* ?? this overwrites the value constructed above? */
772 mcr p15, 0, r0, c1, c0, 0 @ write control reg
774 /* ?? invalidate for the second time? */
775 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
778 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
784 __setup_mmu: sub r3, r4, #16384 @ Page directory size
785 bic r3, r3, #0xff @ Align the pointer
788 * Initialise the page tables, turning on the cacheable and bufferable
789 * bits for the RAM area only.
793 mov r9, r9, lsl #18 @ start of RAM
794 add r10, r9, #0x10000000 @ a reasonable RAM size
795 mov r1, #0x12 @ XN|U + section mapping
796 orr r1, r1, #3 << 10 @ AP=11
798 1: cmp r1, r9 @ if virt > start of RAM
799 cmphs r10, r1 @ && end of RAM > virt
800 bic r1, r1, #0x1c @ clear XN|U + C + B
801 orrlo r1, r1, #0x10 @ Set XN|U for non-RAM
802 orrhs r1, r1, r6 @ set RAM section settings
803 str r1, [r0], #4 @ 1:1 mapping
808 * If ever we are running from Flash, then we surely want the cache
809 * to be enabled also for our execution instance... We map 2MB of it
810 * so there is no map overlap problem for up to 1 MB compressed kernel.
811 * If the execution is in RAM then we would only be duplicating the above.
813 orr r1, r6, #0x04 @ ensure B is set for this
817 orr r1, r1, r2, lsl #20
818 add r0, r3, r2, lsl #2
825 @ Enable unaligned access on v6, to allow better code generation
826 @ for the decompressor C code:
827 __armv6_mmu_cache_on:
828 mrc p15, 0, r0, c1, c0, 0 @ read SCTLR
829 bic r0, r0, #2 @ A (no unaligned access fault)
830 orr r0, r0, #1 << 22 @ U (v6 unaligned access model)
831 mcr p15, 0, r0, c1, c0, 0 @ write SCTLR
832 b __armv4_mmu_cache_on
834 __arm926ejs_mmu_cache_on:
835 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
836 mov r0, #4 @ put dcache in WT mode
837 mcr p15, 7, r0, c15, c0, 0
840 __armv4_mmu_cache_on:
843 mov r6, #CB_BITS | 0x12 @ U
846 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
847 mcr p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
848 mrc p15, 0, r0, c1, c0, 0 @ read control reg
849 orr r0, r0, #0x5000 @ I-cache enable, RR cache replacement
851 ARM_BE8( orr r0, r0, #1 << 25 ) @ big-endian page tables
852 bl __common_mmu_cache_on
854 mcr p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
858 __armv7_mmu_cache_on:
859 enable_cp15_barriers r11
862 mrc p15, 0, r11, c0, c1, 4 @ read ID_MMFR0
864 movne r6, #CB_BITS | 0x02 @ !XN
867 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
869 mcrne p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
871 mrc p15, 0, r0, c1, c0, 0 @ read control reg
872 bic r0, r0, #1 << 28 @ clear SCTLR.TRE
873 orr r0, r0, #0x5000 @ I-cache enable, RR cache replacement
874 orr r0, r0, #0x003c @ write buffer
875 bic r0, r0, #2 @ A (no unaligned access fault)
876 orr r0, r0, #1 << 22 @ U (v6 unaligned access model)
877 @ (needed for ARM1176)
879 ARM_BE8( orr r0, r0, #1 << 25 ) @ big-endian page tables
880 mrcne p15, 0, r6, c2, c0, 2 @ read ttb control reg
881 orrne r0, r0, #1 @ MMU enabled
882 movne r1, #0xfffffffd @ domain 0 = client
883 bic r6, r6, #1 << 31 @ 32-bit translation system
884 bic r6, r6, #(7 << 0) | (1 << 4) @ use only ttbr0
885 mcrne p15, 0, r3, c2, c0, 0 @ load page table pointer
886 mcrne p15, 0, r1, c3, c0, 0 @ load domain access control
887 mcrne p15, 0, r6, c2, c0, 2 @ load ttb control
889 mcr p15, 0, r0, c7, c5, 4 @ ISB
890 mcr p15, 0, r0, c1, c0, 0 @ load control register
891 mrc p15, 0, r0, c1, c0, 0 @ and read it back
893 mcr p15, 0, r0, c7, c5, 4 @ ISB
898 mov r6, #CB_BITS | 0x12 @ U
901 mcr p15, 0, r0, c7, c7, 0 @ Invalidate whole cache
902 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
903 mcr p15, 0, r0, c8, c7, 0 @ flush UTLB
904 mrc p15, 0, r0, c1, c0, 0 @ read control reg
905 orr r0, r0, #0x1000 @ I-cache enable
906 bl __common_mmu_cache_on
908 mcr p15, 0, r0, c8, c7, 0 @ flush UTLB
911 __common_mmu_cache_on:
912 #ifndef CONFIG_THUMB2_KERNEL
914 orr r0, r0, #0x000d @ Write buffer, mmu
917 mcr p15, 0, r3, c2, c0, 0 @ load page table pointer
918 mcr p15, 0, r1, c3, c0, 0 @ load domain access control
920 .align 5 @ cache line aligned
921 1: mcr p15, 0, r0, c1, c0, 0 @ load control register
922 mrc p15, 0, r0, c1, c0, 0 @ and read it back to
923 sub pc, lr, r0, lsr #32 @ properly flush pipeline
926 #define PROC_ENTRY_SIZE (4*5)
929 * Here follow the relocatable cache support functions for the
930 * various processors. This is a generic hook for locating an
931 * entry and jumping to an instruction at the specified offset
932 * from the start of the block. Please note this is all position
942 call_cache_fn: adr r12, proc_types
943 #ifdef CONFIG_CPU_CP15
944 mrc p15, 0, r9, c0, c0 @ get processor ID
945 #elif defined(CONFIG_CPU_V7M)
947 * On v7-M the processor id is located in the V7M_SCB_CPUID
948 * register, but as cache handling is IMPLEMENTATION DEFINED on
949 * v7-M (if existant at all) we just return early here.
950 * If V7M_SCB_CPUID were used the cpu ID functions (i.e.
951 * __armv7_mmu_cache_{on,off,flush}) would be selected which
952 * use cp15 registers that are not implemented on v7-M.
956 ldr r9, =CONFIG_PROCESSOR_ID
958 1: ldr r1, [r12, #0] @ get value
959 ldr r2, [r12, #4] @ get mask
960 eor r1, r1, r9 @ (real ^ match)
962 ARM( addeq pc, r12, r3 ) @ call cache function
963 THUMB( addeq r12, r3 )
964 THUMB( moveq pc, r12 ) @ call cache function
965 add r12, r12, #PROC_ENTRY_SIZE
969 * Table for cache operations. This is basically:
972 * - 'cache on' method instruction
973 * - 'cache off' method instruction
974 * - 'cache flush' method instruction
976 * We match an entry using: ((real_id ^ match) & mask) == 0
978 * Writethrough caches generally only need 'on' and 'off'
979 * methods. Writeback caches _must_ have the flush method
983 .type proc_types,#object
985 .word 0x41000000 @ old ARM ID
994 .word 0x41007000 @ ARM7/710
1003 .word 0x41807200 @ ARM720T (writethrough)
1005 W(b) __armv4_mmu_cache_on
1006 W(b) __armv4_mmu_cache_off
1010 .word 0x41007400 @ ARM74x
1012 W(b) __armv3_mpu_cache_on
1013 W(b) __armv3_mpu_cache_off
1014 W(b) __armv3_mpu_cache_flush
1016 .word 0x41009400 @ ARM94x
1018 W(b) __armv4_mpu_cache_on
1019 W(b) __armv4_mpu_cache_off
1020 W(b) __armv4_mpu_cache_flush
1022 .word 0x41069260 @ ARM926EJ-S (v5TEJ)
1024 W(b) __arm926ejs_mmu_cache_on
1025 W(b) __armv4_mmu_cache_off
1026 W(b) __armv5tej_mmu_cache_flush
1028 .word 0x00007000 @ ARM7 IDs
1037 @ Everything from here on will be the new ID system.
1039 .word 0x4401a100 @ sa110 / sa1100
1041 W(b) __armv4_mmu_cache_on
1042 W(b) __armv4_mmu_cache_off
1043 W(b) __armv4_mmu_cache_flush
1045 .word 0x6901b110 @ sa1110
1047 W(b) __armv4_mmu_cache_on
1048 W(b) __armv4_mmu_cache_off
1049 W(b) __armv4_mmu_cache_flush
1052 .word 0xffffff00 @ PXA9xx
1053 W(b) __armv4_mmu_cache_on
1054 W(b) __armv4_mmu_cache_off
1055 W(b) __armv4_mmu_cache_flush
1057 .word 0x56158000 @ PXA168
1059 W(b) __armv4_mmu_cache_on
1060 W(b) __armv4_mmu_cache_off
1061 W(b) __armv5tej_mmu_cache_flush
1063 .word 0x56050000 @ Feroceon
1065 W(b) __armv4_mmu_cache_on
1066 W(b) __armv4_mmu_cache_off
1067 W(b) __armv5tej_mmu_cache_flush
1069 #ifdef CONFIG_CPU_FEROCEON_OLD_ID
1070 /* this conflicts with the standard ARMv5TE entry */
1071 .long 0x41009260 @ Old Feroceon
1073 b __armv4_mmu_cache_on
1074 b __armv4_mmu_cache_off
1075 b __armv5tej_mmu_cache_flush
1078 .word 0x66015261 @ FA526
1080 W(b) __fa526_cache_on
1081 W(b) __armv4_mmu_cache_off
1082 W(b) __fa526_cache_flush
1084 @ These match on the architecture ID
1086 .word 0x00020000 @ ARMv4T
1088 W(b) __armv4_mmu_cache_on
1089 W(b) __armv4_mmu_cache_off
1090 W(b) __armv4_mmu_cache_flush
1092 .word 0x00050000 @ ARMv5TE
1094 W(b) __armv4_mmu_cache_on
1095 W(b) __armv4_mmu_cache_off
1096 W(b) __armv4_mmu_cache_flush
1098 .word 0x00060000 @ ARMv5TEJ
1100 W(b) __armv4_mmu_cache_on
1101 W(b) __armv4_mmu_cache_off
1102 W(b) __armv5tej_mmu_cache_flush
1104 .word 0x0007b000 @ ARMv6
1106 W(b) __armv6_mmu_cache_on
1107 W(b) __armv4_mmu_cache_off
1108 W(b) __armv6_mmu_cache_flush
1110 .word 0x000f0000 @ new CPU Id
1112 W(b) __armv7_mmu_cache_on
1113 W(b) __armv7_mmu_cache_off
1114 W(b) __armv7_mmu_cache_flush
1116 .word 0 @ unrecognised type
1125 .size proc_types, . - proc_types
1128 * If you get a "non-constant expression in ".if" statement"
1129 * error from the assembler on this line, check that you have
1130 * not accidentally written a "b" instruction where you should
1131 * have written W(b).
1133 .if (. - proc_types) % PROC_ENTRY_SIZE != 0
1134 .error "The size of one or more proc_types entries is wrong."
1138 * Turn off the Cache and MMU. ARMv3 does not support
1139 * reading the control register, but ARMv4 does.
1142 * r0, r1, r2, r3, r9, r12 corrupted
1143 * This routine must preserve:
1147 cache_off: mov r3, #12 @ cache_off function
1150 __armv4_mpu_cache_off:
1151 mrc p15, 0, r0, c1, c0
1153 mcr p15, 0, r0, c1, c0 @ turn MPU and cache off
1155 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
1156 mcr p15, 0, r0, c7, c6, 0 @ flush D-Cache
1157 mcr p15, 0, r0, c7, c5, 0 @ flush I-Cache
1160 __armv3_mpu_cache_off:
1161 mrc p15, 0, r0, c1, c0
1163 mcr p15, 0, r0, c1, c0, 0 @ turn MPU and cache off
1165 mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
1168 __armv4_mmu_cache_off:
1170 mrc p15, 0, r0, c1, c0
1172 mcr p15, 0, r0, c1, c0 @ turn MMU and cache off
1174 mcr p15, 0, r0, c7, c7 @ invalidate whole cache v4
1175 mcr p15, 0, r0, c8, c7 @ invalidate whole TLB v4
1179 __armv7_mmu_cache_off:
1180 mrc p15, 0, r0, c1, c0
1186 mcr p15, 0, r0, c1, c0 @ turn MMU and cache off
1189 mcr p15, 0, r0, c8, c7, 0 @ invalidate whole TLB
1191 mcr p15, 0, r0, c7, c5, 6 @ invalidate BTC
1192 mcr p15, 0, r0, c7, c10, 4 @ DSB
1193 mcr p15, 0, r0, c7, c5, 4 @ ISB
1197 * Clean and flush the cache to maintain consistency.
1200 * r0 = start address
1201 * r1 = end address (exclusive)
1203 * r1, r2, r3, r9, r10, r11, r12 corrupted
1204 * This routine must preserve:
1213 __armv4_mpu_cache_flush:
1218 mcr p15, 0, ip, c7, c6, 0 @ invalidate D cache
1219 mov r1, #7 << 5 @ 8 segments
1220 1: orr r3, r1, #63 << 26 @ 64 entries
1221 2: mcr p15, 0, r3, c7, c14, 2 @ clean & invalidate D index
1222 subs r3, r3, #1 << 26
1223 bcs 2b @ entries 63 to 0
1224 subs r1, r1, #1 << 5
1225 bcs 1b @ segments 7 to 0
1228 mcrne p15, 0, ip, c7, c5, 0 @ invalidate I cache
1229 mcr p15, 0, ip, c7, c10, 4 @ drain WB
1232 __fa526_cache_flush:
1236 mcr p15, 0, r1, c7, c14, 0 @ clean and invalidate D cache
1237 mcr p15, 0, r1, c7, c5, 0 @ flush I cache
1238 mcr p15, 0, r1, c7, c10, 4 @ drain WB
1241 __armv6_mmu_cache_flush:
1244 mcreq p15, 0, r1, c7, c14, 0 @ clean+invalidate D
1245 mcr p15, 0, r1, c7, c5, 0 @ invalidate I+BTB
1246 mcreq p15, 0, r1, c7, c15, 0 @ clean+invalidate unified
1247 mcr p15, 0, r1, c7, c10, 4 @ drain WB
1250 __armv7_mmu_cache_flush:
1251 enable_cp15_barriers r10
1254 mrc p15, 0, r10, c0, c1, 5 @ read ID_MMFR1
1255 tst r10, #0xf << 16 @ hierarchical cache (ARMv7)
1258 mcr p15, 0, r10, c7, c14, 0 @ clean+invalidate D
1261 dcache_line_size r1, r2 @ r1 := dcache min line size
1262 sub r2, r1, #1 @ r2 := line size mask
1263 bic r0, r0, r2 @ round down start to line size
1264 sub r11, r11, #1 @ end address is exclusive
1265 bic r11, r11, r2 @ round down end to line size
1266 0: cmp r0, r11 @ finished?
1268 mcr p15, 0, r0, c7, c14, 1 @ Dcache clean/invalidate by VA
1272 mcr p15, 0, r10, c7, c10, 4 @ DSB
1273 mcr p15, 0, r10, c7, c5, 0 @ invalidate I+BTB
1274 mcr p15, 0, r10, c7, c10, 4 @ DSB
1275 mcr p15, 0, r10, c7, c5, 4 @ ISB
1278 __armv5tej_mmu_cache_flush:
1281 1: mrc p15, 0, APSR_nzcv, c7, c14, 3 @ test,clean,invalidate D cache
1283 mcr p15, 0, r0, c7, c5, 0 @ flush I cache
1284 mcr p15, 0, r0, c7, c10, 4 @ drain WB
1287 __armv4_mmu_cache_flush:
1290 mov r2, #64*1024 @ default: 32K dcache size (*2)
1291 mov r11, #32 @ default: 32 byte line size
1292 mrc p15, 0, r3, c0, c0, 1 @ read cache type
1293 teq r3, r9 @ cache ID register present?
1298 mov r2, r2, lsl r1 @ base dcache size *2
1299 tst r3, #1 << 14 @ test M bit
1300 addne r2, r2, r2, lsr #1 @ +1/2 size if M == 1
1304 mov r11, r11, lsl r3 @ cache line size in bytes
1307 bic r1, r1, #63 @ align to longest cache line
1310 ARM( ldr r3, [r1], r11 ) @ s/w flush D cache
1311 THUMB( ldr r3, [r1] ) @ s/w flush D cache
1312 THUMB( add r1, r1, r11 )
1316 mcr p15, 0, r1, c7, c5, 0 @ flush I cache
1317 mcr p15, 0, r1, c7, c6, 0 @ flush D cache
1318 mcr p15, 0, r1, c7, c10, 4 @ drain WB
1321 __armv3_mmu_cache_flush:
1322 __armv3_mpu_cache_flush:
1326 mcr p15, 0, r1, c7, c0, 0 @ invalidate whole cache v3
1330 * Various debugging routines for printing hex characters and
1331 * memory, which again must be relocatable.
1335 .type phexbuf,#object
1337 .size phexbuf, . - phexbuf
1339 @ phex corrupts {r0, r1, r2, r3}
1340 phex: adr r3, phexbuf
1354 @ puts corrupts {r0, r1, r2, r3}
1355 puts: loadsp r3, r2, r1
1356 1: ldrb r2, [r0], #1
1369 @ putc corrupts {r0, r1, r2, r3}
1376 @ memdump corrupts {r0, r1, r2, r3, r10, r11, r12, lr}
1377 memdump: mov r12, r0
1380 2: mov r0, r11, lsl #2
1388 ldr r0, [r12, r11, lsl #2]
1408 #ifdef CONFIG_ARM_VIRT_EXT
1410 __hyp_reentry_vectors:
1416 W(b) __enter_kernel @ hyp
1419 #endif /* CONFIG_ARM_VIRT_EXT */
1422 mov r0, #0 @ must be 0
1423 mov r1, r7 @ restore architecture number
1424 mov r2, r8 @ restore atags pointer
1425 ARM( mov pc, r4 ) @ call kernel
1426 M_CLASS( add r4, r4, #1 ) @ enter in Thumb mode for M class
1427 THUMB( bx r4 ) @ entry point is always ARM for A/R classes
1431 #ifdef CONFIG_EFI_STUB
1432 ENTRY(efi_enter_kernel)
1433 mov r4, r0 @ preserve image base
1434 mov r8, r1 @ preserve DT pointer
1436 mrc p15, 0, r0, c1, c0, 0 @ read SCTLR
1437 tst r0, #0x1 @ MMU enabled?
1438 orreq r4, r4, #1 @ set LSB if not
1440 mov r0, r8 @ DT start
1441 add r1, r8, r2 @ DT end
1442 bl cache_clean_flush
1444 adr r0, 0f @ switch to our stack
1448 mov r5, #0 @ appended DTB size
1449 mov r7, #0xFFFFFFFF @ machine ID
1451 ENDPROC(efi_enter_kernel)
1452 0: .long .L_user_stack_end - .
1456 .section ".stack", "aw", %nobits
1457 .L_user_stack: .space 4096