[linux-block.git] / arch / sparc / lib / copy_in_user.S

/* SPDX-License-Identifier: GPL-2.0 */
/* copy_in_user.S: Copy from userspace to userspace.
 *
 * Copyright (C) 1999, 2000, 2004 David S. Miller (davem@redhat.com)
 */

#include <linux/linkage.h>
#include <asm/asi.h>
#include <asm/export.h>

#define XCC xcc

#define EX(x,y,z)		\
98:	x,y;			\
	.section __ex_table,"a";\
	.align 4;		\
	.word 98b, z;		\
	.text;			\
	.align 4;

#define EX_O4(x,y) EX(x,y,__retl_o4_plus_8)
#define EX_O2_4(x,y) EX(x,y,__retl_o2_plus_4)
#define EX_O2_1(x,y) EX(x,y,__retl_o2_plus_1)

	.register	%g2,#scratch
	.register	%g3,#scratch

	.text
__retl_o4_plus_8:
	add	%o4, %o2, %o4
	retl
	 add	%o4, 8, %o0
__retl_o2_plus_4:
	retl
	 add	%o2, 4, %o0
__retl_o2_plus_1:
	retl
	 add	%o2, 1, %o0

	.align	32

	/* Don't try to get too fancy here, just nice and
	 * simple.  This is predominantly used for well aligned
	 * small copies in the compat layer.  It is also used
	 * to copy register windows around during thread cloning.
	 */

ENTRY(raw_copy_in_user)	/* %o0=dst, %o1=src, %o2=len */
	cmp		%o2, 0
	be,pn		%XCC, 85f
	 or		%o0, %o1, %o3
	cmp		%o2, 16
	bleu,a,pn	%XCC, 80f
	 or		%o3, %o2, %o3

	/* 16 < len <= 64 */
	andcc		%o3, 0x7, %g0
	bne,pn		%XCC, 90f
	 nop

	andn		%o2, 0x7, %o4
	and		%o2, 0x7, %o2
1:	subcc		%o4, 0x8, %o4
	EX_O4(ldxa [%o1] %asi, %o5)
	EX_O4(stxa %o5, [%o0] %asi)
	add		%o1, 0x8, %o1
	bgu,pt		%XCC, 1b
	 add		%o0, 0x8, %o0
	andcc		%o2, 0x4, %g0
	be,pt		%XCC, 1f
	 nop
	sub		%o2, 0x4, %o2
	EX_O2_4(lduwa [%o1] %asi, %o5)
	EX_O2_4(stwa %o5, [%o0] %asi)
	add		%o1, 0x4, %o1
	add		%o0, 0x4, %o0
1:	cmp		%o2, 0
	be,pt		%XCC, 85f
	 nop
	ba,pt		%xcc, 90f
	 nop

80:	/* 0 < len <= 16 */
	andcc		%o3, 0x3, %g0
	bne,pn		%XCC, 90f
	 nop

82:
	subcc		%o2, 4, %o2
	EX_O2_4(lduwa [%o1] %asi, %g1)
	EX_O2_4(stwa %g1, [%o0] %asi)
	add		%o1, 4, %o1
	bgu,pt		%XCC, 82b
	 add		%o0, 4, %o0

85:	retl
	 clr		%o0

	.align	32
90:
	subcc		%o2, 1, %o2
	EX_O2_1(lduba [%o1] %asi, %g1)
	EX_O2_1(stba %g1, [%o0] %asi)
	add		%o1, 1, %o1
	bgu,pt		%XCC, 90b
	 add		%o0, 1, %o0
	retl
	 clr		%o0
ENDPROC(raw_copy_in_user)
EXPORT_SYMBOL(raw_copy_in_user)
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
1da177e4 LT	2	/* copy_in_user.S: Copy from userspace to userspace.
	3	*
	4	* Copyright (C) 1999, 2000, 2004 David S. Miller (davem@redhat.com)
	5	*/
	6
aeb39876	7	#include <linux/linkage.h>
1da177e4	8	#include <asm/asi.h>
d3867f04	9	#include <asm/export.h>
1da177e4 LT	10
	11	#define XCC xcc
	12
0096ac9f	13	#define EX(x,y,z) \
1da177e4	14	98: x,y; \
4d000d5b	15	.section __ex_table,"a";\
1da177e4	16	.align 4; \
0096ac9f	17	.word 98b, z; \
1da177e4 LT	18	.text; \
	19	.align 4;
	20
0096ac9f DM	21	#define EX_O4(x,y) EX(x,y,__retl_o4_plus_8)
	22	#define EX_O2_4(x,y) EX(x,y,__retl_o2_plus_4)
	23	#define EX_O2_1(x,y) EX(x,y,__retl_o2_plus_1)
	24
1da177e4 LT	25	.register %g2,#scratch
	26	.register %g3,#scratch
	27
	28	.text
0096ac9f DM	29	__retl_o4_plus_8:
	30	add %o4, %o2, %o4
	31	retl
	32	add %o4, 8, %o0
	33	__retl_o2_plus_4:
	34	retl
	35	add %o2, 4, %o0
	36	__retl_o2_plus_1:
	37	retl
	38	add %o2, 1, %o0
	39
1da177e4 LT	40	.align 32
	41
	42	/* Don't try to get too fancy here, just nice and
	43	* simple. This is predominantly used for well aligned
	44	* small copies in the compat layer. It is also used
	45	* to copy register windows around during thread cloning.
	46	*/
	47
31af2f36	48	ENTRY(raw_copy_in_user) /* %o0=dst, %o1=src, %o2=len */
1da177e4 LT	49	cmp %o2, 0
	50	be,pn %XCC, 85f
	51	or %o0, %o1, %o3
	52	cmp %o2, 16
	53	bleu,a,pn %XCC, 80f
	54	or %o3, %o2, %o3
	55
	56	/* 16 < len <= 64 */
	57	andcc %o3, 0x7, %g0
	58	bne,pn %XCC, 90f
aeb39876	59	nop
1da177e4 LT	60
	61	andn %o2, 0x7, %o4
	62	and %o2, 0x7, %o2
	63	1: subcc %o4, 0x8, %o4
0096ac9f DM	64	EX_O4(ldxa [%o1] %asi, %o5)
0096ac9f DM	65	EX_O4(stxa %o5, [%o0] %asi)
aeb39876	66	add %o1, 0x8, %o1
1da177e4	67	bgu,pt %XCC, 1b
aeb39876	68	add %o0, 0x8, %o0
1da177e4 LT	69	andcc %o2, 0x4, %g0
	70	be,pt %XCC, 1f
	71	nop
	72	sub %o2, 0x4, %o2
0096ac9f DM	73	EX_O2_4(lduwa [%o1] %asi, %o5)
0096ac9f DM	74	EX_O2_4(stwa %o5, [%o0] %asi)
1da177e4	75	add %o1, 0x4, %o1
aeb39876	76	add %o0, 0x4, %o0
1da177e4 LT	77	1: cmp %o2, 0
	78	be,pt %XCC, 85f
	79	nop
	80	ba,pt %xcc, 90f
	81	nop
	82
	83	80: /* 0 < len <= 16 */
	84	andcc %o3, 0x3, %g0
	85	bne,pn %XCC, 90f
aeb39876	86	nop
1da177e4 LT	87
	88	82:
	89	subcc %o2, 4, %o2
0096ac9f DM	90	EX_O2_4(lduwa [%o1] %asi, %g1)
0096ac9f DM	91	EX_O2_4(stwa %g1, [%o0] %asi)
aeb39876	92	add %o1, 4, %o1
1da177e4	93	bgu,pt %XCC, 82b
aeb39876	94	add %o0, 4, %o0
1da177e4 LT	95
	96	85: retl
	97	clr %o0
	98
	99	.align 32
	100	90:
	101	subcc %o2, 1, %o2
0096ac9f DM	102	EX_O2_1(lduba [%o1] %asi, %g1)
0096ac9f DM	103	EX_O2_1(stba %g1, [%o0] %asi)
aeb39876	104	add %o1, 1, %o1
1da177e4	105	bgu,pt %XCC, 90b
aeb39876	106	add %o0, 1, %o0
1da177e4 LT	107	retl
1da177e4 LT	108	clr %o0
31af2f36 AV	109	ENDPROC(raw_copy_in_user)
31af2f36 AV	110	EXPORT_SYMBOL(raw_copy_in_user)