[linux-2.6-block.git] / arch / x86 / kernel / head_64.S

/*
 *  linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
 *
 *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
 *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
 *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
 *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
 *  Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
 */


#include <linux/linkage.h>
#include <linux/threads.h>
#include <linux/init.h>
#include <asm/segment.h>
#include <asm/pgtable.h>
#include <asm/page.h>
#include <asm/msr.h>
#include <asm/cache.h>
#include <asm/processor-flags.h>
#include <asm/percpu.h>

#ifdef CONFIG_PARAVIRT
#include <asm/asm-offsets.h>
#include <asm/paravirt.h>
#else
#define GET_CR2_INTO_RCX movq %cr2, %rcx
#endif

/* we are not able to switch in one step to the final KERNEL ADDRESS SPACE
 * because we need identity-mapped pages.
 *
 */

#define pud_index(x)	(((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))

L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
L3_PAGE_OFFSET = pud_index(__PAGE_OFFSET)
L4_START_KERNEL = pgd_index(__START_KERNEL_map)
L3_START_KERNEL = pud_index(__START_KERNEL_map)

	.text
	__HEAD
	.code64
	.globl startup_64
startup_64:

	/*
	 * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	 * and someone has loaded an identity mapped page table
	 * for us.  These identity mapped page tables map all of the
	 * kernel pages and possibly all of memory.
	 *
	 * %esi holds a physical pointer to real_mode_data.
	 *
	 * We come here either directly from a 64bit bootloader, or from
	 * arch/x86_64/boot/compressed/head.S.
	 *
	 * We only come here initially at boot nothing else comes here.
	 *
	 * Since we may be loaded at an address different from what we were
	 * compiled to run at we first fixup the physical addresses in our page
	 * tables and then reload them.
	 */

	/* Compute the delta between the address I am compiled to run at and the
	 * address I am actually running at.
	 */
	leaq	_text(%rip), %rbp
	subq	$_text - __START_KERNEL_map, %rbp

	/* Is the address not 2M aligned? */
	movq	%rbp, %rax
	andl	$~PMD_PAGE_MASK, %eax
	testl	%eax, %eax
	jnz	bad_address

	/* Is the address too large? */
	leaq	_text(%rip), %rdx
	movq	$PGDIR_SIZE, %rax
	cmpq	%rax, %rdx
	jae	bad_address

	/* Fixup the physical addresses in the page table
	 */
	addq	%rbp, init_level4_pgt + 0(%rip)
	addq	%rbp, init_level4_pgt + (L4_PAGE_OFFSET*8)(%rip)
	addq	%rbp, init_level4_pgt + (L4_START_KERNEL*8)(%rip)

	addq	%rbp, level3_ident_pgt + 0(%rip)

	addq	%rbp, level3_kernel_pgt + (510*8)(%rip)
	addq	%rbp, level3_kernel_pgt + (511*8)(%rip)

	addq	%rbp, level2_fixmap_pgt + (506*8)(%rip)

	/* Add an Identity mapping if I am above 1G */
	leaq	_text(%rip), %rdi
	andq	$PMD_PAGE_MASK, %rdi

	movq	%rdi, %rax
	shrq	$PUD_SHIFT, %rax
	andq	$(PTRS_PER_PUD - 1), %rax
	jz	ident_complete

	leaq	(level2_spare_pgt - __START_KERNEL_map + _KERNPG_TABLE)(%rbp), %rdx
	leaq	level3_ident_pgt(%rip), %rbx
	movq	%rdx, 0(%rbx, %rax, 8)

	movq	%rdi, %rax
	shrq	$PMD_SHIFT, %rax
	andq	$(PTRS_PER_PMD - 1), %rax
	leaq	__PAGE_KERNEL_IDENT_LARGE_EXEC(%rdi), %rdx
	leaq	level2_spare_pgt(%rip), %rbx
	movq	%rdx, 0(%rbx, %rax, 8)
ident_complete:

	/*
	 * Fixup the kernel text+data virtual addresses. Note that
	 * we might write invalid pmds, when the kernel is relocated
	 * cleanup_highmap() fixes this up along with the mappings
	 * beyond _end.
	 */

	leaq	level2_kernel_pgt(%rip), %rdi
	leaq	4096(%rdi), %r8
	/* See if it is a valid page table entry */
1:	testq	$1, 0(%rdi)
	jz	2f
	addq	%rbp, 0(%rdi)
	/* Go to the next page */
2:	addq	$8, %rdi
	cmp	%r8, %rdi
	jne	1b

	/* Fixup phys_base */
	addq	%rbp, phys_base(%rip)

	/* Fixup trampoline */
	addq	%rbp, trampoline_level4_pgt + 0(%rip)
	addq	%rbp, trampoline_level4_pgt + (511*8)(%rip)

	/* Due to ENTRY(), sometimes the empty space gets filled with
	 * zeros. Better take a jmp than relying on empty space being
	 * filled with 0x90 (nop)
	 */
	jmp secondary_startup_64
ENTRY(secondary_startup_64)
	/*
	 * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	 * and someone has loaded a mapped page table.
	 *
	 * %esi holds a physical pointer to real_mode_data.
	 *
	 * We come here either from startup_64 (using physical addresses)
	 * or from trampoline.S (using virtual addresses).
	 *
	 * Using virtual addresses from trampoline.S removes the need
	 * to have any identity mapped pages in the kernel page table
	 * after the boot processor executes this code.
	 */

	/* Enable PAE mode and PGE */
	movl	$(X86_CR4_PAE | X86_CR4_PGE), %eax
	movq	%rax, %cr4

	/* Setup early boot stage 4 level pagetables. */
	movq	$(init_level4_pgt - __START_KERNEL_map), %rax
	addq	phys_base(%rip), %rax
	movq	%rax, %cr3

	/* Ensure I am executing from virtual addresses */
	movq	$1f, %rax
	jmp	*%rax
1:

	/* Check if nx is implemented */
	movl	$0x80000001, %eax
	cpuid
	movl	%edx,%edi

	/* Setup EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr
	btsl	$_EFER_SCE, %eax	/* Enable System Call */
	btl	$20,%edi		/* No Execute supported? */
	jnc     1f
	btsl	$_EFER_NX, %eax
1:	wrmsr				/* Make changes effective */

	/* Setup cr0 */
#define CR0_STATE	(X86_CR0_PE | X86_CR0_MP | X86_CR0_ET | \
			 X86_CR0_NE | X86_CR0_WP | X86_CR0_AM | \
			 X86_CR0_PG)
	movl	$CR0_STATE, %eax
	/* Make changes effective */
	movq	%rax, %cr0

	/* Setup a boot time stack */
	movq stack_start(%rip),%rsp

	/* zero EFLAGS after setting rsp */
	pushq $0
	popfq

	/*
	 * We must switch to a new descriptor in kernel space for the GDT
	 * because soon the kernel won't have access anymore to the userspace
	 * addresses where we're currently running on. We have to do that here
	 * because in 32bit we couldn't load a 64bit linear address.
	 */
	lgdt	early_gdt_descr(%rip)

	/* set up data segments */
	xorl %eax,%eax
	movl %eax,%ds
	movl %eax,%ss
	movl %eax,%es

	/*
	 * We don't really need to load %fs or %gs, but load them anyway
	 * to kill any stale realmode selectors.  This allows execution
	 * under VT hardware.
	 */
	movl %eax,%fs
	movl %eax,%gs

	/* Set up %gs.
	 *
	 * The base of %gs always points to the bottom of the irqstack
	 * union.  If the stack protector canary is enabled, it is
	 * located at %gs:40.  Note that, on SMP, the boot cpu uses
	 * init data section till per cpu areas are set up.
	 */
	movl	$MSR_GS_BASE,%ecx
	movl	initial_gs(%rip),%eax
	movl	initial_gs+4(%rip),%edx
	wrmsr	

	/* esi is pointer to real mode structure with interesting info.
	   pass it to C */
	movl	%esi, %edi
	
	/* Finally jump to run C code and to be on real kernel address
	 * Since we are running on identity-mapped space we have to jump
	 * to the full 64bit address, this is only possible as indirect
	 * jump.  In addition we need to ensure %cs is set so we make this
	 * a far return.
	 */
	movq	initial_code(%rip),%rax
	pushq	$0		# fake return address to stop unwinder
	pushq	$__KERNEL_CS	# set correct cs
	pushq	%rax		# target address in negative space
	lretq

	/* SMP bootup changes these two */
	__REFDATA
	.align	8
	ENTRY(initial_code)
	.quad	x86_64_start_kernel
	ENTRY(initial_gs)
	.quad	INIT_PER_CPU_VAR(irq_stack_union)

	ENTRY(stack_start)
	.quad  init_thread_union+THREAD_SIZE-8
	.word  0
	__FINITDATA

bad_address:
	jmp bad_address

	.section ".init.text","ax"
#ifdef CONFIG_EARLY_PRINTK
	.globl early_idt_handlers
early_idt_handlers:
	i = 0
	.rept NUM_EXCEPTION_VECTORS
	movl $i, %esi
	jmp early_idt_handler
	i = i + 1
	.endr
#endif

ENTRY(early_idt_handler)
#ifdef CONFIG_EARLY_PRINTK
	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	incl early_recursion_flag(%rip)
	GET_CR2_INTO_RCX
	movq %rcx,%r9
	xorl %r8d,%r8d		# zero for error code
	movl %esi,%ecx		# get vector number
	# Test %ecx against mask of vectors that push error code.
	cmpl $31,%ecx
	ja 0f
	movl $1,%eax
	salq %cl,%rax
	testl $0x27d00,%eax
	je 0f
	popq %r8		# get error code
0:	movq 0(%rsp),%rcx	# get ip
	movq 8(%rsp),%rdx	# get cs
	xorl %eax,%eax
	leaq early_idt_msg(%rip),%rdi
	call early_printk
	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	call dump_stack
#ifdef CONFIG_KALLSYMS	
	leaq early_idt_ripmsg(%rip),%rdi
	movq 0(%rsp),%rsi	# get rip again
	call __print_symbol
#endif
#endif /* EARLY_PRINTK */
1:	hlt
	jmp 1b

#ifdef CONFIG_EARLY_PRINTK
early_recursion_flag:
	.long 0

early_idt_msg:
	.asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
early_idt_ripmsg:
	.asciz "RIP %s\n"
#endif /* CONFIG_EARLY_PRINTK */
	.previous

#define NEXT_PAGE(name) \
	.balign	PAGE_SIZE; \
ENTRY(name)

/* Automate the creation of 1 to 1 mapping pmd entries */
#define PMDS(START, PERM, COUNT)			\
	i = 0 ;						\
	.rept (COUNT) ;					\
	.quad	(START) + (i << PMD_SHIFT) + (PERM) ;	\
	i = i + 1 ;					\
	.endr

	.data
	/*
	 * This default setting generates an ident mapping at address 0x100000
	 * and a mapping for the kernel that precisely maps virtual address
	 * 0xffffffff80000000 to physical address 0x000000. (always using
	 * 2Mbyte large pages provided by PAE mode)
	 */
NEXT_PAGE(init_level4_pgt)
	.quad	level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.org	init_level4_pgt + L4_PAGE_OFFSET*8, 0
	.quad	level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.org	init_level4_pgt + L4_START_KERNEL*8, 0
	/* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
	.quad	level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE

NEXT_PAGE(level3_ident_pgt)
	.quad	level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.fill	511,8,0

NEXT_PAGE(level3_kernel_pgt)
	.fill	L3_START_KERNEL,8,0
	/* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
	.quad	level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.quad	level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE

NEXT_PAGE(level2_fixmap_pgt)
	.fill	506,8,0
	.quad	level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	/* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
	.fill	5,8,0

NEXT_PAGE(level1_fixmap_pgt)
	.fill	512,8,0

NEXT_PAGE(level2_ident_pgt)
	/* Since I easily can, map the first 1G.
	 * Don't set NX because code runs from these pages.
	 */
	PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)

NEXT_PAGE(level2_kernel_pgt)
	/*
	 * 512 MB kernel mapping. We spend a full page on this pagetable
	 * anyway.
	 *
	 * The kernel code+data+bss must not be bigger than that.
	 *
	 * (NOTE: at +512MB starts the module area, see MODULES_VADDR.
	 *  If you want to increase this then increase MODULES_VADDR
	 *  too.)
	 */
	PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
		KERNEL_IMAGE_SIZE/PMD_SIZE)

NEXT_PAGE(level2_spare_pgt)
	.fill   512, 8, 0

#undef PMDS
#undef NEXT_PAGE

	.data
	.align 16
	.globl early_gdt_descr
early_gdt_descr:
	.word	GDT_ENTRIES*8-1
early_gdt_descr_base:
	.quad	INIT_PER_CPU_VAR(gdt_page)

ENTRY(phys_base)
	/* This must match the first entry in level2_kernel_pgt */
	.quad   0x0000000000000000

#include "../../x86/xen/xen-head.S"
	
	.section .bss, "aw", @nobits
	.align L1_CACHE_BYTES
ENTRY(idt_table)
	.skip IDT_ENTRIES * 16

	.align L1_CACHE_BYTES
ENTRY(nmi_idt_table)
	.skip IDT_ENTRIES * 16

	__PAGE_ALIGNED_BSS
	.align PAGE_SIZE
ENTRY(empty_zero_page)
	.skip PAGE_SIZE
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
	3	*
	4	* Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
	5	* Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
	6	* Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
	7	* Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
1ab60e0f	8	* Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
1da177e4 LT	9	*/
	10
	11
	12	#include <linux/linkage.h>
	13	#include <linux/threads.h>
f6c2e333	14	#include <linux/init.h>
1da177e4	15	#include <asm/segment.h>
67dcbb6b	16	#include <asm/pgtable.h>
1da177e4 LT	17	#include <asm/page.h>
	18	#include <asm/msr.h>
	19	#include <asm/cache.h>
369101da	20	#include <asm/processor-flags.h>
b12d8db8	21	#include <asm/percpu.h>
1ab60e0f	22
49a69787 GOC	23	#ifdef CONFIG_PARAVIRT
	24	#include <asm/asm-offsets.h>
	25	#include <asm/paravirt.h>
	26	#else
	27	#define GET_CR2_INTO_RCX movq %cr2, %rcx
	28	#endif
	29
3ad2f3fb	30	/* we are not able to switch in one step to the final KERNEL ADDRESS SPACE
1ab60e0f VG	31	* because we need identity-mapped pages.
1ab60e0f VG	32	*
1da177e4 LT	33	*/
1da177e4 LT	34
a6523748 EH	35	#define pud_index(x) (((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))
	36
	37	L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
	38	L3_PAGE_OFFSET = pud_index(__PAGE_OFFSET)
	39	L4_START_KERNEL = pgd_index(__START_KERNEL_map)
	40	L3_START_KERNEL = pud_index(__START_KERNEL_map)
	41
1da177e4	42	.text
4ae59b91	43	__HEAD
1ab60e0f VG	44	.code64
	45	.globl startup_64
	46	startup_64:
	47
1da177e4	48	/*
1ab60e0f VG	49	* At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	50	* and someone has loaded an identity mapped page table
	51	* for us. These identity mapped page tables map all of the
	52	* kernel pages and possibly all of memory.
	53	*
	54	* %esi holds a physical pointer to real_mode_data.
	55	*
	56	* We come here either directly from a 64bit bootloader, or from
	57	* arch/x86_64/boot/compressed/head.S.
	58	*
	59	* We only come here initially at boot nothing else comes here.
	60	*
	61	* Since we may be loaded at an address different from what we were
	62	* compiled to run at we first fixup the physical addresses in our page
	63	* tables and then reload them.
1da177e4 LT	64	*/
1da177e4 LT	65
1ab60e0f VG	66	/* Compute the delta between the address I am compiled to run at and the
1ab60e0f VG	67	* address I am actually running at.
1da177e4	68	*/
1ab60e0f VG	69	leaq _text(%rip), %rbp
	70	subq $_text - __START_KERNEL_map, %rbp
	71
	72	/* Is the address not 2M aligned? */
	73	movq %rbp, %rax
31422c51	74	andl $~PMD_PAGE_MASK, %eax
1ab60e0f VG	75	testl %eax, %eax
	76	jnz bad_address
	77
	78	/* Is the address too large? */
	79	leaq _text(%rip), %rdx
	80	movq $PGDIR_SIZE, %rax
	81	cmpq %rax, %rdx
	82	jae bad_address
	83
	84	/* Fixup the physical addresses in the page table
1da177e4	85	*/
1ab60e0f	86	addq %rbp, init_level4_pgt + 0(%rip)
a6523748 EH	87	addq %rbp, init_level4_pgt + (L4_PAGE_OFFSET*8)(%rip)
a6523748 EH	88	addq %rbp, init_level4_pgt + (L4_START_KERNEL*8)(%rip)
1ab60e0f VG	89
1ab60e0f VG	90	addq %rbp, level3_ident_pgt + 0(%rip)
b1c931e3	91
1ab60e0f	92	addq %rbp, level3_kernel_pgt + (510*8)(%rip)
b1c931e3 EB	93	addq %rbp, level3_kernel_pgt + (511*8)(%rip)
	94
	95	addq %rbp, level2_fixmap_pgt + (506*8)(%rip)
1ab60e0f VG	96
	97	/* Add an Identity mapping if I am above 1G */
	98	leaq _text(%rip), %rdi
31422c51	99	andq $PMD_PAGE_MASK, %rdi
1ab60e0f VG	100
	101	movq %rdi, %rax
	102	shrq $PUD_SHIFT, %rax
	103	andq $(PTRS_PER_PUD - 1), %rax
	104	jz ident_complete
	105
	106	leaq (level2_spare_pgt - __START_KERNEL_map + _KERNPG_TABLE)(%rbp), %rdx
	107	leaq level3_ident_pgt(%rip), %rbx
	108	movq %rdx, 0(%rbx, %rax, 8)
	109
	110	movq %rdi, %rax
	111	shrq $PMD_SHIFT, %rax
	112	andq $(PTRS_PER_PMD - 1), %rax
b2bc2731	113	leaq __PAGE_KERNEL_IDENT_LARGE_EXEC(%rdi), %rdx
1ab60e0f VG	114	leaq level2_spare_pgt(%rip), %rbx
	115	movq %rdx, 0(%rbx, %rax, 8)
	116	ident_complete:
	117
31eedd82 TG	118	/*
	119	* Fixup the kernel text+data virtual addresses. Note that
	120	* we might write invalid pmds, when the kernel is relocated
	121	* cleanup_highmap() fixes this up along with the mappings
	122	* beyond _end.
1ab60e0f	123	*/
31eedd82	124
1ab60e0f VG	125	leaq level2_kernel_pgt(%rip), %rdi
	126	leaq 4096(%rdi), %r8
	127	/* See if it is a valid page table entry */
	128	1: testq $1, 0(%rdi)
	129	jz 2f
	130	addq %rbp, 0(%rdi)
	131	/* Go to the next page */
	132	2: addq $8, %rdi
	133	cmp %r8, %rdi
	134	jne 1b
	135
	136	/* Fixup phys_base */
	137	addq %rbp, phys_base(%rip)
1da177e4	138
4822b7fc	139	/* Fixup trampoline */
1ab60e0f VG	140	addq %rbp, trampoline_level4_pgt + 0(%rip)
1ab60e0f VG	141	addq %rbp, trampoline_level4_pgt + (511*8)(%rip)
1da177e4	142
1ab60e0f VG	143	/* Due to ENTRY(), sometimes the empty space gets filled with
	144	* zeros. Better take a jmp than relying on empty space being
	145	* filled with 0x90 (nop)
1da177e4	146	*/
1ab60e0f	147	jmp secondary_startup_64
90b1c208	148	ENTRY(secondary_startup_64)
1ab60e0f VG	149	/*
	150	* At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	151	* and someone has loaded a mapped page table.
	152	*
	153	* %esi holds a physical pointer to real_mode_data.
	154	*
	155	* We come here either from startup_64 (using physical addresses)
	156	* or from trampoline.S (using virtual addresses).
	157	*
	158	* Using virtual addresses from trampoline.S removes the need
	159	* to have any identity mapped pages in the kernel page table
	160	* after the boot processor executes this code.
1da177e4 LT	161	*/
	162
	163	/* Enable PAE mode and PGE */
05139d8f	164	movl $(X86_CR4_PAE \| X86_CR4_PGE), %eax
1da177e4 LT	165	movq %rax, %cr4
	166
	167	/* Setup early boot stage 4 level pagetables. */
cfd243d4	168	movq $(init_level4_pgt - __START_KERNEL_map), %rax
1ab60e0f	169	addq phys_base(%rip), %rax
1da177e4 LT	170	movq %rax, %cr3
1da177e4 LT	171
1ab60e0f VG	172	/* Ensure I am executing from virtual addresses */
	173	movq $1f, %rax
	174	jmp *%rax
	175	1:
	176
1da177e4 LT	177	/* Check if nx is implemented */
	178	movl $0x80000001, %eax
	179	cpuid
	180	movl %edx,%edi
	181
	182	/* Setup EFER (Extended Feature Enable Register) */
	183	movl $MSR_EFER, %ecx
	184	rdmsr
1ab60e0f VG	185	btsl $_EFER_SCE, %eax /* Enable System Call */
1ab60e0f VG	186	btl $20,%edi /* No Execute supported? */
1da177e4 LT	187	jnc 1f
1da177e4 LT	188	btsl $_EFER_NX, %eax
1ab60e0f	189	1: wrmsr /* Make changes effective */
1da177e4 LT	190
1da177e4 LT	191	/* Setup cr0 */
369101da CG	192	#define CR0_STATE (X86_CR0_PE \| X86_CR0_MP \| X86_CR0_ET \| \
	193	X86_CR0_NE \| X86_CR0_WP \| X86_CR0_AM \| \
	194	X86_CR0_PG)
	195	movl $CR0_STATE, %eax
1da177e4 LT	196	/* Make changes effective */
	197	movq %rax, %cr0
	198
	199	/* Setup a boot time stack */
9cf4f298	200	movq stack_start(%rip),%rsp
1da177e4 LT	201
	202	/* zero EFLAGS after setting rsp */
	203	pushq $0
	204	popfq
	205
	206	/*
	207	* We must switch to a new descriptor in kernel space for the GDT
	208	* because soon the kernel won't have access anymore to the userspace
	209	* addresses where we're currently running on. We have to do that here
	210	* because in 32bit we couldn't load a 64bit linear address.
	211	*/
a939098a	212	lgdt early_gdt_descr(%rip)
1da177e4	213
8ec6993d BG	214	/* set up data segments */
8ec6993d BG	215	xorl %eax,%eax
ffb60175 ZA	216	movl %eax,%ds
	217	movl %eax,%ss
	218	movl %eax,%es
	219
	220	/*
	221	* We don't really need to load %fs or %gs, but load them anyway
	222	* to kill any stale realmode selectors. This allows execution
	223	* under VT hardware.
	224	*/
	225	movl %eax,%fs
	226	movl %eax,%gs
	227
f32ff538 TH	228	/* Set up %gs.
f32ff538 TH	229	*
947e76cd BG	230	* The base of %gs always points to the bottom of the irqstack
	231	* union. If the stack protector canary is enabled, it is
	232	* located at %gs:40. Note that, on SMP, the boot cpu uses
	233	* init data section till per cpu areas are set up.
f32ff538	234	*/
1da177e4	235	movl $MSR_GS_BASE,%ecx
650fb439 BG	236	movl initial_gs(%rip),%eax
650fb439 BG	237	movl initial_gs+4(%rip),%edx
1da177e4 LT	238	wrmsr
1da177e4 LT	239
1da177e4 LT	240	/* esi is pointer to real mode structure with interesting info.
	241	pass it to C */
	242	movl %esi, %edi
	243
	244	/* Finally jump to run C code and to be on real kernel address
	245	* Since we are running on identity-mapped space we have to jump
26374c7b EB	246	* to the full 64bit address, this is only possible as indirect
	247	* jump. In addition we need to ensure %cs is set so we make this
	248	* a far return.
1da177e4 LT	249	*/
1da177e4 LT	250	movq initial_code(%rip),%rax
26374c7b EB	251	pushq $0 # fake return address to stop unwinder
	252	pushq $__KERNEL_CS # set correct cs
	253	pushq %rax # target address in negative space
	254	lretq
1da177e4	255
e57113bc	256	/* SMP bootup changes these two */
da5968ae	257	__REFDATA
e57113bc	258	.align 8
f1fbabb3	259	ENTRY(initial_code)
1da177e4	260	.quad x86_64_start_kernel
f32ff538	261	ENTRY(initial_gs)
2add8e23	262	.quad INIT_PER_CPU_VAR(irq_stack_union)
f1fbabb3	263
9cf4f298	264	ENTRY(stack_start)
1da177e4	265	.quad init_thread_union+THREAD_SIZE-8
9cf4f298	266	.word 0
b9af7c0d	267	__FINITDATA
1da177e4	268
1ab60e0f VG	269	bad_address:
	270	jmp bad_address
	271
41bd4eac	272	.section ".init.text","ax"
076f9776	273	#ifdef CONFIG_EARLY_PRINTK
8866cd9d RM	274	.globl early_idt_handlers
8866cd9d RM	275	early_idt_handlers:
749c970a AK	276	i = 0
	277	.rept NUM_EXCEPTION_VECTORS
	278	movl $i, %esi
	279	jmp early_idt_handler
	280	i = i + 1
	281	.endr
076f9776	282	#endif
8866cd9d	283
1da177e4	284	ENTRY(early_idt_handler)
076f9776	285	#ifdef CONFIG_EARLY_PRINTK
b957591f AK	286	cmpl $2,early_recursion_flag(%rip)
	287	jz 1f
	288	incl early_recursion_flag(%rip)
49a69787	289	GET_CR2_INTO_RCX
8866cd9d RM	290	movq %rcx,%r9
	291	xorl %r8d,%r8d # zero for error code
	292	movl %esi,%ecx # get vector number
	293	# Test %ecx against mask of vectors that push error code.
	294	cmpl $31,%ecx
	295	ja 0f
	296	movl $1,%eax
	297	salq %cl,%rax
	298	testl $0x27d00,%eax
	299	je 0f
	300	popq %r8 # get error code
	301	0: movq 0(%rsp),%rcx # get ip
	302	movq 8(%rsp),%rdx # get cs
	303	xorl %eax,%eax
1da177e4 LT	304	leaq early_idt_msg(%rip),%rdi
1da177e4 LT	305	call early_printk
b957591f AK	306	cmpl $2,early_recursion_flag(%rip)
	307	jz 1f
	308	call dump_stack
6574ffd7 AK	309	#ifdef CONFIG_KALLSYMS
6574ffd7 AK	310	leaq early_idt_ripmsg(%rip),%rdi
7aed55d1	311	movq 0(%rsp),%rsi # get rip again
6574ffd7 AK	312	call __print_symbol
6574ffd7 AK	313	#endif
076f9776	314	#endif /* EARLY_PRINTK */
1da177e4 LT	315	1: hlt
1da177e4 LT	316	jmp 1b
076f9776 IM	317
076f9776 IM	318	#ifdef CONFIG_EARLY_PRINTK
b957591f AK	319	early_recursion_flag:
b957591f AK	320	.long 0
1da177e4 LT	321
1da177e4 LT	322	early_idt_msg:
8866cd9d	323	.asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
6574ffd7 AK	324	early_idt_ripmsg:
6574ffd7 AK	325	.asciz "RIP %s\n"
076f9776	326	#endif /* CONFIG_EARLY_PRINTK */
41bd4eac	327	.previous
1da177e4	328
f0cf5d1a	329	#define NEXT_PAGE(name) \
67dcbb6b	330	.balign PAGE_SIZE; \
f0cf5d1a JB	331	ENTRY(name)
f0cf5d1a JB	332
67dcbb6b	333	/* Automate the creation of 1 to 1 mapping pmd entries */
0e192b99 CG	334	#define PMDS(START, PERM, COUNT) \
	335	i = 0 ; \
	336	.rept (COUNT) ; \
	337	.quad (START) + (i << PMD_SHIFT) + (PERM) ; \
	338	i = i + 1 ; \
67dcbb6b VG	339	.endr
67dcbb6b VG	340
b9af7c0d	341	.data
cfd243d4 VG	342	/*
	343	* This default setting generates an ident mapping at address 0x100000
	344	* and a mapping for the kernel that precisely maps virtual address
	345	* 0xffffffff80000000 to physical address 0x000000. (always using
	346	* 2Mbyte large pages provided by PAE mode)
	347	*/
f0cf5d1a	348	NEXT_PAGE(init_level4_pgt)
cfd243d4	349	.quad level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
a6523748	350	.org init_level4_pgt + L4_PAGE_OFFSET*8, 0
cfd243d4	351	.quad level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
a6523748	352	.org init_level4_pgt + L4_START_KERNEL*8, 0
cfd243d4 VG	353	/* (2^48-(2102410241024))/(2^39) = 511 /
cfd243d4 VG	354	.quad level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE
1da177e4	355
f0cf5d1a	356	NEXT_PAGE(level3_ident_pgt)
67dcbb6b	357	.quad level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
1da177e4 LT	358	.fill 511,8,0
1da177e4 LT	359
f0cf5d1a	360	NEXT_PAGE(level3_kernel_pgt)
a6523748	361	.fill L3_START_KERNEL,8,0
1da177e4	362	/* (2^48-(2102410241024)-((2^39)511))/(2^30) = 510 */
67dcbb6b	363	.quad level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
b1c931e3 EB	364	.quad level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	365
	366	NEXT_PAGE(level2_fixmap_pgt)
6596f242 IM	367	.fill 506,8,0
	368	.quad level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	369	/* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
	370	.fill 5,8,0
	371
	372	NEXT_PAGE(level1_fixmap_pgt)
b1c931e3	373	.fill 512,8,0
1da177e4	374
f0cf5d1a	375	NEXT_PAGE(level2_ident_pgt)
67dcbb6b VG	376	/* Since I easily can, map the first 1G.
	377	* Don't set NX because code runs from these pages.
	378	*/
b2bc2731	379	PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)
1ab60e0f	380
f0cf5d1a	381	NEXT_PAGE(level2_kernel_pgt)
88f3aec7	382	/*
85eb69a1	383	* 512 MB kernel mapping. We spend a full page on this pagetable
88f3aec7 IM	384	* anyway.
	385	*
	386	* The kernel code+data+bss must not be bigger than that.
	387	*
85eb69a1	388	* (NOTE: at +512MB starts the module area, see MODULES_VADDR.
88f3aec7 IM	389	* If you want to increase this then increase MODULES_VADDR
	390	* too.)
	391	*/
8490638c	392	PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
d4afe414	393	KERNEL_IMAGE_SIZE/PMD_SIZE)
1da177e4	394
1ab60e0f	395	NEXT_PAGE(level2_spare_pgt)
88f3aec7	396	.fill 512, 8, 0
1ab60e0f	397
67dcbb6b	398	#undef PMDS
f0cf5d1a	399	#undef NEXT_PAGE
1da177e4	400
f0cf5d1a	401	.data
1da177e4	402	.align 16
a939098a GC	403	.globl early_gdt_descr
	404	early_gdt_descr:
	405	.word GDT_ENTRIES*8-1
3e5d8f97	406	early_gdt_descr_base:
2add8e23	407	.quad INIT_PER_CPU_VAR(gdt_page)
1da177e4	408
1ab60e0f VG	409	ENTRY(phys_base)
	410	/* This must match the first entry in level2_kernel_pgt */
	411	.quad 0x0000000000000000
	412
8c5e5ac3	413	#include "../../x86/xen/xen-head.S"
1da177e4	414
e57113bc JB	415	.section .bss, "aw", @nobits
	416	.align L1_CACHE_BYTES
	417	ENTRY(idt_table)
5e112ae2	418	.skip IDT_ENTRIES * 16
1da177e4	419
228bdaa9 SR	420	.align L1_CACHE_BYTES
	421	ENTRY(nmi_idt_table)
	422	.skip IDT_ENTRIES * 16
	423
02b7da37	424	__PAGE_ALIGNED_BSS
e57113bc JB	425	.align PAGE_SIZE
	426	ENTRY(empty_zero_page)
	427	.skip PAGE_SIZE