[linux-2.6-block.git] / arch / powerpc / kernel / vmlinux.lds.S

/* SPDX-License-Identifier: GPL-2.0 */
#ifdef CONFIG_PPC64
#define PROVIDE32(x)	PROVIDE(__unused__##x)
#else
#define PROVIDE32(x)	PROVIDE(x)
#endif

#define BSS_FIRST_SECTIONS *(.bss.prominit)
#define EMITS_PT_NOTE
#define RO_EXCEPTION_TABLE_ALIGN	0

#include <asm/page.h>
#include <asm-generic/vmlinux.lds.h>
#include <asm/cache.h>
#include <asm/thread_info.h>

#define STRICT_ALIGN_SIZE	(1 << CONFIG_DATA_SHIFT)
#define ETEXT_ALIGN_SIZE	(1 << CONFIG_ETEXT_SHIFT)

ENTRY(_stext)

PHDRS {
	text PT_LOAD FLAGS(7); /* RWX */
	note PT_NOTE FLAGS(0);
}

#ifdef CONFIG_PPC64
OUTPUT_ARCH(powerpc:common64)
jiffies = jiffies_64;
#else
OUTPUT_ARCH(powerpc:common)
jiffies = jiffies_64 + 4;
#endif
SECTIONS
{
	. = KERNELBASE;

/*
 * Text, read only data and other permanent read-only sections
 */

	_text = .;
	_stext = .;

	/*
	 * Head text.
	 * This needs to be in its own output section to avoid ld placing
	 * branch trampoline stubs randomly throughout the fixed sections,
	 * which it will do (even if the branch comes from another section)
	 * in order to optimize stub generation.
	 */
	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
#ifdef CONFIG_PPC64
		KEEP(*(.head.text.first_256B));
#ifdef CONFIG_PPC_BOOK3E
#else
		KEEP(*(.head.text.real_vectors));
		*(.head.text.real_trampolines);
		KEEP(*(.head.text.virt_vectors));
		*(.head.text.virt_trampolines);
# if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
		KEEP(*(.head.data.fwnmi_page));
# endif
#endif
#else /* !CONFIG_PPC64 */
		HEAD_TEXT
#endif
	} :text

	__head_end = .;

#ifdef CONFIG_PPC64
	/*
	 * ALIGN(0) overrides the default output section alignment because
	 * this needs to start right after .head.text in order for fixed
	 * section placement to work.
	 */
	.text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
#ifdef CONFIG_LD_HEAD_STUB_CATCH
		KEEP(*(.linker_stub_catch));
		. = . ;
#endif

#else
	.text : AT(ADDR(.text) - LOAD_OFFSET) {
		ALIGN_FUNCTION();
#endif
		/* careful! __ftr_alt_* sections need to be close to .text */
		*(.text.hot TEXT_MAIN .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text);
#ifdef CONFIG_PPC64
		*(.tramp.ftrace.text);
#endif
		SCHED_TEXT
		CPUIDLE_TEXT
		LOCK_TEXT
		KPROBES_TEXT
		IRQENTRY_TEXT
		SOFTIRQENTRY_TEXT
		/*
		 * -Os builds call FP save/restore functions. The powerpc64
		 * linker generates those on demand in the .sfpr section.
		 * .sfpr gets placed at the beginning of a group of input
		 * sections, which can break start-of-text offset if it is
		 * included with the main text sections, so put it by itself.
		 */
		*(.sfpr);
		MEM_KEEP(init.text)
		MEM_KEEP(exit.text)

#ifdef CONFIG_PPC32
		*(.got1)
		__got2_start = .;
		*(.got2)
		__got2_end = .;
#endif /* CONFIG_PPC32 */

	} :text

	. = ALIGN(ETEXT_ALIGN_SIZE);
	_etext = .;
	PROVIDE32 (etext = .);

	/* Read-only data */
	RO_DATA(PAGE_SIZE)

#ifdef CONFIG_PPC64
	. = ALIGN(8);
	__stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
		__start___stf_entry_barrier_fixup = .;
		*(__stf_entry_barrier_fixup)
		__stop___stf_entry_barrier_fixup = .;
	}

	. = ALIGN(8);
	__stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
		__start___stf_exit_barrier_fixup = .;
		*(__stf_exit_barrier_fixup)
		__stop___stf_exit_barrier_fixup = .;
	}

	. = ALIGN(8);
	__rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
		__start___rfi_flush_fixup = .;
		*(__rfi_flush_fixup)
		__stop___rfi_flush_fixup = .;
	}
#endif /* CONFIG_PPC64 */

#ifdef CONFIG_PPC_BARRIER_NOSPEC
	. = ALIGN(8);
	__spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
		__start___barrier_nospec_fixup = .;
		*(__barrier_nospec_fixup)
		__stop___barrier_nospec_fixup = .;
	}
#endif /* CONFIG_PPC_BARRIER_NOSPEC */

#ifdef CONFIG_PPC_FSL_BOOK3E
	. = ALIGN(8);
	__spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
		__start__btb_flush_fixup = .;
		*(__btb_flush_fixup)
		__stop__btb_flush_fixup = .;
	}
#endif

/*
 * Init sections discarded at runtime
 */
	. = ALIGN(STRICT_ALIGN_SIZE);
	__init_begin = .;
	. = ALIGN(PAGE_SIZE);
	.init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
		_sinittext = .;
		INIT_TEXT
		_einittext = .;
#ifdef CONFIG_PPC64
		*(.tramp.ftrace.init);
#endif
	} :text

	/* .exit.text is discarded at runtime, not link time,
	 * to deal with references from __bug_table
	 */
	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
		EXIT_TEXT
	}

	.init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
		INIT_DATA
	}

	.init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
		INIT_SETUP(16)
	}

	.initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
		INIT_CALLS
	}

	.con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
		CON_INITCALL
	}

	. = ALIGN(8);
	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
		__start___ftr_fixup = .;
		KEEP(*(__ftr_fixup))
		__stop___ftr_fixup = .;
	}
	. = ALIGN(8);
	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
		__start___mmu_ftr_fixup = .;
		KEEP(*(__mmu_ftr_fixup))
		__stop___mmu_ftr_fixup = .;
	}
	. = ALIGN(8);
	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
		__start___lwsync_fixup = .;
		KEEP(*(__lwsync_fixup))
		__stop___lwsync_fixup = .;
	}
#ifdef CONFIG_PPC64
	. = ALIGN(8);
	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
		__start___fw_ftr_fixup = .;
		KEEP(*(__fw_ftr_fixup))
		__stop___fw_ftr_fixup = .;
	}
#endif
	.init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
		INIT_RAM_FS
	}

	PERCPU_SECTION(L1_CACHE_BYTES)

	. = ALIGN(8);
	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
		__machine_desc_start = . ;
		KEEP(*(.machine.desc))
		__machine_desc_end = . ;
	}
#ifdef CONFIG_RELOCATABLE
	. = ALIGN(8);
	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
	{
#ifdef CONFIG_PPC32
		__dynamic_symtab = .;
#endif
		*(.dynsym)
	}
	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
	{
		__dynamic_start = .;
		*(.dynamic)
	}
	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
	{
		__rela_dyn_start = .;
		*(.rela*)
	}
#endif
	/* .exit.data is discarded at runtime, not link time,
	 * to deal with references from .exit.text
	 */
	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
		EXIT_DATA
	}

	/* freed after init ends here */
	. = ALIGN(PAGE_SIZE);
	__init_end = .;

/*
 * And now the various read/write data
 */

	. = ALIGN(PAGE_SIZE);
	_sdata = .;

#ifdef CONFIG_PPC32
	.data : AT(ADDR(.data) - LOAD_OFFSET) {
		DATA_DATA
#ifdef CONFIG_UBSAN
		*(.data..Lubsan_data*)
		*(.data..Lubsan_type*)
#endif
		*(.data.rel*)
		*(SDATA_MAIN)
		*(.sdata2)
		*(.got.plt) *(.got)
		*(.plt)
		*(.branch_lt)
	}
#else
	.data : AT(ADDR(.data) - LOAD_OFFSET) {
		DATA_DATA
		*(.data.rel*)
		*(.toc1)
		*(.branch_lt)
	}

#ifdef CONFIG_DEBUG_INFO_BTF
	.BTF : AT(ADDR(.BTF) - LOAD_OFFSET) {
		*(.BTF)
	}
#endif

	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
		__start_opd = .;
		KEEP(*(.opd))
		__end_opd = .;
	}

	. = ALIGN(256);
	.got : AT(ADDR(.got) - LOAD_OFFSET) {
		__toc_start = .;
#ifndef CONFIG_RELOCATABLE
		__prom_init_toc_start = .;
		arch/powerpc/kernel/prom_init.o*(.toc .got)
		__prom_init_toc_end = .;
#endif
		*(.got)
		*(.toc)
	}
#endif

	/* The initial task and kernel stack */
	INIT_TASK_DATA_SECTION(THREAD_ALIGN)

	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
		PAGE_ALIGNED_DATA(PAGE_SIZE)
	}

	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
		CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
	}

	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
		READ_MOSTLY_DATA(L1_CACHE_BYTES)
	}

	. = ALIGN(PAGE_SIZE);
	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
		NOSAVE_DATA
	}

	BUG_TABLE

	. = ALIGN(PAGE_SIZE);
	_edata  =  .;
	PROVIDE32 (edata = .);

/*
 * And finally the bss
 */

	BSS_SECTION(0, 0, 0)

	. = ALIGN(PAGE_SIZE);
	_end = . ;
	PROVIDE32 (end = .);

	STABS_DEBUG

	DWARF_DEBUG

	DISCARDS
	/DISCARD/ : {
		*(*.EMB.apuinfo)
		*(.glink .iplt .plt .rela* .comment)
		*(.gnu.version*)
		*(.gnu.attributes)
		*(.eh_frame)
	}
}
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
c51e3a41	2	#ifdef CONFIG_PPC64
e8222502	3	#define PROVIDE32(x) PROVIDE(__unused__##x)
c51e3a41	4	#else
e8222502	5	#define PROVIDE32(x) PROVIDE(x)
c51e3a41	6	#endif
5f69e388 BH	7
5f69e388 BH	8	#define BSS_FIRST_SECTIONS *(.bss.prominit)
441110a5	9	#define EMITS_PT_NOTE
4e9e559a	10	#define RO_EXCEPTION_TABLE_ALIGN 0
5f69e388	11
4846c5de	12	#include <asm/page.h>
14cf11af	13	#include <asm-generic/vmlinux.lds.h>
bd67fcf9	14	#include <asm/cache.h>
62bef288	15	#include <asm/thread_info.h>
14cf11af	16
166d97d9 CL	17	#define STRICT_ALIGN_SIZE (1 << CONFIG_DATA_SHIFT)
166d97d9 CL	18	#define ETEXT_ALIGN_SIZE (1 << CONFIG_ETEXT_SHIFT)
d924cc3f	19
e19e4ab4 ME	20	ENTRY(_stext)
e19e4ab4 ME	21
c69cccc9	22	PHDRS {
af0f3e9e	23	text PT_LOAD FLAGS(7); /* RWX */
ec556271	24	note PT_NOTE FLAGS(0);
c69cccc9 SB	25	}
c69cccc9 SB	26
cabb5587 SR	27	#ifdef CONFIG_PPC64
	28	OUTPUT_ARCH(powerpc:common64)
	29	jiffies = jiffies_64;
	30	#else
14cf11af PM	31	OUTPUT_ARCH(powerpc:common)
14cf11af PM	32	jiffies = jiffies_64 + 4;
cabb5587	33	#endif
14cf11af PM	34	SECTIONS
14cf11af PM	35	{
e8222502	36	. = KERNELBASE;
14cf11af	37
e8222502 BH	38	/*
	39	* Text, read only data and other permanent read-only sections
	40	*/
	41
57f26649 NP	42	_text = .;
	43	_stext = .;
	44
	45	/*
	46	* Head text.
	47	* This needs to be in its own output section to avoid ld placing
	48	* branch trampoline stubs randomly throughout the fixed sections,
	49	* which it will do (even if the branch comes from another section)
	50	* in order to optimize stub generation.
	51	*/
	52	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
	53	#ifdef CONFIG_PPC64
	54	KEEP(*(.head.text.first_256B));
	55	#ifdef CONFIG_PPC_BOOK3E
57f26649 NP	56	#else
	57	KEEP(*(.head.text.real_vectors));
	58	*(.head.text.real_trampolines);
	59	KEEP(*(.head.text.virt_vectors));
	60	*(.head.text.virt_trampolines);
	61	# if defined(CONFIG_PPC_PSERIES) \|\| defined(CONFIG_PPC_POWERNV)
	62	KEEP(*(.head.data.fwnmi_page));
57f26649 NP	63	# endif
57f26649 NP	64	#endif
57f26649 NP	65	#else /* !CONFIG_PPC64 */
	66	HEAD_TEXT
	67	#endif
af0f3e9e	68	} :text
57f26649	69
7aa5b018 NR	70	__head_end = .;
7aa5b018 NR	71
dadc4a1b NP	72	#ifdef CONFIG_PPC64
dadc4a1b NP	73	/*
a652758a	74	* ALIGN(0) overrides the default output section alignment because
dadc4a1b NP	75	* this needs to start right after .head.text in order for fixed
	76	* section placement to work.
	77	*/
a652758a	78	.text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
951eedeb	79	#ifdef CONFIG_LD_HEAD_STUB_CATCH
4c1d9bb0	80	KEEP(*(.linker_stub_catch));
951eedeb NP	81	. = . ;
	82	#endif
	83
dadc4a1b	84	#else
366234f6	85	.text : AT(ADDR(.text) - LOAD_OFFSET) {
748a7683	86	ALIGN_FUNCTION();
dadc4a1b	87	#endif
13beadd9	88	/* careful! __ftr_alt_* sections need to be close to .text */
4c1d9bb0	89	(.text.hot TEXT_MAIN .text.fixup .text.unlikely .fixup __ftr_alt_ .ref.text);
67361cf8 NR	90	#ifdef CONFIG_PPC64
	91	*(.tramp.ftrace.text);
	92	#endif
e8222502	93	SCHED_TEXT
6727ad9e	94	CPUIDLE_TEXT
e8222502 BH	95	LOCK_TEXT
e8222502 BH	96	KPROBES_TEXT
6794c782	97	IRQENTRY_TEXT
be7635e7	98	SOFTIRQENTRY_TEXT
e8c68825 NP	99	/*
	100	* -Os builds call FP save/restore functions. The powerpc64
	101	* linker generates those on demand in the .sfpr section.
	102	* .sfpr gets placed at the beginning of a group of input
	103	* sections, which can break start-of-text offset if it is
	104	* included with the main text sections, so put it by itself.
	105	*/
	106	*(.sfpr);
7de3b27b ME	107	MEM_KEEP(init.text)
7de3b27b ME	108	MEM_KEEP(exit.text)
14cf11af	109
e8222502 BH	110	#ifdef CONFIG_PPC32
	111	*(.got1)
	112	__got2_start = .;
	113	*(.got2)
	114	__got2_end = .;
	115	#endif /* CONFIG_PPC32 */
	116
af0f3e9e	117	} :text
e8222502	118
166d97d9	119	. = ALIGN(ETEXT_ALIGN_SIZE);
303996da SR	120	_etext = .;
	121	PROVIDE32 (etext = .);
	122
e8222502	123	/* Read-only data */
d924cc3f	124	RO_DATA(PAGE_SIZE)
e8222502	125
aa8a5e00	126	#ifdef CONFIG_PPC64
a048a07d NP	127	. = ALIGN(8);
	128	__stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
	129	__start___stf_entry_barrier_fixup = .;
	130	*(__stf_entry_barrier_fixup)
	131	__stop___stf_entry_barrier_fixup = .;
	132	}
	133
	134	. = ALIGN(8);
	135	__stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
	136	__start___stf_exit_barrier_fixup = .;
	137	*(__stf_exit_barrier_fixup)
	138	__stop___stf_exit_barrier_fixup = .;
	139	}
	140
aa8a5e00 ME	141	. = ALIGN(8);
	142	__rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
	143	__start___rfi_flush_fixup = .;
	144	*(__rfi_flush_fixup)
	145	__stop___rfi_flush_fixup = .;
	146	}
179ab1cb	147	#endif /* CONFIG_PPC64 */
2eea7f06	148
179ab1cb	149	#ifdef CONFIG_PPC_BARRIER_NOSPEC
2eea7f06 MS	150	. = ALIGN(8);
	151	__spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
	152	__start___barrier_nospec_fixup = .;
	153	*(__barrier_nospec_fixup)
	154	__stop___barrier_nospec_fixup = .;
	155	}
179ab1cb	156	#endif /* CONFIG_PPC_BARRIER_NOSPEC */
aa8a5e00	157
76a5eaa3 DC	158	#ifdef CONFIG_PPC_FSL_BOOK3E
	159	. = ALIGN(8);
	160	__spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
	161	__start__btb_flush_fixup = .;
	162	*(__btb_flush_fixup)
	163	__stop__btb_flush_fixup = .;
	164	}
	165	#endif
14cf11af	166
e8222502 BH	167	/*
	168	* Init sections discarded at runtime
	169	*/
d924cc3f	170	. = ALIGN(STRICT_ALIGN_SIZE);
e8222502	171	__init_begin = .;
67361cf8 NR	172	. = ALIGN(PAGE_SIZE);
	173	.init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
	174	_sinittext = .;
	175	INIT_TEXT
	176	_einittext = .;
	177	#ifdef CONFIG_PPC64
	178	*(.tramp.ftrace.init);
	179	#endif
af0f3e9e	180	} :text
e8222502 BH	181
	182	/* .exit.text is discarded at runtime, not link time,
	183	* to deal with references from __bug_table
	184	*/
366234f6	185	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
01ba2bdc SR	186	EXIT_TEXT
01ba2bdc SR	187	}
e8222502	188
366234f6	189	.init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
01ba2bdc	190	INIT_DATA
e8222502 BH	191	}
e8222502 BH	192
366234f6	193	.init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
62bef288	194	INIT_SETUP(16)
e8222502 BH	195	}
e8222502 BH	196
366234f6	197	.initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
62bef288 TA	198	INIT_CALLS
62bef288 TA	199	}
e8222502	200
366234f6	201	.con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
62bef288	202	CON_INITCALL
e8222502 BH	203	}
e8222502 BH	204
e8222502	205	. = ALIGN(8);
366234f6	206	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
cabb5587	207	__start___ftr_fixup = .;
4c1d9bb0	208	KEEP(*(__ftr_fixup))
cabb5587 SR	209	__stop___ftr_fixup = .;
cabb5587 SR	210	}
2d1b2027	211	. = ALIGN(8);
7c03d653 BH	212	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
7c03d653 BH	213	__start___mmu_ftr_fixup = .;
4c1d9bb0	214	KEEP(*(__mmu_ftr_fixup))
7c03d653 BH	215	__stop___mmu_ftr_fixup = .;
	216	}
	217	. = ALIGN(8);
2d1b2027 KG	218	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
2d1b2027 KG	219	__start___lwsync_fixup = .;
4c1d9bb0	220	KEEP(*(__lwsync_fixup))
2d1b2027 KG	221	__stop___lwsync_fixup = .;
2d1b2027 KG	222	}
3f639ee8 SR	223	#ifdef CONFIG_PPC64
3f639ee8 SR	224	. = ALIGN(8);
366234f6	225	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
3f639ee8	226	__start___fw_ftr_fixup = .;
4c1d9bb0	227	KEEP(*(__fw_ftr_fixup))
3f639ee8 SR	228	__stop___fw_ftr_fixup = .;
	229	}
	230	#endif
366234f6	231	.init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
62bef288	232	INIT_RAM_FS
e8222502	233	}
62bef288	234
0415b00d	235	PERCPU_SECTION(L1_CACHE_BYTES)
14cf11af	236
e8222502	237	. = ALIGN(8);
366234f6	238	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
e8222502	239	__machine_desc_start = . ;
4c1d9bb0	240	KEEP(*(.machine.desc))
e8222502 BH	241	__machine_desc_end = . ;
e8222502 BH	242	}
2a4b9c5a	243	#ifdef CONFIG_RELOCATABLE
549e8152	244	. = ALIGN(8);
9c5f7d39 SP	245	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
9c5f7d39 SP	246	{
27d11496	247	#ifdef CONFIG_PPC32
9c5f7d39 SP	248	__dynamic_symtab = .;
	249	#endif
	250	*(.dynsym)
	251	}
549e8152 PM	252	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
	253	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
	254	{
	255	__dynamic_start = .;
	256	*(.dynamic)
	257	}
	258	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
	259	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
	260	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
	261	{
	262	__rela_dyn_start = .;
	263	(.rela)
	264	}
2a4b9c5a	265	#endif
4c812318 SR	266	/* .exit.data is discarded at runtime, not link time,
	267	* to deal with references from .exit.text
	268	*/
	269	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
	270	EXIT_DATA
	271	}
e8222502 BH	272
	273	/* freed after init ends here */
	274	. = ALIGN(PAGE_SIZE);
	275	__init_end = .;
	276
	277	/*
	278	* And now the various read/write data
	279	*/
	280
	281	. = ALIGN(PAGE_SIZE);
	282	_sdata = .;
14cf11af	283
cabb5587	284	#ifdef CONFIG_PPC32
366234f6	285	.data : AT(ADDR(.data) - LOAD_OFFSET) {
ca967258	286	DATA_DATA
beba24ac MM	287	#ifdef CONFIG_UBSAN
	288	(.data..Lubsan_data)
	289	(.data..Lubsan_type)
	290	#endif
a1072607	291	(.data.rel)
4c1d9bb0	292	*(SDATA_MAIN)
83a092cf	293	*(.sdata2)
e8222502	294	(.got.plt) (.got)
83a092cf	295	*(.plt)
98ecc676	296	*(.branch_lt)
e8222502	297	}
cabb5587	298	#else
366234f6	299	.data : AT(ADDR(.data) - LOAD_OFFSET) {
3ae0aa9f MD	300	DATA_DATA
	301	(.data.rel)
	302	*(.toc1)
e8222502 BH	303	*(.branch_lt)
e8222502 BH	304	}
14cf11af	305
cb0cc635 NR	306	#ifdef CONFIG_DEBUG_INFO_BTF
	307	.BTF : AT(ADDR(.BTF) - LOAD_OFFSET) {
	308	*(.BTF)
	309	}
	310	#endif
	311
366234f6	312	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
5633e85b	313	__start_opd = .;
4c1d9bb0	314	KEEP(*(.opd))
5633e85b	315	__end_opd = .;
e8222502 BH	316	}
e8222502 BH	317
5e95235c	318	. = ALIGN(256);
366234f6	319	.got : AT(ADDR(.got) - LOAD_OFFSET) {
e8222502	320	__toc_start = .;
5ac47f7a AB	321	#ifndef CONFIG_RELOCATABLE
	322	__prom_init_toc_start = .;
	323	arch/powerpc/kernel/prom_init.o*(.toc .got)
	324	__prom_init_toc_end = .;
	325	#endif
e8222502 BH	326	*(.got)
	327	*(.toc)
	328	}
cabb5587	329	#endif
14cf11af	330
e8222502	331	/* The initial task and kernel stack */
63289e7d	332	INIT_TASK_DATA_SECTION(THREAD_ALIGN)
14cf11af	333
75b13483	334	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
62bef288	335	PAGE_ALIGNED_DATA(PAGE_SIZE)
e8222502	336	}
14cf11af	337
4af57b78	338	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
62bef288	339	CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
e8222502	340	}
14cf11af	341
54cb27a7	342	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
62bef288	343	READ_MOSTLY_DATA(L1_CACHE_BYTES)
bd67fcf9 TB	344	}
bd67fcf9 TB	345
5be2a213	346	. = ALIGN(PAGE_SIZE);
366234f6	347	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
62bef288	348	NOSAVE_DATA
e8222502	349	}
4a288563	350
b5effd38 PZ	351	BUG_TABLE
b5effd38 PZ	352
903444e4 ME	353	. = ALIGN(PAGE_SIZE);
	354	_edata = .;
	355	PROVIDE32 (edata = .);
	356
e8222502 BH	357	/*
	358	* And finally the bss
	359	*/
	360
62bef288	361	BSS_SECTION(0, 0, 0)
14cf11af	362
e8222502 BH	363	. = ALIGN(PAGE_SIZE);
	364	_end = . ;
	365	PROVIDE32 (end = .);
023bf6f1	366
83a092cf NP	367	STABS_DEBUG
	368
	369	DWARF_DEBUG
	370
023bf6f1	371	DISCARDS
83a092cf NP	372	/DISCARD/ : {
	373	(.EMB.apuinfo)
	374	(.glink .iplt .plt .rela .comment)
	375	(.gnu.version)
	376	*(.gnu.attributes)
	377	*(.eh_frame)
	378	}
14cf11af	379	}