[linux-2.6-block.git] / arch / x86 / lib / checksum_32.S

/*
 * INET		An implementation of the TCP/IP protocol suite for the LINUX
 *		operating system.  INET is implemented using the  BSD Socket
 *		interface as the means of communication with the user level.
 *
 *		IP/TCP/UDP checksumming routines
 *
 * Authors:	Jorge Cwik, <jorge@laser.satlink.net>
 *		Arnt Gulbrandsen, <agulbra@nvg.unit.no>
 *		Tom May, <ftom@netcom.com>
 *              Pentium Pro/II routines:
 *              Alexander Kjeldaas <astor@guardian.no>
 *              Finn Arne Gangstad <finnag@guardian.no>
 *		Lots of code moved from tcp.c and ip.c; see those files
 *		for more names.
 *
 * Changes:     Ingo Molnar, converted csum_partial_copy() to 2.1 exception
 *			     handling.
 *		Andi Kleen,  add zeroing on error
 *                   converted to pure assembler
 *
 *		This program is free software; you can redistribute it and/or
 *		modify it under the terms of the GNU General Public License
 *		as published by the Free Software Foundation; either version
 *		2 of the License, or (at your option) any later version.
 */

#include <linux/linkage.h>
#include <asm/dwarf2.h>
#include <asm/errno.h>
				
/*
 * computes a partial checksum, e.g. for TCP/UDP fragments
 */

/*	
unsigned int csum_partial(const unsigned char * buff, int len, unsigned int sum)
 */
		
.text
		
#ifndef CONFIG_X86_USE_PPRO_CHECKSUM

	  /*		
	   * Experiments with Ethernet and SLIP connections show that buff
	   * is aligned on either a 2-byte or 4-byte boundary.  We get at
	   * least a twofold speedup on 486 and Pentium if it is 4-byte aligned.
	   * Fortunately, it is easy to convert 2-byte alignment to 4-byte
	   * alignment for the unrolled loop.
	   */		
ENTRY(csum_partial)
	CFI_STARTPROC
	pushl_cfi %esi
	CFI_REL_OFFSET esi, 0
	pushl_cfi %ebx
	CFI_REL_OFFSET ebx, 0
	movl 20(%esp),%eax	# Function arg: unsigned int sum
	movl 16(%esp),%ecx	# Function arg: int len
	movl 12(%esp),%esi	# Function arg: unsigned char *buff
	testl $3, %esi		# Check alignment.
	jz 2f			# Jump if alignment is ok.
	testl $1, %esi		# Check alignment.
	jz 10f			# Jump if alignment is boundary of 2bytes.

	# buf is odd
	dec %ecx
	jl 8f
	movzbl (%esi), %ebx
	adcl %ebx, %eax
	roll $8, %eax
	inc %esi
	testl $2, %esi
	jz 2f
10:
	subl $2, %ecx		# Alignment uses up two bytes.
	jae 1f			# Jump if we had at least two bytes.
	addl $2, %ecx		# ecx was < 2.  Deal with it.
	jmp 4f
1:	movw (%esi), %bx
	addl $2, %esi
	addw %bx, %ax
	adcl $0, %eax
2:
	movl %ecx, %edx
	shrl $5, %ecx
	jz 2f
	testl %esi, %esi
1:	movl (%esi), %ebx
	adcl %ebx, %eax
	movl 4(%esi), %ebx
	adcl %ebx, %eax
	movl 8(%esi), %ebx
	adcl %ebx, %eax
	movl 12(%esi), %ebx
	adcl %ebx, %eax
	movl 16(%esi), %ebx
	adcl %ebx, %eax
	movl 20(%esi), %ebx
	adcl %ebx, %eax
	movl 24(%esi), %ebx
	adcl %ebx, %eax
	movl 28(%esi), %ebx
	adcl %ebx, %eax
	lea 32(%esi), %esi
	dec %ecx
	jne 1b
	adcl $0, %eax
2:	movl %edx, %ecx
	andl $0x1c, %edx
	je 4f
	shrl $2, %edx		# This clears CF
3:	adcl (%esi), %eax
	lea 4(%esi), %esi
	dec %edx
	jne 3b
	adcl $0, %eax
4:	andl $3, %ecx
	jz 7f
	cmpl $2, %ecx
	jb 5f
	movw (%esi),%cx
	leal 2(%esi),%esi
	je 6f
	shll $16,%ecx
5:	movb (%esi),%cl
6:	addl %ecx,%eax
	adcl $0, %eax 
7:	
	testl $1, 12(%esp)
	jz 8f
	roll $8, %eax
8:
	popl_cfi %ebx
	CFI_RESTORE ebx
	popl_cfi %esi
	CFI_RESTORE esi
	ret
	CFI_ENDPROC
ENDPROC(csum_partial)

#else

/* Version for PentiumII/PPro */

ENTRY(csum_partial)
	CFI_STARTPROC
	pushl_cfi %esi
	CFI_REL_OFFSET esi, 0
	pushl_cfi %ebx
	CFI_REL_OFFSET ebx, 0
	movl 20(%esp),%eax	# Function arg: unsigned int sum
	movl 16(%esp),%ecx	# Function arg: int len
	movl 12(%esp),%esi	# Function arg:	const unsigned char *buf

	testl $3, %esi         
	jnz 25f                 
10:
	movl %ecx, %edx
	movl %ecx, %ebx
	andl $0x7c, %ebx
	shrl $7, %ecx
	addl %ebx,%esi
	shrl $2, %ebx  
	negl %ebx
	lea 45f(%ebx,%ebx,2), %ebx
	testl %esi, %esi
	jmp *%ebx

	# Handle 2-byte-aligned regions
20:	addw (%esi), %ax
	lea 2(%esi), %esi
	adcl $0, %eax
	jmp 10b
25:
	testl $1, %esi         
	jz 30f                 
	# buf is odd
	dec %ecx
	jl 90f
	movzbl (%esi), %ebx
	addl %ebx, %eax
	adcl $0, %eax
	roll $8, %eax
	inc %esi
	testl $2, %esi
	jz 10b

30:	subl $2, %ecx          
	ja 20b                 
	je 32f
	addl $2, %ecx
	jz 80f
	movzbl (%esi),%ebx	# csumming 1 byte, 2-aligned
	addl %ebx, %eax
	adcl $0, %eax
	jmp 80f
32:
	addw (%esi), %ax	# csumming 2 bytes, 2-aligned
	adcl $0, %eax
	jmp 80f

40: 
	addl -128(%esi), %eax
	adcl -124(%esi), %eax
	adcl -120(%esi), %eax
	adcl -116(%esi), %eax   
	adcl -112(%esi), %eax   
	adcl -108(%esi), %eax
	adcl -104(%esi), %eax
	adcl -100(%esi), %eax
	adcl -96(%esi), %eax
	adcl -92(%esi), %eax
	adcl -88(%esi), %eax
	adcl -84(%esi), %eax
	adcl -80(%esi), %eax
	adcl -76(%esi), %eax
	adcl -72(%esi), %eax
	adcl -68(%esi), %eax
	adcl -64(%esi), %eax     
	adcl -60(%esi), %eax     
	adcl -56(%esi), %eax     
	adcl -52(%esi), %eax   
	adcl -48(%esi), %eax   
	adcl -44(%esi), %eax
	adcl -40(%esi), %eax
	adcl -36(%esi), %eax
	adcl -32(%esi), %eax
	adcl -28(%esi), %eax
	adcl -24(%esi), %eax
	adcl -20(%esi), %eax
	adcl -16(%esi), %eax
	adcl -12(%esi), %eax
	adcl -8(%esi), %eax
	adcl -4(%esi), %eax
45:
	lea 128(%esi), %esi
	adcl $0, %eax
	dec %ecx
	jge 40b
	movl %edx, %ecx
50:	andl $3, %ecx
	jz 80f

	# Handle the last 1-3 bytes without jumping
	notl %ecx		# 1->2, 2->1, 3->0, higher bits are masked
	movl $0xffffff,%ebx	# by the shll and shrl instructions
	shll $3,%ecx
	shrl %cl,%ebx
	andl -128(%esi),%ebx	# esi is 4-aligned so should be ok
	addl %ebx,%eax
	adcl $0,%eax
80: 
	testl $1, 12(%esp)
	jz 90f
	roll $8, %eax
90: 
	popl_cfi %ebx
	CFI_RESTORE ebx
	popl_cfi %esi
	CFI_RESTORE esi
	ret
	CFI_ENDPROC
ENDPROC(csum_partial)
				
#endif

/*
unsigned int csum_partial_copy_generic (const char *src, char *dst,
				  int len, int sum, int *src_err_ptr, int *dst_err_ptr)
 */ 

/*
 * Copy from ds while checksumming, otherwise like csum_partial
 *
 * The macros SRC and DST specify the type of access for the instruction.
 * thus we can call a custom exception handler for all access types.
 *
 * FIXME: could someone double-check whether I haven't mixed up some SRC and
 *	  DST definitions? It's damn hard to trigger all cases.  I hope I got
 *	  them all but there's no guarantee.
 */

#define SRC(y...)			\
	9999: y;			\
	.section __ex_table, "a";	\
	.long 9999b, 6001f	;	\
	.previous

#define DST(y...)			\
	9999: y;			\
	.section __ex_table, "a";	\
	.long 9999b, 6002f	;	\
	.previous

#ifndef CONFIG_X86_USE_PPRO_CHECKSUM

#define ARGBASE 16		
#define FP		12
		
ENTRY(csum_partial_copy_generic)
	CFI_STARTPROC
	subl  $4,%esp	
	CFI_ADJUST_CFA_OFFSET 4
	pushl_cfi %edi
	CFI_REL_OFFSET edi, 0
	pushl_cfi %esi
	CFI_REL_OFFSET esi, 0
	pushl_cfi %ebx
	CFI_REL_OFFSET ebx, 0
	movl ARGBASE+16(%esp),%eax	# sum
	movl ARGBASE+12(%esp),%ecx	# len
	movl ARGBASE+4(%esp),%esi	# src
	movl ARGBASE+8(%esp),%edi	# dst

	testl $2, %edi			# Check alignment. 
	jz 2f				# Jump if alignment is ok.
	subl $2, %ecx			# Alignment uses up two bytes.
	jae 1f				# Jump if we had at least two bytes.
	addl $2, %ecx			# ecx was < 2.  Deal with it.
	jmp 4f
SRC(1:	movw (%esi), %bx	)
	addl $2, %esi
DST(	movw %bx, (%edi)	)
	addl $2, %edi
	addw %bx, %ax	
	adcl $0, %eax
2:
	movl %ecx, FP(%esp)
	shrl $5, %ecx
	jz 2f
	testl %esi, %esi
SRC(1:	movl (%esi), %ebx	)
SRC(	movl 4(%esi), %edx	)
	adcl %ebx, %eax
DST(	movl %ebx, (%edi)	)
	adcl %edx, %eax
DST(	movl %edx, 4(%edi)	)

SRC(	movl 8(%esi), %ebx	)
SRC(	movl 12(%esi), %edx	)
	adcl %ebx, %eax
DST(	movl %ebx, 8(%edi)	)
	adcl %edx, %eax
DST(	movl %edx, 12(%edi)	)

SRC(	movl 16(%esi), %ebx 	)
SRC(	movl 20(%esi), %edx	)
	adcl %ebx, %eax
DST(	movl %ebx, 16(%edi)	)
	adcl %edx, %eax
DST(	movl %edx, 20(%edi)	)

SRC(	movl 24(%esi), %ebx	)
SRC(	movl 28(%esi), %edx	)
	adcl %ebx, %eax
DST(	movl %ebx, 24(%edi)	)
	adcl %edx, %eax
DST(	movl %edx, 28(%edi)	)

	lea 32(%esi), %esi
	lea 32(%edi), %edi
	dec %ecx
	jne 1b
	adcl $0, %eax
2:	movl FP(%esp), %edx
	movl %edx, %ecx
	andl $0x1c, %edx
	je 4f
	shrl $2, %edx			# This clears CF
SRC(3:	movl (%esi), %ebx	)
	adcl %ebx, %eax
DST(	movl %ebx, (%edi)	)
	lea 4(%esi), %esi
	lea 4(%edi), %edi
	dec %edx
	jne 3b
	adcl $0, %eax
4:	andl $3, %ecx
	jz 7f
	cmpl $2, %ecx
	jb 5f
SRC(	movw (%esi), %cx	)
	leal 2(%esi), %esi
DST(	movw %cx, (%edi)	)
	leal 2(%edi), %edi
	je 6f
	shll $16,%ecx
SRC(5:	movb (%esi), %cl	)
DST(	movb %cl, (%edi)	)
6:	addl %ecx, %eax
	adcl $0, %eax
7:
5000:

# Exception handler:
.section .fixup, "ax"							

6001:
	movl ARGBASE+20(%esp), %ebx	# src_err_ptr
	movl $-EFAULT, (%ebx)

	# zero the complete destination - computing the rest
	# is too much work 
	movl ARGBASE+8(%esp), %edi	# dst
	movl ARGBASE+12(%esp), %ecx	# len
	xorl %eax,%eax
	rep ; stosb

	jmp 5000b

6002:
	movl ARGBASE+24(%esp), %ebx	# dst_err_ptr
	movl $-EFAULT,(%ebx)
	jmp 5000b

.previous

	popl_cfi %ebx
	CFI_RESTORE ebx
	popl_cfi %esi
	CFI_RESTORE esi
	popl_cfi %edi
	CFI_RESTORE edi
	popl_cfi %ecx			# equivalent to addl $4,%esp
	ret	
	CFI_ENDPROC
ENDPROC(csum_partial_copy_generic)

#else

/* Version for PentiumII/PPro */

#define ROUND1(x) \
	SRC(movl x(%esi), %ebx	)	;	\
	addl %ebx, %eax			;	\
	DST(movl %ebx, x(%edi)	)	; 

#define ROUND(x) \
	SRC(movl x(%esi), %ebx	)	;	\
	adcl %ebx, %eax			;	\
	DST(movl %ebx, x(%edi)	)	;

#define ARGBASE 12
		
ENTRY(csum_partial_copy_generic)
	CFI_STARTPROC
	pushl_cfi %ebx
	CFI_REL_OFFSET ebx, 0
	pushl_cfi %edi
	CFI_REL_OFFSET edi, 0
	pushl_cfi %esi
	CFI_REL_OFFSET esi, 0
	movl ARGBASE+4(%esp),%esi	#src
	movl ARGBASE+8(%esp),%edi	#dst	
	movl ARGBASE+12(%esp),%ecx	#len
	movl ARGBASE+16(%esp),%eax	#sum
#	movl %ecx, %edx  
	movl %ecx, %ebx  
	movl %esi, %edx
	shrl $6, %ecx     
	andl $0x3c, %ebx  
	negl %ebx
	subl %ebx, %esi  
	subl %ebx, %edi  
	lea  -1(%esi),%edx
	andl $-32,%edx
	lea 3f(%ebx,%ebx), %ebx
	testl %esi, %esi 
	jmp *%ebx
1:	addl $64,%esi
	addl $64,%edi 
	SRC(movb -32(%edx),%bl)	; SRC(movb (%edx),%bl)
	ROUND1(-64) ROUND(-60) ROUND(-56) ROUND(-52)	
	ROUND (-48) ROUND(-44) ROUND(-40) ROUND(-36)	
	ROUND (-32) ROUND(-28) ROUND(-24) ROUND(-20)	
	ROUND (-16) ROUND(-12) ROUND(-8)  ROUND(-4)	
3:	adcl $0,%eax
	addl $64, %edx
	dec %ecx
	jge 1b
4:	movl ARGBASE+12(%esp),%edx	#len
	andl $3, %edx
	jz 7f
	cmpl $2, %edx
	jb 5f
SRC(	movw (%esi), %dx         )
	leal 2(%esi), %esi
DST(	movw %dx, (%edi)         )
	leal 2(%edi), %edi
	je 6f
	shll $16,%edx
5:
SRC(	movb (%esi), %dl         )
DST(	movb %dl, (%edi)         )
6:	addl %edx, %eax
	adcl $0, %eax
7:
.section .fixup, "ax"
6001:	movl	ARGBASE+20(%esp), %ebx	# src_err_ptr	
	movl $-EFAULT, (%ebx)
	# zero the complete destination (computing the rest is too much work)
	movl ARGBASE+8(%esp),%edi	# dst
	movl ARGBASE+12(%esp),%ecx	# len
	xorl %eax,%eax
	rep; stosb
	jmp 7b
6002:	movl ARGBASE+24(%esp), %ebx	# dst_err_ptr
	movl $-EFAULT, (%ebx)
	jmp  7b			
.previous				

	popl_cfi %esi
	CFI_RESTORE esi
	popl_cfi %edi
	CFI_RESTORE edi
	popl_cfi %ebx
	CFI_RESTORE ebx
	ret
	CFI_ENDPROC
ENDPROC(csum_partial_copy_generic)
				
#undef ROUND
#undef ROUND1		
		
#endif
Commit	Line	Data
1da177e4 LT	1	/*
	2	* INET An implementation of the TCP/IP protocol suite for the LINUX
	3	* operating system. INET is implemented using the BSD Socket
	4	* interface as the means of communication with the user level.
	5	*
	6	* IP/TCP/UDP checksumming routines
	7	*
	8	* Authors: Jorge Cwik, <jorge@laser.satlink.net>
	9	* Arnt Gulbrandsen, <agulbra@nvg.unit.no>
	10	* Tom May, <ftom@netcom.com>
	11	* Pentium Pro/II routines:
	12	* Alexander Kjeldaas <astor@guardian.no>
	13	* Finn Arne Gangstad <finnag@guardian.no>
	14	* Lots of code moved from tcp.c and ip.c; see those files
	15	* for more names.
	16	*
	17	* Changes: Ingo Molnar, converted csum_partial_copy() to 2.1 exception
	18	* handling.
	19	* Andi Kleen, add zeroing on error
	20	* converted to pure assembler
	21	*
	22	* This program is free software; you can redistribute it and/or
	23	* modify it under the terms of the GNU General Public License
	24	* as published by the Free Software Foundation; either version
	25	* 2 of the License, or (at your option) any later version.
	26	*/
	27
00e065ea JB	28	#include <linux/linkage.h>
00e065ea JB	29	#include <asm/dwarf2.h>
1da177e4 LT	30	#include <asm/errno.h>
	31
	32	/*
	33	* computes a partial checksum, e.g. for TCP/UDP fragments
	34	*/
	35
	36	/*
	37	unsigned int csum_partial(const unsigned char * buff, int len, unsigned int sum)
	38	*/
	39
	40	.text
1da177e4 LT	41
	42	#ifndef CONFIG_X86_USE_PPRO_CHECKSUM
	43
	44	/*
	45	* Experiments with Ethernet and SLIP connections show that buff
	46	* is aligned on either a 2-byte or 4-byte boundary. We get at
	47	* least a twofold speedup on 486 and Pentium if it is 4-byte aligned.
	48	* Fortunately, it is easy to convert 2-byte alignment to 4-byte
	49	* alignment for the unrolled loop.
	50	*/
00e065ea JB	51	ENTRY(csum_partial)
00e065ea JB	52	CFI_STARTPROC
60cf637a	53	pushl_cfi %esi
00e065ea	54	CFI_REL_OFFSET esi, 0
60cf637a	55	pushl_cfi %ebx
00e065ea	56	CFI_REL_OFFSET ebx, 0
1da177e4 LT	57	movl 20(%esp),%eax # Function arg: unsigned int sum
	58	movl 16(%esp),%ecx # Function arg: int len
	59	movl 12(%esp),%esi # Function arg: unsigned char *buff
	60	testl $3, %esi # Check alignment.
	61	jz 2f # Jump if alignment is ok.
	62	testl $1, %esi # Check alignment.
	63	jz 10f # Jump if alignment is boundary of 2bytes.
	64
	65	# buf is odd
	66	dec %ecx
	67	jl 8f
	68	movzbl (%esi), %ebx
	69	adcl %ebx, %eax
	70	roll $8, %eax
	71	inc %esi
	72	testl $2, %esi
	73	jz 2f
	74	10:
	75	subl $2, %ecx # Alignment uses up two bytes.
	76	jae 1f # Jump if we had at least two bytes.
	77	addl $2, %ecx # ecx was < 2. Deal with it.
	78	jmp 4f
	79	1: movw (%esi), %bx
	80	addl $2, %esi
	81	addw %bx, %ax
	82	adcl $0, %eax
	83	2:
	84	movl %ecx, %edx
	85	shrl $5, %ecx
	86	jz 2f
	87	testl %esi, %esi
	88	1: movl (%esi), %ebx
	89	adcl %ebx, %eax
	90	movl 4(%esi), %ebx
	91	adcl %ebx, %eax
	92	movl 8(%esi), %ebx
	93	adcl %ebx, %eax
	94	movl 12(%esi), %ebx
	95	adcl %ebx, %eax
	96	movl 16(%esi), %ebx
	97	adcl %ebx, %eax
	98	movl 20(%esi), %ebx
	99	adcl %ebx, %eax
	100	movl 24(%esi), %ebx
	101	adcl %ebx, %eax
	102	movl 28(%esi), %ebx
	103	adcl %ebx, %eax
	104	lea 32(%esi), %esi
	105	dec %ecx
	106	jne 1b
	107	adcl $0, %eax
	108	2: movl %edx, %ecx
	109	andl $0x1c, %edx
	110	je 4f
	111	shrl $2, %edx # This clears CF
	112	3: adcl (%esi), %eax
	113	lea 4(%esi), %esi
	114	dec %edx
	115	jne 3b
	116	adcl $0, %eax
	117	4: andl $3, %ecx
	118	jz 7f
	119	cmpl $2, %ecx
	120	jb 5f
121	movw (%esi),%cx
122	leal 2(%esi),%esi
123	je 6f
124	shll $16,%ecx
125	5: movb (%esi),%cl
126	6: addl %ecx,%eax
127	adcl $0, %eax
128	7:
129	testl $1, 12(%esp)
130	jz 8f
131	roll $8, %eax
132	8:
60cf637a	133	popl_cfi %ebx
00e065ea	134	CFI_RESTORE ebx
60cf637a	135	popl_cfi %esi
00e065ea	136	CFI_RESTORE esi
1da177e4	137	ret
00e065ea JB	138	CFI_ENDPROC
00e065ea JB	139	ENDPROC(csum_partial)
1da177e4 LT	140
	141	#else
	142
	143	/* Version for PentiumII/PPro */
	144
00e065ea JB	145	ENTRY(csum_partial)
00e065ea JB	146	CFI_STARTPROC
60cf637a	147	pushl_cfi %esi
00e065ea	148	CFI_REL_OFFSET esi, 0
60cf637a	149	pushl_cfi %ebx
00e065ea	150	CFI_REL_OFFSET ebx, 0
1da177e4 LT	151	movl 20(%esp),%eax # Function arg: unsigned int sum
	152	movl 16(%esp),%ecx # Function arg: int len
	153	movl 12(%esp),%esi # Function arg: const unsigned char *buf
	154
	155	testl $3, %esi
	156	jnz 25f
	157	10:
	158	movl %ecx, %edx
	159	movl %ecx, %ebx
	160	andl $0x7c, %ebx
	161	shrl $7, %ecx
	162	addl %ebx,%esi
	163	shrl $2, %ebx
	164	negl %ebx
	165	lea 45f(%ebx,%ebx,2), %ebx
	166	testl %esi, %esi
	167	jmp *%ebx
	168
	169	# Handle 2-byte-aligned regions
	170	20: addw (%esi), %ax
	171	lea 2(%esi), %esi
	172	adcl $0, %eax
	173	jmp 10b
	174	25:
	175	testl $1, %esi
	176	jz 30f
	177	# buf is odd
	178	dec %ecx
	179	jl 90f
	180	movzbl (%esi), %ebx
	181	addl %ebx, %eax
	182	adcl $0, %eax
	183	roll $8, %eax
	184	inc %esi
	185	testl $2, %esi
	186	jz 10b
	187
	188	30: subl $2, %ecx
	189	ja 20b
	190	je 32f
	191	addl $2, %ecx
	192	jz 80f
	193	movzbl (%esi),%ebx # csumming 1 byte, 2-aligned
	194	addl %ebx, %eax
	195	adcl $0, %eax
	196	jmp 80f
	197	32:
	198	addw (%esi), %ax # csumming 2 bytes, 2-aligned
	199	adcl $0, %eax
	200	jmp 80f
	201
	202	40:
	203	addl -128(%esi), %eax
	204	adcl -124(%esi), %eax
	205	adcl -120(%esi), %eax
	206	adcl -116(%esi), %eax
	207	adcl -112(%esi), %eax
	208	adcl -108(%esi), %eax
	209	adcl -104(%esi), %eax
	210	adcl -100(%esi), %eax
	211	adcl -96(%esi), %eax
	212	adcl -92(%esi), %eax
	213	adcl -88(%esi), %eax
	214	adcl -84(%esi), %eax
215	adcl -80(%esi), %eax
216	adcl -76(%esi), %eax
217	adcl -72(%esi), %eax
218	adcl -68(%esi), %eax
219	adcl -64(%esi), %eax
220	adcl -60(%esi), %eax
221	adcl -56(%esi), %eax
222	adcl -52(%esi), %eax
223	adcl -48(%esi), %eax
224	adcl -44(%esi), %eax
225	adcl -40(%esi), %eax
226	adcl -36(%esi), %eax
227	adcl -32(%esi), %eax
228	adcl -28(%esi), %eax
229	adcl -24(%esi), %eax
230	adcl -20(%esi), %eax
231	adcl -16(%esi), %eax
232	adcl -12(%esi), %eax
233	adcl -8(%esi), %eax
234	adcl -4(%esi), %eax
235	45:
236	lea 128(%esi), %esi
237	adcl $0, %eax
238	dec %ecx
239	jge 40b
240	movl %edx, %ecx
241	50: andl $3, %ecx
242	jz 80f
243
244	# Handle the last 1-3 bytes without jumping
245	notl %ecx # 1->2, 2->1, 3->0, higher bits are masked
246	movl $0xffffff,%ebx # by the shll and shrl instructions
247	shll $3,%ecx
248	shrl %cl,%ebx
249	andl -128(%esi),%ebx # esi is 4-aligned so should be ok
250	addl %ebx,%eax
251	adcl $0,%eax
252	80:
253	testl $1, 12(%esp)
254	jz 90f
255	roll $8, %eax
256	90:
60cf637a	257	popl_cfi %ebx
00e065ea	258	CFI_RESTORE ebx
60cf637a	259	popl_cfi %esi
00e065ea	260	CFI_RESTORE esi
1da177e4	261	ret
00e065ea JB	262	CFI_ENDPROC
00e065ea JB	263	ENDPROC(csum_partial)
1da177e4 LT	264
	265	#endif
	266
	267	/*
	268	unsigned int csum_partial_copy_generic (const char src, char dst,
	269	int len, int sum, int src_err_ptr, int dst_err_ptr)
	270	*/
	271
	272	/*
	273	* Copy from ds while checksumming, otherwise like csum_partial
	274	*
	275	* The macros SRC and DST specify the type of access for the instruction.
	276	* thus we can call a custom exception handler for all access types.
	277	*
	278	* FIXME: could someone double-check whether I haven't mixed up some SRC and
	279	* DST definitions? It's damn hard to trigger all cases. I hope I got
	280	* them all but there's no guarantee.
	281	*/
	282
	283	#define SRC(y...) \
	284	9999: y; \
	285	.section __ex_table, "a"; \
	286	.long 9999b, 6001f ; \
	287	.previous
	288
	289	#define DST(y...) \
	290	9999: y; \
	291	.section __ex_table, "a"; \
	292	.long 9999b, 6002f ; \
	293	.previous
	294
1da177e4 LT	295	#ifndef CONFIG_X86_USE_PPRO_CHECKSUM
	296
	297	#define ARGBASE 16
	298	#define FP 12
	299
00e065ea JB	300	ENTRY(csum_partial_copy_generic)
00e065ea JB	301	CFI_STARTPROC
1da177e4	302	subl $4,%esp
00e065ea	303	CFI_ADJUST_CFA_OFFSET 4
60cf637a	304	pushl_cfi %edi
00e065ea	305	CFI_REL_OFFSET edi, 0
60cf637a	306	pushl_cfi %esi
00e065ea	307	CFI_REL_OFFSET esi, 0
60cf637a	308	pushl_cfi %ebx
00e065ea	309	CFI_REL_OFFSET ebx, 0
1da177e4 LT	310	movl ARGBASE+16(%esp),%eax # sum
	311	movl ARGBASE+12(%esp),%ecx # len
	312	movl ARGBASE+4(%esp),%esi # src
	313	movl ARGBASE+8(%esp),%edi # dst
	314
	315	testl $2, %edi # Check alignment.
	316	jz 2f # Jump if alignment is ok.
	317	subl $2, %ecx # Alignment uses up two bytes.
	318	jae 1f # Jump if we had at least two bytes.
	319	addl $2, %ecx # ecx was < 2. Deal with it.
	320	jmp 4f
	321	SRC(1: movw (%esi), %bx )
	322	addl $2, %esi
	323	DST( movw %bx, (%edi) )
	324	addl $2, %edi
	325	addw %bx, %ax
	326	adcl $0, %eax
	327	2:
	328	movl %ecx, FP(%esp)
	329	shrl $5, %ecx
	330	jz 2f
	331	testl %esi, %esi
	332	SRC(1: movl (%esi), %ebx )
	333	SRC( movl 4(%esi), %edx )
	334	adcl %ebx, %eax
	335	DST( movl %ebx, (%edi) )
	336	adcl %edx, %eax
	337	DST( movl %edx, 4(%edi) )
	338
	339	SRC( movl 8(%esi), %ebx )
	340	SRC( movl 12(%esi), %edx )
	341	adcl %ebx, %eax
	342	DST( movl %ebx, 8(%edi) )
	343	adcl %edx, %eax
	344	DST( movl %edx, 12(%edi) )
	345
	346	SRC( movl 16(%esi), %ebx )
	347	SRC( movl 20(%esi), %edx )
	348	adcl %ebx, %eax
	349	DST( movl %ebx, 16(%edi) )
	350	adcl %edx, %eax
	351	DST( movl %edx, 20(%edi) )
	352
	353	SRC( movl 24(%esi), %ebx )
	354	SRC( movl 28(%esi), %edx )
	355	adcl %ebx, %eax
	356	DST( movl %ebx, 24(%edi) )
	357	adcl %edx, %eax
	358	DST( movl %edx, 28(%edi) )
	359
	360	lea 32(%esi), %esi
	361	lea 32(%edi), %edi
	362	dec %ecx
	363	jne 1b
	364	adcl $0, %eax
	365	2: movl FP(%esp), %edx
	366	movl %edx, %ecx
	367	andl $0x1c, %edx
	368	je 4f
	369	shrl $2, %edx # This clears CF
	370	SRC(3: movl (%esi), %ebx )
	371	adcl %ebx, %eax
	372	DST( movl %ebx, (%edi) )
	373	lea 4(%esi), %esi
374	lea 4(%edi), %edi
375	dec %edx
376	jne 3b
377	adcl $0, %eax
378	4: andl $3, %ecx
379	jz 7f
380	cmpl $2, %ecx
381	jb 5f
382	SRC( movw (%esi), %cx )
383	leal 2(%esi), %esi
384	DST( movw %cx, (%edi) )
385	leal 2(%edi), %edi
386	je 6f
387	shll $16,%ecx
388	SRC(5: movb (%esi), %cl )
389	DST( movb %cl, (%edi) )
390	6: addl %ecx, %eax
391	adcl $0, %eax
392	7:
393	5000:
394
395	# Exception handler:
396	.section .fixup, "ax"
397
398	6001:
399	movl ARGBASE+20(%esp), %ebx # src_err_ptr
400	movl $-EFAULT, (%ebx)
401
402	# zero the complete destination - computing the rest
403	# is too much work
404	movl ARGBASE+8(%esp), %edi # dst
405	movl ARGBASE+12(%esp), %ecx # len
406	xorl %eax,%eax
407	rep ; stosb
408
409	jmp 5000b
410
411	6002:
412	movl ARGBASE+24(%esp), %ebx # dst_err_ptr
413	movl $-EFAULT,(%ebx)
414	jmp 5000b
415
416	.previous
417
60cf637a	418	popl_cfi %ebx
00e065ea	419	CFI_RESTORE ebx
60cf637a	420	popl_cfi %esi
00e065ea	421	CFI_RESTORE esi
60cf637a	422	popl_cfi %edi
00e065ea	423	CFI_RESTORE edi
60cf637a	424	popl_cfi %ecx # equivalent to addl $4,%esp
1da177e4	425	ret
00e065ea JB	426	CFI_ENDPROC
00e065ea JB	427	ENDPROC(csum_partial_copy_generic)
1da177e4 LT	428
	429	#else
	430
	431	/* Version for PentiumII/PPro */
	432
	433	#define ROUND1(x) \
	434	SRC(movl x(%esi), %ebx ) ; \
	435	addl %ebx, %eax ; \
	436	DST(movl %ebx, x(%edi) ) ;
	437
	438	#define ROUND(x) \
	439	SRC(movl x(%esi), %ebx ) ; \
	440	adcl %ebx, %eax ; \
	441	DST(movl %ebx, x(%edi) ) ;
	442
	443	#define ARGBASE 12
	444
00e065ea JB	445	ENTRY(csum_partial_copy_generic)
00e065ea JB	446	CFI_STARTPROC
60cf637a	447	pushl_cfi %ebx
00e065ea	448	CFI_REL_OFFSET ebx, 0
60cf637a	449	pushl_cfi %edi
00e065ea	450	CFI_REL_OFFSET edi, 0
60cf637a	451	pushl_cfi %esi
00e065ea	452	CFI_REL_OFFSET esi, 0
1da177e4 LT	453	movl ARGBASE+4(%esp),%esi #src
	454	movl ARGBASE+8(%esp),%edi #dst
	455	movl ARGBASE+12(%esp),%ecx #len
	456	movl ARGBASE+16(%esp),%eax #sum
	457	# movl %ecx, %edx
	458	movl %ecx, %ebx
	459	movl %esi, %edx
	460	shrl $6, %ecx
	461	andl $0x3c, %ebx
	462	negl %ebx
	463	subl %ebx, %esi
	464	subl %ebx, %edi
	465	lea -1(%esi),%edx
	466	andl $-32,%edx
	467	lea 3f(%ebx,%ebx), %ebx
	468	testl %esi, %esi
	469	jmp *%ebx
	470	1: addl $64,%esi
	471	addl $64,%edi
	472	SRC(movb -32(%edx),%bl) ; SRC(movb (%edx),%bl)
	473	ROUND1(-64) ROUND(-60) ROUND(-56) ROUND(-52)
	474	ROUND (-48) ROUND(-44) ROUND(-40) ROUND(-36)
	475	ROUND (-32) ROUND(-28) ROUND(-24) ROUND(-20)
	476	ROUND (-16) ROUND(-12) ROUND(-8) ROUND(-4)
	477	3: adcl $0,%eax
	478	addl $64, %edx
	479	dec %ecx
	480	jge 1b
	481	4: movl ARGBASE+12(%esp),%edx #len
	482	andl $3, %edx
	483	jz 7f
	484	cmpl $2, %edx
	485	jb 5f
	486	SRC( movw (%esi), %dx )
	487	leal 2(%esi), %esi
	488	DST( movw %dx, (%edi) )
	489	leal 2(%edi), %edi
	490	je 6f
	491	shll $16,%edx
	492	5:
	493	SRC( movb (%esi), %dl )
	494	DST( movb %dl, (%edi) )
	495	6: addl %edx, %eax
	496	adcl $0, %eax
	497	7:
	498	.section .fixup, "ax"
	499	6001: movl ARGBASE+20(%esp), %ebx # src_err_ptr
	500	movl $-EFAULT, (%ebx)
	501	# zero the complete destination (computing the rest is too much work)
	502	movl ARGBASE+8(%esp),%edi # dst
	503	movl ARGBASE+12(%esp),%ecx # len
	504	xorl %eax,%eax
	505	rep; stosb
	506	jmp 7b
	507	6002: movl ARGBASE+24(%esp), %ebx # dst_err_ptr
	508	movl $-EFAULT, (%ebx)
	509	jmp 7b
	510	.previous
	511
60cf637a	512	popl_cfi %esi
00e065ea	513	CFI_RESTORE esi
60cf637a	514	popl_cfi %edi
00e065ea	515	CFI_RESTORE edi
60cf637a	516	popl_cfi %ebx
00e065ea	517	CFI_RESTORE ebx
1da177e4	518	ret
00e065ea JB	519	CFI_ENDPROC
00e065ea JB	520	ENDPROC(csum_partial_copy_generic)
1da177e4 LT	521
	522	#undef ROUND
	523	#undef ROUND1
	524
	525	#endif