[linux-2.6-block.git] / arch / x86 / realmode / rm / trampoline_32.S

/*
 *
 *	Trampoline.S	Derived from Setup.S by Linus Torvalds
 *
 *	4 Jan 1997 Michael Chastain: changed to gnu as.
 *
 *	This is only used for booting secondary CPUs in SMP machine
 *
 *	Entry: CS:IP point to the start of our code, we are
 *	in real mode with no stack, but the rest of the
 *	trampoline page to make our stack and everything else
 *	is a mystery.
 *
 *	We jump into arch/x86/kernel/head_32.S.
 *
 *	On entry to trampoline_data, the processor is in real mode
 *	with 16-bit addressing and 16-bit data.  CS has some value
 *	and IP is zero.  Thus, we load CS to the physical segment
 *	of the real mode code before doing anything further.
 *
 *	The structure real_mode_header includes entries that need
 *	to be set up before executing this code:
 *
 *	startup_32_smp
 *	boot_gdt
 */

#include <linux/linkage.h>
#include <linux/init.h>
#include <asm/segment.h>
#include <asm/page_types.h>
#include "realmode.h"

	.text
	.code16

	.balign	PAGE_SIZE
ENTRY(trampoline_data)
	wbinvd			# Needed for NUMA-Q should be harmless for others

	LJMPW_RM(1f)
1:
	mov	%cs, %ax	# Code and data in the same place
	mov	%ax, %ds

	cli			# We should be safe anyway

	movl	startup_32_smp, %eax	# where we need to go

	movl	$0xA5A5A5A5, trampoline_status
				# write marker for master knows we're running

	/*
	 * GDT tables in non default location kernel can be beyond 16MB and
	 * lgdt will not be able to load the address as in real mode default
	 * operand size is 16bit. Use lgdtl instead to force operand size
	 * to 32 bit.
	 */
	lidtl	boot_idt_descr		# load idt with 0, 0
	lgdtl	boot_gdt_descr		# load gdt with whatever is appropriate

	movw	$1, %dx			# protected mode (PE) bit
	lmsw	%dx			# into protected mode

	ljmpl	$__BOOT_CS, $pa_startup_32

	.section ".text32","ax"
	.code32
ENTRY(startup_32)			# note: also used from wakeup_asm.S
	jmp	*%eax

	.section ".rodata","a"

	.balign	4
boot_idt_descr:
	.word	0				# idt limit = 0
	.long	0				# idt base = 0L

	.data

boot_gdt_descr:
	.word	__BOOT_DS + 7			# gdt limit
GLOBAL(boot_gdt)
	.long	0				# gdt base

	.bss

	.balign	4
GLOBAL(trampoline_status)	.space	4
GLOBAL(startup_32_smp)		.space	4
Commit	Line	Data
48927bbb JS	1	/*
	2	*
	3	* Trampoline.S Derived from Setup.S by Linus Torvalds
	4	*
	5	* 4 Jan 1997 Michael Chastain: changed to gnu as.
	6	*
	7	* This is only used for booting secondary CPUs in SMP machine
	8	*
	9	* Entry: CS:IP point to the start of our code, we are
	10	* in real mode with no stack, but the rest of the
	11	* trampoline page to make our stack and everything else
	12	* is a mystery.
	13	*
	14	* We jump into arch/x86/kernel/head_32.S.
	15	*
	16	* On entry to trampoline_data, the processor is in real mode
	17	* with 16-bit addressing and 16-bit data. CS has some value
	18	* and IP is zero. Thus, we load CS to the physical segment
	19	* of the real mode code before doing anything further.
	20	*
	21	* The structure real_mode_header includes entries that need
	22	* to be set up before executing this code:
	23	*
	24	* startup_32_smp
	25	* boot_gdt
	26	*/
	27
	28	#include <linux/linkage.h>
	29	#include <linux/init.h>
	30	#include <asm/segment.h>
	31	#include <asm/page_types.h>
e5684ec4	32	#include "realmode.h"
48927bbb JS	33
	34	.text
	35	.code16
48927bbb	36
8e029fcd JS	37	.balign PAGE_SIZE
8e029fcd JS	38	ENTRY(trampoline_data)
48927bbb JS	39	wbinvd # Needed for NUMA-Q should be harmless for others
48927bbb JS	40
e5684ec4	41	LJMPW_RM(1f)
48927bbb JS	42	1:
	43	mov %cs, %ax # Code and data in the same place
	44	mov %ax, %ds
	45
	46	cli # We should be safe anyway
	47
968ff9ee PA	48	movl startup_32_smp, %eax # where we need to go
968ff9ee PA	49
48927bbb JS	50	movl $0xA5A5A5A5, trampoline_status
	51	# write marker for master knows we're running
	52
968ff9ee PA	53	/*
968ff9ee PA	54	* GDT tables in non default location kernel can be beyond 16MB and
48927bbb JS	55	* lgdt will not be able to load the address as in real mode default
	56	* operand size is 16bit. Use lgdtl instead to force operand size
	57	* to 32 bit.
	58	*/
48927bbb JS	59	lidtl boot_idt_descr # load idt with 0, 0
	60	lgdtl boot_gdt_descr # load gdt with whatever is appropriate
	61
968ff9ee PA	62	movw $1, %dx # protected mode (PE) bit
968ff9ee PA	63	lmsw %dx # into protected mode
48927bbb	64
968ff9ee PA	65	ljmpl $__BOOT_CS, $pa_startup_32
	66
	67	.section ".text32","ax"
	68	.code32
	69	ENTRY(startup_32) # note: also used from wakeup_asm.S
	70	jmp *%eax
48927bbb	71
8e029fcd	72	.section ".rodata","a"
48927bbb	73
8e029fcd	74	.balign 4
48927bbb JS	75	boot_idt_descr:
	76	.word 0 # idt limit = 0
	77	.long 0 # idt base = 0L
	78
8e029fcd	79	.data
48927bbb	80
8e029fcd JS	81	boot_gdt_descr:
	82	.word __BOOT_DS + 7 # gdt limit
	83	GLOBAL(boot_gdt)
	84	.long 0 # gdt base
	85
	86	.bss
	87
	88	.balign 4
	89	GLOBAL(trampoline_status) .space 4
	90	GLOBAL(startup_32_smp) .space 4