[linux-2.6-block.git] / arch / x86 / mm / mem_encrypt_boot.S

/* SPDX-License-Identifier: GPL-2.0-only */
/*
 * AMD Memory Encryption Support
 *
 * Copyright (C) 2016 Advanced Micro Devices, Inc.
 *
 * Author: Tom Lendacky <thomas.lendacky@amd.com>
 */

#include <linux/linkage.h>
#include <asm/pgtable.h>
#include <asm/page.h>
#include <asm/processor-flags.h>
#include <asm/msr-index.h>
#include <asm/nospec-branch.h>

	.text
	.code64
ENTRY(sme_encrypt_execute)

	/*
	 * Entry parameters:
	 *   RDI - virtual address for the encrypted mapping
	 *   RSI - virtual address for the decrypted mapping
	 *   RDX - length to encrypt
	 *   RCX - virtual address of the encryption workarea, including:
	 *     - stack page (PAGE_SIZE)
	 *     - encryption routine page (PAGE_SIZE)
	 *     - intermediate copy buffer (PMD_PAGE_SIZE)
	 *    R8 - physcial address of the pagetables to use for encryption
	 */

	push	%rbp
	movq	%rsp, %rbp		/* RBP now has original stack pointer */

	/* Set up a one page stack in the non-encrypted memory area */
	movq	%rcx, %rax		/* Workarea stack page */
	leaq	PAGE_SIZE(%rax), %rsp	/* Set new stack pointer */
	addq	$PAGE_SIZE, %rax	/* Workarea encryption routine */

	push	%r12
	movq	%rdi, %r10		/* Encrypted area */
	movq	%rsi, %r11		/* Decrypted area */
	movq	%rdx, %r12		/* Area length */

	/* Copy encryption routine into the workarea */
	movq	%rax, %rdi				/* Workarea encryption routine */
	leaq	__enc_copy(%rip), %rsi			/* Encryption routine */
	movq	$(.L__enc_copy_end - __enc_copy), %rcx	/* Encryption routine length */
	rep	movsb

	/* Setup registers for call */
	movq	%r10, %rdi		/* Encrypted area */
	movq	%r11, %rsi		/* Decrypted area */
	movq	%r8, %rdx		/* Pagetables used for encryption */
	movq	%r12, %rcx		/* Area length */
	movq	%rax, %r8		/* Workarea encryption routine */
	addq	$PAGE_SIZE, %r8		/* Workarea intermediate copy buffer */

	ANNOTATE_RETPOLINE_SAFE
	call	*%rax			/* Call the encryption routine */

	pop	%r12

	movq	%rbp, %rsp		/* Restore original stack pointer */
	pop	%rbp

	ret
ENDPROC(sme_encrypt_execute)

ENTRY(__enc_copy)
/*
 * Routine used to encrypt memory in place.
 *   This routine must be run outside of the kernel proper since
 *   the kernel will be encrypted during the process. So this
 *   routine is defined here and then copied to an area outside
 *   of the kernel where it will remain and run decrypted
 *   during execution.
 *
 *   On entry the registers must be:
 *     RDI - virtual address for the encrypted mapping
 *     RSI - virtual address for the decrypted mapping
 *     RDX - address of the pagetables to use for encryption
 *     RCX - length of area
 *      R8 - intermediate copy buffer
 *
 *     RAX - points to this routine
 *
 * The area will be encrypted by copying from the non-encrypted
 * memory space to an intermediate buffer and then copying from the
 * intermediate buffer back to the encrypted memory space. The physical
 * addresses of the two mappings are the same which results in the area
 * being encrypted "in place".
 */
	/* Enable the new page tables */
	mov	%rdx, %cr3

	/* Flush any global TLBs */
	mov	%cr4, %rdx
	andq	$~X86_CR4_PGE, %rdx
	mov	%rdx, %cr4
	orq	$X86_CR4_PGE, %rdx
	mov	%rdx, %cr4

	push	%r15
	push	%r12

	movq	%rcx, %r9		/* Save area length */
	movq	%rdi, %r10		/* Save encrypted area address */
	movq	%rsi, %r11		/* Save decrypted area address */

	/* Set the PAT register PA5 entry to write-protect */
	movl	$MSR_IA32_CR_PAT, %ecx
	rdmsr
	mov	%rdx, %r15		/* Save original PAT value */
	andl	$0xffff00ff, %edx	/* Clear PA5 */
	orl	$0x00000500, %edx	/* Set PA5 to WP */
	wrmsr

	wbinvd				/* Invalidate any cache entries */

	/* Copy/encrypt up to 2MB at a time */
	movq	$PMD_PAGE_SIZE, %r12
1:
	cmpq	%r12, %r9
	jnb	2f
	movq	%r9, %r12

2:
	movq	%r11, %rsi		/* Source - decrypted area */
	movq	%r8, %rdi		/* Dest   - intermediate copy buffer */
	movq	%r12, %rcx
	rep	movsb

	movq	%r8, %rsi		/* Source - intermediate copy buffer */
	movq	%r10, %rdi		/* Dest   - encrypted area */
	movq	%r12, %rcx
	rep	movsb

	addq	%r12, %r11
	addq	%r12, %r10
	subq	%r12, %r9		/* Kernel length decrement */
	jnz	1b			/* Kernel length not zero? */

	/* Restore PAT register */
	movl	$MSR_IA32_CR_PAT, %ecx
	rdmsr
	mov	%r15, %rdx		/* Restore original PAT value */
	wrmsr

	pop	%r12
	pop	%r15

	ret
.L__enc_copy_end:
ENDPROC(__enc_copy)
Commit	Line	Data
d2912cb1	1	/* SPDX-License-Identifier: GPL-2.0-only */
6ebcb060 TL	2	/*
	3	* AMD Memory Encryption Support
	4	*
	5	* Copyright (C) 2016 Advanced Micro Devices, Inc.
	6	*
	7	* Author: Tom Lendacky <thomas.lendacky@amd.com>
6ebcb060 TL	8	*/
	9
	10	#include <linux/linkage.h>
	11	#include <asm/pgtable.h>
	12	#include <asm/page.h>
	13	#include <asm/processor-flags.h>
	14	#include <asm/msr-index.h>
531bb52a	15	#include <asm/nospec-branch.h>
6ebcb060 TL	16
	17	.text
	18	.code64
	19	ENTRY(sme_encrypt_execute)
	20
	21	/*
	22	* Entry parameters:
107cd253 TL	23	* RDI - virtual address for the encrypted mapping
	24	* RSI - virtual address for the decrypted mapping
	25	* RDX - length to encrypt
6ebcb060 TL	26	* RCX - virtual address of the encryption workarea, including:
	27	* - stack page (PAGE_SIZE)
	28	* - encryption routine page (PAGE_SIZE)
	29	* - intermediate copy buffer (PMD_PAGE_SIZE)
	30	* R8 - physcial address of the pagetables to use for encryption
	31	*/
	32
6e0b52d4 BP	33	push %rbp
6e0b52d4 BP	34	movq %rsp, %rbp /* RBP now has original stack pointer */
6ebcb060 TL	35
	36	/* Set up a one page stack in the non-encrypted memory area */
	37	movq %rcx, %rax /* Workarea stack page */
	38	leaq PAGE_SIZE(%rax), %rsp /* Set new stack pointer */
	39	addq $PAGE_SIZE, %rax /* Workarea encryption routine */
	40
	41	push %r12
107cd253 TL	42	movq %rdi, %r10 /* Encrypted area */
	43	movq %rsi, %r11 /* Decrypted area */
	44	movq %rdx, %r12 /* Area length */
6ebcb060 TL	45
	46	/* Copy encryption routine into the workarea */
	47	movq %rax, %rdi /* Workarea encryption routine */
	48	leaq __enc_copy(%rip), %rsi /* Encryption routine */
	49	movq $(.L__enc_copy_end - __enc_copy), %rcx /* Encryption routine length */
	50	rep movsb
	51
	52	/* Setup registers for call */
107cd253 TL	53	movq %r10, %rdi /* Encrypted area */
107cd253 TL	54	movq %r11, %rsi /* Decrypted area */
6ebcb060	55	movq %r8, %rdx /* Pagetables used for encryption */
107cd253	56	movq %r12, %rcx /* Area length */
6ebcb060 TL	57	movq %rax, %r8 /* Workarea encryption routine */
	58	addq $PAGE_SIZE, %r8 /* Workarea intermediate copy buffer */
	59
531bb52a	60	ANNOTATE_RETPOLINE_SAFE
6ebcb060 TL	61	call %rax / Call the encryption routine */
	62
	63	pop %r12
	64
	65	movq %rbp, %rsp /* Restore original stack pointer */
6e0b52d4	66	pop %rbp
6ebcb060 TL	67
	68	ret
	69	ENDPROC(sme_encrypt_execute)
	70
	71	ENTRY(__enc_copy)
	72	/*
107cd253	73	* Routine used to encrypt memory in place.
6ebcb060 TL	74	* This routine must be run outside of the kernel proper since
	75	* the kernel will be encrypted during the process. So this
	76	* routine is defined here and then copied to an area outside
	77	* of the kernel where it will remain and run decrypted
	78	* during execution.
	79	*
	80	* On entry the registers must be:
107cd253 TL	81	* RDI - virtual address for the encrypted mapping
107cd253 TL	82	* RSI - virtual address for the decrypted mapping
6ebcb060	83	* RDX - address of the pagetables to use for encryption
107cd253	84	* RCX - length of area
6ebcb060 TL	85	* R8 - intermediate copy buffer
	86	*
	87	* RAX - points to this routine
	88	*
107cd253 TL	89	* The area will be encrypted by copying from the non-encrypted
	90	* memory space to an intermediate buffer and then copying from the
	91	* intermediate buffer back to the encrypted memory space. The physical
	92	* addresses of the two mappings are the same which results in the area
	93	* being encrypted "in place".
6ebcb060 TL	94	*/
	95	/* Enable the new page tables */
	96	mov %rdx, %cr3
	97
	98	/* Flush any global TLBs */
	99	mov %cr4, %rdx
	100	andq $~X86_CR4_PGE, %rdx
	101	mov %rdx, %cr4
	102	orq $X86_CR4_PGE, %rdx
	103	mov %rdx, %cr4
	104
13038801	105	push %r15
cc5f01e2	106	push %r12
13038801	107
107cd253 TL	108	movq %rcx, %r9 /* Save area length */
	109	movq %rdi, %r10 /* Save encrypted area address */
	110	movq %rsi, %r11 /* Save decrypted area address */
13038801	111
6ebcb060	112	/* Set the PAT register PA5 entry to write-protect */
6ebcb060 TL	113	movl $MSR_IA32_CR_PAT, %ecx
6ebcb060 TL	114	rdmsr
13038801	115	mov %rdx, %r15 /* Save original PAT value */
6ebcb060 TL	116	andl $0xffff00ff, %edx /* Clear PA5 */
	117	orl $0x00000500, %edx /* Set PA5 to WP */
	118	wrmsr
6ebcb060 TL	119
	120	wbinvd /* Invalidate any cache entries */
	121
cc5f01e2 TL	122	/* Copy/encrypt up to 2MB at a time */
cc5f01e2 TL	123	movq $PMD_PAGE_SIZE, %r12
6ebcb060	124	1:
cc5f01e2 TL	125	cmpq %r12, %r9
	126	jnb 2f
	127	movq %r9, %r12
	128
	129	2:
107cd253	130	movq %r11, %rsi /* Source - decrypted area */
6ebcb060	131	movq %r8, %rdi /* Dest - intermediate copy buffer */
cc5f01e2	132	movq %r12, %rcx
6ebcb060 TL	133	rep movsb
	134
	135	movq %r8, %rsi /* Source - intermediate copy buffer */
107cd253	136	movq %r10, %rdi /* Dest - encrypted area */
cc5f01e2	137	movq %r12, %rcx
6ebcb060 TL	138	rep movsb
6ebcb060 TL	139
cc5f01e2 TL	140	addq %r12, %r11
	141	addq %r12, %r10
	142	subq %r12, %r9 /* Kernel length decrement */
6ebcb060 TL	143	jnz 1b /* Kernel length not zero? */
	144
	145	/* Restore PAT register */
6ebcb060 TL	146	movl $MSR_IA32_CR_PAT, %ecx
6ebcb060 TL	147	rdmsr
13038801	148	mov %r15, %rdx /* Restore original PAT value */
6ebcb060 TL	149	wrmsr
6ebcb060 TL	150
cc5f01e2	151	pop %r12
13038801 TL	152	pop %r15
13038801 TL	153
6ebcb060 TL	154	ret
	155	.L__enc_copy_end:
	156	ENDPROC(__enc_copy)