[linux-block.git] / arch / m68k / kernel / vmlinux-nommu.lds

/* SPDX-License-Identifier: GPL-2.0 */
/*
 *	vmlinux.lds.S -- master linker script for m68knommu arch
 *
 *	(C) Copyright 2002-2012, Greg Ungerer <gerg@snapgear.com>
 *
 *	This linker script is equipped to build either ROM loaded or RAM
 *	run kernels.
 */

#if defined(CONFIG_RAMKERNEL)
#define	KTEXT_ADDR	CONFIG_KERNELBASE
#endif
#if defined(CONFIG_ROMKERNEL)
#define	KTEXT_ADDR	CONFIG_ROMSTART
#define	KDATA_ADDR	CONFIG_KERNELBASE
#define	LOAD_OFFSET	KDATA_ADDR + (ADDR(.text) + SIZEOF(.text))
#endif

#include <asm/page.h>
#include <asm/thread_info.h>
#include <asm-generic/vmlinux.lds.h>

OUTPUT_ARCH(m68k)
ENTRY(_start)

jiffies = jiffies_64 + 4;

SECTIONS {

#ifdef CONFIG_ROMVEC
	. = CONFIG_ROMVEC;
	.romvec : {
		__rom_start = .;
		_romvec = .;
		*(.romvec)
		*(.data..initvect)
	}
#endif

	. = KTEXT_ADDR;

	_text = .;
	_stext = .;
	.text : {
		HEAD_TEXT
		TEXT_TEXT
		IRQENTRY_TEXT
		SOFTIRQENTRY_TEXT
		SCHED_TEXT
		CPUIDLE_TEXT
		LOCK_TEXT
		*(.fixup)
		. = ALIGN(16);
	}
	_etext = .;

#ifdef KDATA_ADDR
	. = KDATA_ADDR;
#endif

	_sdata = .;
	RO_DATA(PAGE_SIZE)
	RW_DATA(16, PAGE_SIZE, THREAD_SIZE)
	_edata = .;

	EXCEPTION_TABLE(16)

	. = ALIGN(PAGE_SIZE);
	__init_begin = .;
	INIT_TEXT_SECTION(PAGE_SIZE)
	INIT_DATA_SECTION(16)
	PERCPU_SECTION(16)
	.m68k_fixup : {
		__start_fixup = .;
		*(.m68k_fixup)
		__stop_fixup = .;
	}
	.init.data : {
		. = ALIGN(PAGE_SIZE);
		__init_end = .;
	}

	BSS_SECTION(0, 0, 0)

	_end = .;

	STABS_DEBUG
	.comment 0 : { *(.comment) }

	/* Sections to be discarded */
	DISCARDS
}
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
1da177e4 LT	2	/*
	3	* vmlinux.lds.S -- master linker script for m68knommu arch
	4	*
f84f52a5	5	* (C) Copyright 2002-2012, Greg Ungerer <gerg@snapgear.com>
1da177e4	6	*
25985edc	7	* This linker script is equipped to build either ROM loaded or RAM
1c952af5	8	* run kernels.
1da177e4 LT	9	*/
1da177e4 LT	10
1da177e4	11	#if defined(CONFIG_RAMKERNEL)
f84f52a5	12	#define KTEXT_ADDR CONFIG_KERNELBASE
1da177e4	13	#endif
f84f52a5 GU	14	#if defined(CONFIG_ROMKERNEL)
	15	#define KTEXT_ADDR CONFIG_ROMSTART
	16	#define KDATA_ADDR CONFIG_KERNELBASE
	17	#define LOAD_OFFSET KDATA_ADDR + (ADDR(.text) + SIZEOF(.text))
1da177e4 LT	18	#endif
1da177e4 LT	19
f84f52a5 GU	20	#include <asm/page.h>
	21	#include <asm/thread_info.h>
	22	#include <asm-generic/vmlinux.lds.h>
1da177e4 LT	23
	24	OUTPUT_ARCH(m68k)
	25	ENTRY(_start)
	26
1da177e4 LT	27	jiffies = jiffies_64 + 4;
	28
	29	SECTIONS {
	30
f84f52a5 GU	31	#ifdef CONFIG_ROMVEC
f84f52a5 GU	32	. = CONFIG_ROMVEC;
1da177e4	33	.romvec : {
f84f52a5	34	__rom_start = .;
1da177e4	35	_romvec = .;
f84f52a5	36	*(.romvec)
2c31c341	37	*(.data..initvect)
f84f52a5	38	}
1da177e4 LT	39	#endif
1da177e4 LT	40
f84f52a5 GU	41	. = KTEXT_ADDR;
	42
	43	_text = .;
	44	_stext = .;
1da177e4	45	.text : {
9b0e7410	46	HEAD_TEXT
7664709b	47	TEXT_TEXT
969de098 GU	48	IRQENTRY_TEXT
969de098 GU	49	SOFTIRQENTRY_TEXT
1da177e4	50	SCHED_TEXT
6727ad9e	51	CPUIDLE_TEXT
779125c2	52	LOCK_TEXT
ed865e31	53	*(.fixup)
f84f52a5 GU	54	. = ALIGN(16);
	55	}
	56	_etext = .;
	57
	58	#ifdef KDATA_ADDR
	59	. = KDATA_ADDR;
	60	#endif
	61
	62	_sdata = .;
93240b32	63	RO_DATA(PAGE_SIZE)
c9174047	64	RW_DATA(16, PAGE_SIZE, THREAD_SIZE)
f84f52a5	65	_edata = .;
1da177e4	66
f84f52a5	67	EXCEPTION_TABLE(16)
1da177e4	68
f84f52a5 GU	69	. = ALIGN(PAGE_SIZE);
	70	__init_begin = .;
	71	INIT_TEXT_SECTION(PAGE_SIZE)
	72	INIT_DATA_SECTION(16)
	73	PERCPU_SECTION(16)
ed865e31 GU	74	.m68k_fixup : {
	75	__start_fixup = .;
	76	*(.m68k_fixup)
	77	__stop_fixup = .;
f84f52a5	78	}
53749f73	79	.init.data : {
f4bed4fb	80	. = ALIGN(PAGE_SIZE);
1da177e4	81	__init_end = .;
f84f52a5 GU	82	}
f84f52a5 GU	83
f84f52a5	84	BSS_SECTION(0, 0, 0)
f84f52a5 GU	85
	86	_end = .;
	87
	88	STABS_DEBUG
	89	.comment 0 : { *(.comment) }
1da177e4	90
f84f52a5	91	/* Sections to be discarded */
023bf6f1	92	DISCARDS
1da177e4 LT	93	}
1da177e4 LT	94