| | 1 | /* SPDX-License-Identifier: GPL-2.0 */ |
| | 2 | #ifdef CONFIG_PPC64 |
| | 3 | #define PROVIDE32(x) PROVIDE(__unused__##x) |
| | 4 | #else |
| | 5 | #define PROVIDE32(x) PROVIDE(x) |
| | 6 | #endif |
| | 7 | |
| | 8 | #define BSS_FIRST_SECTIONS *(.bss.prominit) |
| | 9 | |
| | 10 | #include <asm/page.h> |
| | 11 | #include <asm-generic/vmlinux.lds.h> |
| | 12 | #include <asm/cache.h> |
| | 13 | #include <asm/thread_info.h> |
| | 14 | |
| | 15 | #if defined(CONFIG_STRICT_KERNEL_RWX) && !defined(CONFIG_PPC32) |
| | 16 | #define STRICT_ALIGN_SIZE (1 << 24) |
| | 17 | #else |
| | 18 | #define STRICT_ALIGN_SIZE PAGE_SIZE |
| | 19 | #endif |
| | 20 | |
| | 21 | ENTRY(_stext) |
| | 22 | |
| | 23 | PHDRS { |
| | 24 | kernel PT_LOAD FLAGS(7); /* RWX */ |
| | 25 | notes PT_NOTE FLAGS(0); |
| | 26 | dummy PT_NOTE FLAGS(0); |
| | 27 | |
| | 28 | /* binutils < 2.18 has a bug that makes it misbehave when taking an |
| | 29 | ELF file with all segments at load address 0 as input. This |
| | 30 | happens when running "strip" on vmlinux, because of the AT() magic |
| | 31 | in this linker script. People using GCC >= 4.2 won't run into |
| | 32 | this problem, because the "build-id" support will put some data |
| | 33 | into the "notes" segment (at a non-zero load address). |
| | 34 | |
| | 35 | To work around this, we force some data into both the "dummy" |
| | 36 | segment and the kernel segment, so the dummy segment will get a |
| | 37 | non-zero load address. It's not enough to always create the |
| | 38 | "notes" segment, since if nothing gets assigned to it, its load |
| | 39 | address will be zero. */ |
| | 40 | } |
| | 41 | |
| | 42 | #ifdef CONFIG_PPC64 |
| | 43 | OUTPUT_ARCH(powerpc:common64) |
| | 44 | jiffies = jiffies_64; |
| | 45 | #else |
| | 46 | OUTPUT_ARCH(powerpc:common) |
| | 47 | jiffies = jiffies_64 + 4; |
| | 48 | #endif |
| | 49 | SECTIONS |
| | 50 | { |
| | 51 | . = KERNELBASE; |
| | 52 | |
| | 53 | /* |
| | 54 | * Text, read only data and other permanent read-only sections |
| | 55 | */ |
| | 56 | |
| | 57 | _text = .; |
| | 58 | _stext = .; |
| | 59 | |
| | 60 | /* |
| | 61 | * Head text. |
| | 62 | * This needs to be in its own output section to avoid ld placing |
| | 63 | * branch trampoline stubs randomly throughout the fixed sections, |
| | 64 | * which it will do (even if the branch comes from another section) |
| | 65 | * in order to optimize stub generation. |
| | 66 | */ |
| | 67 | .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { |
| | 68 | #ifdef CONFIG_PPC64 |
| | 69 | KEEP(*(.head.text.first_256B)); |
| | 70 | #ifdef CONFIG_PPC_BOOK3E |
| | 71 | #else |
| | 72 | KEEP(*(.head.text.real_vectors)); |
| | 73 | *(.head.text.real_trampolines); |
| | 74 | KEEP(*(.head.text.virt_vectors)); |
| | 75 | *(.head.text.virt_trampolines); |
| | 76 | # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV) |
| | 77 | KEEP(*(.head.data.fwnmi_page)); |
| | 78 | # endif |
| | 79 | #endif |
| | 80 | #else /* !CONFIG_PPC64 */ |
| | 81 | HEAD_TEXT |
| | 82 | #endif |
| | 83 | } :kernel |
| | 84 | |
| | 85 | __head_end = .; |
| | 86 | |
| | 87 | #ifdef CONFIG_PPC64 |
| | 88 | /* |
| | 89 | * BLOCK(0) overrides the default output section alignment because |
| | 90 | * this needs to start right after .head.text in order for fixed |
| | 91 | * section placement to work. |
| | 92 | */ |
| | 93 | .text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) { |
| | 94 | #ifdef CONFIG_LD_HEAD_STUB_CATCH |
| | 95 | KEEP(*(.linker_stub_catch)); |
| | 96 | . = . ; |
| | 97 | #endif |
| | 98 | |
| | 99 | #else |
| | 100 | .text : AT(ADDR(.text) - LOAD_OFFSET) { |
| | 101 | ALIGN_FUNCTION(); |
| | 102 | #endif |
| | 103 | /* careful! __ftr_alt_* sections need to be close to .text */ |
| | 104 | *(.text.hot TEXT_MAIN .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text); |
| | 105 | #ifdef CONFIG_PPC64 |
| | 106 | *(.tramp.ftrace.text); |
| | 107 | #endif |
| | 108 | SCHED_TEXT |
| | 109 | CPUIDLE_TEXT |
| | 110 | LOCK_TEXT |
| | 111 | KPROBES_TEXT |
| | 112 | IRQENTRY_TEXT |
| | 113 | SOFTIRQENTRY_TEXT |
| | 114 | /* |
| | 115 | * -Os builds call FP save/restore functions. The powerpc64 |
| | 116 | * linker generates those on demand in the .sfpr section. |
| | 117 | * .sfpr gets placed at the beginning of a group of input |
| | 118 | * sections, which can break start-of-text offset if it is |
| | 119 | * included with the main text sections, so put it by itself. |
| | 120 | */ |
| | 121 | *(.sfpr); |
| | 122 | MEM_KEEP(init.text) |
| | 123 | MEM_KEEP(exit.text) |
| | 124 | |
| | 125 | #ifdef CONFIG_PPC32 |
| | 126 | *(.got1) |
| | 127 | __got2_start = .; |
| | 128 | *(.got2) |
| | 129 | __got2_end = .; |
| | 130 | #endif /* CONFIG_PPC32 */ |
| | 131 | |
| | 132 | } :kernel |
| | 133 | |
| | 134 | . = ALIGN(PAGE_SIZE); |
| | 135 | _etext = .; |
| | 136 | PROVIDE32 (etext = .); |
| | 137 | |
| | 138 | /* Read-only data */ |
| | 139 | RO_DATA(PAGE_SIZE) |
| | 140 | |
| | 141 | #ifdef CONFIG_PPC64 |
| | 142 | . = ALIGN(8); |
| | 143 | __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) { |
| | 144 | __start___stf_entry_barrier_fixup = .; |
| | 145 | *(__stf_entry_barrier_fixup) |
| | 146 | __stop___stf_entry_barrier_fixup = .; |
| | 147 | } |
| | 148 | |
| | 149 | . = ALIGN(8); |
| | 150 | __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) { |
| | 151 | __start___stf_exit_barrier_fixup = .; |
| | 152 | *(__stf_exit_barrier_fixup) |
| | 153 | __stop___stf_exit_barrier_fixup = .; |
| | 154 | } |
| | 155 | |
| | 156 | . = ALIGN(8); |
| | 157 | __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) { |
| | 158 | __start___rfi_flush_fixup = .; |
| | 159 | *(__rfi_flush_fixup) |
| | 160 | __stop___rfi_flush_fixup = .; |
| | 161 | } |
| | 162 | #endif /* CONFIG_PPC64 */ |
| | 163 | |
| | 164 | #ifdef CONFIG_PPC_BARRIER_NOSPEC |
| | 165 | . = ALIGN(8); |
| | 166 | __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) { |
| | 167 | __start___barrier_nospec_fixup = .; |
| | 168 | *(__barrier_nospec_fixup) |
| | 169 | __stop___barrier_nospec_fixup = .; |
| | 170 | } |
| | 171 | #endif /* CONFIG_PPC_BARRIER_NOSPEC */ |
| | 172 | |
| | 173 | EXCEPTION_TABLE(0) |
| | 174 | |
| | 175 | NOTES :kernel :notes |
| | 176 | |
| | 177 | /* The dummy segment contents for the bug workaround mentioned above |
| | 178 | near PHDRS. */ |
| | 179 | .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) { |
| | 180 | LONG(0) |
| | 181 | LONG(0) |
| | 182 | LONG(0) |
| | 183 | } :kernel :dummy |
| | 184 | |
| | 185 | /* |
| | 186 | * Init sections discarded at runtime |
| | 187 | */ |
| | 188 | . = ALIGN(STRICT_ALIGN_SIZE); |
| | 189 | __init_begin = .; |
| | 190 | . = ALIGN(PAGE_SIZE); |
| | 191 | .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { |
| | 192 | _sinittext = .; |
| | 193 | INIT_TEXT |
| | 194 | _einittext = .; |
| | 195 | #ifdef CONFIG_PPC64 |
| | 196 | *(.tramp.ftrace.init); |
| | 197 | #endif |
| | 198 | } :kernel |
| | 199 | |
| | 200 | /* .exit.text is discarded at runtime, not link time, |
| | 201 | * to deal with references from __bug_table |
| | 202 | */ |
| | 203 | .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { |
| | 204 | EXIT_TEXT |
| | 205 | } |
| | 206 | |
| | 207 | .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { |
| | 208 | INIT_DATA |
| | 209 | __vtop_table_begin = .; |
| | 210 | KEEP(*(.vtop_fixup)); |
| | 211 | __vtop_table_end = .; |
| | 212 | __ptov_table_begin = .; |
| | 213 | KEEP(*(.ptov_fixup)); |
| | 214 | __ptov_table_end = .; |
| | 215 | } |
| | 216 | |
| | 217 | .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { |
| | 218 | INIT_SETUP(16) |
| | 219 | } |
| | 220 | |
| | 221 | .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) { |
| | 222 | INIT_CALLS |
| | 223 | } |
| | 224 | |
| | 225 | .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) { |
| | 226 | CON_INITCALL |
| | 227 | } |
| | 228 | |
| | 229 | . = ALIGN(8); |
| | 230 | __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) { |
| | 231 | __start___ftr_fixup = .; |
| | 232 | KEEP(*(__ftr_fixup)) |
| | 233 | __stop___ftr_fixup = .; |
| | 234 | } |
| | 235 | . = ALIGN(8); |
| | 236 | __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) { |
| | 237 | __start___mmu_ftr_fixup = .; |
| | 238 | KEEP(*(__mmu_ftr_fixup)) |
| | 239 | __stop___mmu_ftr_fixup = .; |
| | 240 | } |
| | 241 | . = ALIGN(8); |
| | 242 | __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) { |
| | 243 | __start___lwsync_fixup = .; |
| | 244 | KEEP(*(__lwsync_fixup)) |
| | 245 | __stop___lwsync_fixup = .; |
| | 246 | } |
| | 247 | #ifdef CONFIG_PPC64 |
| | 248 | . = ALIGN(8); |
| | 249 | __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) { |
| | 250 | __start___fw_ftr_fixup = .; |
| | 251 | KEEP(*(__fw_ftr_fixup)) |
| | 252 | __stop___fw_ftr_fixup = .; |
| | 253 | } |
| | 254 | #endif |
| | 255 | .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { |
| | 256 | INIT_RAM_FS |
| | 257 | } |
| | 258 | |
| | 259 | PERCPU_SECTION(L1_CACHE_BYTES) |
| | 260 | |
| | 261 | . = ALIGN(8); |
| | 262 | .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) { |
| | 263 | __machine_desc_start = . ; |
| | 264 | KEEP(*(.machine.desc)) |
| | 265 | __machine_desc_end = . ; |
| | 266 | } |
| | 267 | #ifdef CONFIG_RELOCATABLE |
| | 268 | . = ALIGN(8); |
| | 269 | .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET) |
| | 270 | { |
| | 271 | #ifdef CONFIG_PPC32 |
| | 272 | __dynamic_symtab = .; |
| | 273 | #endif |
| | 274 | *(.dynsym) |
| | 275 | } |
| | 276 | .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) } |
| | 277 | .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET) |
| | 278 | { |
| | 279 | __dynamic_start = .; |
| | 280 | *(.dynamic) |
| | 281 | } |
| | 282 | .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) } |
| | 283 | .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) } |
| | 284 | .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET) |
| | 285 | { |
| | 286 | __rela_dyn_start = .; |
| | 287 | *(.rela*) |
| | 288 | } |
| | 289 | #endif |
| | 290 | /* .exit.data is discarded at runtime, not link time, |
| | 291 | * to deal with references from .exit.text |
| | 292 | */ |
| | 293 | .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { |
| | 294 | EXIT_DATA |
| | 295 | } |
| | 296 | |
| | 297 | /* freed after init ends here */ |
| | 298 | . = ALIGN(PAGE_SIZE); |
| | 299 | __init_end = .; |
| | 300 | |
| | 301 | /* |
| | 302 | * And now the various read/write data |
| | 303 | */ |
| | 304 | |
| | 305 | . = ALIGN(PAGE_SIZE); |
| | 306 | _sdata = .; |
| | 307 | |
| | 308 | #ifdef CONFIG_PPC32 |
| | 309 | .data : AT(ADDR(.data) - LOAD_OFFSET) { |
| | 310 | DATA_DATA |
| | 311 | *(.data.rel*) |
| | 312 | *(SDATA_MAIN) |
| | 313 | *(.sdata2) |
| | 314 | *(.got.plt) *(.got) |
| | 315 | *(.plt) |
| | 316 | } |
| | 317 | #else |
| | 318 | .data : AT(ADDR(.data) - LOAD_OFFSET) { |
| | 319 | DATA_DATA |
| | 320 | *(.data.rel*) |
| | 321 | *(.toc1) |
| | 322 | *(.branch_lt) |
| | 323 | } |
| | 324 | |
| | 325 | .opd : AT(ADDR(.opd) - LOAD_OFFSET) { |
| | 326 | __start_opd = .; |
| | 327 | KEEP(*(.opd)) |
| | 328 | __end_opd = .; |
| | 329 | } |
| | 330 | |
| | 331 | . = ALIGN(256); |
| | 332 | .got : AT(ADDR(.got) - LOAD_OFFSET) { |
| | 333 | __toc_start = .; |
| | 334 | #ifndef CONFIG_RELOCATABLE |
| | 335 | __prom_init_toc_start = .; |
| | 336 | arch/powerpc/kernel/prom_init.o*(.toc .got) |
| | 337 | __prom_init_toc_end = .; |
| | 338 | #endif |
| | 339 | *(.got) |
| | 340 | *(.toc) |
| | 341 | } |
| | 342 | #endif |
| | 343 | |
| | 344 | /* The initial task and kernel stack */ |
| | 345 | INIT_TASK_DATA_SECTION(THREAD_SIZE) |
| | 346 | |
| | 347 | .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) { |
| | 348 | PAGE_ALIGNED_DATA(PAGE_SIZE) |
| | 349 | } |
| | 350 | |
| | 351 | .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) { |
| | 352 | CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES) |
| | 353 | } |
| | 354 | |
| | 355 | .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) { |
| | 356 | READ_MOSTLY_DATA(L1_CACHE_BYTES) |
| | 357 | } |
| | 358 | |
| | 359 | . = ALIGN(PAGE_SIZE); |
| | 360 | .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { |
| | 361 | NOSAVE_DATA |
| | 362 | } |
| | 363 | |
| | 364 | BUG_TABLE |
| | 365 | |
| | 366 | . = ALIGN(PAGE_SIZE); |
| | 367 | _edata = .; |
| | 368 | PROVIDE32 (edata = .); |
| | 369 | |
| | 370 | /* |
| | 371 | * And finally the bss |
| | 372 | */ |
| | 373 | |
| | 374 | BSS_SECTION(0, 0, 0) |
| | 375 | |
| | 376 | . = ALIGN(PAGE_SIZE); |
| | 377 | _end = . ; |
| | 378 | PROVIDE32 (end = .); |
| | 379 | |
| | 380 | STABS_DEBUG |
| | 381 | |
| | 382 | DWARF_DEBUG |
| | 383 | |
| | 384 | DISCARDS |
| | 385 | /DISCARD/ : { |
| | 386 | *(*.EMB.apuinfo) |
| | 387 | *(.glink .iplt .plt .rela* .comment) |
| | 388 | *(.gnu.version*) |
| | 389 | *(.gnu.attributes) |
| | 390 | *(.eh_frame) |
| | 391 | } |
| | 392 | } |
projects / linux-2.6-block.git / blame_incremental