[linux-2.6-block.git] / arch / x86 / entry / calling.h

/* SPDX-License-Identifier: GPL-2.0 */
#include <linux/jump_label.h>
#include <asm/unwind_hints.h>
#include <asm/cpufeatures.h>
#include <asm/page_types.h>
#include <asm/percpu.h>
#include <asm/asm-offsets.h>
#include <asm/processor-flags.h>

/*

 x86 function call convention, 64-bit:
 -------------------------------------
  arguments           |  callee-saved      | extra caller-saved | return
 [callee-clobbered]   |                    | [callee-clobbered] |
 ---------------------------------------------------------------------------
 rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]

 ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
   functions when it sees tail-call optimization possibilities) rflags is
   clobbered. Leftover arguments are passed over the stack frame.)

 [*]  In the frame-pointers case rbp is fixed to the stack frame.

 [**] for struct return values wider than 64 bits the return convention is a
      bit more complex: up to 128 bits width we return small structures
      straight in rax, rdx. For structures larger than that (3 words or
      larger) the caller puts a pointer to an on-stack return struct
      [allocated in the caller's stack frame] into the first argument - i.e.
      into rdi. All other arguments shift up by one in this case.
      Fortunately this case is rare in the kernel.

For 32-bit we have the following conventions - kernel is built with
-mregparm=3 and -freg-struct-return:

 x86 function calling convention, 32-bit:
 ----------------------------------------
  arguments         | callee-saved        | extra caller-saved | return
 [callee-clobbered] |                     | [callee-clobbered] |
 -------------------------------------------------------------------------
 eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]

 ( here too esp is obviously invariant across normal function calls. eflags
   is clobbered. Leftover arguments are passed over the stack frame. )

 [*]  In the frame-pointers case ebp is fixed to the stack frame.

 [**] We build with -freg-struct-return, which on 32-bit means similar
      semantics as on 64-bit: edx can be used for a second return value
      (i.e. covering integer and structure sizes up to 64 bits) - after that
      it gets more complex and more expensive: 3-word or larger struct returns
      get done in the caller's frame and the pointer to the return struct goes
      into regparm0, i.e. eax - the other arguments shift up and the
      function's register parameters degenerate to regparm=2 in essence.

*/

#ifdef CONFIG_X86_64

/*
 * 64-bit system call stack frame layout defines and helpers,
 * for assembly code:
 */

/* The layout forms the "struct pt_regs" on the stack: */
/*
 * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
 * unless syscall needs a complete, fully filled "struct pt_regs".
 */
#define R15		0*8
#define R14		1*8
#define R13		2*8
#define R12		3*8
#define RBP		4*8
#define RBX		5*8
/* These regs are callee-clobbered. Always saved on kernel entry. */
#define R11		6*8
#define R10		7*8
#define R9		8*8
#define R8		9*8
#define RAX		10*8
#define RCX		11*8
#define RDX		12*8
#define RSI		13*8
#define RDI		14*8
/*
 * On syscall entry, this is syscall#. On CPU exception, this is error code.
 * On hw interrupt, it's IRQ number:
 */
#define ORIG_RAX	15*8
/* Return frame for iretq */
#define RIP		16*8
#define CS		17*8
#define EFLAGS		18*8
#define RSP		19*8
#define SS		20*8

#define SIZEOF_PTREGS	21*8

.macro PUSH_AND_CLEAR_REGS rdx=%rdx rax=%rax save_ret=0
	/*
	 * Push registers and sanitize registers of values that a
	 * speculation attack might otherwise want to exploit. The
	 * lower registers are likely clobbered well before they
	 * could be put to use in a speculative execution gadget.
	 * Interleave XOR with PUSH for better uop scheduling:
	 */
	.if \save_ret
	pushq	%rsi		/* pt_regs->si */
	movq	8(%rsp), %rsi	/* temporarily store the return address in %rsi */
	movq	%rdi, 8(%rsp)	/* pt_regs->di (overwriting original return address) */
	.else
	pushq   %rdi		/* pt_regs->di */
	pushq   %rsi		/* pt_regs->si */
	.endif
	pushq	\rdx		/* pt_regs->dx */
	xorl	%edx, %edx	/* nospec   dx */
	pushq   %rcx		/* pt_regs->cx */
	xorl	%ecx, %ecx	/* nospec   cx */
	pushq   \rax		/* pt_regs->ax */
	pushq   %r8		/* pt_regs->r8 */
	xorl	%r8d, %r8d	/* nospec   r8 */
	pushq   %r9		/* pt_regs->r9 */
	xorl	%r9d, %r9d	/* nospec   r9 */
	pushq   %r10		/* pt_regs->r10 */
	xorl	%r10d, %r10d	/* nospec   r10 */
	pushq   %r11		/* pt_regs->r11 */
	xorl	%r11d, %r11d	/* nospec   r11*/
	pushq	%rbx		/* pt_regs->rbx */
	xorl    %ebx, %ebx	/* nospec   rbx*/
	pushq	%rbp		/* pt_regs->rbp */
	xorl    %ebp, %ebp	/* nospec   rbp*/
	pushq	%r12		/* pt_regs->r12 */
	xorl	%r12d, %r12d	/* nospec   r12*/
	pushq	%r13		/* pt_regs->r13 */
	xorl	%r13d, %r13d	/* nospec   r13*/
	pushq	%r14		/* pt_regs->r14 */
	xorl	%r14d, %r14d	/* nospec   r14*/
	pushq	%r15		/* pt_regs->r15 */
	xorl	%r15d, %r15d	/* nospec   r15*/
	UNWIND_HINT_REGS
	.if \save_ret
	pushq	%rsi		/* return address on top of stack */
	.endif
.endm

.macro POP_REGS pop_rdi=1 skip_r11rcx=0
	popq %r15
	popq %r14
	popq %r13
	popq %r12
	popq %rbp
	popq %rbx
	.if \skip_r11rcx
	popq %rsi
	.else
	popq %r11
	.endif
	popq %r10
	popq %r9
	popq %r8
	popq %rax
	.if \skip_r11rcx
	popq %rsi
	.else
	popq %rcx
	.endif
	popq %rdx
	popq %rsi
	.if \pop_rdi
	popq %rdi
	.endif
.endm

/*
 * This is a sneaky trick to help the unwinder find pt_regs on the stack.  The
 * frame pointer is replaced with an encoded pointer to pt_regs.  The encoding
 * is just setting the LSB, which makes it an invalid stack address and is also
 * a signal to the unwinder that it's a pt_regs pointer in disguise.
 *
 * NOTE: This macro must be used *after* PUSH_AND_CLEAR_REGS because it corrupts
 * the original rbp.
 */
.macro ENCODE_FRAME_POINTER ptregs_offset=0
#ifdef CONFIG_FRAME_POINTER
	leaq 1+\ptregs_offset(%rsp), %rbp
#endif
.endm

#ifdef CONFIG_PAGE_TABLE_ISOLATION

/*
 * PAGE_TABLE_ISOLATION PGDs are 8k.  Flip bit 12 to switch between the two
 * halves:
 */
#define PTI_USER_PGTABLE_BIT		PAGE_SHIFT
#define PTI_USER_PGTABLE_MASK		(1 << PTI_USER_PGTABLE_BIT)
#define PTI_USER_PCID_BIT		X86_CR3_PTI_PCID_USER_BIT
#define PTI_USER_PCID_MASK		(1 << PTI_USER_PCID_BIT)
#define PTI_USER_PGTABLE_AND_PCID_MASK  (PTI_USER_PCID_MASK | PTI_USER_PGTABLE_MASK)

.macro SET_NOFLUSH_BIT	reg:req
	bts	$X86_CR3_PCID_NOFLUSH_BIT, \reg
.endm

.macro ADJUST_KERNEL_CR3 reg:req
	ALTERNATIVE "", "SET_NOFLUSH_BIT \reg", X86_FEATURE_PCID
	/* Clear PCID and "PAGE_TABLE_ISOLATION bit", point CR3 at kernel pagetables: */
	andq    $(~PTI_USER_PGTABLE_AND_PCID_MASK), \reg
.endm

.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
	mov	%cr3, \scratch_reg
	ADJUST_KERNEL_CR3 \scratch_reg
	mov	\scratch_reg, %cr3
.Lend_\@:
.endm

#define THIS_CPU_user_pcid_flush_mask   \
	PER_CPU_VAR(cpu_tlbstate) + TLB_STATE_user_pcid_flush_mask

.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
	mov	%cr3, \scratch_reg

	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID

	/*
	 * Test if the ASID needs a flush.
	 */
	movq	\scratch_reg, \scratch_reg2
	andq	$(0x7FF), \scratch_reg		/* mask ASID */
	bt	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	jnc	.Lnoflush_\@

	/* Flush needed, clear the bit */
	btr	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	movq	\scratch_reg2, \scratch_reg
	jmp	.Lwrcr3_pcid_\@

.Lnoflush_\@:
	movq	\scratch_reg2, \scratch_reg
	SET_NOFLUSH_BIT \scratch_reg

.Lwrcr3_pcid_\@:
	/* Flip the ASID to the user version */
	orq	$(PTI_USER_PCID_MASK), \scratch_reg

.Lwrcr3_\@:
	/* Flip the PGD to the user version */
	orq     $(PTI_USER_PGTABLE_MASK), \scratch_reg
	mov	\scratch_reg, %cr3
.Lend_\@:
.endm

.macro SWITCH_TO_USER_CR3_STACK	scratch_reg:req
	pushq	%rax
	SWITCH_TO_USER_CR3_NOSTACK scratch_reg=\scratch_reg scratch_reg2=%rax
	popq	%rax
.endm

.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
	ALTERNATIVE "jmp .Ldone_\@", "", X86_FEATURE_PTI
	movq	%cr3, \scratch_reg
	movq	\scratch_reg, \save_reg
	/*
	 * Test the user pagetable bit. If set, then the user page tables
	 * are active. If clear CR3 already has the kernel page table
	 * active.
	 */
	bt	$PTI_USER_PGTABLE_BIT, \scratch_reg
	jnc	.Ldone_\@

	ADJUST_KERNEL_CR3 \scratch_reg
	movq	\scratch_reg, %cr3

.Ldone_\@:
.endm

.macro RESTORE_CR3 scratch_reg:req save_reg:req
	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI

	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID

	/*
	 * KERNEL pages can always resume with NOFLUSH as we do
	 * explicit flushes.
	 */
	bt	$PTI_USER_PGTABLE_BIT, \save_reg
	jnc	.Lnoflush_\@

	/*
	 * Check if there's a pending flush for the user ASID we're
	 * about to set.
	 */
	movq	\save_reg, \scratch_reg
	andq	$(0x7FF), \scratch_reg
	bt	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	jnc	.Lnoflush_\@

	btr	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	jmp	.Lwrcr3_\@

.Lnoflush_\@:
	SET_NOFLUSH_BIT \save_reg

.Lwrcr3_\@:
	/*
	 * The CR3 write could be avoided when not changing its value,
	 * but would require a CR3 read *and* a scratch register.
	 */
	movq	\save_reg, %cr3
.Lend_\@:
.endm

#else /* CONFIG_PAGE_TABLE_ISOLATION=n: */

.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
.endm
.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
.endm
.macro SWITCH_TO_USER_CR3_STACK scratch_reg:req
.endm
.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
.endm
.macro RESTORE_CR3 scratch_reg:req save_reg:req
.endm

#endif

.macro STACKLEAK_ERASE_NOCLOBBER
#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	PUSH_AND_CLEAR_REGS
	call stackleak_erase
	POP_REGS
#endif
.endm

#endif /* CONFIG_X86_64 */

.macro STACKLEAK_ERASE
#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	call stackleak_erase
#endif
.endm

/*
 * This does 'call enter_from_user_mode' unless we can avoid it based on
 * kernel config or using the static jump infrastructure.
 */
.macro CALL_enter_from_user_mode
#ifdef CONFIG_CONTEXT_TRACKING
#ifdef CONFIG_JUMP_LABEL
	STATIC_JUMP_IF_FALSE .Lafter_call_\@, context_tracking_enabled, def=0
#endif
	call enter_from_user_mode
.Lafter_call_\@:
#endif
.endm
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
478dc89c	2	#include <linux/jump_label.h>
8c1f7558	3	#include <asm/unwind_hints.h>
8a09317b DH	4	#include <asm/cpufeatures.h>
8a09317b DH	5	#include <asm/page_types.h>
6fd166aa PZ	6	#include <asm/percpu.h>
	7	#include <asm/asm-offsets.h>
	8	#include <asm/processor-flags.h>
478dc89c	9
0c2bd5a5	10	/*
063f8913 IM	11
	12	x86 function call convention, 64-bit:
	13	-------------------------------------
	14	arguments \| callee-saved \| extra caller-saved \| return
	15	[callee-clobbered] \| \| [callee-clobbered] \|
	16	---------------------------------------------------------------------------
	17	rdi rsi rdx rcx r8-9 \| rbx rbp [] r12-15 \| r10-11 \| rax, rdx [*]
	18
	19	( rsp is obviously invariant across normal function calls. (gcc can 'merge'
	20	functions when it sees tail-call optimization possibilities) rflags is
	21	clobbered. Leftover arguments are passed over the stack frame.)
	22
	23	[*] In the frame-pointers case rbp is fixed to the stack frame.
	24
	25	[**] for struct return values wider than 64 bits the return convention is a
	26	bit more complex: up to 128 bits width we return small structures
	27	straight in rax, rdx. For structures larger than that (3 words or
	28	larger) the caller puts a pointer to an on-stack return struct
	29	[allocated in the caller's stack frame] into the first argument - i.e.
	30	into rdi. All other arguments shift up by one in this case.
	31	Fortunately this case is rare in the kernel.
	32
	33	For 32-bit we have the following conventions - kernel is built with
	34	-mregparm=3 and -freg-struct-return:
	35
	36	x86 function calling convention, 32-bit:
	37	----------------------------------------
	38	arguments \| callee-saved \| extra caller-saved \| return
	39	[callee-clobbered] \| \| [callee-clobbered] \|
	40	-------------------------------------------------------------------------
	41	eax edx ecx \| ebx edi esi ebp [] \| <none> \| eax, edx [*]
	42
	43	( here too esp is obviously invariant across normal function calls. eflags
	44	is clobbered. Leftover arguments are passed over the stack frame. )
	45
	46	[*] In the frame-pointers case ebp is fixed to the stack frame.
	47
	48	[**] We build with -freg-struct-return, which on 32-bit means similar
	49	semantics as on 64-bit: edx can be used for a second return value
	50	(i.e. covering integer and structure sizes up to 64 bits) - after that
	51	it gets more complex and more expensive: 3-word or larger struct returns
	52	get done in the caller's frame and the pointer to the return struct goes
	53	into regparm0, i.e. eax - the other arguments shift up and the
	54	function's register parameters degenerate to regparm=2 in essence.
	55
	56	*/
	57
1a338ac3 PZ	58	#ifdef CONFIG_X86_64
1a338ac3 PZ	59
063f8913	60	/*
1b2b23d8 TG	61	* 64-bit system call stack frame layout defines and helpers,
1b2b23d8 TG	62	* for assembly code:
0c2bd5a5	63	*/
1da177e4	64
76f5df43 DV	65	/* The layout forms the "struct pt_regs" on the stack: */
	66	/*
	67	* C ABI says these regs are callee-preserved. They aren't saved on kernel entry
	68	* unless syscall needs a complete, fully filled "struct pt_regs".
	69	*/
	70	#define R15 0*8
	71	#define R14 1*8
	72	#define R13 2*8
	73	#define R12 3*8
	74	#define RBP 4*8
	75	#define RBX 5*8
	76	/* These regs are callee-clobbered. Always saved on kernel entry. */
	77	#define R11 6*8
	78	#define R10 7*8
	79	#define R9 8*8
	80	#define R8 9*8
	81	#define RAX 10*8
	82	#define RCX 11*8
	83	#define RDX 12*8
	84	#define RSI 13*8
	85	#define RDI 14*8
	86	/*
	87	* On syscall entry, this is syscall#. On CPU exception, this is error code.
	88	* On hw interrupt, it's IRQ number:
	89	*/
	90	#define ORIG_RAX 15*8
	91	/* Return frame for iretq */
	92	#define RIP 16*8
	93	#define CS 17*8
	94	#define EFLAGS 18*8
	95	#define RSP 19*8
	96	#define SS 20*8
	97
911d2bb5 DV	98	#define SIZEOF_PTREGS 21*8
911d2bb5 DV	99
9e809d15	100	.macro PUSH_AND_CLEAR_REGS rdx=%rdx rax=%rax save_ret=0
3f01daec DB	101	/*
	102	* Push registers and sanitize registers of values that a
	103	* speculation attack might otherwise want to exploit. The
	104	* lower registers are likely clobbered well before they
	105	* could be put to use in a speculative execution gadget.
	106	* Interleave XOR with PUSH for better uop scheduling:
	107	*/
9e809d15 DB	108	.if \save_ret
	109	pushq %rsi /* pt_regs->si */
	110	movq 8(%rsp), %rsi /* temporarily store the return address in %rsi */
	111	movq %rdi, 8(%rsp) /* pt_regs->di (overwriting original return address) */
	112	.else
3f01daec DB	113	pushq %rdi /* pt_regs->di */
3f01daec DB	114	pushq %rsi /* pt_regs->si */
9e809d15	115	.endif
30907fd1	116	pushq \rdx /* pt_regs->dx */
6dc936f1	117	xorl %edx, %edx /* nospec dx */
3f01daec	118	pushq %rcx /* pt_regs->cx */
6dc936f1	119	xorl %ecx, %ecx /* nospec cx */
30907fd1	120	pushq \rax /* pt_regs->ax */
3f01daec	121	pushq %r8 /* pt_regs->r8 */
ced5d0bf	122	xorl %r8d, %r8d /* nospec r8 */
3f01daec	123	pushq %r9 /* pt_regs->r9 */
ced5d0bf	124	xorl %r9d, %r9d /* nospec r9 */
3f01daec	125	pushq %r10 /* pt_regs->r10 */
ced5d0bf	126	xorl %r10d, %r10d /* nospec r10 */
3f01daec	127	pushq %r11 /* pt_regs->r11 */
ced5d0bf	128	xorl %r11d, %r11d /* nospec r11*/
3f01daec DB	129	pushq %rbx /* pt_regs->rbx */
	130	xorl %ebx, %ebx /* nospec rbx*/
	131	pushq %rbp /* pt_regs->rbp */
	132	xorl %ebp, %ebp /* nospec rbp*/
	133	pushq %r12 /* pt_regs->r12 */
ced5d0bf	134	xorl %r12d, %r12d /* nospec r12*/
3f01daec	135	pushq %r13 /* pt_regs->r13 */
ced5d0bf	136	xorl %r13d, %r13d /* nospec r13*/
3f01daec	137	pushq %r14 /* pt_regs->r14 */
ced5d0bf	138	xorl %r14d, %r14d /* nospec r14*/
3f01daec	139	pushq %r15 /* pt_regs->r15 */
ced5d0bf	140	xorl %r15d, %r15d /* nospec r15*/
3f01daec	141	UNWIND_HINT_REGS
9e809d15 DB	142	.if \save_ret
	143	pushq %rsi /* return address on top of stack */
	144	.endif
92816f57	145	.endm
3f01daec	146
92816f57	147	.macro POP_REGS pop_rdi=1 skip_r11rcx=0
e872045b AL	148	popq %r15
	149	popq %r14
	150	popq %r13
	151	popq %r12
	152	popq %rbp
	153	popq %rbx
502af0d7 DB	154	.if \skip_r11rcx
	155	popq %rsi
	156	.else
e872045b	157	popq %r11
502af0d7	158	.endif
e872045b AL	159	popq %r10
	160	popq %r9
	161	popq %r8
	162	popq %rax
502af0d7 DB	163	.if \skip_r11rcx
	164	popq %rsi
	165	.else
e872045b	166	popq %rcx
502af0d7	167	.endif
e872045b AL	168	popq %rdx
e872045b AL	169	popq %rsi
502af0d7	170	.if \pop_rdi
e872045b	171	popq %rdi
502af0d7	172	.endif
92816f57	173	.endm
1a338ac3	174
946c1911 JP	175	/*
	176	* This is a sneaky trick to help the unwinder find pt_regs on the stack. The
	177	* frame pointer is replaced with an encoded pointer to pt_regs. The encoding
	178	* is just setting the LSB, which makes it an invalid stack address and is also
	179	* a signal to the unwinder that it's a pt_regs pointer in disguise.
	180	*
dde3036d	181	* NOTE: This macro must be used after PUSH_AND_CLEAR_REGS because it corrupts
946c1911 JP	182	* the original rbp.
	183	*/
	184	.macro ENCODE_FRAME_POINTER ptregs_offset=0
	185	#ifdef CONFIG_FRAME_POINTER
0ca7d5ba	186	leaq 1+\ptregs_offset(%rsp), %rbp
946c1911 JP	187	#endif
	188	.endm
	189
8a09317b DH	190	#ifdef CONFIG_PAGE_TABLE_ISOLATION
8a09317b DH	191
6fd166aa PZ	192	/*
	193	* PAGE_TABLE_ISOLATION PGDs are 8k. Flip bit 12 to switch between the two
	194	* halves:
	195	*/
f10ee3dc TG	196	#define PTI_USER_PGTABLE_BIT PAGE_SHIFT
	197	#define PTI_USER_PGTABLE_MASK (1 << PTI_USER_PGTABLE_BIT)
	198	#define PTI_USER_PCID_BIT X86_CR3_PTI_PCID_USER_BIT
	199	#define PTI_USER_PCID_MASK (1 << PTI_USER_PCID_BIT)
	200	#define PTI_USER_PGTABLE_AND_PCID_MASK (PTI_USER_PCID_MASK \| PTI_USER_PGTABLE_MASK)
8a09317b	201
6fd166aa PZ	202	.macro SET_NOFLUSH_BIT reg:req
6fd166aa PZ	203	bts $X86_CR3_PCID_NOFLUSH_BIT, \reg
8a09317b DH	204	.endm
8a09317b DH	205
6fd166aa PZ	206	.macro ADJUST_KERNEL_CR3 reg:req
	207	ALTERNATIVE "", "SET_NOFLUSH_BIT \reg", X86_FEATURE_PCID
	208	/* Clear PCID and "PAGE_TABLE_ISOLATION bit", point CR3 at kernel pagetables: */
f10ee3dc	209	andq $(~PTI_USER_PGTABLE_AND_PCID_MASK), \reg
8a09317b DH	210	.endm
	211
	212	.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
aa8c6248	213	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
8a09317b DH	214	mov %cr3, \scratch_reg
	215	ADJUST_KERNEL_CR3 \scratch_reg
	216	mov \scratch_reg, %cr3
aa8c6248	217	.Lend_\@:
8a09317b DH	218	.endm
8a09317b DH	219
6fd166aa PZ	220	#define THIS_CPU_user_pcid_flush_mask \
	221	PER_CPU_VAR(cpu_tlbstate) + TLB_STATE_user_pcid_flush_mask
	222
	223	.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
aa8c6248	224	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
8a09317b	225	mov %cr3, \scratch_reg
6fd166aa PZ	226
	227	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID
	228
	229	/*
	230	* Test if the ASID needs a flush.
	231	*/
	232	movq \scratch_reg, \scratch_reg2
	233	andq $(0x7FF), \scratch_reg /* mask ASID */
	234	bt \scratch_reg, THIS_CPU_user_pcid_flush_mask
	235	jnc .Lnoflush_\@
	236
	237	/* Flush needed, clear the bit */
	238	btr \scratch_reg, THIS_CPU_user_pcid_flush_mask
	239	movq \scratch_reg2, \scratch_reg
f10ee3dc	240	jmp .Lwrcr3_pcid_\@
6fd166aa PZ	241
	242	.Lnoflush_\@:
	243	movq \scratch_reg2, \scratch_reg
	244	SET_NOFLUSH_BIT \scratch_reg
	245
f10ee3dc TG	246	.Lwrcr3_pcid_\@:
	247	/* Flip the ASID to the user version */
	248	orq $(PTI_USER_PCID_MASK), \scratch_reg
	249
6fd166aa	250	.Lwrcr3_\@:
f10ee3dc TG	251	/* Flip the PGD to the user version */
f10ee3dc TG	252	orq $(PTI_USER_PGTABLE_MASK), \scratch_reg
8a09317b	253	mov \scratch_reg, %cr3
aa8c6248	254	.Lend_\@:
8a09317b DH	255	.endm
8a09317b DH	256
6fd166aa PZ	257	.macro SWITCH_TO_USER_CR3_STACK scratch_reg:req
	258	pushq %rax
	259	SWITCH_TO_USER_CR3_NOSTACK scratch_reg=\scratch_reg scratch_reg2=%rax
	260	popq %rax
	261	.endm
	262
8a09317b	263	.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
aa8c6248	264	ALTERNATIVE "jmp .Ldone_\@", "", X86_FEATURE_PTI
8a09317b DH	265	movq %cr3, \scratch_reg
	266	movq \scratch_reg, \save_reg
	267	/*
f10ee3dc TG	268	* Test the user pagetable bit. If set, then the user page tables
	269	* are active. If clear CR3 already has the kernel page table
	270	* active.
8a09317b	271	*/
f10ee3dc TG	272	bt $PTI_USER_PGTABLE_BIT, \scratch_reg
f10ee3dc TG	273	jnc .Ldone_\@
8a09317b DH	274
	275	ADJUST_KERNEL_CR3 \scratch_reg
	276	movq \scratch_reg, %cr3
	277
	278	.Ldone_\@:
	279	.endm
	280
21e94459	281	.macro RESTORE_CR3 scratch_reg:req save_reg:req
aa8c6248	282	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
21e94459 PZ	283
	284	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID
	285
	286	/*
	287	* KERNEL pages can always resume with NOFLUSH as we do
	288	* explicit flushes.
	289	*/
f10ee3dc	290	bt $PTI_USER_PGTABLE_BIT, \save_reg
21e94459 PZ	291	jnc .Lnoflush_\@
	292
	293	/*
	294	* Check if there's a pending flush for the user ASID we're
	295	* about to set.
	296	*/
	297	movq \save_reg, \scratch_reg
	298	andq $(0x7FF), \scratch_reg
	299	bt \scratch_reg, THIS_CPU_user_pcid_flush_mask
	300	jnc .Lnoflush_\@
	301
	302	btr \scratch_reg, THIS_CPU_user_pcid_flush_mask
	303	jmp .Lwrcr3_\@
	304
	305	.Lnoflush_\@:
	306	SET_NOFLUSH_BIT \save_reg
	307
	308	.Lwrcr3_\@:
8a09317b DH	309	/*
	310	* The CR3 write could be avoided when not changing its value,
	311	* but would require a CR3 read and a scratch register.
	312	*/
	313	movq \save_reg, %cr3
aa8c6248	314	.Lend_\@:
8a09317b DH	315	.endm
	316
	317	#else /* CONFIG_PAGE_TABLE_ISOLATION=n: */
	318
	319	.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
	320	.endm
6fd166aa PZ	321	.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
	322	.endm
	323	.macro SWITCH_TO_USER_CR3_STACK scratch_reg:req
8a09317b DH	324	.endm
	325	.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
	326	.endm
21e94459	327	.macro RESTORE_CR3 scratch_reg:req save_reg:req
8a09317b DH	328	.endm
	329
	330	#endif
	331
afaef01c AP	332	.macro STACKLEAK_ERASE_NOCLOBBER
	333	#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	334	PUSH_AND_CLEAR_REGS
	335	call stackleak_erase
	336	POP_REGS
	337	#endif
	338	.endm
	339
1a338ac3 PZ	340	#endif /* CONFIG_X86_64 */
1a338ac3 PZ	341
afaef01c AP	342	.macro STACKLEAK_ERASE
	343	#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	344	call stackleak_erase
	345	#endif
	346	.endm
	347
478dc89c AL	348	/*
	349	* This does 'call enter_from_user_mode' unless we can avoid it based on
	350	* kernel config or using the static jump infrastructure.
	351	*/
	352	.macro CALL_enter_from_user_mode
	353	#ifdef CONFIG_CONTEXT_TRACKING
e9666d10	354	#ifdef CONFIG_JUMP_LABEL
e769742d	355	STATIC_JUMP_IF_FALSE .Lafter_call_\@, context_tracking_enabled, def=0
478dc89c AL	356	#endif
	357	call enter_from_user_mode
	358	.Lafter_call_\@:
	359	#endif
	360	.endm