[linux-2.6-block.git] / arch / x86 / entry / calling.h

/* SPDX-License-Identifier: GPL-2.0 */
#include <linux/jump_label.h>
#include <asm/unwind_hints.h>
#include <asm/cpufeatures.h>
#include <asm/page_types.h>
#include <asm/percpu.h>
#include <asm/asm-offsets.h>
#include <asm/processor-flags.h>

/*

 x86 function call convention, 64-bit:
 -------------------------------------
  arguments           |  callee-saved      | extra caller-saved | return
 [callee-clobbered]   |                    | [callee-clobbered] |
 ---------------------------------------------------------------------------
 rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]

 ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
   functions when it sees tail-call optimization possibilities) rflags is
   clobbered. Leftover arguments are passed over the stack frame.)

 [*]  In the frame-pointers case rbp is fixed to the stack frame.

 [**] for struct return values wider than 64 bits the return convention is a
      bit more complex: up to 128 bits width we return small structures
      straight in rax, rdx. For structures larger than that (3 words or
      larger) the caller puts a pointer to an on-stack return struct
      [allocated in the caller's stack frame] into the first argument - i.e.
      into rdi. All other arguments shift up by one in this case.
      Fortunately this case is rare in the kernel.

For 32-bit we have the following conventions - kernel is built with
-mregparm=3 and -freg-struct-return:

 x86 function calling convention, 32-bit:
 ----------------------------------------
  arguments         | callee-saved        | extra caller-saved | return
 [callee-clobbered] |                     | [callee-clobbered] |
 -------------------------------------------------------------------------
 eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]

 ( here too esp is obviously invariant across normal function calls. eflags
   is clobbered. Leftover arguments are passed over the stack frame. )

 [*]  In the frame-pointers case ebp is fixed to the stack frame.

 [**] We build with -freg-struct-return, which on 32-bit means similar
      semantics as on 64-bit: edx can be used for a second return value
      (i.e. covering integer and structure sizes up to 64 bits) - after that
      it gets more complex and more expensive: 3-word or larger struct returns
      get done in the caller's frame and the pointer to the return struct goes
      into regparm0, i.e. eax - the other arguments shift up and the
      function's register parameters degenerate to regparm=2 in essence.

*/

#ifdef CONFIG_X86_64

/*
 * 64-bit system call stack frame layout defines and helpers,
 * for assembly code:
 */

/* The layout forms the "struct pt_regs" on the stack: */
/*
 * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
 * unless syscall needs a complete, fully filled "struct pt_regs".
 */
#define R15		0*8
#define R14		1*8
#define R13		2*8
#define R12		3*8
#define RBP		4*8
#define RBX		5*8
/* These regs are callee-clobbered. Always saved on kernel entry. */
#define R11		6*8
#define R10		7*8
#define R9		8*8
#define R8		9*8
#define RAX		10*8
#define RCX		11*8
#define RDX		12*8
#define RSI		13*8
#define RDI		14*8
/*
 * On syscall entry, this is syscall#. On CPU exception, this is error code.
 * On hw interrupt, it's IRQ number:
 */
#define ORIG_RAX	15*8
/* Return frame for iretq */
#define RIP		16*8
#define CS		17*8
#define EFLAGS		18*8
#define RSP		19*8
#define SS		20*8

#define SIZEOF_PTREGS	21*8

.macro PUSH_AND_CLEAR_REGS rdx=%rdx rax=%rax save_ret=0
	/*
	 * Push registers and sanitize registers of values that a
	 * speculation attack might otherwise want to exploit. The
	 * lower registers are likely clobbered well before they
	 * could be put to use in a speculative execution gadget.
	 * Interleave XOR with PUSH for better uop scheduling:
	 */
	.if \save_ret
	pushq	%rsi		/* pt_regs->si */
	movq	8(%rsp), %rsi	/* temporarily store the return address in %rsi */
	movq	%rdi, 8(%rsp)	/* pt_regs->di (overwriting original return address) */
	.else
	pushq   %rdi		/* pt_regs->di */
	pushq   %rsi		/* pt_regs->si */
	.endif
	pushq	\rdx		/* pt_regs->dx */
	xorl	%edx, %edx	/* nospec   dx */
	pushq   %rcx		/* pt_regs->cx */
	xorl	%ecx, %ecx	/* nospec   cx */
	pushq   \rax		/* pt_regs->ax */
	pushq   %r8		/* pt_regs->r8 */
	xorl	%r8d, %r8d	/* nospec   r8 */
	pushq   %r9		/* pt_regs->r9 */
	xorl	%r9d, %r9d	/* nospec   r9 */
	pushq   %r10		/* pt_regs->r10 */
	xorl	%r10d, %r10d	/* nospec   r10 */
	pushq   %r11		/* pt_regs->r11 */
	xorl	%r11d, %r11d	/* nospec   r11*/
	pushq	%rbx		/* pt_regs->rbx */
	xorl    %ebx, %ebx	/* nospec   rbx*/
	pushq	%rbp		/* pt_regs->rbp */
	xorl    %ebp, %ebp	/* nospec   rbp*/
	pushq	%r12		/* pt_regs->r12 */
	xorl	%r12d, %r12d	/* nospec   r12*/
	pushq	%r13		/* pt_regs->r13 */
	xorl	%r13d, %r13d	/* nospec   r13*/
	pushq	%r14		/* pt_regs->r14 */
	xorl	%r14d, %r14d	/* nospec   r14*/
	pushq	%r15		/* pt_regs->r15 */
	xorl	%r15d, %r15d	/* nospec   r15*/
	UNWIND_HINT_REGS
	.if \save_ret
	pushq	%rsi		/* return address on top of stack */
	.endif
.endm

.macro POP_REGS pop_rdi=1 skip_r11rcx=0
	popq %r15
	popq %r14
	popq %r13
	popq %r12
	popq %rbp
	popq %rbx
	.if \skip_r11rcx
	popq %rsi
	.else
	popq %r11
	.endif
	popq %r10
	popq %r9
	popq %r8
	popq %rax
	.if \skip_r11rcx
	popq %rsi
	.else
	popq %rcx
	.endif
	popq %rdx
	popq %rsi
	.if \pop_rdi
	popq %rdi
	.endif
.endm

#ifdef CONFIG_PAGE_TABLE_ISOLATION

/*
 * PAGE_TABLE_ISOLATION PGDs are 8k.  Flip bit 12 to switch between the two
 * halves:
 */
#define PTI_USER_PGTABLE_BIT		PAGE_SHIFT
#define PTI_USER_PGTABLE_MASK		(1 << PTI_USER_PGTABLE_BIT)
#define PTI_USER_PCID_BIT		X86_CR3_PTI_PCID_USER_BIT
#define PTI_USER_PCID_MASK		(1 << PTI_USER_PCID_BIT)
#define PTI_USER_PGTABLE_AND_PCID_MASK  (PTI_USER_PCID_MASK | PTI_USER_PGTABLE_MASK)

.macro SET_NOFLUSH_BIT	reg:req
	bts	$X86_CR3_PCID_NOFLUSH_BIT, \reg
.endm

.macro ADJUST_KERNEL_CR3 reg:req
	ALTERNATIVE "", "SET_NOFLUSH_BIT \reg", X86_FEATURE_PCID
	/* Clear PCID and "PAGE_TABLE_ISOLATION bit", point CR3 at kernel pagetables: */
	andq    $(~PTI_USER_PGTABLE_AND_PCID_MASK), \reg
.endm

.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
	mov	%cr3, \scratch_reg
	ADJUST_KERNEL_CR3 \scratch_reg
	mov	\scratch_reg, %cr3
.Lend_\@:
.endm

#define THIS_CPU_user_pcid_flush_mask   \
	PER_CPU_VAR(cpu_tlbstate) + TLB_STATE_user_pcid_flush_mask

.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
	mov	%cr3, \scratch_reg

	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID

	/*
	 * Test if the ASID needs a flush.
	 */
	movq	\scratch_reg, \scratch_reg2
	andq	$(0x7FF), \scratch_reg		/* mask ASID */
	bt	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	jnc	.Lnoflush_\@

	/* Flush needed, clear the bit */
	btr	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	movq	\scratch_reg2, \scratch_reg
	jmp	.Lwrcr3_pcid_\@

.Lnoflush_\@:
	movq	\scratch_reg2, \scratch_reg
	SET_NOFLUSH_BIT \scratch_reg

.Lwrcr3_pcid_\@:
	/* Flip the ASID to the user version */
	orq	$(PTI_USER_PCID_MASK), \scratch_reg

.Lwrcr3_\@:
	/* Flip the PGD to the user version */
	orq     $(PTI_USER_PGTABLE_MASK), \scratch_reg
	mov	\scratch_reg, %cr3
.Lend_\@:
.endm

.macro SWITCH_TO_USER_CR3_STACK	scratch_reg:req
	pushq	%rax
	SWITCH_TO_USER_CR3_NOSTACK scratch_reg=\scratch_reg scratch_reg2=%rax
	popq	%rax
.endm

.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
	ALTERNATIVE "jmp .Ldone_\@", "", X86_FEATURE_PTI
	movq	%cr3, \scratch_reg
	movq	\scratch_reg, \save_reg
	/*
	 * Test the user pagetable bit. If set, then the user page tables
	 * are active. If clear CR3 already has the kernel page table
	 * active.
	 */
	bt	$PTI_USER_PGTABLE_BIT, \scratch_reg
	jnc	.Ldone_\@

	ADJUST_KERNEL_CR3 \scratch_reg
	movq	\scratch_reg, %cr3

.Ldone_\@:
.endm

.macro RESTORE_CR3 scratch_reg:req save_reg:req
	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI

	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID

	/*
	 * KERNEL pages can always resume with NOFLUSH as we do
	 * explicit flushes.
	 */
	bt	$PTI_USER_PGTABLE_BIT, \save_reg
	jnc	.Lnoflush_\@

	/*
	 * Check if there's a pending flush for the user ASID we're
	 * about to set.
	 */
	movq	\save_reg, \scratch_reg
	andq	$(0x7FF), \scratch_reg
	bt	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	jnc	.Lnoflush_\@

	btr	\scratch_reg, THIS_CPU_user_pcid_flush_mask
	jmp	.Lwrcr3_\@

.Lnoflush_\@:
	SET_NOFLUSH_BIT \save_reg

.Lwrcr3_\@:
	/*
	 * The CR3 write could be avoided when not changing its value,
	 * but would require a CR3 read *and* a scratch register.
	 */
	movq	\save_reg, %cr3
.Lend_\@:
.endm

#else /* CONFIG_PAGE_TABLE_ISOLATION=n: */

.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
.endm
.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
.endm
.macro SWITCH_TO_USER_CR3_STACK scratch_reg:req
.endm
.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
.endm
.macro RESTORE_CR3 scratch_reg:req save_reg:req
.endm

#endif

/*
 * Mitigate Spectre v1 for conditional swapgs code paths.
 *
 * FENCE_SWAPGS_USER_ENTRY is used in the user entry swapgs code path, to
 * prevent a speculative swapgs when coming from kernel space.
 *
 * FENCE_SWAPGS_KERNEL_ENTRY is used in the kernel entry non-swapgs code path,
 * to prevent the swapgs from getting speculatively skipped when coming from
 * user space.
 */
.macro FENCE_SWAPGS_USER_ENTRY
	ALTERNATIVE "", "lfence", X86_FEATURE_FENCE_SWAPGS_USER
.endm
.macro FENCE_SWAPGS_KERNEL_ENTRY
	ALTERNATIVE "", "lfence", X86_FEATURE_FENCE_SWAPGS_KERNEL
.endm

.macro STACKLEAK_ERASE_NOCLOBBER
#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	PUSH_AND_CLEAR_REGS
	call stackleak_erase
	POP_REGS
#endif
.endm

#endif /* CONFIG_X86_64 */

.macro STACKLEAK_ERASE
#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	call stackleak_erase
#endif
.endm

/*
 * This does 'call enter_from_user_mode' unless we can avoid it based on
 * kernel config or using the static jump infrastructure.
 */
.macro CALL_enter_from_user_mode
#ifdef CONFIG_CONTEXT_TRACKING
#ifdef CONFIG_JUMP_LABEL
	STATIC_JUMP_IF_FALSE .Lafter_call_\@, context_tracking_enabled, def=0
#endif
	call enter_from_user_mode
.Lafter_call_\@:
#endif
.endm

#ifdef CONFIG_PARAVIRT_XXL
#define GET_CR2_INTO(reg) GET_CR2_INTO_AX ; _ASM_MOV %_ASM_AX, reg
#else
#define GET_CR2_INTO(reg) _ASM_MOV %cr2, reg
#endif
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
478dc89c	2	#include <linux/jump_label.h>
8c1f7558	3	#include <asm/unwind_hints.h>
8a09317b DH	4	#include <asm/cpufeatures.h>
8a09317b DH	5	#include <asm/page_types.h>
6fd166aa PZ	6	#include <asm/percpu.h>
	7	#include <asm/asm-offsets.h>
	8	#include <asm/processor-flags.h>
478dc89c	9
0c2bd5a5	10	/*
063f8913 IM	11
	12	x86 function call convention, 64-bit:
	13	-------------------------------------
	14	arguments \| callee-saved \| extra caller-saved \| return
	15	[callee-clobbered] \| \| [callee-clobbered] \|
	16	---------------------------------------------------------------------------
	17	rdi rsi rdx rcx r8-9 \| rbx rbp [] r12-15 \| r10-11 \| rax, rdx [*]
	18
	19	( rsp is obviously invariant across normal function calls. (gcc can 'merge'
	20	functions when it sees tail-call optimization possibilities) rflags is
	21	clobbered. Leftover arguments are passed over the stack frame.)
	22
	23	[*] In the frame-pointers case rbp is fixed to the stack frame.
	24
	25	[**] for struct return values wider than 64 bits the return convention is a
	26	bit more complex: up to 128 bits width we return small structures
	27	straight in rax, rdx. For structures larger than that (3 words or
	28	larger) the caller puts a pointer to an on-stack return struct
	29	[allocated in the caller's stack frame] into the first argument - i.e.
	30	into rdi. All other arguments shift up by one in this case.
	31	Fortunately this case is rare in the kernel.
	32
	33	For 32-bit we have the following conventions - kernel is built with
	34	-mregparm=3 and -freg-struct-return:
	35
	36	x86 function calling convention, 32-bit:
	37	----------------------------------------
	38	arguments \| callee-saved \| extra caller-saved \| return
	39	[callee-clobbered] \| \| [callee-clobbered] \|
	40	-------------------------------------------------------------------------
	41	eax edx ecx \| ebx edi esi ebp [] \| <none> \| eax, edx [*]
	42
	43	( here too esp is obviously invariant across normal function calls. eflags
	44	is clobbered. Leftover arguments are passed over the stack frame. )
	45
	46	[*] In the frame-pointers case ebp is fixed to the stack frame.
	47
	48	[**] We build with -freg-struct-return, which on 32-bit means similar
	49	semantics as on 64-bit: edx can be used for a second return value
	50	(i.e. covering integer and structure sizes up to 64 bits) - after that
	51	it gets more complex and more expensive: 3-word or larger struct returns
	52	get done in the caller's frame and the pointer to the return struct goes
	53	into regparm0, i.e. eax - the other arguments shift up and the
	54	function's register parameters degenerate to regparm=2 in essence.
	55
	56	*/
	57
1a338ac3 PZ	58	#ifdef CONFIG_X86_64
1a338ac3 PZ	59
063f8913	60	/*
1b2b23d8 TG	61	* 64-bit system call stack frame layout defines and helpers,
1b2b23d8 TG	62	* for assembly code:
0c2bd5a5	63	*/
1da177e4	64
76f5df43 DV	65	/* The layout forms the "struct pt_regs" on the stack: */
	66	/*
	67	* C ABI says these regs are callee-preserved. They aren't saved on kernel entry
	68	* unless syscall needs a complete, fully filled "struct pt_regs".
	69	*/
	70	#define R15 0*8
	71	#define R14 1*8
	72	#define R13 2*8
	73	#define R12 3*8
	74	#define RBP 4*8
	75	#define RBX 5*8
	76	/* These regs are callee-clobbered. Always saved on kernel entry. */
	77	#define R11 6*8
	78	#define R10 7*8
	79	#define R9 8*8
	80	#define R8 9*8
	81	#define RAX 10*8
	82	#define RCX 11*8
	83	#define RDX 12*8
	84	#define RSI 13*8
	85	#define RDI 14*8
	86	/*
	87	* On syscall entry, this is syscall#. On CPU exception, this is error code.
	88	* On hw interrupt, it's IRQ number:
	89	*/
	90	#define ORIG_RAX 15*8
	91	/* Return frame for iretq */
	92	#define RIP 16*8
	93	#define CS 17*8
	94	#define EFLAGS 18*8
	95	#define RSP 19*8
	96	#define SS 20*8
	97
911d2bb5 DV	98	#define SIZEOF_PTREGS 21*8
911d2bb5 DV	99
9e809d15	100	.macro PUSH_AND_CLEAR_REGS rdx=%rdx rax=%rax save_ret=0
3f01daec DB	101	/*
	102	* Push registers and sanitize registers of values that a
	103	* speculation attack might otherwise want to exploit. The
	104	* lower registers are likely clobbered well before they
	105	* could be put to use in a speculative execution gadget.
	106	* Interleave XOR with PUSH for better uop scheduling:
	107	*/
9e809d15 DB	108	.if \save_ret
	109	pushq %rsi /* pt_regs->si */
	110	movq 8(%rsp), %rsi /* temporarily store the return address in %rsi */
	111	movq %rdi, 8(%rsp) /* pt_regs->di (overwriting original return address) */
	112	.else
3f01daec DB	113	pushq %rdi /* pt_regs->di */
3f01daec DB	114	pushq %rsi /* pt_regs->si */
9e809d15	115	.endif
30907fd1	116	pushq \rdx /* pt_regs->dx */
6dc936f1	117	xorl %edx, %edx /* nospec dx */
3f01daec	118	pushq %rcx /* pt_regs->cx */
6dc936f1	119	xorl %ecx, %ecx /* nospec cx */
30907fd1	120	pushq \rax /* pt_regs->ax */
3f01daec	121	pushq %r8 /* pt_regs->r8 */
ced5d0bf	122	xorl %r8d, %r8d /* nospec r8 */
3f01daec	123	pushq %r9 /* pt_regs->r9 */
ced5d0bf	124	xorl %r9d, %r9d /* nospec r9 */
3f01daec	125	pushq %r10 /* pt_regs->r10 */
ced5d0bf	126	xorl %r10d, %r10d /* nospec r10 */
3f01daec	127	pushq %r11 /* pt_regs->r11 */
ced5d0bf	128	xorl %r11d, %r11d /* nospec r11*/
3f01daec DB	129	pushq %rbx /* pt_regs->rbx */
	130	xorl %ebx, %ebx /* nospec rbx*/
	131	pushq %rbp /* pt_regs->rbp */
	132	xorl %ebp, %ebp /* nospec rbp*/
	133	pushq %r12 /* pt_regs->r12 */
ced5d0bf	134	xorl %r12d, %r12d /* nospec r12*/
3f01daec	135	pushq %r13 /* pt_regs->r13 */
ced5d0bf	136	xorl %r13d, %r13d /* nospec r13*/
3f01daec	137	pushq %r14 /* pt_regs->r14 */
ced5d0bf	138	xorl %r14d, %r14d /* nospec r14*/
3f01daec	139	pushq %r15 /* pt_regs->r15 */
ced5d0bf	140	xorl %r15d, %r15d /* nospec r15*/
3f01daec	141	UNWIND_HINT_REGS
9e809d15 DB	142	.if \save_ret
	143	pushq %rsi /* return address on top of stack */
	144	.endif
92816f57	145	.endm
3f01daec	146
92816f57	147	.macro POP_REGS pop_rdi=1 skip_r11rcx=0
e872045b AL	148	popq %r15
	149	popq %r14
	150	popq %r13
	151	popq %r12
	152	popq %rbp
	153	popq %rbx
502af0d7 DB	154	.if \skip_r11rcx
	155	popq %rsi
	156	.else
e872045b	157	popq %r11
502af0d7	158	.endif
e872045b AL	159	popq %r10
	160	popq %r9
	161	popq %r8
	162	popq %rax
502af0d7 DB	163	.if \skip_r11rcx
	164	popq %rsi
	165	.else
e872045b	166	popq %rcx
502af0d7	167	.endif
e872045b AL	168	popq %rdx
e872045b AL	169	popq %rsi
502af0d7	170	.if \pop_rdi
e872045b	171	popq %rdi
502af0d7	172	.endif
92816f57	173	.endm
1a338ac3	174
8a09317b DH	175	#ifdef CONFIG_PAGE_TABLE_ISOLATION
8a09317b DH	176
6fd166aa PZ	177	/*
	178	* PAGE_TABLE_ISOLATION PGDs are 8k. Flip bit 12 to switch between the two
	179	* halves:
	180	*/
f10ee3dc TG	181	#define PTI_USER_PGTABLE_BIT PAGE_SHIFT
	182	#define PTI_USER_PGTABLE_MASK (1 << PTI_USER_PGTABLE_BIT)
	183	#define PTI_USER_PCID_BIT X86_CR3_PTI_PCID_USER_BIT
	184	#define PTI_USER_PCID_MASK (1 << PTI_USER_PCID_BIT)
	185	#define PTI_USER_PGTABLE_AND_PCID_MASK (PTI_USER_PCID_MASK \| PTI_USER_PGTABLE_MASK)
8a09317b	186
6fd166aa PZ	187	.macro SET_NOFLUSH_BIT reg:req
6fd166aa PZ	188	bts $X86_CR3_PCID_NOFLUSH_BIT, \reg
8a09317b DH	189	.endm
8a09317b DH	190
6fd166aa PZ	191	.macro ADJUST_KERNEL_CR3 reg:req
	192	ALTERNATIVE "", "SET_NOFLUSH_BIT \reg", X86_FEATURE_PCID
	193	/* Clear PCID and "PAGE_TABLE_ISOLATION bit", point CR3 at kernel pagetables: */
f10ee3dc	194	andq $(~PTI_USER_PGTABLE_AND_PCID_MASK), \reg
8a09317b DH	195	.endm
	196
	197	.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
aa8c6248	198	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
8a09317b DH	199	mov %cr3, \scratch_reg
	200	ADJUST_KERNEL_CR3 \scratch_reg
	201	mov \scratch_reg, %cr3
aa8c6248	202	.Lend_\@:
8a09317b DH	203	.endm
8a09317b DH	204
6fd166aa PZ	205	#define THIS_CPU_user_pcid_flush_mask \
	206	PER_CPU_VAR(cpu_tlbstate) + TLB_STATE_user_pcid_flush_mask
	207
	208	.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
aa8c6248	209	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
8a09317b	210	mov %cr3, \scratch_reg
6fd166aa PZ	211
	212	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID
	213
	214	/*
	215	* Test if the ASID needs a flush.
	216	*/
	217	movq \scratch_reg, \scratch_reg2
	218	andq $(0x7FF), \scratch_reg /* mask ASID */
	219	bt \scratch_reg, THIS_CPU_user_pcid_flush_mask
	220	jnc .Lnoflush_\@
	221
	222	/* Flush needed, clear the bit */
	223	btr \scratch_reg, THIS_CPU_user_pcid_flush_mask
	224	movq \scratch_reg2, \scratch_reg
f10ee3dc	225	jmp .Lwrcr3_pcid_\@
6fd166aa PZ	226
	227	.Lnoflush_\@:
	228	movq \scratch_reg2, \scratch_reg
	229	SET_NOFLUSH_BIT \scratch_reg
	230
f10ee3dc TG	231	.Lwrcr3_pcid_\@:
	232	/* Flip the ASID to the user version */
	233	orq $(PTI_USER_PCID_MASK), \scratch_reg
	234
6fd166aa	235	.Lwrcr3_\@:
f10ee3dc TG	236	/* Flip the PGD to the user version */
f10ee3dc TG	237	orq $(PTI_USER_PGTABLE_MASK), \scratch_reg
8a09317b	238	mov \scratch_reg, %cr3
aa8c6248	239	.Lend_\@:
8a09317b DH	240	.endm
8a09317b DH	241
6fd166aa PZ	242	.macro SWITCH_TO_USER_CR3_STACK scratch_reg:req
	243	pushq %rax
	244	SWITCH_TO_USER_CR3_NOSTACK scratch_reg=\scratch_reg scratch_reg2=%rax
	245	popq %rax
	246	.endm
	247
8a09317b	248	.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
aa8c6248	249	ALTERNATIVE "jmp .Ldone_\@", "", X86_FEATURE_PTI
8a09317b DH	250	movq %cr3, \scratch_reg
	251	movq \scratch_reg, \save_reg
	252	/*
f10ee3dc TG	253	* Test the user pagetable bit. If set, then the user page tables
	254	* are active. If clear CR3 already has the kernel page table
	255	* active.
8a09317b	256	*/
f10ee3dc TG	257	bt $PTI_USER_PGTABLE_BIT, \scratch_reg
f10ee3dc TG	258	jnc .Ldone_\@
8a09317b DH	259
	260	ADJUST_KERNEL_CR3 \scratch_reg
	261	movq \scratch_reg, %cr3
	262
	263	.Ldone_\@:
	264	.endm
	265
21e94459	266	.macro RESTORE_CR3 scratch_reg:req save_reg:req
aa8c6248	267	ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
21e94459 PZ	268
	269	ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID
	270
	271	/*
	272	* KERNEL pages can always resume with NOFLUSH as we do
	273	* explicit flushes.
	274	*/
f10ee3dc	275	bt $PTI_USER_PGTABLE_BIT, \save_reg
21e94459 PZ	276	jnc .Lnoflush_\@
	277
	278	/*
	279	* Check if there's a pending flush for the user ASID we're
	280	* about to set.
	281	*/
	282	movq \save_reg, \scratch_reg
	283	andq $(0x7FF), \scratch_reg
	284	bt \scratch_reg, THIS_CPU_user_pcid_flush_mask
	285	jnc .Lnoflush_\@
	286
	287	btr \scratch_reg, THIS_CPU_user_pcid_flush_mask
	288	jmp .Lwrcr3_\@
	289
	290	.Lnoflush_\@:
	291	SET_NOFLUSH_BIT \save_reg
	292
	293	.Lwrcr3_\@:
8a09317b DH	294	/*
	295	* The CR3 write could be avoided when not changing its value,
	296	* but would require a CR3 read and a scratch register.
	297	*/
	298	movq \save_reg, %cr3
aa8c6248	299	.Lend_\@:
8a09317b DH	300	.endm
	301
	302	#else /* CONFIG_PAGE_TABLE_ISOLATION=n: */
	303
	304	.macro SWITCH_TO_KERNEL_CR3 scratch_reg:req
	305	.endm
6fd166aa PZ	306	.macro SWITCH_TO_USER_CR3_NOSTACK scratch_reg:req scratch_reg2:req
	307	.endm
	308	.macro SWITCH_TO_USER_CR3_STACK scratch_reg:req
8a09317b DH	309	.endm
	310	.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
	311	.endm
21e94459	312	.macro RESTORE_CR3 scratch_reg:req save_reg:req
8a09317b DH	313	.endm
	314
	315	#endif
	316
18ec54fd JP	317	/*
	318	* Mitigate Spectre v1 for conditional swapgs code paths.
	319	*
	320	* FENCE_SWAPGS_USER_ENTRY is used in the user entry swapgs code path, to
	321	* prevent a speculative swapgs when coming from kernel space.
	322	*
	323	* FENCE_SWAPGS_KERNEL_ENTRY is used in the kernel entry non-swapgs code path,
	324	* to prevent the swapgs from getting speculatively skipped when coming from
	325	* user space.
	326	*/
	327	.macro FENCE_SWAPGS_USER_ENTRY
	328	ALTERNATIVE "", "lfence", X86_FEATURE_FENCE_SWAPGS_USER
	329	.endm
	330	.macro FENCE_SWAPGS_KERNEL_ENTRY
	331	ALTERNATIVE "", "lfence", X86_FEATURE_FENCE_SWAPGS_KERNEL
	332	.endm
	333
afaef01c AP	334	.macro STACKLEAK_ERASE_NOCLOBBER
	335	#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	336	PUSH_AND_CLEAR_REGS
	337	call stackleak_erase
	338	POP_REGS
	339	#endif
	340	.endm
	341
1a338ac3 PZ	342	#endif /* CONFIG_X86_64 */
1a338ac3 PZ	343
afaef01c AP	344	.macro STACKLEAK_ERASE
	345	#ifdef CONFIG_GCC_PLUGIN_STACKLEAK
	346	call stackleak_erase
	347	#endif
	348	.endm
	349
478dc89c AL	350	/*
	351	* This does 'call enter_from_user_mode' unless we can avoid it based on
	352	* kernel config or using the static jump infrastructure.
	353	*/
	354	.macro CALL_enter_from_user_mode
	355	#ifdef CONFIG_CONTEXT_TRACKING
e9666d10	356	#ifdef CONFIG_JUMP_LABEL
e769742d	357	STATIC_JUMP_IF_FALSE .Lafter_call_\@, context_tracking_enabled, def=0
478dc89c AL	358	#endif
	359	call enter_from_user_mode
	360	.Lafter_call_\@:
	361	#endif
	362	.endm
55aedddb PZ	363
	364	#ifdef CONFIG_PARAVIRT_XXL
	365	#define GET_CR2_INTO(reg) GET_CR2_INTO_AX ; _ASM_MOV %_ASM_AX, reg
	366	#else
	367	#define GET_CR2_INTO(reg) _ASM_MOV %cr2, reg
	368	#endif