[linux-block.git] / arch / frv / kernel / vmlinux.lds.S

/* SPDX-License-Identifier: GPL-2.0 */
/* ld script to make FRV Linux kernel
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
 */
OUTPUT_FORMAT("elf32-frv", "elf32-frv", "elf32-frv")
OUTPUT_ARCH(frv)
ENTRY(_start)

#include <asm-generic/vmlinux.lds.h>
#include <asm/processor.h>
#include <asm/page.h>
#include <asm/cache.h>
#include <asm/thread_info.h>

jiffies = jiffies_64 + 4;

__page_offset = CONFIG_PAGE_OFFSET;	/* start of area covered by struct pages */
__kernel_image_start = __page_offset;	/* address at which kernel image resides */

SECTIONS
{
  . = __kernel_image_start;

  /* discardable initialisation code and data */
  . = ALIGN(PAGE_SIZE);			/* Init code and data */
  __init_begin = .;

  _sinittext = .;
  .init.text : {
	HEAD_TEXT
#ifndef CONFIG_DEBUG_INFO
	INIT_TEXT
	EXIT_TEXT
	EXIT_DATA
	*(.exitcall.exit)
#endif
  }
  _einittext = .;

  INIT_DATA_SECTION(8)
  PERCPU_SECTION(L1_CACHE_BYTES)

  . = ALIGN(PAGE_SIZE);
  __init_end = .;

  .trap : {
	/* trap table management - read entry-table.S before modifying */
	. = ALIGN(8192);
	__trap_tables = .;
	*(.trap.user)
	*(.trap.kernel)
	. = ALIGN(4096);
	*(.trap.break)
  }

  /* Text and read-only data */
  . = ALIGN(4);
  _text = .;
  _stext = .;
  .text : {
	*(.text..start)
	*(.text..entry)
	*(.text..break)
	*(.text..tlbmiss)
	TEXT_TEXT
	SCHED_TEXT
	CPUIDLE_TEXT
	LOCK_TEXT
#ifdef CONFIG_DEBUG_INFO
	INIT_TEXT
	EXIT_TEXT
	*(.exitcall.exit)
#endif
	*(.fixup)
	*(.gnu.warning)
	*(.exitcall.exit)
	} = 0x9090

  _etext = .;			/* End of text section */

  RODATA

  .rodata : {
	*(.trap.vector)

	/* this clause must not be modified - the ordering and adjacency are imperative */
	__trap_fixup_tables = .;
	*(.trap.fixup.user .trap.fixup.kernel)

	}

  EXCEPTION_TABLE(8)

  _sdata = .;
  .data : {			/* Data */
	INIT_TASK_DATA(THREAD_SIZE)
	CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
	DATA_DATA
	*(.data.*)
	EXIT_DATA
	CONSTRUCTORS
	}

  _edata = .;			/* End of data section */

  BUG_TABLE

  /* GP section */
  . = ALIGN(L1_CACHE_BYTES);
  _gp = . + 2048;
  PROVIDE (gp = _gp);

  .sdata : { *(.sdata .sdata.*) }

  /* BSS */
  . = ALIGN(L1_CACHE_BYTES);
  __bss_start = .;

  .sbss		: { *(.sbss .sbss.*) }
  .bss		: { *(.bss .bss.*) }
  .bss..stack	: { *(.bss) }

  __bss_stop = .;
  _end = . ;
  . = ALIGN(PAGE_SIZE);
  __kernel_image_end = .;

  STABS_DEBUG
  DWARF_DEBUG

  .comment 0 : { *(.comment) }

  DISCARDS
}

__kernel_image_size_no_bss = __bss_start - __kernel_image_start;
Commit	Line	Data
b2441318	1	/* SPDX-License-Identifier: GPL-2.0 */
1da177e4 LT	2	/* ld script to make FRV Linux kernel
	3	* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
	4	*/
	5	OUTPUT_FORMAT("elf32-frv", "elf32-frv", "elf32-frv")
	6	OUTPUT_ARCH(frv)
	7	ENTRY(_start)
	8
	9	#include <asm-generic/vmlinux.lds.h>
	10	#include <asm/processor.h>
	11	#include <asm/page.h>
	12	#include <asm/cache.h>
	13	#include <asm/thread_info.h>
	14
	15	jiffies = jiffies_64 + 4;
	16
7038220a	17	__page_offset = CONFIG_PAGE_OFFSET; /* start of area covered by struct pages */
1da177e4 LT	18	__kernel_image_start = __page_offset; /* address at which kernel image resides */
	19
	20	SECTIONS
	21	{
	22	. = __kernel_image_start;
	23
	24	/* discardable initialisation code and data */
	25	. = ALIGN(PAGE_SIZE); /* Init code and data */
	26	__init_begin = .;
	27
	28	_sinittext = .;
	29	.init.text : {
b6a8d95c	30	HEAD_TEXT
1da177e4	31	#ifndef CONFIG_DEBUG_INFO
01ba2bdc SR	32	INIT_TEXT
	33	EXIT_TEXT
	34	EXIT_DATA
1da177e4 LT	35	*(.exitcall.exit)
	36	#endif
	37	}
	38	_einittext = .;
1da177e4	39
9c88b25b	40	INIT_DATA_SECTION(8)
0415b00d	41	PERCPU_SECTION(L1_CACHE_BYTES)
1da177e4	42
9c88b25b	43	. = ALIGN(PAGE_SIZE);
1da177e4 LT	44	__init_end = .;
1da177e4 LT	45
1da177e4 LT	46	.trap : {
	47	/* trap table management - read entry-table.S before modifying */
	48	. = ALIGN(8192);
	49	__trap_tables = .;
	50	*(.trap.user)
	51	*(.trap.kernel)
	52	. = ALIGN(4096);
	53	*(.trap.break)
	54	}
	55
1da177e4 LT	56	/* Text and read-only data */
	57	. = ALIGN(4);
	58	_text = .;
	59	_stext = .;
	60	.text : {
b6f4e451 DV	61	*(.text..start)
	62	*(.text..entry)
	63	*(.text..break)
	64	*(.text..tlbmiss)
3c835670 DH	65	TEXT_TEXT
3c835670 DH	66	SCHED_TEXT
6727ad9e	67	CPUIDLE_TEXT
3c835670	68	LOCK_TEXT
1da177e4	69	#ifdef CONFIG_DEBUG_INFO
01ba2bdc SR	70	INIT_TEXT
01ba2bdc SR	71	EXIT_TEXT
d897d2b5	72	*(.exitcall.exit)
3c835670	73	#endif
1da177e4 LT	74	*(.fixup)
	75	*(.gnu.warning)
	76	*(.exitcall.exit)
	77	} = 0x9090
	78
	79	_etext = .; /* End of text section */
	80
	81	RODATA
	82
	83	.rodata : {
	84	*(.trap.vector)
	85
	86	/* this clause must not be modified - the ordering and adjacency are imperative */
	87	__trap_fixup_tables = .;
	88	*(.trap.fixup.user .trap.fixup.kernel)
	89
	90	}
	91
9c88b25b	92	EXCEPTION_TABLE(8)
1da177e4 LT	93
	94	_sdata = .;
	95	.data : { /* Data */
9c88b25b NE	96	INIT_TASK_DATA(THREAD_SIZE)
9c88b25b NE	97	CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
ca967258 SR	98	DATA_DATA
ca967258 SR	99	(.data.)
01ba2bdc	100	EXIT_DATA
1da177e4 LT	101	CONSTRUCTORS
	102	}
	103
	104	_edata = .; /* End of data section */
	105
b5effd38 PZ	106	BUG_TABLE
b5effd38 PZ	107
1da177e4 LT	108	/* GP section */
	109	. = ALIGN(L1_CACHE_BYTES);
	110	_gp = . + 2048;
	111	PROVIDE (gp = _gp);
	112
	113	.sdata : { (.sdata .sdata.) }
	114
	115	/* BSS */
	116	. = ALIGN(L1_CACHE_BYTES);
	117	__bss_start = .;
	118
	119	.sbss : { (.sbss .sbss.) }
	120	.bss : { (.bss .bss.) }
1360e070	121	.bss..stack : { *(.bss) }
1da177e4 LT	122
	123	__bss_stop = .;
	124	_end = . ;
	125	. = ALIGN(PAGE_SIZE);
	126	__kernel_image_end = .;
	127
9c88b25b NE	128	STABS_DEBUG
9c88b25b NE	129	DWARF_DEBUG
1da177e4 LT	130
1da177e4 LT	131	.comment 0 : { *(.comment) }
405d967d	132
023bf6f1	133	DISCARDS
1da177e4 LT	134	}
	135
	136	__kernel_image_size_no_bss = __bss_start - __kernel_image_start;