Commit | Line | Data |
---|---|---|
1da177e4 LT |
1 | /* ld script to make x86-64 Linux kernel |
2 | * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>; | |
3 | */ | |
4 | ||
5ded01e8 EB |
5 | #define LOAD_OFFSET __START_KERNEL_map |
6 | ||
1da177e4 | 7 | #include <asm-generic/vmlinux.lds.h> |
5ded01e8 | 8 | #include <asm/page.h> |
1da177e4 | 9 | |
bb33421d AK |
10 | #undef i386 /* in case the preprocessor is a 32bit one */ |
11 | ||
1da177e4 LT |
12 | OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64") |
13 | OUTPUT_ARCH(i386:x86-64) | |
14 | ENTRY(phys_startup_64) | |
15 | jiffies_64 = jiffies; | |
08269c6d | 16 | _proxy_pda = 1; |
f2a9e1de IC |
17 | PHDRS { |
18 | text PT_LOAD FLAGS(5); /* R_E */ | |
19 | data PT_LOAD FLAGS(7); /* RWE */ | |
20 | user PT_LOAD FLAGS(7); /* RWE */ | |
dbaab49f | 21 | data.init PT_LOAD FLAGS(7); /* RWE */ |
f2a9e1de IC |
22 | note PT_NOTE FLAGS(4); /* R__ */ |
23 | } | |
1da177e4 LT |
24 | SECTIONS |
25 | { | |
5ded01e8 | 26 | . = __START_KERNEL; |
1da177e4 LT |
27 | phys_startup_64 = startup_64 - LOAD_OFFSET; |
28 | _text = .; /* Text and read-only data */ | |
5ded01e8 | 29 | .text : AT(ADDR(.text) - LOAD_OFFSET) { |
4bdc3b7f | 30 | /* First the code that has to be first for bootstrapping */ |
eaeae0cc | 31 | *(.bootstrap.text) |
6fb14755 | 32 | _stext = .; |
4bdc3b7f | 33 | /* Then the rest */ |
7664709b | 34 | TEXT_TEXT |
1da177e4 LT |
35 | SCHED_TEXT |
36 | LOCK_TEXT | |
0f2fbdcb | 37 | KPROBES_TEXT |
1da177e4 LT |
38 | *(.fixup) |
39 | *(.gnu.warning) | |
f2a9e1de | 40 | } :text = 0x9090 |
5ded01e8 EB |
41 | /* out-of-line lock text */ |
42 | .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) } | |
1da177e4 LT |
43 | |
44 | _etext = .; /* End of text section */ | |
45 | ||
46 | . = ALIGN(16); /* Exception table */ | |
47 | __start___ex_table = .; | |
5ded01e8 | 48 | __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) } |
1da177e4 LT |
49 | __stop___ex_table = .; |
50 | ||
c31a0bf3 JF |
51 | BUG_TABLE |
52 | ||
6fb14755 JB |
53 | RODATA |
54 | ||
3af98153 | 55 | . = ALIGN(PAGE_SIZE); /* Align data segment to page size boundary */ |
5ded01e8 EB |
56 | /* Data */ |
57 | .data : AT(ADDR(.data) - LOAD_OFFSET) { | |
ca967258 | 58 | DATA_DATA |
1da177e4 | 59 | CONSTRUCTORS |
f2a9e1de | 60 | } :data |
1da177e4 LT |
61 | |
62 | _edata = .; /* End of data section */ | |
63 | ||
5ded01e8 | 64 | . = ALIGN(PAGE_SIZE); |
1da177e4 | 65 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); |
5ded01e8 EB |
66 | .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) { |
67 | *(.data.cacheline_aligned) | |
68 | } | |
e405d067 | 69 | . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES); |
6c036527 CL |
70 | .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { |
71 | *(.data.read_mostly) | |
72 | } | |
5ded01e8 EB |
73 | |
74 | #define VSYSCALL_ADDR (-10*1024*1024) | |
d312ceda AM |
75 | #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095)) |
76 | #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095)) | |
5ded01e8 EB |
77 | |
78 | #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR) | |
79 | #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET) | |
80 | ||
81 | #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR) | |
82 | #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET) | |
1da177e4 | 83 | |
5ded01e8 | 84 | . = VSYSCALL_ADDR; |
f2a9e1de | 85 | .vsyscall_0 : AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user |
5ded01e8 | 86 | __vsyscall_0 = VSYSCALL_VIRT_ADDR; |
1da177e4 | 87 | |
1da177e4 | 88 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); |
7460ed28 | 89 | .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) } |
90 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); | |
91 | .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data)) | |
92 | { *(.vsyscall_gtod_data) } | |
93 | vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data); | |
5ded01e8 | 94 | |
141a892f ED |
95 | |
96 | .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) | |
97 | { *(.vsyscall_1) } | |
98 | .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) | |
99 | { *(.vsyscall_2) } | |
100 | ||
c08c8205 VP |
101 | .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) } |
102 | vgetcpu_mode = VVIRT(.vgetcpu_mode); | |
103 | ||
1da177e4 | 104 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); |
5ded01e8 EB |
105 | .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) } |
106 | jiffies = VVIRT(.jiffies); | |
107 | ||
7460ed28 | 108 | .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) |
109 | { *(.vsyscall_3) } | |
5ded01e8 EB |
110 | |
111 | . = VSYSCALL_VIRT_ADDR + 4096; | |
112 | ||
113 | #undef VSYSCALL_ADDR | |
114 | #undef VSYSCALL_PHYS_ADDR | |
115 | #undef VSYSCALL_VIRT_ADDR | |
116 | #undef VLOAD_OFFSET | |
117 | #undef VLOAD | |
118 | #undef VVIRT_OFFSET | |
119 | #undef VVIRT | |
1da177e4 LT |
120 | |
121 | . = ALIGN(8192); /* init_task */ | |
5ded01e8 EB |
122 | .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) { |
123 | *(.data.init_task) | |
dbaab49f | 124 | }:data.init |
1da177e4 LT |
125 | |
126 | . = ALIGN(4096); | |
5ded01e8 EB |
127 | .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) { |
128 | *(.data.page_aligned) | |
129 | } | |
1da177e4 | 130 | |
d167a518 GH |
131 | /* might get freed after init */ |
132 | . = ALIGN(4096); | |
133 | __smp_alt_begin = .; | |
134 | __smp_alt_instructions = .; | |
135 | .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) { | |
136 | *(.smp_altinstructions) | |
137 | } | |
138 | __smp_alt_instructions_end = .; | |
139 | . = ALIGN(8); | |
140 | __smp_locks = .; | |
141 | .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) { | |
142 | *(.smp_locks) | |
143 | } | |
144 | __smp_locks_end = .; | |
145 | .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) { | |
146 | *(.smp_altinstr_replacement) | |
147 | } | |
148 | . = ALIGN(4096); | |
149 | __smp_alt_end = .; | |
150 | ||
1da177e4 LT |
151 | . = ALIGN(4096); /* Init code and data */ |
152 | __init_begin = .; | |
5ded01e8 | 153 | .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { |
1da177e4 LT |
154 | _sinittext = .; |
155 | *(.init.text) | |
156 | _einittext = .; | |
157 | } | |
158 | __initdata_begin = .; | |
5ded01e8 | 159 | .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) } |
1da177e4 LT |
160 | __initdata_end = .; |
161 | . = ALIGN(16); | |
162 | __setup_start = .; | |
5ded01e8 | 163 | .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) } |
1da177e4 LT |
164 | __setup_end = .; |
165 | __initcall_start = .; | |
5ded01e8 | 166 | .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) { |
61ce1efe | 167 | INITCALLS |
1da177e4 LT |
168 | } |
169 | __initcall_end = .; | |
170 | __con_initcall_start = .; | |
5ded01e8 EB |
171 | .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) { |
172 | *(.con_initcall.init) | |
173 | } | |
1da177e4 LT |
174 | __con_initcall_end = .; |
175 | SECURITY_INIT | |
176 | . = ALIGN(8); | |
177 | __alt_instructions = .; | |
5ded01e8 EB |
178 | .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) { |
179 | *(.altinstructions) | |
180 | } | |
1da177e4 | 181 | __alt_instructions_end = .; |
5ded01e8 EB |
182 | .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) { |
183 | *(.altinstr_replacement) | |
184 | } | |
1da177e4 LT |
185 | /* .exit.text is discard at runtime, not link time, to deal with references |
186 | from .altinstructions and .eh_frame */ | |
5ded01e8 EB |
187 | .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) } |
188 | .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) } | |
67d38229 JPS |
189 | |
190 | #ifdef CONFIG_BLK_DEV_INITRD | |
1da177e4 LT |
191 | . = ALIGN(4096); |
192 | __initramfs_start = .; | |
5ded01e8 | 193 | .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) } |
14c3f855 | 194 | __initramfs_end = .; |
67d38229 JPS |
195 | #endif |
196 | ||
5fb7dc37 FY |
197 | PERCPU(4096) |
198 | ||
b38337a6 AK |
199 | . = ALIGN(4096); |
200 | __init_end = .; | |
1da177e4 LT |
201 | |
202 | . = ALIGN(4096); | |
203 | __nosave_begin = .; | |
5ded01e8 | 204 | .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) } |
1da177e4 LT |
205 | . = ALIGN(4096); |
206 | __nosave_end = .; | |
207 | ||
120b1142 VG |
208 | __bss_start = .; /* BSS */ |
209 | .bss : AT(ADDR(.bss) - LOAD_OFFSET) { | |
210 | *(.bss.page_aligned) | |
211 | *(.bss) | |
212 | } | |
213 | __bss_stop = .; | |
214 | ||
1da177e4 LT |
215 | _end = . ; |
216 | ||
217 | /* Sections to be discarded */ | |
218 | /DISCARD/ : { | |
219 | *(.exitcall.exit) | |
1da177e4 | 220 | *(.eh_frame) |
1da177e4 LT |
221 | } |
222 | ||
4413a511 PBG |
223 | STABS_DEBUG |
224 | ||
225 | DWARF_DEBUG | |
1da177e4 | 226 | } |