Commit | Line | Data |
---|---|---|
1da177e4 LT |
1 | /* |
2 | * Linker script for vsyscall DSO. The vsyscall page is an ELF shared | |
3 | * object prelinked to its virtual address, and with only one read-only | |
4 | * segment (that fits in one page). This script controls its layout. | |
5 | */ | |
86feeaa8 | 6 | #include <asm/asm-offsets.h> |
1da177e4 LT |
7 | |
8 | SECTIONS | |
9 | { | |
10 | . = VSYSCALL_BASE + SIZEOF_HEADERS; | |
11 | ||
12 | .hash : { *(.hash) } :text | |
13 | .dynsym : { *(.dynsym) } | |
14 | .dynstr : { *(.dynstr) } | |
15 | .gnu.version : { *(.gnu.version) } | |
16 | .gnu.version_d : { *(.gnu.version_d) } | |
17 | .gnu.version_r : { *(.gnu.version_r) } | |
18 | ||
19 | /* This linker script is used both with -r and with -shared. | |
20 | For the layouts to match, we need to skip more than enough | |
21 | space for the dynamic symbol table et al. If this amount | |
22 | is insufficient, ld -shared will barf. Just increase it here. */ | |
23 | . = VSYSCALL_BASE + 0x400; | |
24 | ||
25 | .text : { *(.text) } :text =0x90909090 | |
c97db4a0 | 26 | .note : { *(.note.*) } :text :note |
1da177e4 LT |
27 | .eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr |
28 | .eh_frame : { KEEP (*(.eh_frame)) } :text | |
29 | .dynamic : { *(.dynamic) } :text :dynamic | |
30 | .useless : { | |
31 | *(.got.plt) *(.got) | |
32 | *(.data .data.* .gnu.linkonce.d.*) | |
33 | *(.dynbss) | |
34 | *(.bss .bss.* .gnu.linkonce.b.*) | |
35 | } :text | |
36 | } | |
37 | ||
38 | /* | |
39 | * We must supply the ELF program headers explicitly to get just one | |
40 | * PT_LOAD segment, and set the flags explicitly to make segments read-only. | |
41 | */ | |
42 | PHDRS | |
43 | { | |
44 | text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */ | |
45 | dynamic PT_DYNAMIC FLAGS(4); /* PF_R */ | |
c97db4a0 | 46 | note PT_NOTE FLAGS(4); /* PF_R */ |
1da177e4 LT |
47 | eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */ |
48 | } | |
49 | ||
50 | /* | |
51 | * This controls what symbols we export from the DSO. | |
52 | */ | |
53 | VERSION | |
54 | { | |
55 | LINUX_2.5 { | |
56 | global: | |
57 | __kernel_vsyscall; | |
58 | __kernel_sigreturn; | |
59 | __kernel_rt_sigreturn; | |
60 | ||
61 | local: *; | |
62 | }; | |
63 | } | |
64 | ||
65 | /* The ELF entry point can be used to set the AT_SYSINFO value. */ | |
66 | ENTRY(__kernel_vsyscall); |