[linux-2.6-block.git] / arch / parisc / kernel / head.S

/* This file is subject to the terms and conditions of the GNU General Public
 * License.  See the file "COPYING" in the main directory of this archive
 * for more details.
 *
 * Copyright (C) 1999-2007 by Helge Deller <deller@gmx.de>
 * Copyright 1999 SuSE GmbH (Philipp Rumpf)
 * Copyright 1999 Philipp Rumpf (prumpf@tux.org)
 * Copyright 2000 Hewlett Packard (Paul Bame, bame@puffin.external.hp.com)
 * Copyright (C) 2001 Grant Grundler (Hewlett Packard)
 * Copyright (C) 2004 Kyle McMartin <kyle@debian.org>
 *
 * Initial Version 04-23-1999 by Helge Deller <deller@gmx.de>
 */

#include <asm/asm-offsets.h>
#include <asm/psw.h>
#include <asm/pdc.h>
	
#include <asm/assembly.h>
#include <asm/pgtable.h>

#include <linux/linkage.h>
#include <linux/init.h>

	.level	PA_ASM_LEVEL

	__INITDATA
ENTRY(boot_args)
	.word 0 /* arg0 */
	.word 0 /* arg1 */
	.word 0 /* arg2 */
	.word 0 /* arg3 */
END(boot_args)

	__HEAD

	.align	4
	.import init_thread_union,data
	.import fault_vector_20,code    /* IVA parisc 2.0 32 bit */
#ifndef CONFIG_64BIT
        .import fault_vector_11,code    /* IVA parisc 1.1 32 bit */
	.import	$global$		/* forward declaration */
#endif /*!CONFIG_64BIT*/
ENTRY(parisc_kernel_start)
	.proc
	.callinfo

	/* Make sure sr4-sr7 are set to zero for the kernel address space */
	mtsp	%r0,%sr4
	mtsp	%r0,%sr5
	mtsp	%r0,%sr6
	mtsp	%r0,%sr7

	/* Clear BSS (shouldn't the boot loader do this?) */

	.import __bss_start,data
	.import __bss_stop,data

	load32		PA(__bss_start),%r3
	load32		PA(__bss_stop),%r4
$bss_loop:
	cmpb,<<,n       %r3,%r4,$bss_loop
	stw,ma          %r0,4(%r3)

	/* Save away the arguments the boot loader passed in (32 bit args) */
	load32		PA(boot_args),%r1
	stw,ma          %arg0,4(%r1)
	stw,ma          %arg1,4(%r1)
	stw,ma          %arg2,4(%r1)
	stw,ma          %arg3,4(%r1)

	/* Initialize startup VM. Just map first 16/32 MB of memory */
	load32		PA(swapper_pg_dir),%r4
	mtctl		%r4,%cr24	/* Initialize kernel root pointer */
	mtctl		%r4,%cr25	/* Initialize user root pointer */

#if CONFIG_PGTABLE_LEVELS == 3
	/* Set pmd in pgd */
	load32		PA(pmd0),%r5
	shrd            %r5,PxD_VALUE_SHIFT,%r3	
	ldo		(PxD_FLAG_PRESENT+PxD_FLAG_VALID)(%r3),%r3
	stw		%r3,ASM_PGD_ENTRY*ASM_PGD_ENTRY_SIZE(%r4)
	ldo		ASM_PMD_ENTRY*ASM_PMD_ENTRY_SIZE(%r5),%r4
#else
	/* 2-level page table, so pmd == pgd */
	ldo		ASM_PGD_ENTRY*ASM_PGD_ENTRY_SIZE(%r4),%r4
#endif

	/* Fill in pmd with enough pte directories */
	load32		PA(pg0),%r1
	SHRREG		%r1,PxD_VALUE_SHIFT,%r3
	ldo		(PxD_FLAG_PRESENT+PxD_FLAG_VALID)(%r3),%r3

	ldi		ASM_PT_INITIAL,%r1

1:
	stw		%r3,0(%r4)
	ldo		(PAGE_SIZE >> PxD_VALUE_SHIFT)(%r3),%r3
	addib,>		-1,%r1,1b
#if CONFIG_PGTABLE_LEVELS == 3
	ldo             ASM_PMD_ENTRY_SIZE(%r4),%r4
#else
	ldo             ASM_PGD_ENTRY_SIZE(%r4),%r4
#endif


	/* Now initialize the PTEs themselves.  We use RWX for
	 * everything ... it will get remapped correctly later */
	ldo		0+_PAGE_KERNEL_RWX(%r0),%r3 /* Hardwired 0 phys addr start */
	load32		(1<<(KERNEL_INITIAL_ORDER-PAGE_SHIFT)),%r11 /* PFN count */
	load32		PA(pg0),%r1

$pgt_fill_loop:
	STREGM          %r3,ASM_PTE_ENTRY_SIZE(%r1)
	ldo		(1<<PFN_PTE_SHIFT)(%r3),%r3 /* add one PFN */
	addib,>		-1,%r11,$pgt_fill_loop
	nop

	/* Load the return address...er...crash 'n burn */
	copy		%r0,%r2

	/* And the RFI Target address too */
	load32		start_parisc,%r11

	/* And the initial task pointer */
	load32		init_thread_union,%r6
	mtctl           %r6,%cr30

	/* And the stack pointer too */
	ldo             THREAD_SZ_ALGN(%r6),%sp

#if defined(CONFIG_64BIT) && defined(CONFIG_FUNCTION_TRACER)
	.import _mcount,data
	/* initialize mcount FPTR */
	/* Get the global data pointer */
	loadgp
	load32		PA(_mcount), %r10
	std		%dp,0x18(%r10)
#endif

#ifdef CONFIG_64BIT
	/* Get PDCE_PROC for monarch CPU. */
#define MEM_PDC_LO 0x388
#define MEM_PDC_HI 0x35C
	ldw             MEM_PDC_LO(%r0),%r3
	ldw             MEM_PDC_HI(%r0),%r10
	depd            %r10, 31, 32, %r3        /* move to upper word */
#endif


#ifdef CONFIG_SMP
	/* Set the smp rendezvous address into page zero.
	** It would be safer to do this in init_smp_config() but
	** it's just way easier to deal with here because
	** of 64-bit function ptrs and the address is local to this file.
	*/
	load32		PA(smp_slave_stext),%r10
	stw		%r10,0x10(%r0)	/* MEM_RENDEZ */
	stw		%r0,0x28(%r0)	/* MEM_RENDEZ_HI - assume addr < 4GB */

	/* FALLTHROUGH */
	.procend

	/*
	** Code Common to both Monarch and Slave processors.
	** Entry:
	**
	**  1.1:	
	**    %r11 must contain RFI target address.
	**    %r25/%r26 args to pass to target function
	**    %r2  in case rfi target decides it didn't like something
	**
	**  2.0w:
	**    %r3  PDCE_PROC address
	**    %r11 RFI target address
	**
	** Caller must init: SR4-7, %sp, %r10, %cr24/25, 
	*/
common_stext:
	.proc
	.callinfo
#else
	/* Clear PDC entry point - we won't use it */
	stw		%r0,0x10(%r0)	/* MEM_RENDEZ */
	stw		%r0,0x28(%r0)	/* MEM_RENDEZ_HI */
#endif /*CONFIG_SMP*/

#ifdef CONFIG_64BIT
	tophys_r1	%sp

	/* Save the rfi target address */
	ldd             TI_TASK-THREAD_SZ_ALGN(%sp), %r10
	tophys_r1       %r10
	std             %r11,  TASK_PT_GR11(%r10)
	/* Switch to wide mode Superdome doesn't support narrow PDC
	** calls.
	*/
1:	mfia            %rp             /* clear upper part of pcoq */
	ldo             2f-1b(%rp),%rp
	depdi           0,31,32,%rp
	bv              (%rp)
	ssm             PSW_SM_W,%r0

        /* Set Wide mode as the "Default" (eg for traps)
        ** First trap occurs *right* after (or part of) rfi for slave CPUs.
        ** Someday, palo might not do this for the Monarch either.
        */
2:
	mfctl		%cr30,%r6		/* PCX-W2 firmware bug */

	ldo             PDC_PSW(%r0),%arg0              /* 21 */
	ldo             PDC_PSW_SET_DEFAULTS(%r0),%arg1 /* 2 */
	ldo             PDC_PSW_WIDE_BIT(%r0),%arg2     /* 2 */
	load32          PA(stext_pdc_ret), %rp
	bv              (%r3)
	copy            %r0,%arg3

stext_pdc_ret:
	mtctl		%r6,%cr30		/* restore task thread info */

	/* restore rfi target address*/
	ldd             TI_TASK-THREAD_SZ_ALGN(%sp), %r10
	tophys_r1       %r10
	ldd             TASK_PT_GR11(%r10), %r11
	tovirt_r1       %sp
#endif
	
	/* PARANOID: clear user scratch/user space SR's */
	mtsp	%r0,%sr0
	mtsp	%r0,%sr1
	mtsp	%r0,%sr2
	mtsp	%r0,%sr3

	/* Initialize Protection Registers */
	mtctl	%r0,%cr8
	mtctl	%r0,%cr9
	mtctl	%r0,%cr12
	mtctl	%r0,%cr13

	/* Initialize the global data pointer */
	loadgp

	/* Set up our interrupt table.  HPMCs might not work after this! 
	 *
	 * We need to install the correct iva for PA1.1 or PA2.0. The
	 * following short sequence of instructions can determine this
	 * (without being illegal on a PA1.1 machine).
	 */
#ifndef CONFIG_64BIT
	ldi		32,%r10
	mtctl		%r10,%cr11
	.level 2.0
	mfctl,w		%cr11,%r10
	.level 1.1
	comib,<>,n	0,%r10,$is_pa20
	ldil		L%PA(fault_vector_11),%r10
	b		$install_iva
	ldo		R%PA(fault_vector_11)(%r10),%r10

$is_pa20:
	.level		PA_ASM_LEVEL /* restore 1.1 || 2.0w */
#endif /*!CONFIG_64BIT*/
	load32		PA(fault_vector_20),%r10

$install_iva:
	mtctl		%r10,%cr14

	b		aligned_rfi  /* Prepare to RFI! Man all the cannons! */
	nop

	.align 128
aligned_rfi:
	pcxt_ssm_bug

	copy		%r3, %arg0	/* PDCE_PROC for smp_callin() */

	rsm		PSW_SM_QUIET,%r0	/* off troublesome PSW bits */
	/* Don't need NOPs, have 8 compliant insn before rfi */

	mtctl		%r0,%cr17	/* Clear IIASQ tail */
	mtctl		%r0,%cr17	/* Clear IIASQ head */

	/* Load RFI target into PC queue */
	mtctl		%r11,%cr18	/* IIAOQ head */
	ldo		4(%r11),%r11
	mtctl		%r11,%cr18	/* IIAOQ tail */

	load32		KERNEL_PSW,%r10
	mtctl		%r10,%ipsw
	
	/* Jump through hyperspace to Virt Mode */
	rfi
	nop

	.procend

#ifdef CONFIG_SMP

	.import smp_init_current_idle_task,data
	.import	smp_callin,code

#ifndef CONFIG_64BIT
smp_callin_rtn:
        .proc
	.callinfo
	break	1,1		/*  Break if returned from start_secondary */
	nop
	nop
        .procend
#endif /*!CONFIG_64BIT*/

/***************************************************************************
* smp_slave_stext is executed by all non-monarch Processors when the Monarch
* pokes the slave CPUs in smp.c:smp_boot_cpus().
*
* Once here, registers values are initialized in order to branch to virtual
* mode. Once all available/eligible CPUs are in virtual mode, all are
* released and start out by executing their own idle task.
*****************************************************************************/
smp_slave_stext:
        .proc
	.callinfo

	/*
	** Initialize Space registers
	*/
	mtsp	   %r0,%sr4
	mtsp	   %r0,%sr5
	mtsp	   %r0,%sr6
	mtsp	   %r0,%sr7

#ifdef CONFIG_64BIT
	/*
	 *  Enable Wide mode early, in case the task_struct for the idle
	 *  task in smp_init_current_idle_task was allocated above 4GB.
	 */
1:	mfia            %rp             /* clear upper part of pcoq */
	ldo             2f-1b(%rp),%rp
	depdi           0,31,32,%rp
	bv              (%rp)
	ssm             PSW_SM_W,%r0
2:
#endif

	/*  Initialize the SP - monarch sets up smp_init_current_idle_task */
	load32		PA(smp_init_current_idle_task),%sp
	LDREG		0(%sp),%sp	/* load task address */
	tophys_r1	%sp
	LDREG		TASK_THREAD_INFO(%sp),%sp
	mtctl           %sp,%cr30       /* store in cr30 */
	ldo             THREAD_SZ_ALGN(%sp),%sp

	/* point CPU to kernel page tables */
	load32		PA(swapper_pg_dir),%r4
	mtctl		%r4,%cr24	/* Initialize kernel root pointer */
	mtctl		%r4,%cr25	/* Initialize user root pointer */

#ifdef CONFIG_64BIT
	/* Setup PDCE_PROC entry */
	copy            %arg0,%r3
#else
	/* Load RFI *return* address in case smp_callin bails */
	load32		smp_callin_rtn,%r2
#endif
	
	/* Load RFI target address.  */
	load32		smp_callin,%r11
	
	/* ok...common code can handle the rest */
	b		common_stext
	nop

	.procend
#endif /* CONFIG_SMP */

ENDPROC(parisc_kernel_start)

#ifndef CONFIG_64BIT
	.section .data..ro_after_init

	.align	4
	.export	$global$,data

	.type	$global$,@object
	.size	$global$,4
$global$:	
	.word 0
#endif /*!CONFIG_64BIT*/
Commit	Line	Data
1da177e4 LT	1	/* This file is subject to the terms and conditions of the GNU General Public
	2	* License. See the file "COPYING" in the main directory of this archive
	3	* for more details.
	4	*
8e9e9844	5	* Copyright (C) 1999-2007 by Helge Deller <deller@gmx.de>
1da177e4 LT	6	* Copyright 1999 SuSE GmbH (Philipp Rumpf)
	7	* Copyright 1999 Philipp Rumpf (prumpf@tux.org)
	8	* Copyright 2000 Hewlett Packard (Paul Bame, bame@puffin.external.hp.com)
	9	* Copyright (C) 2001 Grant Grundler (Hewlett Packard)
	10	* Copyright (C) 2004 Kyle McMartin <kyle@debian.org>
	11	*
	12	* Initial Version 04-23-1999 by Helge Deller <deller@gmx.de>
	13	*/
	14
0013a854	15	#include <asm/asm-offsets.h>
1da177e4 LT	16	#include <asm/psw.h>
	17	#include <asm/pdc.h>
	18
	19	#include <asm/assembly.h>
	20	#include <asm/pgtable.h>
	21
8e9e9844	22	#include <linux/linkage.h>
0c634cc6	23	#include <linux/init.h>
8e9e9844	24
1829dda0	25	.level PA_ASM_LEVEL
1da177e4	26
0c634cc6	27	__INITDATA
8e9e9844	28	ENTRY(boot_args)
1da177e4 LT	29	.word 0 /* arg0 */
	30	.word 0 /* arg1 */
	31	.word 0 /* arg2 */
	32	.word 0 /* arg3 */
8e9e9844	33	END(boot_args)
1da177e4	34
1138a72c KM	35	__HEAD
1138a72c KM	36
1da177e4 LT	37	.align 4
	38	.import init_thread_union,data
	39	.import fault_vector_20,code /* IVA parisc 2.0 32 bit */
413059f2	40	#ifndef CONFIG_64BIT
1da177e4 LT	41	.import fault_vector_11,code /* IVA parisc 1.1 32 bit */
1da177e4 LT	42	.import $global$ /* forward declaration */
413059f2	43	#endif /!CONFIG_64BIT/
161bd3bf	44	ENTRY(parisc_kernel_start)
1da177e4 LT	45	.proc
	46	.callinfo
	47
	48	/* Make sure sr4-sr7 are set to zero for the kernel address space */
	49	mtsp %r0,%sr4
	50	mtsp %r0,%sr5
	51	mtsp %r0,%sr6
	52	mtsp %r0,%sr7
	53
	54	/* Clear BSS (shouldn't the boot loader do this?) */
	55
	56	.import __bss_start,data
	57	.import __bss_stop,data
	58
	59	load32 PA(__bss_start),%r3
	60	load32 PA(__bss_stop),%r4
	61	$bss_loop:
	62	cmpb,<<,n %r3,%r4,$bss_loop
	63	stw,ma %r0,4(%r3)
	64
	65	/* Save away the arguments the boot loader passed in (32 bit args) */
	66	load32 PA(boot_args),%r1
	67	stw,ma %arg0,4(%r1)
	68	stw,ma %arg1,4(%r1)
	69	stw,ma %arg2,4(%r1)
	70	stw,ma %arg3,4(%r1)
	71
332b42e4	72	/* Initialize startup VM. Just map first 16/32 MB of memory */
1da177e4 LT	73	load32 PA(swapper_pg_dir),%r4
	74	mtctl %r4,%cr24 /* Initialize kernel root pointer */
	75	mtctl %r4,%cr25 /* Initialize user root pointer */
	76
f24ffde4	77	#if CONFIG_PGTABLE_LEVELS == 3
1da177e4 LT	78	/* Set pmd in pgd */
	79	load32 PA(pmd0),%r5
	80	shrd %r5,PxD_VALUE_SHIFT,%r3
2fd83038	81	ldo (PxD_FLAG_PRESENT+PxD_FLAG_VALID)(%r3),%r3
1da177e4 LT	82	stw %r3,ASM_PGD_ENTRY*ASM_PGD_ENTRY_SIZE(%r4)
	83	ldo ASM_PMD_ENTRY*ASM_PMD_ENTRY_SIZE(%r5),%r4
	84	#else
	85	/* 2-level page table, so pmd == pgd */
2fd83038	86	ldo ASM_PGD_ENTRY*ASM_PGD_ENTRY_SIZE(%r4),%r4
1da177e4 LT	87	#endif
	88
	89	/* Fill in pmd with enough pte directories */
	90	load32 PA(pg0),%r1
	91	SHRREG %r1,PxD_VALUE_SHIFT,%r3
	92	ldo (PxD_FLAG_PRESENT+PxD_FLAG_VALID)(%r3),%r3
	93
	94	ldi ASM_PT_INITIAL,%r1
	95
	96	1:
	97	stw %r3,0(%r4)
80af0876	98	ldo (PAGE_SIZE >> PxD_VALUE_SHIFT)(%r3),%r3
1da177e4	99	addib,> -1,%r1,1b
f24ffde4	100	#if CONFIG_PGTABLE_LEVELS == 3
1da177e4 LT	101	ldo ASM_PMD_ENTRY_SIZE(%r4),%r4
	102	#else
	103	ldo ASM_PGD_ENTRY_SIZE(%r4),%r4
	104	#endif
	105
	106
d7dd2ff1 JB	107	/* Now initialize the PTEs themselves. We use RWX for
	108	* everything ... it will get remapped correctly later */
	109	ldo 0+_PAGE_KERNEL_RWX(%r0),%r3 /* Hardwired 0 phys addr start */
332b42e4	110	load32 (1<<(KERNEL_INITIAL_ORDER-PAGE_SHIFT)),%r11 /* PFN count */
1da177e4 LT	111	load32 PA(pg0),%r1
	112
	113	$pgt_fill_loop:
	114	STREGM %r3,ASM_PTE_ENTRY_SIZE(%r1)
2fd83038 HD	115	ldo (1<<PFN_PTE_SHIFT)(%r3),%r3 /* add one PFN */
2fd83038 HD	116	addib,> -1,%r11,$pgt_fill_loop
1da177e4 LT	117	nop
	118
	119	/* Load the return address...er...crash 'n burn */
	120	copy %r0,%r2
	121
	122	/* And the RFI Target address too */
089d5528	123	load32 start_parisc,%r11
1da177e4 LT	124
	125	/* And the initial task pointer */
	126	load32 init_thread_union,%r6
	127	mtctl %r6,%cr30
	128
	129	/* And the stack pointer too */
	130	ldo THREAD_SZ_ALGN(%r6),%sp
	131
366dd4ea HD	132	#if defined(CONFIG_64BIT) && defined(CONFIG_FUNCTION_TRACER)
	133	.import _mcount,data
	134	/* initialize mcount FPTR */
	135	/* Get the global data pointer */
	136	loadgp
	137	load32 PA(_mcount), %r10
	138	std %dp,0x18(%r10)
	139	#endif
	140
0ed1fe4a HD	141	#ifdef CONFIG_64BIT
	142	/* Get PDCE_PROC for monarch CPU. */
	143	#define MEM_PDC_LO 0x388
	144	#define MEM_PDC_HI 0x35C
	145	ldw MEM_PDC_LO(%r0),%r3
	146	ldw MEM_PDC_HI(%r0),%r10
	147	depd %r10, 31, 32, %r3 /* move to upper word */
	148	#endif
	149
	150
1da177e4	151	#ifdef CONFIG_SMP
25985edc	152	/* Set the smp rendezvous address into page zero.
1da177e4 LT	153	** It would be safer to do this in init_smp_config() but
	154	** it's just way easier to deal with here because
	155	** of 64-bit function ptrs and the address is local to this file.
	156	*/
	157	load32 PA(smp_slave_stext),%r10
	158	stw %r10,0x10(%r0) /* MEM_RENDEZ */
	159	stw %r0,0x28(%r0) /* MEM_RENDEZ_HI - assume addr < 4GB */
	160
	161	/* FALLTHROUGH */
	162	.procend
	163
	164	/*
	165	** Code Common to both Monarch and Slave processors.
	166	** Entry:
	167	**
	168	** 1.1:
	169	** %r11 must contain RFI target address.
	170	** %r25/%r26 args to pass to target function
	171	** %r2 in case rfi target decides it didn't like something
	172	**
	173	** 2.0w:
	174	** %r3 PDCE_PROC address
	175	** %r11 RFI target address
	176	**
	177	** Caller must init: SR4-7, %sp, %r10, %cr24/25,
	178	*/
	179	common_stext:
	180	.proc
	181	.callinfo
	182	#else
	183	/* Clear PDC entry point - we won't use it */
	184	stw %r0,0x10(%r0) /* MEM_RENDEZ */
	185	stw %r0,0x28(%r0) /* MEM_RENDEZ_HI */
	186	#endif /CONFIG_SMP/
	187
413059f2	188	#ifdef CONFIG_64BIT
1da177e4 LT	189	tophys_r1 %sp
	190
	191	/* Save the rfi target address */
	192	ldd TI_TASK-THREAD_SZ_ALGN(%sp), %r10
	193	tophys_r1 %r10
	194	std %r11, TASK_PT_GR11(%r10)
	195	/* Switch to wide mode Superdome doesn't support narrow PDC
	196	** calls.
	197	*/
	198	1: mfia %rp /* clear upper part of pcoq */
	199	ldo 2f-1b(%rp),%rp
	200	depdi 0,31,32,%rp
	201	bv (%rp)
	202	ssm PSW_SM_W,%r0
	203
	204	/* Set Wide mode as the "Default" (eg for traps)
	205	** First trap occurs right after (or part of) rfi for slave CPUs.
	206	** Someday, palo might not do this for the Monarch either.
	207	*/
	208	2:
54e181e0 HD	209	mfctl %cr30,%r6 /* PCX-W2 firmware bug */
54e181e0 HD	210
1da177e4 LT	211	ldo PDC_PSW(%r0),%arg0 /* 21 */
	212	ldo PDC_PSW_SET_DEFAULTS(%r0),%arg1 /* 2 */
	213	ldo PDC_PSW_WIDE_BIT(%r0),%arg2 /* 2 */
	214	load32 PA(stext_pdc_ret), %rp
	215	bv (%r3)
	216	copy %r0,%arg3
	217
	218	stext_pdc_ret:
54e181e0 HD	219	mtctl %r6,%cr30 /* restore task thread info */
54e181e0 HD	220
1da177e4 LT	221	/* restore rfi target address*/
	222	ldd TI_TASK-THREAD_SZ_ALGN(%sp), %r10
	223	tophys_r1 %r10
	224	ldd TASK_PT_GR11(%r10), %r11
	225	tovirt_r1 %sp
	226	#endif
	227
	228	/* PARANOID: clear user scratch/user space SR's */
	229	mtsp %r0,%sr0
	230	mtsp %r0,%sr1
	231	mtsp %r0,%sr2
	232	mtsp %r0,%sr3
	233
	234	/* Initialize Protection Registers */
	235	mtctl %r0,%cr8
	236	mtctl %r0,%cr9
	237	mtctl %r0,%cr12
	238	mtctl %r0,%cr13
	239
1da177e4 LT	240	/* Initialize the global data pointer */
	241	loadgp
	242
	243	/* Set up our interrupt table. HPMCs might not work after this!
	244	*
	245	* We need to install the correct iva for PA1.1 or PA2.0. The
	246	* following short sequence of instructions can determine this
	247	* (without being illegal on a PA1.1 machine).
	248	*/
413059f2	249	#ifndef CONFIG_64BIT
1da177e4 LT	250	ldi 32,%r10
	251	mtctl %r10,%cr11
	252	.level 2.0
	253	mfctl,w %cr11,%r10
	254	.level 1.1
	255	comib,<>,n 0,%r10,$is_pa20
	256	ldil L%PA(fault_vector_11),%r10
	257	b $install_iva
	258	ldo R%PA(fault_vector_11)(%r10),%r10
	259
	260	$is_pa20:
1829dda0	261	.level PA_ASM_LEVEL /* restore 1.1 \|\| 2.0w */
413059f2	262	#endif /!CONFIG_64BIT/
1da177e4 LT	263	load32 PA(fault_vector_20),%r10
	264
	265	$install_iva:
	266	mtctl %r10,%cr14
	267
896a3756	268	b aligned_rfi /* Prepare to RFI! Man all the cannons! */
1da177e4 LT	269	nop
1da177e4 LT	270
896a3756	271	.align 128
1da177e4	272	aligned_rfi:
896a3756	273	pcxt_ssm_bug
1da177e4	274
0ed1fe4a HD	275	copy %r3, %arg0 /* PDCE_PROC for smp_callin() */
0ed1fe4a HD	276
896a3756 GG	277	rsm PSW_SM_QUIET,%r0 /* off troublesome PSW bits */
896a3756 GG	278	/* Don't need NOPs, have 8 compliant insn before rfi */
1da177e4	279
1da177e4 LT	280	mtctl %r0,%cr17 /* Clear IIASQ tail */
	281	mtctl %r0,%cr17 /* Clear IIASQ head */
	282
	283	/* Load RFI target into PC queue */
	284	mtctl %r11,%cr18 /* IIAOQ head */
	285	ldo 4(%r11),%r11
	286	mtctl %r11,%cr18 /* IIAOQ tail */
896a3756 GG	287
	288	load32 KERNEL_PSW,%r10
	289	mtctl %r10,%ipsw
1da177e4	290
896a3756	291	/* Jump through hyperspace to Virt Mode */
1da177e4 LT	292	rfi
	293	nop
	294
	295	.procend
	296
	297	#ifdef CONFIG_SMP
	298
	299	.import smp_init_current_idle_task,data
	300	.import smp_callin,code
	301
413059f2	302	#ifndef CONFIG_64BIT
1da177e4 LT	303	smp_callin_rtn:
	304	.proc
	305	.callinfo
	306	break 1,1 /* Break if returned from start_secondary */
	307	nop
	308	nop
	309	.procend
413059f2	310	#endif /!CONFIG_64BIT/
1da177e4 LT	311
	312	/***************************************************************************
	313	* smp_slave_stext is executed by all non-monarch Processors when the Monarch
	314	* pokes the slave CPUs in smp.c:smp_boot_cpus().
	315	*
	316	* Once here, registers values are initialized in order to branch to virtual
	317	* mode. Once all available/eligible CPUs are in virtual mode, all are
	318	* released and start out by executing their own idle task.
	319	*****************************************************************************/
	320	smp_slave_stext:
	321	.proc
	322	.callinfo
	323
	324	/*
	325	** Initialize Space registers
	326	*/
	327	mtsp %r0,%sr4
	328	mtsp %r0,%sr5
	329	mtsp %r0,%sr6
	330	mtsp %r0,%sr7
	331
6b1370ae SS	332	#ifdef CONFIG_64BIT
	333	/*
	334	* Enable Wide mode early, in case the task_struct for the idle
	335	* task in smp_init_current_idle_task was allocated above 4GB.
	336	*/
	337	1: mfia %rp /* clear upper part of pcoq */
	338	ldo 2f-1b(%rp),%rp
	339	depdi 0,31,32,%rp
	340	bv (%rp)
	341	ssm PSW_SM_W,%r0
	342	2:
	343	#endif
	344
1da177e4 LT	345	/* Initialize the SP - monarch sets up smp_init_current_idle_task */
	346	load32 PA(smp_init_current_idle_task),%sp
	347	LDREG 0(%sp),%sp /* load task address */
	348	tophys_r1 %sp
	349	LDREG TASK_THREAD_INFO(%sp),%sp
	350	mtctl %sp,%cr30 /* store in cr30 */
	351	ldo THREAD_SZ_ALGN(%sp),%sp
	352
	353	/* point CPU to kernel page tables */
	354	load32 PA(swapper_pg_dir),%r4
	355	mtctl %r4,%cr24 /* Initialize kernel root pointer */
	356	mtctl %r4,%cr25 /* Initialize user root pointer */
	357
413059f2	358	#ifdef CONFIG_64BIT
1da177e4 LT	359	/* Setup PDCE_PROC entry */
	360	copy %arg0,%r3
	361	#else
	362	/* Load RFI return address in case smp_callin bails */
	363	load32 smp_callin_rtn,%r2
	364	#endif
	365
	366	/* Load RFI target address. */
	367	load32 smp_callin,%r11
	368
	369	/* ok...common code can handle the rest */
	370	b common_stext
	371	nop
	372
	373	.procend
	374	#endif /* CONFIG_SMP */
8e9e9844	375
161bd3bf	376	ENDPROC(parisc_kernel_start)
8e9e9844	377
413059f2	378	#ifndef CONFIG_64BIT
dc1b3c0d	379	.section .data..ro_after_init
1da177e4 LT	380
	381	.align 4
	382	.export $global$,data
	383
	384	.type $global$,@object
	385	.size $global$,4
	386	$global$:
	387	.word 0
413059f2	388	#endif /!CONFIG_64BIT/