[linux-2.6-block.git] / arch / x86 / boot / compressed / head_64.S

/*
 *  linux/boot/head.S
 *
 *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
 */

/*
 *  head.S contains the 32-bit startup code.
 *
 * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
 * the page directory will exist. The startup code will be overwritten by
 * the page directory. [According to comments etc elsewhere on a compressed
 * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
 *
 * Page 0 is deliberately kept safe, since System Management Mode code in 
 * laptops may need to access the BIOS data stored there.  This is also
 * useful for future device drivers that either access the BIOS via VM86 
 * mode.
 */

/*
 * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
 */
	.code32
	.text

#include <linux/init.h>
#include <linux/linkage.h>
#include <asm/segment.h>
#include <asm/boot.h>
#include <asm/msr.h>
#include <asm/processor-flags.h>
#include <asm/asm-offsets.h>

	__HEAD
	.code32
ENTRY(startup_32)
	/*
	 * 32bit entry is 0 and it is ABI so immutable!
	 * If we come here directly from a bootloader,
	 * kernel(text+data+bss+brk) ramdisk, zero_page, command line
	 * all need to be under the 4G limit.
	 */
	cld
	/*
	 * Test KEEP_SEGMENTS flag to see if the bootloader is asking
	 * us to not reload segments
	 */
	testb $(1<<6), BP_loadflags(%esi)
	jnz 1f

	cli
	movl	$(__BOOT_DS), %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
1:

/*
 * Calculate the delta between where we were compiled to run
 * at and where we were actually loaded at.  This can only be done
 * with a short local call on x86.  Nothing  else will tell us what
 * address we are running at.  The reserved chunk of the real-mode
 * data at 0x1e4 (defined as a scratch field) are used as the stack
 * for this calculation. Only 4 bytes are needed.
 */
	leal	(BP_scratch+4)(%esi), %esp
	call	1f
1:	popl	%ebp
	subl	$1b, %ebp

/* setup a stack and make sure cpu supports long mode. */
	movl	$boot_stack_end, %eax
	addl	%ebp, %eax
	movl	%eax, %esp

	call	verify_cpu
	testl	%eax, %eax
	jnz	no_longmode

/*
 * Compute the delta between where we were compiled to run at
 * and where the code will actually run at.
 *
 * %ebp contains the address we are loaded at by the boot loader and %ebx
 * contains the address where we should move the kernel image temporarily
 * for safe in-place decompression.
 */

#ifdef CONFIG_RELOCATABLE
	movl	%ebp, %ebx
	movl	BP_kernel_alignment(%esi), %eax
	decl	%eax
	addl	%eax, %ebx
	notl	%eax
	andl	%eax, %ebx
	cmpl	$LOAD_PHYSICAL_ADDR, %ebx
	jge	1f
#endif
	movl	$LOAD_PHYSICAL_ADDR, %ebx
1:

	/* Target address to relocate to for decompression */
	addl	$z_extract_offset, %ebx

/*
 * Prepare for entering 64 bit mode
 */

	/* Load new GDT with the 64bit segments using 32bit descriptor */
	leal	gdt(%ebp), %eax
	movl	%eax, gdt+2(%ebp)
	lgdt	gdt(%ebp)

	/* Enable PAE mode */
	movl	%cr4, %eax
	orl	$X86_CR4_PAE, %eax
	movl	%eax, %cr4

 /*
  * Build early 4G boot pagetable
  */
	/* Initialize Page tables to 0 */
	leal	pgtable(%ebx), %edi
	xorl	%eax, %eax
	movl	$((4096*6)/4), %ecx
	rep	stosl

	/* Build Level 4 */
	leal	pgtable + 0(%ebx), %edi
	leal	0x1007 (%edi), %eax
	movl	%eax, 0(%edi)

	/* Build Level 3 */
	leal	pgtable + 0x1000(%ebx), %edi
	leal	0x1007(%edi), %eax
	movl	$4, %ecx
1:	movl	%eax, 0x00(%edi)
	addl	$0x00001000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Build Level 2 */
	leal	pgtable + 0x2000(%ebx), %edi
	movl	$0x00000183, %eax
	movl	$2048, %ecx
1:	movl	%eax, 0(%edi)
	addl	$0x00200000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Enable the boot page tables */
	leal	pgtable(%ebx), %eax
	movl	%eax, %cr3

	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr
	btsl	$_EFER_LME, %eax
	wrmsr

	/* After gdt is loaded */
	xorl	%eax, %eax
	lldt	%ax
	movl    $0x20, %eax
	ltr	%ax

	/*
	 * Setup for the jump to 64bit mode
	 *
	 * When the jump is performend we will be in long mode but
	 * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	 * (and in turn EFER.LMA = 1).	To jump into 64bit mode we use
	 * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	 * We place all of the values on our mini stack so lret can
	 * used to perform that far jump.
	 */
	pushl	$__KERNEL_CS
	leal	startup_64(%ebp), %eax
#ifdef CONFIG_EFI_MIXED
	movl	efi32_config(%ebp), %ebx
	cmp	$0, %ebx
	jz	1f
	leal	handover_entry(%ebp), %eax
1:
#endif
	pushl	%eax

	/* Enter paged protected Mode, activating Long Mode */
	movl	$(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
	movl	%eax, %cr0

	/* Jump from 32bit compatibility mode into 64bit mode. */
	lret
ENDPROC(startup_32)

#ifdef CONFIG_EFI_MIXED
	.org 0x190
ENTRY(efi32_stub_entry)
	add	$0x4, %esp		/* Discard return address */
	popl	%ecx
	popl	%edx
	popl	%esi

	leal	(BP_scratch+4)(%esi), %esp
	call	1f
1:	pop	%ebp
	subl	$1b, %ebp

	movl	%ecx, efi32_config(%ebp)
	movl	%edx, efi32_config+8(%ebp)
	sgdtl	efi32_boot_gdt(%ebp)

	leal	efi32_config(%ebp), %eax
	movl	%eax, efi_config(%ebp)

	jmp	startup_32
ENDPROC(efi32_stub_entry)
#endif

	.code64
	.org 0x200
ENTRY(startup_64)
	/*
	 * 64bit entry is 0x200 and it is ABI so immutable!
	 * We come here either from startup_32 or directly from a
	 * 64bit bootloader.
	 * If we come here from a bootloader, kernel(text+data+bss+brk),
	 * ramdisk, zero_page, command line could be above 4G.
	 * We depend on an identity mapped page table being provided
	 * that maps our entire kernel(text+data+bss+brk), zero page
	 * and command line.
	 */
#ifdef CONFIG_EFI_STUB
	/*
	 * The entry point for the PE/COFF executable is efi_pe_entry, so
	 * only legacy boot loaders will execute this jmp.
	 */
	jmp	preferred_addr

ENTRY(efi_pe_entry)
	movq	%rcx, efi64_config(%rip)	/* Handle */
	movq	%rdx, efi64_config+8(%rip) /* EFI System table pointer */

	leaq	efi64_config(%rip), %rax
	movq	%rax, efi_config(%rip)

	call	1f
1:	popq	%rbp
	subq	$1b, %rbp

	/*
	 * Relocate efi_config->call().
	 */
	addq	%rbp, efi64_config+88(%rip)

	movq	%rax, %rdi
	call	make_boot_params
	cmpq	$0,%rax
	je	fail
	mov	%rax, %rsi
	leaq	startup_32(%rip), %rax
	movl	%eax, BP_code32_start(%rsi)
	jmp	2f		/* Skip the relocation */

handover_entry:
	call	1f
1:	popq	%rbp
	subq	$1b, %rbp

	/*
	 * Relocate efi_config->call().
	 */
	movq	efi_config(%rip), %rax
	addq	%rbp, 88(%rax)
2:
	movq	efi_config(%rip), %rdi
	call	efi_main
	movq	%rax,%rsi
	cmpq	$0,%rax
	jne	2f
fail:
	/* EFI init failed, so hang. */
	hlt
	jmp	fail
2:
	movl	BP_code32_start(%esi), %eax
	leaq	preferred_addr(%rax), %rax
	jmp	*%rax

preferred_addr:
#endif

	/* Setup data segments. */
	xorl	%eax, %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
	movl	%eax, %fs
	movl	%eax, %gs

	/*
	 * Compute the decompressed kernel start address.  It is where
	 * we were loaded at aligned to a 2M boundary. %rbp contains the
	 * decompressed kernel start address.
	 *
	 * If it is a relocatable kernel then decompress and run the kernel
	 * from load address aligned to 2MB addr, otherwise decompress and
	 * run the kernel from LOAD_PHYSICAL_ADDR
	 *
	 * We cannot rely on the calculation done in 32-bit mode, since we
	 * may have been invoked via the 64-bit entry point.
	 */

	/* Start with the delta to where the kernel will run at. */
#ifdef CONFIG_RELOCATABLE
	leaq	startup_32(%rip) /* - $startup_32 */, %rbp
	movl	BP_kernel_alignment(%rsi), %eax
	decl	%eax
	addq	%rax, %rbp
	notq	%rax
	andq	%rax, %rbp
	cmpq	$LOAD_PHYSICAL_ADDR, %rbp
	jge	1f
#endif
	movq	$LOAD_PHYSICAL_ADDR, %rbp
1:

	/* Target address to relocate to for decompression */
	leaq	z_extract_offset(%rbp), %rbx

	/* Set up the stack */
	leaq	boot_stack_end(%rbx), %rsp

	/* Zero EFLAGS */
	pushq	$0
	popfq

/*
 * Copy the compressed kernel to the end of our buffer
 * where decompression in place becomes safe.
 */
	pushq	%rsi
	leaq	(_bss-8)(%rip), %rsi
	leaq	(_bss-8)(%rbx), %rdi
	movq	$_bss /* - $startup_32 */, %rcx
	shrq	$3, %rcx
	std
	rep	movsq
	cld
	popq	%rsi

/*
 * Jump to the relocated address.
 */
	leaq	relocated(%rbx), %rax
	jmp	*%rax

#ifdef CONFIG_EFI_STUB
	.org 0x390
ENTRY(efi64_stub_entry)
	movq	%rdi, efi64_config(%rip)	/* Handle */
	movq	%rsi, efi64_config+8(%rip) /* EFI System table pointer */

	leaq	efi64_config(%rip), %rax
	movq	%rax, efi_config(%rip)

	movq	%rdx, %rsi
	jmp	handover_entry
ENDPROC(efi64_stub_entry)
#endif

	.text
relocated:

/*
 * Clear BSS (stack is currently empty)
 */
	xorl	%eax, %eax
	leaq    _bss(%rip), %rdi
	leaq    _ebss(%rip), %rcx
	subq	%rdi, %rcx
	shrq	$3, %rcx
	rep	stosq

/*
 * Adjust our own GOT
 */
	leaq	_got(%rip), %rdx
	leaq	_egot(%rip), %rcx
1:
	cmpq	%rcx, %rdx
	jae	2f
	addq	%rbx, (%rdx)
	addq	$8, %rdx
	jmp	1b
2:
	
/*
 * Do the decompression, and jump to the new kernel..
 */
	pushq	%rsi			/* Save the real mode argument */
	movq	$z_run_size, %r9	/* size of kernel with .bss and .brk */
	pushq	%r9
	movq	%rsi, %rdi		/* real mode address */
	leaq	boot_heap(%rip), %rsi	/* malloc area for uncompression */
	leaq	input_data(%rip), %rdx  /* input_data */
	movl	$z_input_len, %ecx	/* input_len */
	movq	%rbp, %r8		/* output target address */
	movq	$z_output_len, %r9	/* decompressed length, end of relocs */
	call	decompress_kernel	/* returns kernel location in %rax */
	popq	%r9
	popq	%rsi

/*
 * Jump to the decompressed kernel.
 */
	jmp	*%rax

	.code32
no_longmode:
	/* This isn't an x86-64 CPU so hang */
1:
	hlt
	jmp     1b

#include "../../kernel/verify_cpu.S"

	.data
gdt:
	.word	gdt_end - gdt
	.long	gdt
	.word	0
	.quad	0x0000000000000000	/* NULL descriptor */
	.quad	0x00af9a000000ffff	/* __KERNEL_CS */
	.quad	0x00cf92000000ffff	/* __KERNEL_DS */
	.quad	0x0080890000000000	/* TS descriptor */
	.quad   0x0000000000000000	/* TS continued */
gdt_end:

#ifdef CONFIG_EFI_STUB
efi_config:
	.quad	0

#ifdef CONFIG_EFI_MIXED
	.global efi32_config
efi32_config:
	.fill	11,8,0
	.quad	efi64_thunk
	.byte	0
#endif

	.global efi64_config
efi64_config:
	.fill	11,8,0
	.quad	efi_call
	.byte	1
#endif /* CONFIG_EFI_STUB */

/*
 * Stack and heap for uncompression
 */
	.bss
	.balign 4
boot_heap:
	.fill BOOT_HEAP_SIZE, 1, 0
boot_stack:
	.fill BOOT_STACK_SIZE, 1, 0
boot_stack_end:

/*
 * Space for page tables (not in .bss so not zeroed)
 */
	.section ".pgtable","a",@nobits
	.balign 4096
pgtable:
	.fill 6*4096, 1, 0
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/boot/head.S
	3	*
	4	* Copyright (C) 1991, 1992, 1993 Linus Torvalds
1da177e4 LT	5	*/
	6
	7	/*
	8	* head.S contains the 32-bit startup code.
	9	*
	10	* NOTE!!! Startup happens at absolute address 0x00001000, which is also where
	11	* the page directory will exist. The startup code will be overwritten by
	12	* the page directory. [According to comments etc elsewhere on a compressed
	13	* kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
	14	*
	15	* Page 0 is deliberately kept safe, since System Management Mode code in
	16	* laptops may need to access the BIOS data stored there. This is also
	17	* useful for future device drivers that either access the BIOS via VM86
	18	* mode.
	19	*/
	20
	21	/*
f4549448	22	* High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
1da177e4	23	*/
b40d68d5 PA	24	.code32
b40d68d5 PA	25	.text
1da177e4	26
1dc818c1	27	#include <linux/init.h>
1da177e4 LT	28	#include <linux/linkage.h>
1da177e4 LT	29	#include <asm/segment.h>
7c539764	30	#include <asm/boot.h>
1ab60e0f	31	#include <asm/msr.h>
e83e31f4	32	#include <asm/processor-flags.h>
bd53147d	33	#include <asm/asm-offsets.h>
1da177e4	34
1dc818c1	35	__HEAD
1da177e4	36	.code32
2d4eeecb	37	ENTRY(startup_32)
8ee2f2df YL	38	/*
	39	* 32bit entry is 0 and it is ABI so immutable!
	40	* If we come here directly from a bootloader,
	41	* kernel(text+data+bss+brk) ramdisk, zero_page, command line
	42	* all need to be under the 4G limit.
	43	*/
1da177e4	44	cld
b40d68d5 PA	45	/*
	46	* Test KEEP_SEGMENTS flag to see if the bootloader is asking
	47	* us to not reload segments
	48	*/
bd53147d EB	49	testb $(1<<6), BP_loadflags(%esi)
	50	jnz 1f
	51
1da177e4	52	cli
2dead15f	53	movl $(__BOOT_DS), %eax
1ab60e0f VG	54	movl %eax, %ds
	55	movl %eax, %es
	56	movl %eax, %ss
bd53147d	57	1:
1ab60e0f	58
b40d68d5 PA	59	/*
b40d68d5 PA	60	* Calculate the delta between where we were compiled to run
1ab60e0f VG	61	* at and where we were actually loaded at. This can only be done
	62	* with a short local call on x86. Nothing else will tell us what
	63	* address we are running at. The reserved chunk of the real-mode
85414b69 PA	64	* data at 0x1e4 (defined as a scratch field) are used as the stack
85414b69 PA	65	* for this calculation. Only 4 bytes are needed.
1ab60e0f	66	*/
bd2a3698	67	leal (BP_scratch+4)(%esi), %esp
1ab60e0f VG	68	call 1f
	69	1: popl %ebp
	70	subl $1b, %ebp
	71
a4831e08	72	/* setup a stack and make sure cpu supports long mode. */
7c539764	73	movl $boot_stack_end, %eax
a4831e08 VG	74	addl %ebp, %eax
	75	movl %eax, %esp
	76
	77	call verify_cpu
	78	testl %eax, %eax
	79	jnz no_longmode
	80
b40d68d5 PA	81	/*
b40d68d5 PA	82	* Compute the delta between where we were compiled to run at
1ab60e0f	83	* and where the code will actually run at.
b40d68d5 PA	84	*
b40d68d5 PA	85	* %ebp contains the address we are loaded at by the boot loader and %ebx
1ab60e0f VG	86	* contains the address where we should move the kernel image temporarily
	87	* for safe in-place decompression.
	88	*/
	89
	90	#ifdef CONFIG_RELOCATABLE
	91	movl %ebp, %ebx
37ba7ab5 PA	92	movl BP_kernel_alignment(%esi), %eax
	93	decl %eax
	94	addl %eax, %ebx
	95	notl %eax
	96	andl %eax, %ebx
8ab3820f KC	97	cmpl $LOAD_PHYSICAL_ADDR, %ebx
8ab3820f KC	98	jge 1f
1ab60e0f	99	#endif
8ab3820f KC	100	movl $LOAD_PHYSICAL_ADDR, %ebx
8ab3820f KC	101	1:
1ab60e0f	102
02a884c0 PA	103	/* Target address to relocate to for decompression */
02a884c0 PA	104	addl $z_extract_offset, %ebx
1da177e4 LT	105
1da177e4 LT	106	/*
1ab60e0f	107	* Prepare for entering 64 bit mode
1da177e4	108	*/
1ab60e0f VG	109
	110	/* Load new GDT with the 64bit segments using 32bit descriptor */
	111	leal gdt(%ebp), %eax
	112	movl %eax, gdt+2(%ebp)
	113	lgdt gdt(%ebp)
	114
	115	/* Enable PAE mode */
108d3f44 MF	116	movl %cr4, %eax
108d3f44 MF	117	orl $X86_CR4_PAE, %eax
1ab60e0f VG	118	movl %eax, %cr4
	119
	120	/*
	121	* Build early 4G boot pagetable
	122	*/
b40d68d5	123	/* Initialize Page tables to 0 */
1ab60e0f VG	124	leal pgtable(%ebx), %edi
	125	xorl %eax, %eax
	126	movl $((4096*6)/4), %ecx
	127	rep stosl
	128
	129	/* Build Level 4 */
	130	leal pgtable + 0(%ebx), %edi
	131	leal 0x1007 (%edi), %eax
	132	movl %eax, 0(%edi)
	133
	134	/* Build Level 3 */
	135	leal pgtable + 0x1000(%ebx), %edi
	136	leal 0x1007(%edi), %eax
	137	movl $4, %ecx
	138	1: movl %eax, 0x00(%edi)
	139	addl $0x00001000, %eax
	140	addl $8, %edi
	141	decl %ecx
	142	jnz 1b
	143
	144	/* Build Level 2 */
	145	leal pgtable + 0x2000(%ebx), %edi
	146	movl $0x00000183, %eax
	147	movl $2048, %ecx
	148	1: movl %eax, 0(%edi)
	149	addl $0x00200000, %eax
	150	addl $8, %edi
	151	decl %ecx
	152	jnz 1b
	153
	154	/* Enable the boot page tables */
	155	leal pgtable(%ebx), %eax
	156	movl %eax, %cr3
	157
	158	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	159	movl $MSR_EFER, %ecx
	160	rdmsr
	161	btsl $_EFER_LME, %eax
	162	wrmsr
	163
d3c433bf YL	164	/* After gdt is loaded */
	165	xorl %eax, %eax
	166	lldt %ax
	167	movl $0x20, %eax
	168	ltr %ax
	169
b40d68d5 PA	170	/*
b40d68d5 PA	171	* Setup for the jump to 64bit mode
1ab60e0f VG	172	*
	173	* When the jump is performend we will be in long mode but
	174	* in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	175	* (and in turn EFER.LMA = 1). To jump into 64bit mode we use
	176	* the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	177	* We place all of the values on our mini stack so lret can
	178	* used to perform that far jump.
	179	*/
	180	pushl $__KERNEL_CS
	181	leal startup_64(%ebp), %eax
b8ff87a6 MF	182	#ifdef CONFIG_EFI_MIXED
	183	movl efi32_config(%ebp), %ebx
	184	cmp $0, %ebx
	185	jz 1f
	186	leal handover_entry(%ebp), %eax
	187	1:
	188	#endif
1ab60e0f VG	189	pushl %eax
	190
	191	/* Enter paged protected Mode, activating Long Mode */
e83e31f4	192	movl $(X86_CR0_PG \| X86_CR0_PE), %eax /* Enable Paging and Protected mode */
1ab60e0f VG	193	movl %eax, %cr0
	194
	195	/* Jump from 32bit compatibility mode into 64bit mode. */
	196	lret
2d4eeecb	197	ENDPROC(startup_32)
1ab60e0f	198
b8ff87a6 MF	199	#ifdef CONFIG_EFI_MIXED
	200	.org 0x190
	201	ENTRY(efi32_stub_entry)
	202	add $0x4, %esp /* Discard return address */
	203	popl %ecx
	204	popl %edx
	205	popl %esi
	206
	207	leal (BP_scratch+4)(%esi), %esp
	208	call 1f
	209	1: pop %ebp
	210	subl $1b, %ebp
	211
	212	movl %ecx, efi32_config(%ebp)
	213	movl %edx, efi32_config+8(%ebp)
	214	sgdtl efi32_boot_gdt(%ebp)
	215
	216	leal efi32_config(%ebp), %eax
	217	movl %eax, efi_config(%ebp)
	218
	219	jmp startup_32
	220	ENDPROC(efi32_stub_entry)
	221	#endif
	222
1ab60e0f	223	.code64
a4831e08	224	.org 0x200
1ab60e0f	225	ENTRY(startup_64)
b40d68d5	226	/*
8ee2f2df	227	* 64bit entry is 0x200 and it is ABI so immutable!
b40d68d5	228	* We come here either from startup_32 or directly from a
8ee2f2df YL	229	* 64bit bootloader.
	230	* If we come here from a bootloader, kernel(text+data+bss+brk),
	231	* ramdisk, zero_page, command line could be above 4G.
	232	* We depend on an identity mapped page table being provided
	233	* that maps our entire kernel(text+data+bss+brk), zero page
	234	* and command line.
1ab60e0f	235	*/
291f3632	236	#ifdef CONFIG_EFI_STUB
b1994304	237	/*
99f857db DW	238	* The entry point for the PE/COFF executable is efi_pe_entry, so
99f857db DW	239	* only legacy boot loaders will execute this jmp.
b1994304 MF	240	*/
	241	jmp preferred_addr
	242
99f857db	243	ENTRY(efi_pe_entry)
54b52d87 MF	244	movq %rcx, efi64_config(%rip) /* Handle */
	245	movq %rdx, efi64_config+8(%rip) /* EFI System table pointer */
	246
	247	leaq efi64_config(%rip), %rax
	248	movq %rax, efi_config(%rip)
	249
	250	call 1f
	251	1: popq %rbp
	252	subq $1b, %rbp
	253
	254	/*
f3670394	255	* Relocate efi_config->call().
54b52d87 MF	256	*/
	257	addq %rbp, efi64_config+88(%rip)
	258
	259	movq %rax, %rdi
9ca8f72a MF	260	call make_boot_params
9ca8f72a MF	261	cmpq $0,%rax
54b52d87 MF	262	je fail
54b52d87 MF	263	mov %rax, %rsi
7e8213c1 MF	264	leaq startup_32(%rip), %rax
7e8213c1 MF	265	movl %eax, BP_code32_start(%rsi)
54b52d87	266	jmp 2f /* Skip the relocation */
9ca8f72a	267
b8ff87a6	268	handover_entry:
54b52d87 MF	269	call 1f
	270	1: popq %rbp
	271	subq $1b, %rbp
	272
	273	/*
f3670394	274	* Relocate efi_config->call().
54b52d87 MF	275	*/
	276	movq efi_config(%rip), %rax
	277	addq %rbp, 88(%rax)
54b52d87 MF	278	2:
54b52d87 MF	279	movq efi_config(%rip), %rdi
291f3632	280	call efi_main
291f3632	281	movq %rax,%rsi
b1994304 MF	282	cmpq $0,%rax
b1994304 MF	283	jne 2f
54b52d87	284	fail:
b1994304 MF	285	/* EFI init failed, so hang. */
b1994304 MF	286	hlt
54b52d87	287	jmp fail
b1994304	288	2:
7e8213c1	289	movl BP_code32_start(%esi), %eax
291f3632 MF	290	leaq preferred_addr(%rax), %rax
	291	jmp *%rax
	292
	293	preferred_addr:
	294	#endif
1ab60e0f VG	295
	296	/* Setup data segments. */
	297	xorl %eax, %eax
	298	movl %eax, %ds
	299	movl %eax, %es
	300	movl %eax, %ss
08da5a2c ZA	301	movl %eax, %fs
08da5a2c ZA	302	movl %eax, %gs
1ab60e0f	303
b40d68d5 PA	304	/*
b40d68d5 PA	305	* Compute the decompressed kernel start address. It is where
1ab60e0f VG	306	* we were loaded at aligned to a 2M boundary. %rbp contains the
	307	* decompressed kernel start address.
	308	*
	309	* If it is a relocatable kernel then decompress and run the kernel
	310	* from load address aligned to 2MB addr, otherwise decompress and
40b387a8	311	* run the kernel from LOAD_PHYSICAL_ADDR
02a884c0 PA	312	*
	313	* We cannot rely on the calculation done in 32-bit mode, since we
	314	* may have been invoked via the 64-bit entry point.
1ab60e0f VG	315	*/
	316
	317	/* Start with the delta to where the kernel will run at. */
	318	#ifdef CONFIG_RELOCATABLE
	319	leaq startup_32(%rip) /* - $startup_32 */, %rbp
37ba7ab5 PA	320	movl BP_kernel_alignment(%rsi), %eax
	321	decl %eax
	322	addq %rax, %rbp
	323	notq %rax
	324	andq %rax, %rbp
8ab3820f KC	325	cmpq $LOAD_PHYSICAL_ADDR, %rbp
8ab3820f KC	326	jge 1f
1ab60e0f	327	#endif
8ab3820f KC	328	movq $LOAD_PHYSICAL_ADDR, %rbp
8ab3820f KC	329	1:
1ab60e0f	330
02a884c0 PA	331	/* Target address to relocate to for decompression */
02a884c0 PA	332	leaq z_extract_offset(%rbp), %rbx
1ab60e0f	333
0a137736 PA	334	/* Set up the stack */
	335	leaq boot_stack_end(%rbx), %rsp
	336
	337	/* Zero EFLAGS */
	338	pushq $0
	339	popfq
	340
b40d68d5 PA	341	/*
b40d68d5 PA	342	* Copy the compressed kernel to the end of our buffer
1ab60e0f VG	343	* where decompression in place becomes safe.
1ab60e0f VG	344	*/
36d3793c PA	345	pushq %rsi
	346	leaq (_bss-8)(%rip), %rsi
	347	leaq (_bss-8)(%rbx), %rdi
5b11f1ce	348	movq $_bss /* - $startup_32 */, %rcx
36d3793c PA	349	shrq $3, %rcx
	350	std
	351	rep movsq
	352	cld
	353	popq %rsi
1ab60e0f VG	354
	355	/*
	356	* Jump to the relocated address.
	357	*/
	358	leaq relocated(%rbx), %rax
	359	jmp *%rax
	360
b8ff87a6 MF	361	#ifdef CONFIG_EFI_STUB
	362	.org 0x390
	363	ENTRY(efi64_stub_entry)
	364	movq %rdi, efi64_config(%rip) /* Handle */
	365	movq %rsi, efi64_config+8(%rip) /* EFI System table pointer */
	366
	367	leaq efi64_config(%rip), %rax
	368	movq %rax, efi_config(%rip)
	369
	370	movq %rdx, %rsi
	371	jmp handover_entry
	372	ENDPROC(efi64_stub_entry)
	373	#endif
	374
b40d68d5	375	.text
1ab60e0f VG	376	relocated:
1ab60e0f VG	377
1da177e4	378	/*
0a137736	379	* Clear BSS (stack is currently empty)
1da177e4	380	*/
36d3793c PA	381	xorl %eax, %eax
	382	leaq _bss(%rip), %rdi
	383	leaq _ebss(%rip), %rcx
1ab60e0f	384	subq %rdi, %rcx
36d3793c PA	385	shrq $3, %rcx
36d3793c PA	386	rep stosq
1ab60e0f	387
f3670394 LT	388	/*
	389	* Adjust our own GOT
	390	*/
	391	leaq _got(%rip), %rdx
	392	leaq _egot(%rip), %rcx
	393	1:
	394	cmpq %rcx, %rdx
	395	jae 2f
	396	addq %rbx, (%rdx)
	397	addq $8, %rdx
	398	jmp 1b
	399	2:
	400
1da177e4 LT	401	/*
	402	* Do the decompression, and jump to the new kernel..
	403	*/
02a884c0	404	pushq %rsi /* Save the real mode argument */
e6023367 JM	405	movq $z_run_size, %r9 /* size of kernel with .bss and .brk */
e6023367 JM	406	pushq %r9
02a884c0 PA	407	movq %rsi, %rdi /* real mode address */
	408	leaq boot_heap(%rip), %rsi /* malloc area for uncompression */
	409	leaq input_data(%rip), %rdx /* input_data */
	410	movl $z_input_len, %ecx /* input_len */
	411	movq %rbp, %r8 /* output target address */
e6023367	412	movq $z_output_len, %r9 /* decompressed length, end of relocs */
8ab3820f	413	call decompress_kernel /* returns kernel location in %rax */
e6023367	414	popq %r9
1ab60e0f	415	popq %rsi
1da177e4	416
1da177e4	417	/*
1ab60e0f	418	* Jump to the decompressed kernel.
1da177e4	419	*/
8ab3820f	420	jmp *%rax
1da177e4	421
187a8a73 YL	422	.code32
	423	no_longmode:
	424	/* This isn't an x86-64 CPU so hang */
	425	1:
	426	hlt
	427	jmp 1b
	428
	429	#include "../../kernel/verify_cpu.S"
	430
1ab60e0f VG	431	.data
	432	gdt:
	433	.word gdt_end - gdt
	434	.long gdt
	435	.word 0
	436	.quad 0x0000000000000000 /* NULL descriptor */
	437	.quad 0x00af9a000000ffff /* __KERNEL_CS */
	438	.quad 0x00cf92000000ffff /* __KERNEL_DS */
08da5a2c ZA	439	.quad 0x0080890000000000 /* TS descriptor */
08da5a2c ZA	440	.quad 0x0000000000000000 /* TS continued */
1ab60e0f	441	gdt_end:
7c539764	442
3db4cafd	443	#ifdef CONFIG_EFI_STUB
54b52d87 MF	444	efi_config:
	445	.quad 0
	446
b8ff87a6 MF	447	#ifdef CONFIG_EFI_MIXED
	448	.global efi32_config
	449	efi32_config:
	450	.fill 11,8,0
	451	.quad efi64_thunk
	452	.byte 0
	453	#endif
	454
54b52d87 MF	455	.global efi64_config
	456	efi64_config:
	457	.fill 11,8,0
62fa6e69	458	.quad efi_call
54b52d87	459	.byte 1
3db4cafd MF	460	#endif /* CONFIG_EFI_STUB */
3db4cafd MF	461
b40d68d5 PA	462	/*
	463	* Stack and heap for uncompression
	464	*/
	465	.bss
	466	.balign 4
7c539764 AH	467	boot_heap:
	468	.fill BOOT_HEAP_SIZE, 1, 0
	469	boot_stack:
	470	.fill BOOT_STACK_SIZE, 1, 0
	471	boot_stack_end:
5b11f1ce PA	472
	473	/*
	474	* Space for page tables (not in .bss so not zeroed)
	475	*/
	476	.section ".pgtable","a",@nobits
	477	.balign 4096
	478	pgtable:
	479	.fill 6*4096, 1, 0