[linux-2.6-block.git] / scripts / kconfig / zconf.l

%option nostdinit noyywrap never-interactive full ecs
%option 8bit nodefault yylineno
%x COMMAND HELP STRING PARAM ASSIGN_VAL
%{
/*
 * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
 * Released under the terms of the GNU GPL v2.0.
 */

#include <assert.h>
#include <limits.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <unistd.h>

#include "lkc.h"

#define START_STRSIZE	16

static struct {
	struct file *file;
	int lineno;
} current_pos;

static char *text;
static int text_size, text_asize;

struct buffer {
	struct buffer *parent;
	YY_BUFFER_STATE state;
};

struct buffer *current_buf;

static int last_ts, first_ts;

static char *expand_token(const char *in, size_t n);
static void append_expanded_string(const char *in);
static void zconf_endhelp(void);
static void zconf_endfile(void);

static void new_string(void)
{
	text = xmalloc(START_STRSIZE);
	text_asize = START_STRSIZE;
	text_size = 0;
	*text = 0;
}

static void append_string(const char *str, int size)
{
	int new_size = text_size + size + 1;
	if (new_size > text_asize) {
		new_size += START_STRSIZE - 1;
		new_size &= -START_STRSIZE;
		text = xrealloc(text, new_size);
		text_asize = new_size;
	}
	memcpy(text + text_size, str, size);
	text_size += size;
	text[text_size] = 0;
}

static void alloc_string(const char *str, int size)
{
	text = xmalloc(size + 1);
	memcpy(text, str, size);
	text[size] = 0;
}

static void warn_ignored_character(char chr)
{
	fprintf(stderr,
	        "%s:%d:warning: ignoring unsupported character '%c'\n",
	        zconf_curname(), zconf_lineno(), chr);
}
%}

n	[A-Za-z0-9_-]

%%
	int str = 0;
	int ts, i;

[ \t]*#.*\n	|
[ \t]*\n	{
	return T_EOL;
}
[ \t]*#.*


[ \t]+	{
	BEGIN(COMMAND);
}

.	{
	unput(yytext[0]);
	BEGIN(COMMAND);
}


<COMMAND>{
	{n}+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		current_pos.file = current_file;
		current_pos.lineno = yylineno;
		if (id && id->flags & TF_COMMAND) {
			BEGIN(PARAM);
			yylval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		yylval.string = text;
		return T_VARIABLE;
	}
	({n}|$)+	{
		/* this token includes at least one '$' */
		yylval.string = expand_token(yytext, yyleng);
		if (strlen(yylval.string))
			return T_VARIABLE;
		free(yylval.string);
	}
	"="	{ BEGIN(ASSIGN_VAL); yylval.flavor = VAR_RECURSIVE; return T_ASSIGN; }
	":="	{ BEGIN(ASSIGN_VAL); yylval.flavor = VAR_SIMPLE; return T_ASSIGN; }
	"+="	{ BEGIN(ASSIGN_VAL); yylval.flavor = VAR_APPEND; return T_ASSIGN; }
	[[:blank:]]+
	.	warn_ignored_character(*yytext);
	\n	{
		BEGIN(INITIAL);
		return T_EOL;
	}
}

<ASSIGN_VAL>{
	[^[:blank:]\n]+.*	{
		alloc_string(yytext, yyleng);
		yylval.string = text;
		return T_ASSIGN_VAL;
	}
	\n	{ BEGIN(INITIAL); return T_EOL; }
	.
}

<PARAM>{
	"&&"	return T_AND;
	"||"	return T_OR;
	"("	return T_OPEN_PAREN;
	")"	return T_CLOSE_PAREN;
	"!"	return T_NOT;
	"="	return T_EQUAL;
	"!="	return T_UNEQUAL;
	"<="	return T_LESS_EQUAL;
	">="	return T_GREATER_EQUAL;
	"<"	return T_LESS;
	">"	return T_GREATER;
	\"|\'	{
		str = yytext[0];
		new_string();
		BEGIN(STRING);
	}
	\n	BEGIN(INITIAL); return T_EOL;
	({n}|[/.])+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		if (id && id->flags & TF_PARAM) {
			yylval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		yylval.string = text;
		return T_WORD;
	}
	({n}|[/.$])+	{
		/* this token includes at least one '$' */
		yylval.string = expand_token(yytext, yyleng);
		if (strlen(yylval.string))
			return T_WORD;
		free(yylval.string);
	}
	#.*	/* comment */
	\\\n	;
	[[:blank:]]+
	.	warn_ignored_character(*yytext);
	<<EOF>> {
		BEGIN(INITIAL);
	}
}

<STRING>{
	"$".*	append_expanded_string(yytext);
	[^$'"\\\n]+/\n	{
		append_string(yytext, yyleng);
		yylval.string = text;
		return T_WORD_QUOTE;
	}
	[^$'"\\\n]+	{
		append_string(yytext, yyleng);
	}
	\\.?/\n	{
		append_string(yytext + 1, yyleng - 1);
		yylval.string = text;
		return T_WORD_QUOTE;
	}
	\\.?	{
		append_string(yytext + 1, yyleng - 1);
	}
	\'|\"	{
		if (str == yytext[0]) {
			BEGIN(PARAM);
			yylval.string = text;
			return T_WORD_QUOTE;
		} else
			append_string(yytext, 1);
	}
	\n	{
		fprintf(stderr,
			"%s:%d:warning: multi-line strings not supported\n",
			zconf_curname(), zconf_lineno());
		BEGIN(INITIAL);
		return T_EOL;
	}
	<<EOF>>	{
		BEGIN(INITIAL);
	}
}

<HELP>{
	[ \t]+	{
		ts = 0;
		for (i = 0; i < yyleng; i++) {
			if (yytext[i] == '\t')
				ts = (ts & ~7) + 8;
			else
				ts++;
		}
		last_ts = ts;
		if (first_ts) {
			if (ts < first_ts) {
				zconf_endhelp();
				return T_HELPTEXT;
			}
			ts -= first_ts;
			while (ts > 8) {
				append_string("        ", 8);
				ts -= 8;
			}
			append_string("        ", ts);
		}
	}
	[ \t]*\n/[^ \t\n] {
		zconf_endhelp();
		return T_HELPTEXT;
	}
	[ \t]*\n	{
		append_string("\n", 1);
	}
	[^ \t\n].* {
		while (yyleng) {
			if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
				break;
			yyleng--;
		}
		append_string(yytext, yyleng);
		if (!first_ts)
			first_ts = last_ts;
	}
	<<EOF>>	{
		zconf_endhelp();
		return T_HELPTEXT;
	}
}

<<EOF>>	{
	if (current_file) {
		zconf_endfile();
		return T_EOL;
	}
	fclose(yyin);
	yyterminate();
}

%%
static char *expand_token(const char *in, size_t n)
{
	char *out;
	int c;
	char c2;
	const char *rest, *end;

	new_string();
	append_string(in, n);

	/* get the whole line because we do not know the end of token. */
	while ((c = input()) != EOF) {
		if (c == '\n') {
			unput(c);
			break;
		}
		c2 = c;
		append_string(&c2, 1);
	}

	rest = text;
	out = expand_one_token(&rest);

	/* push back unused characters to the input stream */
	end = rest + strlen(rest);
	while (end > rest)
		unput(*--end);

	free(text);

	return out;
}

static void append_expanded_string(const char *str)
{
	const char *end;
	char *res;

	str++;

	res = expand_dollar(&str);

	/* push back unused characters to the input stream */
	end = str + strlen(str);
	while (end > str)
		unput(*--end);

	append_string(res, strlen(res));

	free(res);
}

void zconf_starthelp(void)
{
	new_string();
	last_ts = first_ts = 0;
	BEGIN(HELP);
}

static void zconf_endhelp(void)
{
	yylval.string = text;
	BEGIN(INITIAL);
}


/*
 * Try to open specified file with following names:
 * ./name
 * $(srctree)/name
 * The latter is used when srctree is separate from objtree
 * when compiling the kernel.
 * Return NULL if file is not found.
 */
FILE *zconf_fopen(const char *name)
{
	char *env, fullname[PATH_MAX+1];
	FILE *f;

	f = fopen(name, "r");
	if (!f && name != NULL && name[0] != '/') {
		env = getenv(SRCTREE);
		if (env) {
			sprintf(fullname, "%s/%s", env, name);
			f = fopen(fullname, "r");
		}
	}
	return f;
}

void zconf_initscan(const char *name)
{
	yyin = zconf_fopen(name);
	if (!yyin) {
		fprintf(stderr, "can't find file %s\n", name);
		exit(1);
	}

	current_buf = xmalloc(sizeof(*current_buf));
	memset(current_buf, 0, sizeof(*current_buf));

	current_file = file_lookup(name);
	yylineno = 1;
}

void zconf_nextfile(const char *name)
{
	struct file *iter;
	struct file *file = file_lookup(name);
	struct buffer *buf = xmalloc(sizeof(*buf));
	memset(buf, 0, sizeof(*buf));

	current_buf->state = YY_CURRENT_BUFFER;
	yyin = zconf_fopen(file->name);
	if (!yyin) {
		fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
			zconf_curname(), zconf_lineno(), file->name);
		exit(1);
	}
	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	buf->parent = current_buf;
	current_buf = buf;

	current_file->lineno = yylineno;
	file->parent = current_file;

	for (iter = current_file; iter; iter = iter->parent) {
		if (!strcmp(iter->name, file->name)) {
			fprintf(stderr,
				"Recursive inclusion detected.\n"
				"Inclusion path:\n"
				"  current file : %s\n", file->name);
			iter = file;
			do {
				iter = iter->parent;
				fprintf(stderr, "  included from: %s:%d\n",
					iter->name, iter->lineno - 1);
			} while (strcmp(iter->name, file->name));
			exit(1);
		}
	}

	yylineno = 1;
	current_file = file;
}

static void zconf_endfile(void)
{
	struct buffer *parent;

	current_file = current_file->parent;
	if (current_file)
		yylineno = current_file->lineno;

	parent = current_buf->parent;
	if (parent) {
		fclose(yyin);
		yy_delete_buffer(YY_CURRENT_BUFFER);
		yy_switch_to_buffer(parent->state);
	}
	free(current_buf);
	current_buf = parent;
}

int zconf_lineno(void)
{
	return current_pos.lineno;
}

const char *zconf_curname(void)
{
	return current_pos.file ? current_pos.file->name : "<none>";
}
Commit	Line	Data
674eed8a	1	%option nostdinit noyywrap never-interactive full ecs
18492685	2	%option 8bit nodefault yylineno
9ced3bdd	3	%x COMMAND HELP STRING PARAM ASSIGN_VAL
1da177e4 LT	4	%{
	5	/*
	6	* Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
	7	* Released under the terms of the GNU GPL v2.0.
	8	*/
	9
9ced3bdd	10	#include <assert.h>
1da177e4 LT	11	#include <limits.h>
	12	#include <stdio.h>
	13	#include <stdlib.h>
	14	#include <string.h>
	15	#include <unistd.h>
	16
1da177e4 LT	17	#include "lkc.h"
	18
	19	#define START_STRSIZE 16
	20
a02f0570 RZ	21	static struct {
	22	struct file *file;
	23	int lineno;
	24	} current_pos;
	25
7a88488b	26	static char *text;
1da177e4 LT	27	static int text_size, text_asize;
	28
	29	struct buffer {
bb66fc67 MY	30	struct buffer *parent;
bb66fc67 MY	31	YY_BUFFER_STATE state;
1da177e4 LT	32	};
	33
	34	struct buffer *current_buf;
	35
	36	static int last_ts, first_ts;
	37
104daea1 MY	38	static char expand_token(const char in, size_t n);
104daea1 MY	39	static void append_expanded_string(const char *in);
1da177e4	40	static void zconf_endhelp(void);
a02f0570	41	static void zconf_endfile(void);
1da177e4	42
65166571	43	static void new_string(void)
1da177e4	44	{
177acf78	45	text = xmalloc(START_STRSIZE);
1da177e4	46	text_asize = START_STRSIZE;
1da177e4	47	text_size = 0;
7a88488b	48	*text = 0;
1da177e4 LT	49	}
1da177e4 LT	50
65166571	51	static void append_string(const char *str, int size)
1da177e4 LT	52	{
	53	int new_size = text_size + size + 1;
	54	if (new_size > text_asize) {
7a88488b RZ	55	new_size += START_STRSIZE - 1;
7a88488b RZ	56	new_size &= -START_STRSIZE;
d717f24d	57	text = xrealloc(text, new_size);
1da177e4	58	text_asize = new_size;
1da177e4	59	}
7a88488b	60	memcpy(text + text_size, str, size);
1da177e4	61	text_size += size;
7a88488b	62	text[text_size] = 0;
1da177e4 LT	63	}
1da177e4 LT	64
65166571	65	static void alloc_string(const char *str, int size)
1da177e4	66	{
177acf78	67	text = xmalloc(size + 1);
1da177e4 LT	68	memcpy(text, str, size);
	69	text[size] = 0;
	70	}
c2264564 AR	71
	72	static void warn_ignored_character(char chr)
	73	{
	74	fprintf(stderr,
	75	"%s:%d:warning: ignoring unsupported character '%c'\n",
	76	zconf_curname(), zconf_lineno(), chr);
	77	}
1da177e4 LT	78	%}
1da177e4 LT	79
c2264564	80	n [A-Za-z0-9_-]
1da177e4 LT	81
	82	%%
	83	int str = 0;
	84	int ts, i;
	85
a02f0570 RZ	86	[ \t]#.\n \|
a02f0570 RZ	87	[ \t]*\n {
a02f0570 RZ	88	return T_EOL;
a02f0570 RZ	89	}
1da177e4 LT	90	[ \t]#.
1da177e4 LT	91
1da177e4 LT	92
	93	[ \t]+ {
	94	BEGIN(COMMAND);
	95	}
	96
	97	. {
	98	unput(yytext[0]);
	99	BEGIN(COMMAND);
	100	}
	101
	102
	103	<COMMAND>{
1da177e4	104	{n}+ {
61f956f5	105	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
a02f0570	106	current_pos.file = current_file;
18492685	107	current_pos.lineno = yylineno;
7a88488b	108	if (id && id->flags & TF_COMMAND) {
9de07153	109	BEGIN(PARAM);
765f4cde	110	yylval.id = id;
7a88488b RZ	111	return id->token;
7a88488b RZ	112	}
1da177e4	113	alloc_string(yytext, yyleng);
765f4cde	114	yylval.string = text;
9ced3bdd	115	return T_VARIABLE;
1da177e4	116	}
82bc8bd8 MY	117	({n}\|$)+ {
	118	/* this token includes at least one '$' */
	119	yylval.string = expand_token(yytext, yyleng);
	120	if (strlen(yylval.string))
	121	return T_VARIABLE;
	122	free(yylval.string);
	123	}
1175c025 MY	124	"=" { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_RECURSIVE; return T_ASSIGN; }
1175c025 MY	125	":=" { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_SIMPLE; return T_ASSIGN; }
ed2a22f2	126	"+=" { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_APPEND; return T_ASSIGN; }
9ced3bdd	127	[[:blank:]]+
c2264564	128	. warn_ignored_character(*yytext);
a02f0570 RZ	129	\n {
a02f0570 RZ	130	BEGIN(INITIAL);
a02f0570 RZ	131	return T_EOL;
a02f0570 RZ	132	}
1da177e4 LT	133	}
1da177e4 LT	134
9ced3bdd MY	135	<ASSIGN_VAL>{
	136	[^[:blank:]\n]+.* {
	137	alloc_string(yytext, yyleng);
	138	yylval.string = text;
	139	return T_ASSIGN_VAL;
	140	}
	141	\n { BEGIN(INITIAL); return T_EOL; }
	142	.
	143	}
	144
1da177e4 LT	145	<PARAM>{
	146	"&&" return T_AND;
	147	"\|\|" return T_OR;
	148	"(" return T_OPEN_PAREN;
	149	")" return T_CLOSE_PAREN;
	150	"!" return T_NOT;
	151	"=" return T_EQUAL;
	152	"!=" return T_UNEQUAL;
31847b67 JB	153	"<=" return T_LESS_EQUAL;
	154	">=" return T_GREATER_EQUAL;
	155	"<" return T_LESS;
	156	">" return T_GREATER;
1da177e4 LT	157	\"\|\' {
	158	str = yytext[0];
	159	new_string();
	160	BEGIN(STRING);
	161	}
18492685	162	\n BEGIN(INITIAL); return T_EOL;
c2264564	163	({n}\|[/.])+ {
61f956f5	164	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
3370f9f0	165	if (id && id->flags & TF_PARAM) {
765f4cde	166	yylval.id = id;
7a88488b	167	return id->token;
3370f9f0	168	}
1da177e4	169	alloc_string(yytext, yyleng);
765f4cde	170	yylval.string = text;
1da177e4 LT	171	return T_WORD;
1da177e4 LT	172	}
104daea1 MY	173	({n}\|[/.$])+ {
	174	/* this token includes at least one '$' */
	175	yylval.string = expand_token(yytext, yyleng);
	176	if (strlen(yylval.string))
	177	return T_WORD;
	178	free(yylval.string);
	179	}
1da177e4	180	#.* /* comment */
18492685	181	\\\n ;
2e0d737f	182	[[:blank:]]+
c2264564	183	. warn_ignored_character(*yytext);
1da177e4 LT	184	<<EOF>> {
	185	BEGIN(INITIAL);
	186	}
	187	}
	188
	189	<STRING>{
104daea1 MY	190	"$".* append_expanded_string(yytext);
104daea1 MY	191	[^$'"\\\n]+/\n {
1da177e4	192	append_string(yytext, yyleng);
765f4cde	193	yylval.string = text;
1da177e4 LT	194	return T_WORD_QUOTE;
1da177e4 LT	195	}
104daea1	196	[^$'"\\\n]+ {
1da177e4 LT	197	append_string(yytext, yyleng);
	198	}
	199	\\.?/\n {
	200	append_string(yytext + 1, yyleng - 1);
765f4cde	201	yylval.string = text;
1da177e4 LT	202	return T_WORD_QUOTE;
	203	}
	204	\\.? {
	205	append_string(yytext + 1, yyleng - 1);
	206	}
	207	\'\|\" {
	208	if (str == yytext[0]) {
	209	BEGIN(PARAM);
765f4cde	210	yylval.string = text;
1da177e4 LT	211	return T_WORD_QUOTE;
	212	} else
	213	append_string(yytext, 1);
	214	}
	215	\n {
9e3e10c7 MY	216	fprintf(stderr,
	217	"%s:%d:warning: multi-line strings not supported\n",
	218	zconf_curname(), zconf_lineno());
1da177e4 LT	219	BEGIN(INITIAL);
	220	return T_EOL;
	221	}
	222	<<EOF>> {
	223	BEGIN(INITIAL);
	224	}
	225	}
	226
	227	<HELP>{
	228	[ \t]+ {
	229	ts = 0;
	230	for (i = 0; i < yyleng; i++) {
	231	if (yytext[i] == '\t')
	232	ts = (ts & ~7) + 8;
	233	else
	234	ts++;
	235	}
	236	last_ts = ts;
	237	if (first_ts) {
	238	if (ts < first_ts) {
	239	zconf_endhelp();
	240	return T_HELPTEXT;
	241	}
	242	ts -= first_ts;
	243	while (ts > 8) {
	244	append_string(" ", 8);
	245	ts -= 8;
	246	}
	247	append_string(" ", ts);
	248	}
	249	}
	250	[ \t]*\n/[^ \t\n] {
1da177e4 LT	251	zconf_endhelp();
	252	return T_HELPTEXT;
	253	}
	254	[ \t]*\n {
1da177e4 LT	255	append_string("\n", 1);
	256	}
	257	[^ \t\n].* {
f7a4b4cd EG	258	while (yyleng) {
	259	if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
	260	break;
	261	yyleng--;
	262	}
1da177e4 LT	263	append_string(yytext, yyleng);
	264	if (!first_ts)
	265	first_ts = last_ts;
	266	}
	267	<<EOF>> {
	268	zconf_endhelp();
	269	return T_HELPTEXT;
	270	}
	271	}
	272
	273	<<EOF>> {
a02f0570	274	if (current_file) {
1da177e4	275	zconf_endfile();
a02f0570	276	return T_EOL;
1da177e4 LT	277	}
	278	fclose(yyin);
	279	yyterminate();
	280	}
	281
	282	%%
104daea1 MY	283	static char expand_token(const char in, size_t n)
	284	{
	285	char *out;
	286	int c;
	287	char c2;
	288	const char rest, end;
	289
	290	new_string();
	291	append_string(in, n);
	292
	293	/* get the whole line because we do not know the end of token. */
	294	while ((c = input()) != EOF) {
	295	if (c == '\n') {
	296	unput(c);
	297	break;
	298	}
	299	c2 = c;
	300	append_string(&c2, 1);
	301	}
	302
	303	rest = text;
	304	out = expand_one_token(&rest);
	305
	306	/* push back unused characters to the input stream */
	307	end = rest + strlen(rest);
	308	while (end > rest)
	309	unput(*--end);
	310
	311	free(text);
	312
	313	return out;
	314	}
	315
	316	static void append_expanded_string(const char *str)
	317	{
	318	const char *end;
	319	char *res;
	320
	321	str++;
	322
	323	res = expand_dollar(&str);
	324
	325	/* push back unused characters to the input stream */
	326	end = str + strlen(str);
	327	while (end > str)
	328	unput(*--end);
	329
	330	append_string(res, strlen(res));
	331
	332	free(res);
	333	}
	334
1da177e4 LT	335	void zconf_starthelp(void)
	336	{
	337	new_string();
	338	last_ts = first_ts = 0;
	339	BEGIN(HELP);
	340	}
	341
	342	static void zconf_endhelp(void)
	343	{
765f4cde	344	yylval.string = text;
1da177e4 LT	345	BEGIN(INITIAL);
	346	}
	347
	348
	349	/*
	350	* Try to open specified file with following names:
	351	* ./name
	352	* $(srctree)/name
	353	* The latter is used when srctree is separate from objtree
	354	* when compiling the kernel.
	355	* Return NULL if file is not found.
	356	*/
	357	FILE zconf_fopen(const char name)
	358	{
	359	char *env, fullname[PATH_MAX+1];
	360	FILE *f;
	361
	362	f = fopen(name, "r");
11de39e2	363	if (!f && name != NULL && name[0] != '/') {
1da177e4 LT	364	env = getenv(SRCTREE);
	365	if (env) {
	366	sprintf(fullname, "%s/%s", env, name);
	367	f = fopen(fullname, "r");
	368	}
	369	}
	370	return f;
	371	}
	372
	373	void zconf_initscan(const char *name)
	374	{
	375	yyin = zconf_fopen(name);
	376	if (!yyin) {
9e3e10c7	377	fprintf(stderr, "can't find file %s\n", name);
1da177e4 LT	378	exit(1);
	379	}
	380
177acf78	381	current_buf = xmalloc(sizeof(*current_buf));
1da177e4 LT	382	memset(current_buf, 0, sizeof(*current_buf));
	383
	384	current_file = file_lookup(name);
18492685	385	yylineno = 1;
1da177e4 LT	386	}
	387
	388	void zconf_nextfile(const char *name)
	389	{
f094f8a1	390	struct file *iter;
1da177e4	391	struct file *file = file_lookup(name);
177acf78	392	struct buffer buf = xmalloc(sizeof(buf));
1da177e4 LT	393	memset(buf, 0, sizeof(*buf));
	394
	395	current_buf->state = YY_CURRENT_BUFFER;
e82dae90	396	yyin = zconf_fopen(file->name);
1da177e4	397	if (!yyin) {
9e3e10c7 MY	398	fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
9e3e10c7 MY	399	zconf_curname(), zconf_lineno(), file->name);
1da177e4 LT	400	exit(1);
	401	}
	402	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	403	buf->parent = current_buf;
	404	current_buf = buf;
	405
18492685	406	current_file->lineno = yylineno;
379a8eb8 MY	407	file->parent = current_file;
	408
	409	for (iter = current_file; iter; iter = iter->parent) {
	410	if (!strcmp(iter->name, file->name)) {
9e3e10c7	411	fprintf(stderr,
32a94b8b MY	412	"Recursive inclusion detected.\n"
32a94b8b MY	413	"Inclusion path:\n"
379a8eb8 MY	414	" current file : %s\n", file->name);
379a8eb8 MY	415	iter = file;
5ae6fcc4	416	do {
f094f8a1	417	iter = iter->parent;
32a94b8b	418	fprintf(stderr, " included from: %s:%d\n",
5ae6fcc4	419	iter->name, iter->lineno - 1);
379a8eb8	420	} while (strcmp(iter->name, file->name));
f094f8a1 YM	421	exit(1);
f094f8a1 YM	422	}
1da177e4	423	}
379a8eb8	424
18492685	425	yylineno = 1;
1da177e4 LT	426	current_file = file;
	427	}
	428
a02f0570	429	static void zconf_endfile(void)
1da177e4 LT	430	{
	431	struct buffer *parent;
	432
1da177e4	433	current_file = current_file->parent;
18492685 MY	434	if (current_file)
18492685 MY	435	yylineno = current_file->lineno;
1da177e4 LT	436
	437	parent = current_buf->parent;
	438	if (parent) {
	439	fclose(yyin);
	440	yy_delete_buffer(YY_CURRENT_BUFFER);
	441	yy_switch_to_buffer(parent->state);
	442	}
	443	free(current_buf);
	444	current_buf = parent;
1da177e4 LT	445	}
	446
	447	int zconf_lineno(void)
	448	{
a02f0570	449	return current_pos.lineno;
1da177e4 LT	450	}
1da177e4 LT	451
2e7a0918	452	const char *zconf_curname(void)
1da177e4	453	{
a02f0570	454	return current_pos.file ? current_pos.file->name : "<none>";
1da177e4	455	}