Commit | Line | Data |
---|---|---|
07ad157f RR |
1 | #include <linux/linkage.h> |
2 | #include <linux/lguest.h> | |
47436aa4 | 3 | #include <asm/lguest_hcall.h> |
07ad157f RR |
4 | #include <asm/asm-offsets.h> |
5 | #include <asm/thread_info.h> | |
876be9d8 | 6 | #include <asm/processor-flags.h> |
07ad157f | 7 | |
2e04ef76 RR |
8 | /*G:020 |
9 | * Our story starts with the kernel booting into startup_32 in | |
a6bd8e13 RR |
10 | * arch/x86/kernel/head_32.S. It expects a boot header, which is created by |
11 | * the bootloader (the Launcher in our case). | |
12 | * | |
13 | * The startup_32 function does very little: it clears the uninitialized global | |
14 | * C variables which we expect to be zero (ie. BSS) and then copies the boot | |
15 | * header and kernel command line somewhere safe. Finally it checks the | |
16 | * 'hardware_subarch' field. This was introduced in 2.6.24 for lguest and Xen: | |
17 | * if it's set to '1' (lguest's assigned number), then it calls us here. | |
47436aa4 RR |
18 | * |
19 | * WARNING: be very careful here! We're running at addresses equal to physical | |
20 | * addesses (around 0), not above PAGE_OFFSET as most code expectes | |
21 | * (eg. 0xC0000000). Jumps are relative, so they're OK, but we can't touch any | |
a6bd8e13 | 22 | * data without remembering to subtract __PAGE_OFFSET! |
07ad157f | 23 | * |
b2b47c21 | 24 | * The .section line puts this code in .init.text so it will be discarded after |
2e04ef76 RR |
25 | * boot. |
26 | */ | |
07ad157f | 27 | .section .init.text, "ax", @progbits |
814a0e5c | 28 | ENTRY(lguest_entry) |
2e04ef76 RR |
29 | /* |
30 | * We make the "initialization" hypercall now to tell the Host about | |
31 | * us, and also find out where it put our page tables. | |
32 | */ | |
47436aa4 | 33 | movl $LHCALL_LGUEST_INIT, %eax |
4cd8b5e2 | 34 | movl $lguest_data - __PAGE_OFFSET, %ebx |
091ebf07 | 35 | int $LGUEST_TRAP_ENTRY |
47436aa4 | 36 | |
47436aa4 RR |
37 | /* Set up the initial stack so we can run C code. */ |
38 | movl $(init_thread_union+THREAD_SIZE),%esp | |
39 | ||
2e04ef76 | 40 | /* Jumps are relative: we're running __PAGE_OFFSET too low. */ |
47436aa4 | 41 | jmp lguest_init+__PAGE_OFFSET |
07ad157f | 42 | |
2e04ef76 RR |
43 | /*G:055 |
44 | * We create a macro which puts the assembler code between lgstart_ and lgend_ | |
45 | * markers. These templates are put in the .text section: they can't be | |
46 | * discarded after boot as we may need to patch modules, too. | |
47 | */ | |
bbbd2bf0 | 48 | .text |
07ad157f RR |
49 | #define LGUEST_PATCH(name, insns...) \ |
50 | lgstart_##name: insns; lgend_##name:; \ | |
51 | .globl lgstart_##name; .globl lgend_##name | |
52 | ||
53 | LGUEST_PATCH(cli, movl $0, lguest_data+LGUEST_DATA_irq_enabled) | |
07ad157f | 54 | LGUEST_PATCH(pushf, movl lguest_data+LGUEST_DATA_irq_enabled, %eax) |
61f4bc83 | 55 | |
2e04ef76 RR |
56 | /*G:033 |
57 | * But using those wrappers is inefficient (we'll see why that doesn't matter | |
58 | * for save_fl and irq_disable later). If we write our routines carefully in | |
59 | * assembler, we can avoid clobbering any registers and avoid jumping through | |
60 | * the wrapper functions. | |
61f4bc83 RR |
61 | * |
62 | * I skipped over our first piece of assembler, but this one is worth studying | |
2e04ef76 RR |
63 | * in a bit more detail so I'll describe in easy stages. First, the routine to |
64 | * enable interrupts: | |
65 | */ | |
61f4bc83 | 66 | ENTRY(lg_irq_enable) |
2e04ef76 RR |
67 | /* |
68 | * The reverse of irq_disable, this sets lguest_data.irq_enabled to | |
69 | * X86_EFLAGS_IF (ie. "Interrupts enabled"). | |
70 | */ | |
61f4bc83 | 71 | movl $X86_EFLAGS_IF, lguest_data+LGUEST_DATA_irq_enabled |
2e04ef76 RR |
72 | /* |
73 | * But now we need to check if the Host wants to know: there might have | |
61f4bc83 RR |
74 | * been interrupts waiting to be delivered, in which case it will have |
75 | * set lguest_data.irq_pending to X86_EFLAGS_IF. If it's not zero, we | |
2e04ef76 RR |
76 | * jump to send_interrupts, otherwise we're done. |
77 | */ | |
61f4bc83 RR |
78 | testl $0, lguest_data+LGUEST_DATA_irq_pending |
79 | jnz send_interrupts | |
2e04ef76 RR |
80 | /* |
81 | * One cool thing about x86 is that you can do many things without using | |
61f4bc83 | 82 | * a register. In this case, the normal path hasn't needed to save or |
2e04ef76 RR |
83 | * restore any registers at all! |
84 | */ | |
61f4bc83 RR |
85 | ret |
86 | send_interrupts: | |
2e04ef76 RR |
87 | /* |
88 | * OK, now we need a register: eax is used for the hypercall number, | |
61f4bc83 RR |
89 | * which is LHCALL_SEND_INTERRUPTS. |
90 | * | |
91 | * We used not to bother with this pending detection at all, which was | |
92 | * much simpler. Sooner or later the Host would realize it had to | |
93 | * send us an interrupt. But that turns out to make performance 7 | |
94 | * times worse on a simple tcp benchmark. So now we do this the hard | |
2e04ef76 RR |
95 | * way. |
96 | */ | |
61f4bc83 RR |
97 | pushl %eax |
98 | movl $LHCALL_SEND_INTERRUPTS, %eax | |
2e04ef76 RR |
99 | /* |
100 | * This is a vmcall instruction (same thing that KVM uses). Older | |
61f4bc83 | 101 | * assembler versions might not know the "vmcall" instruction, so we |
2e04ef76 RR |
102 | * create one manually here. |
103 | */ | |
61f4bc83 | 104 | .byte 0x0f,0x01,0xc1 /* KVM_HYPERCALL */ |
a91d74a3 | 105 | /* Put eax back the way we found it. */ |
61f4bc83 RR |
106 | popl %eax |
107 | ret | |
108 | ||
2e04ef76 RR |
109 | /* |
110 | * Finally, the "popf" or "restore flags" routine. The %eax register holds the | |
61f4bc83 | 111 | * flags (in practice, either X86_EFLAGS_IF or 0): if it's X86_EFLAGS_IF we're |
2e04ef76 RR |
112 | * enabling interrupts again, if it's 0 we're leaving them off. |
113 | */ | |
61f4bc83 RR |
114 | ENTRY(lg_restore_fl) |
115 | /* This is just "lguest_data.irq_enabled = flags;" */ | |
116 | movl %eax, lguest_data+LGUEST_DATA_irq_enabled | |
2e04ef76 RR |
117 | /* |
118 | * Now, if the %eax value has enabled interrupts and | |
61f4bc83 RR |
119 | * lguest_data.irq_pending is set, we want to tell the Host so it can |
120 | * deliver any outstanding interrupts. Fortunately, both values will | |
121 | * be X86_EFLAGS_IF (ie. 512) in that case, and the "testl" | |
122 | * instruction will AND them together for us. If both are set, we | |
2e04ef76 RR |
123 | * jump to send_interrupts. |
124 | */ | |
61f4bc83 RR |
125 | testl lguest_data+LGUEST_DATA_irq_pending, %eax |
126 | jnz send_interrupts | |
127 | /* Again, the normal path has used no extra registers. Clever, huh? */ | |
128 | ret | |
a91d74a3 | 129 | /*:*/ |
07ad157f | 130 | |
07ad157f RR |
131 | /* These demark the EIP range where host should never deliver interrupts. */ |
132 | .global lguest_noirq_start | |
133 | .global lguest_noirq_end | |
134 | ||
2e04ef76 RR |
135 | /*M:004 |
136 | * When the Host reflects a trap or injects an interrupt into the Guest, it | |
137 | * sets the eflags interrupt bit on the stack based on lguest_data.irq_enabled, | |
138 | * so the Guest iret logic does the right thing when restoring it. However, | |
139 | * when the Host sets the Guest up for direct traps, such as system calls, the | |
140 | * processor is the one to push eflags onto the stack, and the interrupt bit | |
141 | * will be 1 (in reality, interrupts are always enabled in the Guest). | |
f56a384e RR |
142 | * |
143 | * This turns out to be harmless: the only trap which should happen under Linux | |
144 | * with interrupts disabled is Page Fault (due to our lazy mapping of vmalloc | |
145 | * regions), which has to be reflected through the Host anyway. If another | |
146 | * trap *does* go off when interrupts are disabled, the Guest will panic, and | |
2e04ef76 RR |
147 | * we'll never get to this iret! |
148 | :*/ | |
f56a384e | 149 | |
2e04ef76 RR |
150 | /*G:045 |
151 | * There is one final paravirt_op that the Guest implements, and glancing at it | |
152 | * you can see why I left it to last. It's *cool*! It's in *assembler*! | |
b2b47c21 RR |
153 | * |
154 | * The "iret" instruction is used to return from an interrupt or trap. The | |
155 | * stack looks like this: | |
156 | * old address | |
157 | * old code segment & privilege level | |
158 | * old processor flags ("eflags") | |
159 | * | |
160 | * The "iret" instruction pops those values off the stack and restores them all | |
161 | * at once. The only problem is that eflags includes the Interrupt Flag which | |
162 | * the Guest can't change: the CPU will simply ignore it when we do an "iret". | |
163 | * So we have to copy eflags from the stack to lguest_data.irq_enabled before | |
164 | * we do the "iret". | |
165 | * | |
166 | * There are two problems with this: firstly, we need to use a register to do | |
167 | * the copy and secondly, the whole thing needs to be atomic. The first | |
168 | * problem is easy to solve: push %eax on the stack so we can use it, and then | |
169 | * restore it at the end just before the real "iret". | |
170 | * | |
171 | * The second is harder: copying eflags to lguest_data.irq_enabled will turn | |
172 | * interrupts on before we're finished, so we could be interrupted before we | |
173 | * return to userspace or wherever. Our solution to this is to surround the | |
174 | * code with lguest_noirq_start: and lguest_noirq_end: labels. We tell the | |
175 | * Host that it is *never* to interrupt us there, even if interrupts seem to be | |
2e04ef76 RR |
176 | * enabled. |
177 | */ | |
07ad157f RR |
178 | ENTRY(lguest_iret) |
179 | pushl %eax | |
180 | movl 12(%esp), %eax | |
181 | lguest_noirq_start: | |
2e04ef76 RR |
182 | /* |
183 | * Note the %ss: segment prefix here. Normal data accesses use the | |
b2b47c21 RR |
184 | * "ds" segment, but that will have already been restored for whatever |
185 | * we're returning to (such as userspace): we can't trust it. The %ss: | |
2e04ef76 RR |
186 | * prefix makes sure we use the stack segment, which is still valid. |
187 | */ | |
07ad157f RR |
188 | movl %eax,%ss:lguest_data+LGUEST_DATA_irq_enabled |
189 | popl %eax | |
190 | iret | |
191 | lguest_noirq_end: |