[linux-2.6-block.git] / scripts / kconfig / lexer.l

/* SPDX-License-Identifier: GPL-2.0 */
/*
 * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
 */
%option nostdinit noyywrap never-interactive full ecs
%option 8bit nodefault yylineno
%x ASSIGN_VAL HELP STRING
%{

#include <assert.h>
#include <limits.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <unistd.h>

#include "lkc.h"
#include "parser.tab.h"

#define YY_DECL		static int yylex1(void)

#define START_STRSIZE	16

static struct {
	struct file *file;
	int lineno;
} current_pos;

static int prev_prev_token = T_EOL;
static int prev_token = T_EOL;
static char *text;
static int text_size, text_asize;

struct buffer {
	struct buffer *parent;
	YY_BUFFER_STATE state;
};

struct buffer *current_buf;

static int last_ts, first_ts;

static char *expand_token(const char *in, size_t n);
static void append_expanded_string(const char *in);
static void zconf_endhelp(void);
static void zconf_endfile(void);

static void new_string(void)
{
	text = xmalloc(START_STRSIZE);
	text_asize = START_STRSIZE;
	text_size = 0;
	*text = 0;
}

static void append_string(const char *str, int size)
{
	int new_size = text_size + size + 1;
	if (new_size > text_asize) {
		new_size += START_STRSIZE - 1;
		new_size &= -START_STRSIZE;
		text = xrealloc(text, new_size);
		text_asize = new_size;
	}
	memcpy(text + text_size, str, size);
	text_size += size;
	text[text_size] = 0;
}

static void alloc_string(const char *str, int size)
{
	text = xmalloc(size + 1);
	memcpy(text, str, size);
	text[size] = 0;
}

static void warn_ignored_character(char chr)
{
	fprintf(stderr,
	        "%s:%d:warning: ignoring unsupported character '%c'\n",
	        current_file->name, yylineno, chr);
}
%}

n	[A-Za-z0-9_-]

%%
	int str = 0;
	int ts, i;

#.*			/* ignore comment */
[ \t]*			/* whitespaces */
\\\n			/* escaped new line */
\n			return T_EOL;
"allnoconfig_y"		return T_ALLNOCONFIG_Y;
"bool"			return T_BOOL;
"choice"		return T_CHOICE;
"comment"		return T_COMMENT;
"config"		return T_CONFIG;
"def_bool"		return T_DEF_BOOL;
"def_tristate"		return T_DEF_TRISTATE;
"default"		return T_DEFAULT;
"defconfig_list"	return T_DEFCONFIG_LIST;
"depends"		return T_DEPENDS;
"endchoice"		return T_ENDCHOICE;
"endif"			return T_ENDIF;
"endmenu"		return T_ENDMENU;
"help"|"---help---"	return T_HELP;
"hex"			return T_HEX;
"if"			return T_IF;
"imply"			return T_IMPLY;
"int"			return T_INT;
"mainmenu"		return T_MAINMENU;
"menu"			return T_MENU;
"menuconfig"		return T_MENUCONFIG;
"modules"		return T_MODULES;
"on"			return T_ON;
"option"		return T_OPTION;
"optional"		return T_OPTIONAL;
"prompt"		return T_PROMPT;
"range"			return T_RANGE;
"select"		return T_SELECT;
"source"		return T_SOURCE;
"string"		return T_STRING;
"tristate"		return T_TRISTATE;
"visible"		return T_VISIBLE;
"||"			return T_OR;
"&&"			return T_AND;
"="			return T_EQUAL;
"!="			return T_UNEQUAL;
"<"			return T_LESS;
"<="			return T_LESS_EQUAL;
">"			return T_GREATER;
">="			return T_GREATER_EQUAL;
"!"			return T_NOT;
"("			return T_OPEN_PAREN;
")"			return T_CLOSE_PAREN;
":="			return T_COLON_EQUAL;
"+="			return T_PLUS_EQUAL;
\"|\'			{
				str = yytext[0];
				new_string();
				BEGIN(STRING);
			}
{n}+			{
				alloc_string(yytext, yyleng);
				yylval.string = text;
				return T_WORD;
			}
({n}|$)+		{
				/* this token includes at least one '$' */
				yylval.string = expand_token(yytext, yyleng);
				if (strlen(yylval.string))
					return T_WORD;
				free(yylval.string);
			}
.			warn_ignored_character(*yytext);

<ASSIGN_VAL>{
	[^[:blank:]\n]+.*	{
		alloc_string(yytext, yyleng);
		yylval.string = text;
		return T_ASSIGN_VAL;
	}
	\n	{ BEGIN(INITIAL); return T_EOL; }
	.
}

<STRING>{
	"$".*	append_expanded_string(yytext);
	[^$'"\\\n]+	{
		append_string(yytext, yyleng);
	}
	\\.?	{
		append_string(yytext + 1, yyleng - 1);
	}
	\'|\"	{
		if (str == yytext[0]) {
			BEGIN(INITIAL);
			yylval.string = text;
			return T_WORD_QUOTE;
		} else
			append_string(yytext, 1);
	}
	\n	{
		fprintf(stderr,
			"%s:%d:warning: multi-line strings not supported\n",
			zconf_curname(), zconf_lineno());
		unput('\n');
		BEGIN(INITIAL);
		yylval.string = text;
		return T_WORD_QUOTE;
	}
	<<EOF>>	{
		BEGIN(INITIAL);
		yylval.string = text;
		return T_WORD_QUOTE;
	}
}

<HELP>{
	[ \t]+	{
		ts = 0;
		for (i = 0; i < yyleng; i++) {
			if (yytext[i] == '\t')
				ts = (ts & ~7) + 8;
			else
				ts++;
		}
		last_ts = ts;
		if (first_ts) {
			if (ts < first_ts) {
				zconf_endhelp();
				return T_HELPTEXT;
			}
			ts -= first_ts;
			while (ts > 8) {
				append_string("        ", 8);
				ts -= 8;
			}
			append_string("        ", ts);
		}
	}
	[ \t]*\n/[^ \t\n] {
		zconf_endhelp();
		return T_HELPTEXT;
	}
	[ \t]*\n	{
		append_string("\n", 1);
	}
	[^ \t\n].* {
		while (yyleng) {
			if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
				break;
			yyleng--;
		}
		append_string(yytext, yyleng);
		if (!first_ts)
			first_ts = last_ts;
	}
	<<EOF>>	{
		zconf_endhelp();
		return T_HELPTEXT;
	}
}

<<EOF>>	{
	BEGIN(INITIAL);

	if (prev_token != T_EOL && prev_token != T_HELPTEXT)
		fprintf(stderr, "%s:%d:warning: no new line at end of file\n",
			current_file->name, yylineno);

	if (current_file) {
		zconf_endfile();
		return T_EOL;
	}
	fclose(yyin);
	yyterminate();
}

%%

/* second stage lexer */
int yylex(void)
{
	int token;

repeat:
	token = yylex1();

	if (prev_token == T_EOL || prev_token == T_HELPTEXT) {
		if (token == T_EOL) {
			/* Do not pass unneeded T_EOL to the parser. */
			goto repeat;
		} else {
			/*
			 * For the parser, update file/lineno at the first token
			 * of each statement. Generally, \n is a statement
			 * terminator in Kconfig, but it is not always true
			 * because \n could be escaped by a backslash.
			 */
			current_pos.file = current_file;
			current_pos.lineno = yylineno;
		}
	}

	if (prev_prev_token == T_EOL && prev_token == T_WORD &&
	    (token == T_EQUAL || token == T_COLON_EQUAL || token == T_PLUS_EQUAL))
		BEGIN(ASSIGN_VAL);

	prev_prev_token = prev_token;
	prev_token = token;

	return token;
}

static char *expand_token(const char *in, size_t n)
{
	char *out;
	int c;
	char c2;
	const char *rest, *end;

	new_string();
	append_string(in, n);

	/* get the whole line because we do not know the end of token. */
	while ((c = input()) != EOF) {
		if (c == '\n') {
			unput(c);
			break;
		}
		c2 = c;
		append_string(&c2, 1);
	}

	rest = text;
	out = expand_one_token(&rest);

	/* push back unused characters to the input stream */
	end = rest + strlen(rest);
	while (end > rest)
		unput(*--end);

	free(text);

	return out;
}

static void append_expanded_string(const char *str)
{
	const char *end;
	char *res;

	str++;

	res = expand_dollar(&str);

	/* push back unused characters to the input stream */
	end = str + strlen(str);
	while (end > str)
		unput(*--end);

	append_string(res, strlen(res));

	free(res);
}

void zconf_starthelp(void)
{
	new_string();
	last_ts = first_ts = 0;
	BEGIN(HELP);
}

static void zconf_endhelp(void)
{
	yylval.string = text;
	BEGIN(INITIAL);
}


/*
 * Try to open specified file with following names:
 * ./name
 * $(srctree)/name
 * The latter is used when srctree is separate from objtree
 * when compiling the kernel.
 * Return NULL if file is not found.
 */
FILE *zconf_fopen(const char *name)
{
	char *env, fullname[PATH_MAX+1];
	FILE *f;

	f = fopen(name, "r");
	if (!f && name != NULL && name[0] != '/') {
		env = getenv(SRCTREE);
		if (env) {
			snprintf(fullname, sizeof(fullname),
				 "%s/%s", env, name);
			f = fopen(fullname, "r");
		}
	}
	return f;
}

void zconf_initscan(const char *name)
{
	yyin = zconf_fopen(name);
	if (!yyin) {
		fprintf(stderr, "can't find file %s\n", name);
		exit(1);
	}

	current_buf = xmalloc(sizeof(*current_buf));
	memset(current_buf, 0, sizeof(*current_buf));

	current_file = file_lookup(name);
	yylineno = 1;
}

void zconf_nextfile(const char *name)
{
	struct file *iter;
	struct file *file = file_lookup(name);
	struct buffer *buf = xmalloc(sizeof(*buf));
	memset(buf, 0, sizeof(*buf));

	current_buf->state = YY_CURRENT_BUFFER;
	yyin = zconf_fopen(file->name);
	if (!yyin) {
		fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
			zconf_curname(), zconf_lineno(), file->name);
		exit(1);
	}
	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	buf->parent = current_buf;
	current_buf = buf;

	current_file->lineno = yylineno;
	file->parent = current_file;

	for (iter = current_file; iter; iter = iter->parent) {
		if (!strcmp(iter->name, file->name)) {
			fprintf(stderr,
				"Recursive inclusion detected.\n"
				"Inclusion path:\n"
				"  current file : %s\n", file->name);
			iter = file;
			do {
				iter = iter->parent;
				fprintf(stderr, "  included from: %s:%d\n",
					iter->name, iter->lineno - 1);
			} while (strcmp(iter->name, file->name));
			exit(1);
		}
	}

	yylineno = 1;
	current_file = file;
}

static void zconf_endfile(void)
{
	struct buffer *parent;

	current_file = current_file->parent;
	if (current_file)
		yylineno = current_file->lineno;

	parent = current_buf->parent;
	if (parent) {
		fclose(yyin);
		yy_delete_buffer(YY_CURRENT_BUFFER);
		yy_switch_to_buffer(parent->state);
	}
	free(current_buf);
	current_buf = parent;
}

int zconf_lineno(void)
{
	return current_pos.lineno;
}

const char *zconf_curname(void)
{
	return current_pos.file ? current_pos.file->name : "<none>";
}
Commit	Line	Data
0c874100 MY	1	/* SPDX-License-Identifier: GPL-2.0 */
	2	/*
	3	* Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
	4	*/
674eed8a	5	%option nostdinit noyywrap never-interactive full ecs
18492685	6	%option 8bit nodefault yylineno
979f2b2f	7	%x ASSIGN_VAL HELP STRING
1da177e4	8	%{
1da177e4	9
9ced3bdd	10	#include <assert.h>
1da177e4 LT	11	#include <limits.h>
	12	#include <stdio.h>
	13	#include <stdlib.h>
	14	#include <string.h>
	15	#include <unistd.h>
	16
1da177e4	17	#include "lkc.h"
769a1c02	18	#include "parser.tab.h"
1da177e4	19
cc66bca7 MY	20	#define YY_DECL static int yylex1(void)
cc66bca7 MY	21
1da177e4 LT	22	#define START_STRSIZE 16
1da177e4 LT	23
a02f0570 RZ	24	static struct {
	25	struct file *file;
	26	int lineno;
	27	} current_pos;
	28
824fa3b3	29	static int prev_prev_token = T_EOL;
cc66bca7	30	static int prev_token = T_EOL;
7a88488b	31	static char *text;
1da177e4 LT	32	static int text_size, text_asize;
	33
	34	struct buffer {
bb66fc67 MY	35	struct buffer *parent;
bb66fc67 MY	36	YY_BUFFER_STATE state;
1da177e4 LT	37	};
	38
	39	struct buffer *current_buf;
	40
	41	static int last_ts, first_ts;
	42
104daea1 MY	43	static char expand_token(const char in, size_t n);
104daea1 MY	44	static void append_expanded_string(const char *in);
1da177e4	45	static void zconf_endhelp(void);
a02f0570	46	static void zconf_endfile(void);
1da177e4	47
65166571	48	static void new_string(void)
1da177e4	49	{
177acf78	50	text = xmalloc(START_STRSIZE);
1da177e4	51	text_asize = START_STRSIZE;
1da177e4	52	text_size = 0;
7a88488b	53	*text = 0;
1da177e4 LT	54	}
1da177e4 LT	55
65166571	56	static void append_string(const char *str, int size)
1da177e4 LT	57	{
	58	int new_size = text_size + size + 1;
	59	if (new_size > text_asize) {
7a88488b RZ	60	new_size += START_STRSIZE - 1;
7a88488b RZ	61	new_size &= -START_STRSIZE;
d717f24d	62	text = xrealloc(text, new_size);
1da177e4	63	text_asize = new_size;
1da177e4	64	}
7a88488b	65	memcpy(text + text_size, str, size);
1da177e4	66	text_size += size;
7a88488b	67	text[text_size] = 0;
1da177e4 LT	68	}
1da177e4 LT	69
65166571	70	static void alloc_string(const char *str, int size)
1da177e4	71	{
177acf78	72	text = xmalloc(size + 1);
1da177e4 LT	73	memcpy(text, str, size);
	74	text[size] = 0;
	75	}
c2264564 AR	76
	77	static void warn_ignored_character(char chr)
	78	{
	79	fprintf(stderr,
	80	"%s:%d:warning: ignoring unsupported character '%c'\n",
77c1c0fa	81	current_file->name, yylineno, chr);
c2264564	82	}
1da177e4 LT	83	%}
1da177e4 LT	84
c2264564	85	n [A-Za-z0-9_-]
1da177e4 LT	86
	87	%%
	88	int str = 0;
	89	int ts, i;
	90
979f2b2f MY	91	#.* /* ignore comment */
	92	[ \t]* /* whitespaces */
	93	\\\n /* escaped new line */
	94	\n return T_EOL;
	95	"allnoconfig_y" return T_ALLNOCONFIG_Y;
	96	"bool" return T_BOOL;
	97	"choice" return T_CHOICE;
	98	"comment" return T_COMMENT;
	99	"config" return T_CONFIG;
	100	"def_bool" return T_DEF_BOOL;
	101	"def_tristate" return T_DEF_TRISTATE;
	102	"default" return T_DEFAULT;
	103	"defconfig_list" return T_DEFCONFIG_LIST;
	104	"depends" return T_DEPENDS;
	105	"endchoice" return T_ENDCHOICE;
	106	"endif" return T_ENDIF;
	107	"endmenu" return T_ENDMENU;
	108	"help"\|"---help---" return T_HELP;
	109	"hex" return T_HEX;
	110	"if" return T_IF;
	111	"imply" return T_IMPLY;
	112	"int" return T_INT;
	113	"mainmenu" return T_MAINMENU;
	114	"menu" return T_MENU;
	115	"menuconfig" return T_MENUCONFIG;
	116	"modules" return T_MODULES;
	117	"on" return T_ON;
	118	"option" return T_OPTION;
	119	"optional" return T_OPTIONAL;
	120	"prompt" return T_PROMPT;
	121	"range" return T_RANGE;
	122	"select" return T_SELECT;
	123	"source" return T_SOURCE;
	124	"string" return T_STRING;
	125	"tristate" return T_TRISTATE;
	126	"visible" return T_VISIBLE;
	127	"\|\|" return T_OR;
	128	"&&" return T_AND;
	129	"=" return T_EQUAL;
	130	"!=" return T_UNEQUAL;
	131	"<" return T_LESS;
	132	"<=" return T_LESS_EQUAL;
	133	">" return T_GREATER;
	134	">=" return T_GREATER_EQUAL;
	135	"!" return T_NOT;
	136	"(" return T_OPEN_PAREN;
	137	")" return T_CLOSE_PAREN;
	138	":=" return T_COLON_EQUAL;
	139	"+=" return T_PLUS_EQUAL;
	140	\"\|\' {
	141	str = yytext[0];
	142	new_string();
	143	BEGIN(STRING);
	144	}
	145	{n}+ {
	146	alloc_string(yytext, yyleng);
	147	yylval.string = text;
	148	return T_WORD;
	149	}
	150	({n}\|$)+ {
	151	/* this token includes at least one '$' */
	152	yylval.string = expand_token(yytext, yyleng);
	153	if (strlen(yylval.string))
	154	return T_WORD;
155	free(yylval.string);
156	}
157	. warn_ignored_character(*yytext);
1da177e4	158
9ced3bdd MY	159	<ASSIGN_VAL>{
	160	[^[:blank:]\n]+.* {
	161	alloc_string(yytext, yyleng);
	162	yylval.string = text;
	163	return T_ASSIGN_VAL;
	164	}
	165	\n { BEGIN(INITIAL); return T_EOL; }
	166	.
	167	}
	168
1da177e4	169	<STRING>{
104daea1	170	"$".* append_expanded_string(yytext);
104daea1	171	[^$'"\\\n]+ {
1da177e4 LT	172	append_string(yytext, yyleng);
1da177e4 LT	173	}
1da177e4 LT	174	\\.? {
	175	append_string(yytext + 1, yyleng - 1);
	176	}
	177	\'\|\" {
	178	if (str == yytext[0]) {
979f2b2f	179	BEGIN(INITIAL);
765f4cde	180	yylval.string = text;
1da177e4 LT	181	return T_WORD_QUOTE;
	182	} else
	183	append_string(yytext, 1);
	184	}
	185	\n {
9e3e10c7 MY	186	fprintf(stderr,
	187	"%s:%d:warning: multi-line strings not supported\n",
	188	zconf_curname(), zconf_lineno());
21c5ecf6	189	unput('\n');
1da177e4	190	BEGIN(INITIAL);
21c5ecf6 MY	191	yylval.string = text;
21c5ecf6 MY	192	return T_WORD_QUOTE;
1da177e4 LT	193	}
	194	<<EOF>> {
	195	BEGIN(INITIAL);
fbac5977 MY	196	yylval.string = text;
fbac5977 MY	197	return T_WORD_QUOTE;
1da177e4 LT	198	}
	199	}
	200
	201	<HELP>{
	202	[ \t]+ {
	203	ts = 0;
	204	for (i = 0; i < yyleng; i++) {
	205	if (yytext[i] == '\t')
	206	ts = (ts & ~7) + 8;
	207	else
	208	ts++;
	209	}
	210	last_ts = ts;
	211	if (first_ts) {
	212	if (ts < first_ts) {
	213	zconf_endhelp();
	214	return T_HELPTEXT;
	215	}
	216	ts -= first_ts;
	217	while (ts > 8) {
	218	append_string(" ", 8);
	219	ts -= 8;
	220	}
	221	append_string(" ", ts);
	222	}
	223	}
	224	[ \t]*\n/[^ \t\n] {
1da177e4 LT	225	zconf_endhelp();
	226	return T_HELPTEXT;
	227	}
	228	[ \t]*\n {
1da177e4 LT	229	append_string("\n", 1);
	230	}
	231	[^ \t\n].* {
f7a4b4cd EG	232	while (yyleng) {
	233	if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
	234	break;
	235	yyleng--;
	236	}
1da177e4 LT	237	append_string(yytext, yyleng);
	238	if (!first_ts)
	239	first_ts = last_ts;
	240	}
	241	<<EOF>> {
	242	zconf_endhelp();
	243	return T_HELPTEXT;
	244	}
	245	}
	246
	247	<<EOF>> {
0bcc547e MY	248	BEGIN(INITIAL);
0bcc547e MY	249
72367933 MY	250	if (prev_token != T_EOL && prev_token != T_HELPTEXT)
	251	fprintf(stderr, "%s:%d:warning: no new line at end of file\n",
	252	current_file->name, yylineno);
	253
a02f0570	254	if (current_file) {
1da177e4	255	zconf_endfile();
a02f0570	256	return T_EOL;
1da177e4 LT	257	}
	258	fclose(yyin);
	259	yyterminate();
	260	}
	261
	262	%%
cc66bca7 MY	263
	264	/* second stage lexer */
	265	int yylex(void)
	266	{
	267	int token;
	268
	269	repeat:
	270	token = yylex1();
	271
4b31a32c MY	272	if (prev_token == T_EOL \|\| prev_token == T_HELPTEXT) {
	273	if (token == T_EOL) {
	274	/* Do not pass unneeded T_EOL to the parser. */
	275	goto repeat;
	276	} else {
	277	/*
	278	* For the parser, update file/lineno at the first token
	279	* of each statement. Generally, \n is a statement
	280	* terminator in Kconfig, but it is not always true
	281	* because \n could be escaped by a backslash.
	282	*/
	283	current_pos.file = current_file;
	284	current_pos.lineno = yylineno;
	285	}
	286	}
cc66bca7	287
824fa3b3 MY	288	if (prev_prev_token == T_EOL && prev_token == T_WORD &&
	289	(token == T_EQUAL \|\| token == T_COLON_EQUAL \|\| token == T_PLUS_EQUAL))
	290	BEGIN(ASSIGN_VAL);
	291
	292	prev_prev_token = prev_token;
cc66bca7 MY	293	prev_token = token;
	294
	295	return token;
	296	}
	297
104daea1 MY	298	static char expand_token(const char in, size_t n)
	299	{
	300	char *out;
	301	int c;
	302	char c2;
	303	const char rest, end;
	304
	305	new_string();
	306	append_string(in, n);
	307
	308	/* get the whole line because we do not know the end of token. */
	309	while ((c = input()) != EOF) {
	310	if (c == '\n') {
	311	unput(c);
	312	break;
	313	}
	314	c2 = c;
	315	append_string(&c2, 1);
	316	}
	317
	318	rest = text;
	319	out = expand_one_token(&rest);
	320
	321	/* push back unused characters to the input stream */
	322	end = rest + strlen(rest);
	323	while (end > rest)
	324	unput(*--end);
	325
	326	free(text);
	327
	328	return out;
	329	}
	330
	331	static void append_expanded_string(const char *str)
	332	{
	333	const char *end;
	334	char *res;
	335
	336	str++;
	337
	338	res = expand_dollar(&str);
	339
	340	/* push back unused characters to the input stream */
	341	end = str + strlen(str);
	342	while (end > str)
	343	unput(*--end);
	344
	345	append_string(res, strlen(res));
	346
	347	free(res);
	348	}
	349
1da177e4 LT	350	void zconf_starthelp(void)
	351	{
	352	new_string();
	353	last_ts = first_ts = 0;
	354	BEGIN(HELP);
	355	}
	356
	357	static void zconf_endhelp(void)
	358	{
765f4cde	359	yylval.string = text;
1da177e4 LT	360	BEGIN(INITIAL);
	361	}
	362
	363
	364	/*
	365	* Try to open specified file with following names:
	366	* ./name
	367	* $(srctree)/name
	368	* The latter is used when srctree is separate from objtree
	369	* when compiling the kernel.
	370	* Return NULL if file is not found.
	371	*/
	372	FILE zconf_fopen(const char name)
	373	{
	374	char *env, fullname[PATH_MAX+1];
	375	FILE *f;
	376
	377	f = fopen(name, "r");
11de39e2	378	if (!f && name != NULL && name[0] != '/') {
1da177e4 LT	379	env = getenv(SRCTREE);
1da177e4 LT	380	if (env) {
b9d1a8e9 JG	381	snprintf(fullname, sizeof(fullname),
b9d1a8e9 JG	382	"%s/%s", env, name);
1da177e4 LT	383	f = fopen(fullname, "r");
	384	}
	385	}
	386	return f;
	387	}
	388
	389	void zconf_initscan(const char *name)
	390	{
	391	yyin = zconf_fopen(name);
	392	if (!yyin) {
9e3e10c7	393	fprintf(stderr, "can't find file %s\n", name);
1da177e4 LT	394	exit(1);
	395	}
	396
177acf78	397	current_buf = xmalloc(sizeof(*current_buf));
1da177e4 LT	398	memset(current_buf, 0, sizeof(*current_buf));
	399
	400	current_file = file_lookup(name);
18492685	401	yylineno = 1;
1da177e4 LT	402	}
	403
	404	void zconf_nextfile(const char *name)
	405	{
f094f8a1	406	struct file *iter;
1da177e4	407	struct file *file = file_lookup(name);
177acf78	408	struct buffer buf = xmalloc(sizeof(buf));
1da177e4 LT	409	memset(buf, 0, sizeof(*buf));
	410
	411	current_buf->state = YY_CURRENT_BUFFER;
e82dae90	412	yyin = zconf_fopen(file->name);
1da177e4	413	if (!yyin) {
9e3e10c7 MY	414	fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
9e3e10c7 MY	415	zconf_curname(), zconf_lineno(), file->name);
1da177e4 LT	416	exit(1);
	417	}
	418	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	419	buf->parent = current_buf;
	420	current_buf = buf;
	421
18492685	422	current_file->lineno = yylineno;
379a8eb8 MY	423	file->parent = current_file;
	424
	425	for (iter = current_file; iter; iter = iter->parent) {
	426	if (!strcmp(iter->name, file->name)) {
9e3e10c7	427	fprintf(stderr,
32a94b8b MY	428	"Recursive inclusion detected.\n"
32a94b8b MY	429	"Inclusion path:\n"
379a8eb8 MY	430	" current file : %s\n", file->name);
379a8eb8 MY	431	iter = file;
5ae6fcc4	432	do {
f094f8a1	433	iter = iter->parent;
32a94b8b	434	fprintf(stderr, " included from: %s:%d\n",
5ae6fcc4	435	iter->name, iter->lineno - 1);
379a8eb8	436	} while (strcmp(iter->name, file->name));
f094f8a1 YM	437	exit(1);
f094f8a1 YM	438	}
1da177e4	439	}
379a8eb8	440
18492685	441	yylineno = 1;
1da177e4 LT	442	current_file = file;
	443	}
	444
a02f0570	445	static void zconf_endfile(void)
1da177e4 LT	446	{
	447	struct buffer *parent;
	448
1da177e4	449	current_file = current_file->parent;
18492685 MY	450	if (current_file)
18492685 MY	451	yylineno = current_file->lineno;
1da177e4 LT	452
	453	parent = current_buf->parent;
	454	if (parent) {
	455	fclose(yyin);
	456	yy_delete_buffer(YY_CURRENT_BUFFER);
	457	yy_switch_to_buffer(parent->state);
	458	}
	459	free(current_buf);
	460	current_buf = parent;
1da177e4 LT	461	}
	462
	463	int zconf_lineno(void)
	464	{
a02f0570	465	return current_pos.lineno;
1da177e4 LT	466	}
1da177e4 LT	467
2e7a0918	468	const char *zconf_curname(void)
1da177e4	469	{
a02f0570	470	return current_pos.file ? current_pos.file->name : "<none>";
1da177e4	471	}