[linux-block.git] / arch / s390 / kernel / head.S

/*
 * Copyright IBM Corp. 1999,2009
 *
 *    Author(s): Hartmut Penner <hp@de.ibm.com>
 *		 Martin Schwidefsky <schwidefsky@de.ibm.com>
 *		 Rob van der Heij <rvdhei@iae.nl>
 *		 Heiko Carstens <heiko.carstens@de.ibm.com>
 *
 * There are 5 different IPL methods
 *  1) load the image directly into ram at address 0 and do an PSW restart
 *  2) linload will load the image from address 0x10000 to memory 0x10000
 *     and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
 *  3) generate the tape ipl header, store the generated image on a tape
 *     and ipl from it
 *     In case of SL tape you need to IPL 5 times to get past VOL1 etc
 *  4) generate the vm reader ipl header, move the generated image to the
 *     VM reader (use option NOH!) and do a ipl from reader (VM only)
 *  5) direct call of start by the SALIPL loader
 *  We use the cpuid to distinguish between VM and native ipl
 *  params for kernel are pushed to 0x10400 (see setup.h)
 *
 */

#include <linux/init.h>
#include <asm/setup.h>
#include <asm/lowcore.h>
#include <asm/asm-offsets.h>
#include <asm/thread_info.h>
#include <asm/page.h>

#ifdef CONFIG_64BIT
#define ARCH_OFFSET	4
#else
#define ARCH_OFFSET	0
#endif

__HEAD
#ifndef CONFIG_IPL
	.org   0
	.long  0x00080000,0x80000000+startup	# Just a restart PSW
#else
#ifdef CONFIG_IPL_TAPE
#define IPL_BS 1024
	.org   0
	.long  0x00080000,0x80000000+iplstart	# The first 24 bytes are loaded
	.long  0x27000000,0x60000001		# by ipl to addresses 0-23.
	.long  0x02000000,0x20000000+IPL_BS	# (a PSW and two CCWs).
	.long  0x00000000,0x00000000		# external old psw
	.long  0x00000000,0x00000000		# svc old psw
	.long  0x00000000,0x00000000		# program check old psw
	.long  0x00000000,0x00000000		# machine check old psw
	.long  0x00000000,0x00000000		# io old psw
	.long  0x00000000,0x00000000
	.long  0x00000000,0x00000000
	.long  0x00000000,0x00000000
	.long  0x000a0000,0x00000058		# external new psw
	.long  0x000a0000,0x00000060		# svc new psw
	.long  0x000a0000,0x00000068		# program check new psw
	.long  0x000a0000,0x00000070		# machine check new psw
	.long  0x00080000,0x80000000+.Lioint	# io new psw

	.org   0x100
#
# subroutine for loading from tape
# Paramters:
#  R1 = device number
#  R2 = load address
.Lloader:
	st	%r14,.Lldret
	la	%r3,.Lorbread		# r3 = address of orb
	la	%r5,.Lirb		# r5 = address of irb
	st	%r2,.Lccwread+4 	# initialize CCW data addresses
	lctl	%c6,%c6,.Lcr6
	slr	%r2,%r2
.Lldlp:
	la	%r6,3			# 3 retries
.Lssch:
	ssch	0(%r3)			# load chunk of IPL_BS bytes
	bnz	.Llderr
.Lw4end:
	bas	%r14,.Lwait4io
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Lrecov
	slr	%r7,%r7
	icm	%r7,3,10(%r5)		# get residual count
	lcr	%r7,%r7
	la	%r7,IPL_BS(%r7) 	# IPL_BS-residual=#bytes read
	ar	%r2,%r7 		# add to total size
	tm	8(%r5),0x01		# found a tape mark ?
	bnz	.Ldone
	l	%r0,.Lccwread+4 	# update CCW data addresses
	ar	%r0,%r7
	st	%r0,.Lccwread+4
	b	.Lldlp
.Ldone:
	l	%r14,.Lldret
	br	%r14			# r2 contains the total size
.Lrecov:
	bas	%r14,.Lsense		# do the sensing
	bct	%r6,.Lssch		# dec. retry count & branch
	b	.Llderr
#
# Sense subroutine
#
.Lsense:
	st	%r14,.Lsnsret
	la	%r7,.Lorbsense
	ssch	0(%r7)			# start sense command
	bnz	.Llderr
	bas	%r14,.Lwait4io
	l	%r14,.Lsnsret
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Llderr
	br	%r14
#
# Wait for interrupt subroutine
#
.Lwait4io:
	lpsw	.Lwaitpsw
.Lioint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwait4io
	tsch	0(%r5)
	slr	%r0,%r0
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Lwtexit
	tm	8(%r5),0x04		# got device end ?
	bz	.Lwait4io
.Lwtexit:
	br	%r14
.Llderr:
	lpsw	.Lcrash

	.align	8
.Lorbread:
	.long	0x00000000,0x0080ff00,.Lccwread
	.align	8
.Lorbsense:
	.long	0x00000000,0x0080ff00,.Lccwsense
	.align	8
.Lccwread:
	.long	0x02200000+IPL_BS,0x00000000
.Lccwsense:
	.long	0x04200001,0x00000000
.Lwaitpsw:
	.long	0x020a0000,0x80000000+.Lioint

.Lirb:	.long	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.Lcr6:	.long	0xff000000
	.align	8
.Lcrash:.long	0x000a0000,0x00000000
.Lldret:.long	0
.Lsnsret: .long 0
#endif	/* CONFIG_IPL_TAPE */

#ifdef CONFIG_IPL_VM
#define IPL_BS	0x730
	.org	0
	.long	0x00080000,0x80000000+iplstart	# The first 24 bytes are loaded
	.long	0x02000018,0x60000050		# by ipl to addresses 0-23.
	.long	0x02000068,0x60000050		# (a PSW and two CCWs).
	.fill	80-24,1,0x40			# bytes 24-79 are discarded !!
	.long	0x020000f0,0x60000050		# The next 160 byte are loaded
	.long	0x02000140,0x60000050		# to addresses 0x18-0xb7
	.long	0x02000190,0x60000050		# They form the continuation
	.long	0x020001e0,0x60000050		# of the CCW program started
	.long	0x02000230,0x60000050		# by ipl and load the range
	.long	0x02000280,0x60000050		# 0x0f0-0x730 from the image
	.long	0x020002d0,0x60000050		# to the range 0x0f0-0x730
	.long	0x02000320,0x60000050		# in memory. At the end of
	.long	0x02000370,0x60000050		# the channel program the PSW
	.long	0x020003c0,0x60000050		# at location 0 is loaded.
	.long	0x02000410,0x60000050		# Initial processing starts
	.long	0x02000460,0x60000050		# at 0xf0 = iplstart.
	.long	0x020004b0,0x60000050
	.long	0x02000500,0x60000050
	.long	0x02000550,0x60000050
	.long	0x020005a0,0x60000050
	.long	0x020005f0,0x60000050
	.long	0x02000640,0x60000050
	.long	0x02000690,0x60000050
	.long	0x020006e0,0x20000050

	.org	0xf0
#
# subroutine for loading cards from the reader
#
.Lloader:
	la	%r3,.Lorb		# r2 = address of orb into r2
	la	%r5,.Lirb		# r4 = address of irb
	la	%r6,.Lccws
	la	%r7,20
.Linit:
	st	%r2,4(%r6)		# initialize CCW data addresses
	la	%r2,0x50(%r2)
	la	%r6,8(%r6)
	bct	7,.Linit

	lctl	%c6,%c6,.Lcr6		# set IO subclass mask
	slr	%r2,%r2
.Lldlp:
	ssch	0(%r3)			# load chunk of 1600 bytes
	bnz	.Llderr
.Lwait4irq:
	mvc	0x78(8),.Lnewpsw	# set up IO interrupt psw
	lpsw	.Lwaitpsw
.Lioint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwait4irq
	tsch	0(%r5)

	slr	%r0,%r0
	ic	%r0,8(%r5)		# get device status
	chi	%r0,8			# channel end ?
	be	.Lcont
	chi	%r0,12			# channel end + device end ?
	be	.Lcont

	l	%r0,4(%r5)
	s	%r0,8(%r3)		# r0/8 = number of ccws executed
	mhi	%r0,10			# *10 = number of bytes in ccws
	lh	%r3,10(%r5)		# get residual count
	sr	%r0,%r3 		# #ccws*80-residual=#bytes read
	ar	%r2,%r0

	br	%r14			# r2 contains the total size

.Lcont:
	ahi	%r2,0x640		# add 0x640 to total size
	la	%r6,.Lccws
	la	%r7,20
.Lincr:
	l	%r0,4(%r6)		# update CCW data addresses
	ahi	%r0,0x640
	st	%r0,4(%r6)
	ahi	%r6,8
	bct	7,.Lincr

	b	.Lldlp
.Llderr:
	lpsw	.Lcrash

	.align	8
.Lorb:	.long	0x00000000,0x0080ff00,.Lccws
.Lirb:	.long	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.Lcr6:	.long	0xff000000
.Lloadp:.long	0,0
	.align	8
.Lcrash:.long	0x000a0000,0x00000000
.Lnewpsw:
	.long	0x00080000,0x80000000+.Lioint
.Lwaitpsw:
	.long	0x020a0000,0x80000000+.Lioint

	.align	8
.Lccws: .rept	19
	.long	0x02600050,0x00000000
	.endr
	.long	0x02200050,0x00000000
#endif	/* CONFIG_IPL_VM */

iplstart:
	lh	%r1,0xb8		# test if subchannel number
	bct	%r1,.Lnoload		#  is valid
	l	%r1,0xb8		# load ipl subchannel number
	la	%r2,IPL_BS		# load start address
	bas	%r14,.Lloader		# load rest of ipl image
	l	%r12,.Lparm		# pointer to parameter area
	st	%r1,IPL_DEVICE+ARCH_OFFSET-PARMAREA(%r12) # save ipl device number

#
# load parameter file from ipl device
#
.Lagain1:
	l	%r2,.Linitrd		# ramdisk loc. is temp
	bas	%r14,.Lloader		# load parameter file
	ltr	%r2,%r2 		# got anything ?
	bz	.Lnopf
	chi	%r2,895
	bnh	.Lnotrunc
	la	%r2,895
.Lnotrunc:
	l	%r4,.Linitrd
	clc	0(3,%r4),.L_hdr		# if it is HDRx
	bz	.Lagain1		# skip dataset header
	clc	0(3,%r4),.L_eof		# if it is EOFx
	bz	.Lagain1		# skip dateset trailer
	la	%r5,0(%r4,%r2)
	lr	%r3,%r2
.Lidebc:
	tm	0(%r5),0x80		# high order bit set ?
	bo	.Ldocv			#  yes -> convert from EBCDIC
	ahi	%r5,-1
	bct	%r3,.Lidebc
	b	.Lnocv
.Ldocv:
	l	%r3,.Lcvtab
	tr	0(256,%r4),0(%r3)	# convert parameters to ascii
	tr	256(256,%r4),0(%r3)
	tr	512(256,%r4),0(%r3)
	tr	768(122,%r4),0(%r3)
.Lnocv: la	%r3,COMMAND_LINE-PARMAREA(%r12) # load adr. of command line
	mvc	0(256,%r3),0(%r4)
	mvc	256(256,%r3),256(%r4)
	mvc	512(256,%r3),512(%r4)
	mvc	768(122,%r3),768(%r4)
	slr	%r0,%r0
	b	.Lcntlp
.Ldelspc:
	ic	%r0,0(%r2,%r3)
	chi	%r0,0x20		# is it a space ?
	be	.Lcntlp
	ahi	%r2,1
	b	.Leolp
.Lcntlp:
	brct	%r2,.Ldelspc
.Leolp:
	slr	%r0,%r0
	stc	%r0,0(%r2,%r3)		# terminate buffer
.Lnopf:

#
# load ramdisk from ipl device
#
.Lagain2:
	l	%r2,.Linitrd		# addr of ramdisk
	st	%r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
	bas	%r14,.Lloader		# load ramdisk
	st	%r2,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r12) # store size of rd
	ltr	%r2,%r2
	bnz	.Lrdcont
	st	%r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # no ramdisk found
.Lrdcont:
	l	%r2,.Linitrd

	clc	0(3,%r2),.L_hdr		# skip HDRx and EOFx
	bz	.Lagain2
	clc	0(3,%r2),.L_eof
	bz	.Lagain2

#ifdef CONFIG_IPL_VM
#
# reset files in VM reader
#
	stidp	__LC_CPUID		# store cpuid
	tm	__LC_CPUID,0xff 	# running VM ?
	bno	.Lnoreset
	la	%r2,.Lreset
	lhi	%r3,26
	diag	%r2,%r3,8
	la	%r5,.Lirb
	stsch	0(%r5)			# check if irq is pending
	tm	30(%r5),0x0f		# by verifying if any of the
	bnz	.Lwaitforirq		# activity or status control
	tm	31(%r5),0xff		# bits is set in the schib
	bz	.Lnoreset
.Lwaitforirq:
	mvc	0x78(8),.Lrdrnewpsw	# set up IO interrupt psw
.Lwaitrdrirq:
	lpsw	.Lrdrwaitpsw
.Lrdrint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwaitrdrirq
	la	%r5,.Lirb
	tsch	0(%r5)
.Lnoreset:
	b	.Lnoload

	.align	8
.Lrdrnewpsw:
	.long	0x00080000,0x80000000+.Lrdrint
.Lrdrwaitpsw:
	.long	0x020a0000,0x80000000+.Lrdrint
#endif

#
# everything loaded, go for it
#
.Lnoload:
	l	%r1,.Lstartup
	br	%r1

.Linitrd:.long _end + 0x400000		# default address of initrd
.Lparm:	.long  PARMAREA
.Lstartup: .long startup
.Lcvtab:.long	_ebcasc 		# ebcdic to ascii table
.Lreset:.byte	0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
	.byte	0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
	.byte	0xc8,0xd6,0xd3,0xc4	# "change rdr all keep nohold"
.L_eof: .long	0xc5d6c600	 /* C'EOF' */
.L_hdr: .long	0xc8c4d900	 /* C'HDR' */

#endif	/* CONFIG_IPL */

#
# SALIPL loader support. Based on a patch by Rob van der Heij.
# This entry point is called directly from the SALIPL loader and
# doesn't need a builtin ipl record.
#
	.org	0x800
	.globl	start
start:
	stm	%r0,%r15,0x07b0		# store registers
	basr	%r12,%r0
.base:
	l	%r11,.parm
	l	%r8,.cmd		# pointer to command buffer

	ltr	%r9,%r9			# do we have SALIPL parameters?
	bp	.sk8x8

	mvc	0(64,%r8),0x00b0	# copy saved registers
	xc	64(240-64,%r8),0(%r8)	# remainder of buffer
	tr	0(64,%r8),.lowcase
	b	.gotr
.sk8x8:
	mvc	0(240,%r8),0(%r9)	# copy iplparms into buffer
.gotr:
	l	%r10,.tbl		# EBCDIC to ASCII table
	tr	0(240,%r8),0(%r10)
	slr	%r0,%r0
	st	%r0,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r11)
	st	%r0,INITRD_START+ARCH_OFFSET-PARMAREA(%r11)
	j	startup 		# continue with startup
.tbl:	.long	_ebcasc			# translate table
.cmd:	.long	COMMAND_LINE		# address of command line buffer
.parm:	.long	PARMAREA
.lowcase:
	.byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
	.byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
	.byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
	.byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
	.byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
	.byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
	.byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
	.byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
	.byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
	.byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
	.byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
	.byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
	.byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
	.byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
	.byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
	.byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f

	.byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
	.byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
	.byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
	.byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
	.byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
	.byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
	.byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
	.byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
	.byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87	# .abcdefg
	.byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf	# hi
	.byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97	# .jklmnop
	.byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf	# qr
	.byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7	# ..stuvwx
	.byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef	# yz
	.byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
	.byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff

#
# startup-code at 0x10000, running in absolute addressing mode
# this is called either by the ipl loader or directly by PSW restart
# or linload or SALIPL
#
	.org	0x10000
startup:basr	%r13,0			# get base
.LPG0:
	xc	0x200(256),0x200	# partially clear lowcore
	xc	0x300(256),0x300
	l	%r1,5f-.LPG0(%r13)
	stck	0(%r1)
	spt	6f-.LPG0(%r13)
	mvc	__LC_LAST_UPDATE_CLOCK(8),0(%r1)
	mvc	__LC_LAST_UPDATE_TIMER(8),6f-.LPG0(%r13)
	mvc	__LC_EXIT_TIMER(8),5f-.LPG0(%r13)
#ifndef CONFIG_MARCH_G5
	# check capabilities against MARCH_{G5,Z900,Z990,Z9_109,Z10}
	xc	__LC_STFL_FAC_LIST(8),__LC_STFL_FAC_LIST
	stfl	__LC_STFL_FAC_LIST	# store facility list
	tm	__LC_STFL_FAC_LIST,0x01	# stfle available ?
	jz	0f
	la	%r0,0
	.insn	s,0xb2b00000,__LC_STFL_FAC_LIST	# store facility list extended
0:	l	%r0,__LC_STFL_FAC_LIST
	n	%r0,2f+8-.LPG0(%r13)
	cl	%r0,2f+8-.LPG0(%r13)
	jne	1f
	l	%r0,__LC_STFL_FAC_LIST+4
	n	%r0,2f+12-.LPG0(%r13)
	cl	%r0,2f+12-.LPG0(%r13)
	je	3f
1:	l	%r15,.Lstack-.LPG0(%r13)
	ahi	%r15,1<<(PAGE_SHIFT+THREAD_ORDER) # init_task_union+THREAD_SIZE
	ahi	%r15,-96
	la	%r2,.Lals_string-.LPG0(%r13)
	l	%r3,.Lsclp_print-.LPG0(%r13)
	basr	%r14,%r3
	lpsw	2f-.LPG0(%r13)		# machine type not good enough, crash
.Lals_string:
	.asciz	"The Linux kernel requires more recent processor hardware"
.Lsclp_print:
	.long	_sclp_print_early
.Lstack:
	.long	init_thread_union
	.align 16
2:	.long	0x000a0000,0x8badcccc
#if defined(CONFIG_64BIT)
#if defined(CONFIG_MARCH_Z10)
	.long 0xc100efe3, 0xf0680000
#elif defined(CONFIG_MARCH_Z9_109)
	.long 0xc100efc3, 0x00000000
#elif defined(CONFIG_MARCH_Z990)
	.long 0xc0002000, 0x00000000
#elif defined(CONFIG_MARCH_Z900)
	.long 0xc0000000, 0x00000000
#endif
#else
#if defined(CONFIG_MARCH_Z10)
	.long 0x8100c880, 0x00000000
#elif defined(CONFIG_MARCH_Z9_109)
	.long 0x8100c880, 0x00000000
#elif defined(CONFIG_MARCH_Z990)
	.long 0x80002000, 0x00000000
#elif defined(CONFIG_MARCH_Z900)
	.long 0x80000000, 0x00000000
#endif
#endif
3:
#endif

	l	%r13,4f-.LPG0(%r13)
	b	0(%r13)
	.align	4
4:	.long	startup_continue
5:	.long	sched_clock_base_cc
	.align	8
6:	.long	0x7fffffff,0xffffffff

#
# params at 10400 (setup.h)
#
	.org	PARMAREA
	.long	0,0			# IPL_DEVICE
	.long	0,0			# INITRD_START
	.long	0,0			# INITRD_SIZE

	.org	COMMAND_LINE
	.byte	"root=/dev/ram0 ro"
	.byte	0

#ifdef CONFIG_64BIT
#include "head64.S"
#else
#include "head31.S"
#endif
Commit	Line	Data
1da177e4	1	/*
d90cbd46	2	* Copyright IBM Corp. 1999,2009
0ad775db HC	3	*
	4	* Author(s): Hartmut Penner <hp@de.ibm.com>
	5	* Martin Schwidefsky <schwidefsky@de.ibm.com>
	6	* Rob van der Heij <rvdhei@iae.nl>
	7	* Heiko Carstens <heiko.carstens@de.ibm.com>
1da177e4 LT	8	*
	9	* There are 5 different IPL methods
	10	* 1) load the image directly into ram at address 0 and do an PSW restart
	11	* 2) linload will load the image from address 0x10000 to memory 0x10000
	12	* and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
	13	* 3) generate the tape ipl header, store the generated image on a tape
	14	* and ipl from it
	15	* In case of SL tape you need to IPL 5 times to get past VOL1 etc
	16	* 4) generate the vm reader ipl header, move the generated image to the
	17	* VM reader (use option NOH!) and do a ipl from reader (VM only)
	18	* 5) direct call of start by the SALIPL loader
	19	* We use the cpuid to distinguish between VM and native ipl
	20	* params for kernel are pushed to 0x10400 (see setup.h)
0ad775db	21	*
1da177e4 LT	22	*/
1da177e4 LT	23
2133bb8d	24	#include <linux/init.h>
1da177e4 LT	25	#include <asm/setup.h>
1da177e4 LT	26	#include <asm/lowcore.h>
0013a854	27	#include <asm/asm-offsets.h>
1da177e4 LT	28	#include <asm/thread_info.h>
	29	#include <asm/page.h>
	30
347a8dc3	31	#ifdef CONFIG_64BIT
0ad775db HC	32	#define ARCH_OFFSET 4
	33	#else
	34	#define ARCH_OFFSET 0
	35	#endif
	36
2133bb8d	37	__HEAD
1da177e4	38	#ifndef CONFIG_IPL
25d83cbf HC	39	.org 0
25d83cbf HC	40	.long 0x00080000,0x80000000+startup # Just a restart PSW
1da177e4 LT	41	#else
	42	#ifdef CONFIG_IPL_TAPE
	43	#define IPL_BS 1024
25d83cbf HC	44	.org 0
	45	.long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
	46	.long 0x27000000,0x60000001 # by ipl to addresses 0-23.
	47	.long 0x02000000,0x20000000+IPL_BS # (a PSW and two CCWs).
	48	.long 0x00000000,0x00000000 # external old psw
	49	.long 0x00000000,0x00000000 # svc old psw
	50	.long 0x00000000,0x00000000 # program check old psw
	51	.long 0x00000000,0x00000000 # machine check old psw
	52	.long 0x00000000,0x00000000 # io old psw
	53	.long 0x00000000,0x00000000
	54	.long 0x00000000,0x00000000
	55	.long 0x00000000,0x00000000
	56	.long 0x000a0000,0x00000058 # external new psw
	57	.long 0x000a0000,0x00000060 # svc new psw
	58	.long 0x000a0000,0x00000068 # program check new psw
	59	.long 0x000a0000,0x00000070 # machine check new psw
	60	.long 0x00080000,0x80000000+.Lioint # io new psw
1da177e4	61
25d83cbf	62	.org 0x100
1da177e4 LT	63	#
1da177e4 LT	64	# subroutine for loading from tape
25d83cbf	65	# Paramters:
1da177e4 LT	66	# R1 = device number
1da177e4 LT	67	# R2 = load address
25d83cbf HC	68	.Lloader:
	69	st %r14,.Lldret
	70	la %r3,.Lorbread # r3 = address of orb
	71	la %r5,.Lirb # r5 = address of irb
	72	st %r2,.Lccwread+4 # initialize CCW data addresses
	73	lctl %c6,%c6,.Lcr6
	74	slr %r2,%r2
1da177e4	75	.Lldlp:
25d83cbf	76	la %r6,3 # 3 retries
1da177e4	77	.Lssch:
25d83cbf HC	78	ssch 0(%r3) # load chunk of IPL_BS bytes
25d83cbf HC	79	bnz .Llderr
1da177e4	80	.Lw4end:
25d83cbf HC	81	bas %r14,.Lwait4io
	82	tm 8(%r5),0x82 # do we have a problem ?
	83	bnz .Lrecov
	84	slr %r7,%r7
	85	icm %r7,3,10(%r5) # get residual count
	86	lcr %r7,%r7
	87	la %r7,IPL_BS(%r7) # IPL_BS-residual=#bytes read
	88	ar %r2,%r7 # add to total size
	89	tm 8(%r5),0x01 # found a tape mark ?
	90	bnz .Ldone
	91	l %r0,.Lccwread+4 # update CCW data addresses
	92	ar %r0,%r7
	93	st %r0,.Lccwread+4
	94	b .Lldlp
1da177e4	95	.Ldone:
25d83cbf HC	96	l %r14,.Lldret
25d83cbf HC	97	br %r14 # r2 contains the total size
1da177e4	98	.Lrecov:
25d83cbf HC	99	bas %r14,.Lsense # do the sensing
	100	bct %r6,.Lssch # dec. retry count & branch
	101	b .Llderr
1da177e4 LT	102	#
	103	# Sense subroutine
	104	#
	105	.Lsense:
25d83cbf HC	106	st %r14,.Lsnsret
	107	la %r7,.Lorbsense
	108	ssch 0(%r7) # start sense command
	109	bnz .Llderr
	110	bas %r14,.Lwait4io
	111	l %r14,.Lsnsret
	112	tm 8(%r5),0x82 # do we have a problem ?
	113	bnz .Llderr
	114	br %r14
1da177e4 LT	115	#
	116	# Wait for interrupt subroutine
	117	#
	118	.Lwait4io:
25d83cbf	119	lpsw .Lwaitpsw
1da177e4	120	.Lioint:
25d83cbf HC	121	c %r1,0xb8 # compare subchannel number
	122	bne .Lwait4io
	123	tsch 0(%r5)
	124	slr %r0,%r0
	125	tm 8(%r5),0x82 # do we have a problem ?
	126	bnz .Lwtexit
	127	tm 8(%r5),0x04 # got device end ?
	128	bz .Lwait4io
1da177e4	129	.Lwtexit:
25d83cbf	130	br %r14
1da177e4	131	.Llderr:
25d83cbf	132	lpsw .Lcrash
1da177e4	133
25d83cbf	134	.align 8
1da177e4	135	.Lorbread:
25d83cbf HC	136	.long 0x00000000,0x0080ff00,.Lccwread
25d83cbf HC	137	.align 8
1da177e4	138	.Lorbsense:
25d83cbf HC	139	.long 0x00000000,0x0080ff00,.Lccwsense
25d83cbf HC	140	.align 8
1da177e4	141	.Lccwread:
25d83cbf	142	.long 0x02200000+IPL_BS,0x00000000
1da177e4	143	.Lccwsense:
25d83cbf	144	.long 0x04200001,0x00000000
1da177e4	145	.Lwaitpsw:
25d83cbf	146	.long 0x020a0000,0x80000000+.Lioint
1da177e4	147
25d83cbf HC	148	.Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
	149	.Lcr6: .long 0xff000000
	150	.align 8
	151	.Lcrash:.long 0x000a0000,0x00000000
	152	.Lldret:.long 0
1da177e4	153	.Lsnsret: .long 0
25d83cbf	154	#endif /* CONFIG_IPL_TAPE */
1da177e4 LT	155
1da177e4 LT	156	#ifdef CONFIG_IPL_VM
25d83cbf HC	157	#define IPL_BS 0x730
	158	.org 0
	159	.long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
	160	.long 0x02000018,0x60000050 # by ipl to addresses 0-23.
	161	.long 0x02000068,0x60000050 # (a PSW and two CCWs).
	162	.fill 80-24,1,0x40 # bytes 24-79 are discarded !!
	163	.long 0x020000f0,0x60000050 # The next 160 byte are loaded
	164	.long 0x02000140,0x60000050 # to addresses 0x18-0xb7
	165	.long 0x02000190,0x60000050 # They form the continuation
	166	.long 0x020001e0,0x60000050 # of the CCW program started
	167	.long 0x02000230,0x60000050 # by ipl and load the range
	168	.long 0x02000280,0x60000050 # 0x0f0-0x730 from the image
	169	.long 0x020002d0,0x60000050 # to the range 0x0f0-0x730
	170	.long 0x02000320,0x60000050 # in memory. At the end of
	171	.long 0x02000370,0x60000050 # the channel program the PSW
	172	.long 0x020003c0,0x60000050 # at location 0 is loaded.
	173	.long 0x02000410,0x60000050 # Initial processing starts
	174	.long 0x02000460,0x60000050 # at 0xf0 = iplstart.
	175	.long 0x020004b0,0x60000050
	176	.long 0x02000500,0x60000050
	177	.long 0x02000550,0x60000050
	178	.long 0x020005a0,0x60000050
	179	.long 0x020005f0,0x60000050
	180	.long 0x02000640,0x60000050
	181	.long 0x02000690,0x60000050
	182	.long 0x020006e0,0x20000050
1da177e4	183
25d83cbf	184	.org 0xf0
1da177e4 LT	185	#
	186	# subroutine for loading cards from the reader
	187	#
25d83cbf HC	188	.Lloader:
	189	la %r3,.Lorb # r2 = address of orb into r2
	190	la %r5,.Lirb # r4 = address of irb
	191	la %r6,.Lccws
	192	la %r7,20
1da177e4	193	.Linit:
25d83cbf HC	194	st %r2,4(%r6) # initialize CCW data addresses
	195	la %r2,0x50(%r2)
	196	la %r6,8(%r6)
	197	bct 7,.Linit
1da177e4	198
25d83cbf HC	199	lctl %c6,%c6,.Lcr6 # set IO subclass mask
25d83cbf HC	200	slr %r2,%r2
1da177e4	201	.Lldlp:
25d83cbf HC	202	ssch 0(%r3) # load chunk of 1600 bytes
25d83cbf HC	203	bnz .Llderr
1da177e4	204	.Lwait4irq:
25d83cbf HC	205	mvc 0x78(8),.Lnewpsw # set up IO interrupt psw
25d83cbf HC	206	lpsw .Lwaitpsw
1da177e4	207	.Lioint:
25d83cbf HC	208	c %r1,0xb8 # compare subchannel number
	209	bne .Lwait4irq
	210	tsch 0(%r5)
1da177e4	211
25d83cbf HC	212	slr %r0,%r0
	213	ic %r0,8(%r5) # get device status
	214	chi %r0,8 # channel end ?
	215	be .Lcont
	216	chi %r0,12 # channel end + device end ?
	217	be .Lcont
1da177e4	218
25d83cbf HC	219	l %r0,4(%r5)
	220	s %r0,8(%r3) # r0/8 = number of ccws executed
	221	mhi %r0,10 # *10 = number of bytes in ccws
	222	lh %r3,10(%r5) # get residual count
	223	sr %r0,%r3 # #ccws*80-residual=#bytes read
	224	ar %r2,%r0
	225
	226	br %r14 # r2 contains the total size
1da177e4 LT	227
1da177e4 LT	228	.Lcont:
25d83cbf HC	229	ahi %r2,0x640 # add 0x640 to total size
	230	la %r6,.Lccws
	231	la %r7,20
1da177e4	232	.Lincr:
25d83cbf HC	233	l %r0,4(%r6) # update CCW data addresses
	234	ahi %r0,0x640
	235	st %r0,4(%r6)
	236	ahi %r6,8
	237	bct 7,.Lincr
1da177e4	238
25d83cbf	239	b .Lldlp
1da177e4	240	.Llderr:
25d83cbf	241	lpsw .Lcrash
1da177e4	242
25d83cbf HC	243	.align 8
	244	.Lorb: .long 0x00000000,0x0080ff00,.Lccws
	245	.Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
	246	.Lcr6: .long 0xff000000
	247	.Lloadp:.long 0,0
	248	.align 8
	249	.Lcrash:.long 0x000a0000,0x00000000
1da177e4	250	.Lnewpsw:
25d83cbf	251	.long 0x00080000,0x80000000+.Lioint
1da177e4	252	.Lwaitpsw:
25d83cbf	253	.long 0x020a0000,0x80000000+.Lioint
1da177e4	254
25d83cbf HC	255	.align 8
	256	.Lccws: .rept 19
	257	.long 0x02600050,0x00000000
	258	.endr
	259	.long 0x02200050,0x00000000
	260	#endif /* CONFIG_IPL_VM */
1da177e4 LT	261
1da177e4 LT	262	iplstart:
25d83cbf HC	263	lh %r1,0xb8 # test if subchannel number
	264	bct %r1,.Lnoload # is valid
	265	l %r1,0xb8 # load ipl subchannel number
	266	la %r2,IPL_BS # load start address
	267	bas %r14,.Lloader # load rest of ipl image
	268	l %r12,.Lparm # pointer to parameter area
	269	st %r1,IPL_DEVICE+ARCH_OFFSET-PARMAREA(%r12) # save ipl device number
1da177e4 LT	270
	271	#
	272	# load parameter file from ipl device
	273	#
	274	.Lagain1:
25d83cbf HC	275	l %r2,.Linitrd # ramdisk loc. is temp
	276	bas %r14,.Lloader # load parameter file
	277	ltr %r2,%r2 # got anything ?
	278	bz .Lnopf
	279	chi %r2,895
	280	bnh .Lnotrunc
	281	la %r2,895
1da177e4	282	.Lnotrunc:
25d83cbf HC	283	l %r4,.Linitrd
	284	clc 0(3,%r4),.L_hdr # if it is HDRx
	285	bz .Lagain1 # skip dataset header
	286	clc 0(3,%r4),.L_eof # if it is EOFx
	287	bz .Lagain1 # skip dateset trailer
	288	la %r5,0(%r4,%r2)
	289	lr %r3,%r2
1da177e4	290	.Lidebc:
25d83cbf HC	291	tm 0(%r5),0x80 # high order bit set ?
	292	bo .Ldocv # yes -> convert from EBCDIC
	293	ahi %r5,-1
	294	bct %r3,.Lidebc
	295	b .Lnocv
1da177e4	296	.Ldocv:
25d83cbf HC	297	l %r3,.Lcvtab
	298	tr 0(256,%r4),0(%r3) # convert parameters to ascii
	299	tr 256(256,%r4),0(%r3)
	300	tr 512(256,%r4),0(%r3)
	301	tr 768(122,%r4),0(%r3)
	302	.Lnocv: la %r3,COMMAND_LINE-PARMAREA(%r12) # load adr. of command line
	303	mvc 0(256,%r3),0(%r4)
	304	mvc 256(256,%r3),256(%r4)
	305	mvc 512(256,%r3),512(%r4)
	306	mvc 768(122,%r3),768(%r4)
	307	slr %r0,%r0
	308	b .Lcntlp
1da177e4	309	.Ldelspc:
25d83cbf HC	310	ic %r0,0(%r2,%r3)
	311	chi %r0,0x20 # is it a space ?
	312	be .Lcntlp
	313	ahi %r2,1
	314	b .Leolp
1da177e4	315	.Lcntlp:
25d83cbf	316	brct %r2,.Ldelspc
1da177e4	317	.Leolp:
25d83cbf HC	318	slr %r0,%r0
25d83cbf HC	319	stc %r0,0(%r2,%r3) # terminate buffer
1da177e4 LT	320	.Lnopf:
	321
	322	#
	323	# load ramdisk from ipl device
25d83cbf	324	#
1da177e4	325	.Lagain2:
25d83cbf HC	326	l %r2,.Linitrd # addr of ramdisk
	327	st %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
	328	bas %r14,.Lloader # load ramdisk
	329	st %r2,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r12) # store size of rd
	330	ltr %r2,%r2
	331	bnz .Lrdcont
	332	st %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # no ramdisk found
1da177e4	333	.Lrdcont:
25d83cbf	334	l %r2,.Linitrd
1da177e4	335
25d83cbf HC	336	clc 0(3,%r2),.L_hdr # skip HDRx and EOFx
	337	bz .Lagain2
	338	clc 0(3,%r2),.L_eof
	339	bz .Lagain2
1da177e4 LT	340
	341	#ifdef CONFIG_IPL_VM
	342	#
	343	# reset files in VM reader
	344	#
25d83cbf HC	345	stidp __LC_CPUID # store cpuid
	346	tm __LC_CPUID,0xff # running VM ?
	347	bno .Lnoreset
	348	la %r2,.Lreset
	349	lhi %r3,26
	350	diag %r2,%r3,8
	351	la %r5,.Lirb
	352	stsch 0(%r5) # check if irq is pending
	353	tm 30(%r5),0x0f # by verifying if any of the
	354	bnz .Lwaitforirq # activity or status control
	355	tm 31(%r5),0xff # bits is set in the schib
	356	bz .Lnoreset
350e3ade	357	.Lwaitforirq:
25d83cbf	358	mvc 0x78(8),.Lrdrnewpsw # set up IO interrupt psw
2b071886	359	.Lwaitrdrirq:
25d83cbf	360	lpsw .Lrdrwaitpsw
2b071886	361	.Lrdrint:
25d83cbf HC	362	c %r1,0xb8 # compare subchannel number
	363	bne .Lwaitrdrirq
	364	la %r5,.Lirb
	365	tsch 0(%r5)
1da177e4	366	.Lnoreset:
25d83cbf	367	b .Lnoload
2b071886	368
25d83cbf	369	.align 8
2b071886	370	.Lrdrnewpsw:
25d83cbf	371	.long 0x00080000,0x80000000+.Lrdrint
2b071886	372	.Lrdrwaitpsw:
25d83cbf	373	.long 0x020a0000,0x80000000+.Lrdrint
1da177e4	374	#endif
2b071886	375
1da177e4 LT	376	#
	377	# everything loaded, go for it
	378	#
	379	.Lnoload:
25d83cbf HC	380	l %r1,.Lstartup
25d83cbf HC	381	br %r1
1da177e4	382
25d83cbf	383	.Linitrd:.long _end + 0x400000 # default address of initrd
1da177e4 LT	384	.Lparm: .long PARMAREA
1da177e4 LT	385	.Lstartup: .long startup
25d83cbf HC	386	.Lcvtab:.long _ebcasc # ebcdic to ascii table
	387	.Lreset:.byte 0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
	388	.byte 0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
	389	.byte 0xc8,0xd6,0xd3,0xc4 # "change rdr all keep nohold"
	390	.L_eof: .long 0xc5d6c600 /* C'EOF' */
	391	.L_hdr: .long 0xc8c4d900 /* C'HDR' */
1da177e4	392
25d83cbf	393	#endif /* CONFIG_IPL */
1da177e4 LT	394
	395	#
	396	# SALIPL loader support. Based on a patch by Rob van der Heij.
	397	# This entry point is called directly from the SALIPL loader and
	398	# doesn't need a builtin ipl record.
	399	#
25d83cbf HC	400	.org 0x800
25d83cbf HC	401	.globl start
1da177e4	402	start:
25d83cbf HC	403	stm %r0,%r15,0x07b0 # store registers
25d83cbf HC	404	basr %r12,%r0
1da177e4	405	.base:
25d83cbf HC	406	l %r11,.parm
25d83cbf HC	407	l %r8,.cmd # pointer to command buffer
1da177e4	408
25d83cbf HC	409	ltr %r9,%r9 # do we have SALIPL parameters?
25d83cbf HC	410	bp .sk8x8
1da177e4	411
25d83cbf HC	412	mvc 0(64,%r8),0x00b0 # copy saved registers
	413	xc 64(240-64,%r8),0(%r8) # remainder of buffer
	414	tr 0(64,%r8),.lowcase
	415	b .gotr
1da177e4	416	.sk8x8:
25d83cbf	417	mvc 0(240,%r8),0(%r9) # copy iplparms into buffer
1da177e4	418	.gotr:
25d83cbf HC	419	l %r10,.tbl # EBCDIC to ASCII table
25d83cbf HC	420	tr 0(240,%r8),0(%r10)
25d83cbf HC	421	slr %r0,%r0
	422	st %r0,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r11)
	423	st %r0,INITRD_START+ARCH_OFFSET-PARMAREA(%r11)
	424	j startup # continue with startup
	425	.tbl: .long _ebcasc # translate table
	426	.cmd: .long COMMAND_LINE # address of command line buffer
	427	.parm: .long PARMAREA
1da177e4	428	.lowcase:
25d83cbf	429	.byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
1da177e4	430	.byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
25d83cbf	431	.byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
1da177e4	432	.byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
25d83cbf	433	.byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
1da177e4	434	.byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
25d83cbf	435	.byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
1da177e4	436	.byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
25d83cbf	437	.byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
1da177e4	438	.byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
25d83cbf	439	.byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
1da177e4	440	.byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
25d83cbf	441	.byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
1da177e4	442	.byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
25d83cbf	443	.byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
1da177e4 LT	444	.byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f
1da177e4 LT	445
25d83cbf	446	.byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
1da177e4	447	.byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
25d83cbf	448	.byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
1da177e4	449	.byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
25d83cbf	450	.byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
1da177e4	451	.byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
25d83cbf	452	.byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
1da177e4	453	.byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
25d83cbf	454	.byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87 # .abcdefg
1da177e4	455	.byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf # hi
25d83cbf	456	.byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97 # .jklmnop
1da177e4 LT	457	.byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf # qr
	458	.byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7 # ..stuvwx
	459	.byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef # yz
25d83cbf	460	.byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
1da177e4 LT	461	.byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff
1da177e4 LT	462
e37f50e1 MS	463	#
	464	# startup-code at 0x10000, running in absolute addressing mode
	465	# this is called either by the ipl loader or directly by PSW restart
	466	# or linload or SALIPL
	467	#
	468	.org 0x10000
	469	startup:basr %r13,0 # get base
	470	.LPG0:
866ba284 MS	471	xc 0x200(256),0x200 # partially clear lowcore
866ba284 MS	472	xc 0x300(256),0x300
b6112ccb MS	473	l %r1,5f-.LPG0(%r13)
b6112ccb MS	474	stck 0(%r1)
ab96e798 MS	475	spt 6f-.LPG0(%r13)
	476	mvc __LC_LAST_UPDATE_CLOCK(8),0(%r1)
	477	mvc __LC_LAST_UPDATE_TIMER(8),6f-.LPG0(%r13)
	478	mvc __LC_EXIT_TIMER(8),5f-.LPG0(%r13)
e37f50e1	479	#ifndef CONFIG_MARCH_G5
8c4caa4f MS	480	# check capabilities against MARCH_{G5,Z900,Z990,Z9_109,Z10}
	481	xc __LC_STFL_FAC_LIST(8),__LC_STFL_FAC_LIST
	482	stfl __LC_STFL_FAC_LIST # store facility list
	483	tm __LC_STFL_FAC_LIST,0x01 # stfle available ?
	484	jz 0f
	485	la %r0,0
	486	.insn s,0xb2b00000,__LC_STFL_FAC_LIST # store facility list extended
	487	0: l %r0,__LC_STFL_FAC_LIST
	488	n %r0,2f+8-.LPG0(%r13)
	489	cl %r0,2f+8-.LPG0(%r13)
	490	jne 1f
	491	l %r0,__LC_STFL_FAC_LIST+4
	492	n %r0,2f+12-.LPG0(%r13)
	493	cl %r0,2f+12-.LPG0(%r13)
	494	je 3f
d90cbd46 HC	495	1: l %r15,.Lstack-.LPG0(%r13)
	496	ahi %r15,1<<(PAGE_SHIFT+THREAD_ORDER) # init_task_union+THREAD_SIZE
	497	ahi %r15,-96
	498	la %r2,.Lals_string-.LPG0(%r13)
	499	l %r3,.Lsclp_print-.LPG0(%r13)
	500	basr %r14,%r3
	501	lpsw 2f-.LPG0(%r13) # machine type not good enough, crash
	502	.Lals_string:
	503	.asciz "The Linux kernel requires more recent processor hardware"
	504	.Lsclp_print:
	505	.long _sclp_print_early
	506	.Lstack:
	507	.long init_thread_union
e37f50e1	508	.align 16
8c4caa4f MS	509	2: .long 0x000a0000,0x8badcccc
	510	#if defined(CONFIG_64BIT)
	511	#if defined(CONFIG_MARCH_Z10)
	512	.long 0xc100efe3, 0xf0680000
	513	#elif defined(CONFIG_MARCH_Z9_109)
	514	.long 0xc100efc3, 0x00000000
	515	#elif defined(CONFIG_MARCH_Z990)
	516	.long 0xc0002000, 0x00000000
	517	#elif defined(CONFIG_MARCH_Z900)
	518	.long 0xc0000000, 0x00000000
	519	#endif
	520	#else
e37f50e1	521	#if defined(CONFIG_MARCH_Z10)
8c4caa4f	522	.long 0x8100c880, 0x00000000
e37f50e1	523	#elif defined(CONFIG_MARCH_Z9_109)
8c4caa4f	524	.long 0x8100c880, 0x00000000
e37f50e1	525	#elif defined(CONFIG_MARCH_Z990)
8c4caa4f	526	.long 0x80002000, 0x00000000
e37f50e1	527	#elif defined(CONFIG_MARCH_Z900)
8c4caa4f MS	528	.long 0x80000000, 0x00000000
8c4caa4f MS	529	#endif
e37f50e1	530	#endif
8c4caa4f	531	3:
e37f50e1 MS	532	#endif
e37f50e1 MS	533
b6112ccb	534	l %r13,4f-.LPG0(%r13)
e37f50e1	535	b 0(%r13)
ab96e798	536	.align 4
b6112ccb MS	537	4: .long startup_continue
b6112ccb MS	538	5: .long sched_clock_base_cc
ab96e798 MS	539	.align 8
ab96e798 MS	540	6: .long 0x7fffffff,0xffffffff
e37f50e1 MS	541
	542	#
	543	# params at 10400 (setup.h)
	544	#
	545	.org PARMAREA
	546	.long 0,0 # IPL_DEVICE
	547	.long 0,0 # INITRD_START
	548	.long 0,0 # INITRD_SIZE
	549
	550	.org COMMAND_LINE
	551	.byte "root=/dev/ram0 ro"
	552	.byte 0
	553
347a8dc3	554	#ifdef CONFIG_64BIT
0ad775db HC	555	#include "head64.S"
	556	#else
	557	#include "head31.S"
1da177e4	558	#endif