[linux-2.6-block.git] / arch / arm64 / kernel / entry-ftrace.S

/*
 * arch/arm64/kernel/entry-ftrace.S
 *
 * Copyright (C) 2013 Linaro Limited
 * Author: AKASHI Takahiro <takahiro.akashi@linaro.org>
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */

#include <linux/linkage.h>
#include <asm/assembler.h>
#include <asm/ftrace.h>
#include <asm/insn.h>

/*
 * Gcc with -pg will put the following code in the beginning of each function:
 *      mov x0, x30
 *      bl _mcount
 *	[function's body ...]
 * "bl _mcount" may be replaced to "bl ftrace_caller" or NOP if dynamic
 * ftrace is enabled.
 *
 * Please note that x0 as an argument will not be used here because we can
 * get lr(x30) of instrumented function at any time by winding up call stack
 * as long as the kernel is compiled without -fomit-frame-pointer.
 * (or CONFIG_FRAME_POINTER, this is forced on arm64)
 *
 * stack layout after mcount_enter in _mcount():
 *
 * current sp/fp =>  0:+-----+
 * in _mcount()        | x29 | -> instrumented function's fp
 *                     +-----+
 *                     | x30 | -> _mcount()'s lr (= instrumented function's pc)
 * old sp       => +16:+-----+
 * when instrumented   |     |
 * function calls      | ... |
 * _mcount()           |     |
 *                     |     |
 * instrumented => +xx:+-----+
 * function's fp       | x29 | -> parent's fp
 *                     +-----+
 *                     | x30 | -> instrumented function's lr (= parent's pc)
 *                     +-----+
 *                     | ... |
 */

	.macro mcount_enter
	stp	x29, x30, [sp, #-16]!
	mov	x29, sp
	.endm

	.macro mcount_exit
	ldp	x29, x30, [sp], #16
	ret
	.endm

	.macro mcount_adjust_addr rd, rn
	sub	\rd, \rn, #AARCH64_INSN_SIZE
	.endm

	/* for instrumented function's parent */
	.macro mcount_get_parent_fp reg
	ldr	\reg, [x29]
	ldr	\reg, [\reg]
	.endm

	/* for instrumented function */
	.macro mcount_get_pc0 reg
	mcount_adjust_addr	\reg, x30
	.endm

	.macro mcount_get_pc reg
	ldr	\reg, [x29, #8]
	mcount_adjust_addr	\reg, \reg
	.endm

	.macro mcount_get_lr reg
	ldr	\reg, [x29]
	ldr	\reg, [\reg, #8]
	.endm

	.macro mcount_get_lr_addr reg
	ldr	\reg, [x29]
	add	\reg, \reg, #8
	.endm

#ifndef CONFIG_DYNAMIC_FTRACE
/*
 * void _mcount(unsigned long return_address)
 * @return_address: return address to instrumented function
 *
 * This function makes calls, if enabled, to:
 *     - tracer function to probe instrumented function's entry,
 *     - ftrace_graph_caller to set up an exit hook
 */
ENTRY(_mcount)
	mcount_enter

	ldr_l	x2, ftrace_trace_function
	adr	x0, ftrace_stub
	cmp	x0, x2			// if (ftrace_trace_function
	b.eq	skip_ftrace_call	//     != ftrace_stub) {

	mcount_get_pc	x0		//       function's pc
	mcount_get_lr	x1		//       function's lr (= parent's pc)
	blr	x2			//   (*ftrace_trace_function)(pc, lr);

skip_ftrace_call:			// }
#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	ldr_l	x2, ftrace_graph_return
	cmp	x0, x2			//   if ((ftrace_graph_return
	b.ne	ftrace_graph_caller	//        != ftrace_stub)

	ldr_l	x2, ftrace_graph_entry	//     || (ftrace_graph_entry
	adr_l	x0, ftrace_graph_entry_stub //     != ftrace_graph_entry_stub))
	cmp	x0, x2
	b.ne	ftrace_graph_caller	//     ftrace_graph_caller();
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
	mcount_exit
ENDPROC(_mcount)
EXPORT_SYMBOL(_mcount)
NOKPROBE(_mcount)

#else /* CONFIG_DYNAMIC_FTRACE */
/*
 * _mcount() is used to build the kernel with -pg option, but all the branch
 * instructions to _mcount() are replaced to NOP initially at kernel start up,
 * and later on, NOP to branch to ftrace_caller() when enabled or branch to
 * NOP when disabled per-function base.
 */
ENTRY(_mcount)
	ret
ENDPROC(_mcount)
EXPORT_SYMBOL(_mcount)
NOKPROBE(_mcount)

/*
 * void ftrace_caller(unsigned long return_address)
 * @return_address: return address to instrumented function
 *
 * This function is a counterpart of _mcount() in 'static' ftrace, and
 * makes calls to:
 *     - tracer function to probe instrumented function's entry,
 *     - ftrace_graph_caller to set up an exit hook
 */
ENTRY(ftrace_caller)
	mcount_enter

	mcount_get_pc0	x0		//     function's pc
	mcount_get_lr	x1		//     function's lr

GLOBAL(ftrace_call)			// tracer(pc, lr);
	nop				// This will be replaced with "bl xxx"
					// where xxx can be any kind of tracer.

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
GLOBAL(ftrace_graph_call)		// ftrace_graph_caller();
	nop				// If enabled, this will be replaced
					// "b ftrace_graph_caller"
#endif

	mcount_exit
ENDPROC(ftrace_caller)
#endif /* CONFIG_DYNAMIC_FTRACE */

ENTRY(ftrace_stub)
	ret
ENDPROC(ftrace_stub)

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
/*
 * void ftrace_graph_caller(void)
 *
 * Called from _mcount() or ftrace_caller() when function_graph tracer is
 * selected.
 * This function w/ prepare_ftrace_return() fakes link register's value on
 * the call stack in order to intercept instrumented function's return path
 * and run return_to_handler() later on its exit.
 */
ENTRY(ftrace_graph_caller)
	mcount_get_pc		  x0	//     function's pc
	mcount_get_lr_addr	  x1	//     pointer to function's saved lr
	mcount_get_parent_fp	  x2	//     parent's fp
	bl	prepare_ftrace_return	// prepare_ftrace_return(pc, &lr, fp)

	mcount_exit
ENDPROC(ftrace_graph_caller)

/*
 * void return_to_handler(void)
 *
 * Run ftrace_return_to_handler() before going back to parent.
 * @fp is checked against the value passed by ftrace_graph_caller().
 */
ENTRY(return_to_handler)
	/* save return value regs */
	sub sp, sp, #64
	stp x0, x1, [sp]
	stp x2, x3, [sp, #16]
	stp x4, x5, [sp, #32]
	stp x6, x7, [sp, #48]

	mov	x0, x29			//     parent's fp
	bl	ftrace_return_to_handler// addr = ftrace_return_to_hander(fp);
	mov	x30, x0			// restore the original return address

	/* restore return value regs */
	ldp x0, x1, [sp]
	ldp x2, x3, [sp, #16]
	ldp x4, x5, [sp, #32]
	ldp x6, x7, [sp, #48]
	add sp, sp, #64

	ret
END(return_to_handler)
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
Commit	Line	Data
819e50e2 AT	1	/*
	2	* arch/arm64/kernel/entry-ftrace.S
	3	*
	4	* Copyright (C) 2013 Linaro Limited
	5	* Author: AKASHI Takahiro <takahiro.akashi@linaro.org>
	6	*
	7	* This program is free software; you can redistribute it and/or modify
	8	* it under the terms of the GNU General Public License version 2 as
	9	* published by the Free Software Foundation.
	10	*/
	11
	12	#include <linux/linkage.h>
f705d954	13	#include <asm/assembler.h>
819e50e2 AT	14	#include <asm/ftrace.h>
	15	#include <asm/insn.h>
	16
	17	/*
	18	* Gcc with -pg will put the following code in the beginning of each function:
	19	* mov x0, x30
	20	* bl _mcount
	21	* [function's body ...]
	22	* "bl _mcount" may be replaced to "bl ftrace_caller" or NOP if dynamic
	23	* ftrace is enabled.
	24	*
	25	* Please note that x0 as an argument will not be used here because we can
	26	* get lr(x30) of instrumented function at any time by winding up call stack
	27	* as long as the kernel is compiled without -fomit-frame-pointer.
	28	* (or CONFIG_FRAME_POINTER, this is forced on arm64)
	29	*
	30	* stack layout after mcount_enter in _mcount():
	31	*
	32	* current sp/fp => 0:+-----+
	33	* in _mcount() \| x29 \| -> instrumented function's fp
	34	* +-----+
	35	* \| x30 \| -> _mcount()'s lr (= instrumented function's pc)
	36	* old sp => +16:+-----+
	37	* when instrumented \| \|
	38	* function calls \| ... \|
	39	* _mcount() \| \|
	40	* \| \|
	41	* instrumented => +xx:+-----+
	42	* function's fp \| x29 \| -> parent's fp
	43	* +-----+
	44	* \| x30 \| -> instrumented function's lr (= parent's pc)
	45	* +-----+
	46	* \| ... \|
	47	*/
	48
	49	.macro mcount_enter
	50	stp x29, x30, [sp, #-16]!
	51	mov x29, sp
	52	.endm
	53
	54	.macro mcount_exit
	55	ldp x29, x30, [sp], #16
	56	ret
	57	.endm
	58
	59	.macro mcount_adjust_addr rd, rn
	60	sub \rd, \rn, #AARCH64_INSN_SIZE
	61	.endm
	62
	63	/* for instrumented function's parent */
	64	.macro mcount_get_parent_fp reg
	65	ldr \reg, [x29]
	66	ldr \reg, [\reg]
	67	.endm
	68
	69	/* for instrumented function */
	70	.macro mcount_get_pc0 reg
	71	mcount_adjust_addr \reg, x30
	72	.endm
	73
	74	.macro mcount_get_pc reg
	75	ldr \reg, [x29, #8]
	76	mcount_adjust_addr \reg, \reg
	77	.endm
78
79	.macro mcount_get_lr reg
80	ldr \reg, [x29]
81	ldr \reg, [\reg, #8]
819e50e2 AT	82	.endm
	83
	84	.macro mcount_get_lr_addr reg
	85	ldr \reg, [x29]
	86	add \reg, \reg, #8
	87	.endm
	88
bd7d38db	89	#ifndef CONFIG_DYNAMIC_FTRACE
819e50e2 AT	90	/*
	91	* void _mcount(unsigned long return_address)
	92	* @return_address: return address to instrumented function
	93	*
	94	* This function makes calls, if enabled, to:
	95	* - tracer function to probe instrumented function's entry,
	96	* - ftrace_graph_caller to set up an exit hook
	97	*/
	98	ENTRY(_mcount)
819e50e2 AT	99	mcount_enter
819e50e2 AT	100
829d2bd1	101	ldr_l x2, ftrace_trace_function
819e50e2 AT	102	adr x0, ftrace_stub
	103	cmp x0, x2 // if (ftrace_trace_function
	104	b.eq skip_ftrace_call // != ftrace_stub) {
	105
	106	mcount_get_pc x0 // function's pc
	107	mcount_get_lr x1 // function's lr (= parent's pc)
	108	blr x2 // (*ftrace_trace_function)(pc, lr);
	109
d125bffc JT	110	skip_ftrace_call: // }
d125bffc JT	111	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
829d2bd1	112	ldr_l x2, ftrace_graph_return
f1ba46ee AB	113	cmp x0, x2 // if ((ftrace_graph_return
	114	b.ne ftrace_graph_caller // != ftrace_stub)
	115
829d2bd1 MR	116	ldr_l x2, ftrace_graph_entry // \|\| (ftrace_graph_entry
829d2bd1 MR	117	adr_l x0, ftrace_graph_entry_stub // != ftrace_graph_entry_stub))
819e50e2 AT	118	cmp x0, x2
819e50e2 AT	119	b.ne ftrace_graph_caller // ftrace_graph_caller();
819e50e2	120	#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
d125bffc	121	mcount_exit
819e50e2	122	ENDPROC(_mcount)
dbd31962 MR	123	EXPORT_SYMBOL(_mcount)
dbd31962 MR	124	NOKPROBE(_mcount)
819e50e2	125
bd7d38db AT	126	#else /* CONFIG_DYNAMIC_FTRACE */
	127	/*
	128	* _mcount() is used to build the kernel with -pg option, but all the branch
	129	* instructions to _mcount() are replaced to NOP initially at kernel start up,
	130	* and later on, NOP to branch to ftrace_caller() when enabled or branch to
	131	* NOP when disabled per-function base.
	132	*/
	133	ENTRY(_mcount)
	134	ret
	135	ENDPROC(_mcount)
dbd31962 MR	136	EXPORT_SYMBOL(_mcount)
dbd31962 MR	137	NOKPROBE(_mcount)
bd7d38db AT	138
	139	/*
	140	* void ftrace_caller(unsigned long return_address)
	141	* @return_address: return address to instrumented function
	142	*
	143	* This function is a counterpart of _mcount() in 'static' ftrace, and
	144	* makes calls to:
	145	* - tracer function to probe instrumented function's entry,
	146	* - ftrace_graph_caller to set up an exit hook
	147	*/
	148	ENTRY(ftrace_caller)
	149	mcount_enter
	150
	151	mcount_get_pc0 x0 // function's pc
	152	mcount_get_lr x1 // function's lr
	153
e4fe1966	154	GLOBAL(ftrace_call) // tracer(pc, lr);
bd7d38db AT	155	nop // This will be replaced with "bl xxx"
	156	// where xxx can be any kind of tracer.
	157
	158	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
e4fe1966	159	GLOBAL(ftrace_graph_call) // ftrace_graph_caller();
bd7d38db AT	160	nop // If enabled, this will be replaced
	161	// "b ftrace_graph_caller"
	162	#endif
	163
	164	mcount_exit
	165	ENDPROC(ftrace_caller)
	166	#endif /* CONFIG_DYNAMIC_FTRACE */
	167
819e50e2 AT	168	ENTRY(ftrace_stub)
	169	ret
	170	ENDPROC(ftrace_stub)
	171
	172	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	173	/*
	174	* void ftrace_graph_caller(void)
	175	*
	176	* Called from _mcount() or ftrace_caller() when function_graph tracer is
	177	* selected.
	178	* This function w/ prepare_ftrace_return() fakes link register's value on
	179	* the call stack in order to intercept instrumented function's return path
	180	* and run return_to_handler() later on its exit.
	181	*/
	182	ENTRY(ftrace_graph_caller)
7dc48bf9 MR	183	mcount_get_pc x0 // function's pc
7dc48bf9 MR	184	mcount_get_lr_addr x1 // pointer to function's saved lr
819e50e2	185	mcount_get_parent_fp x2 // parent's fp
7dc48bf9	186	bl prepare_ftrace_return // prepare_ftrace_return(pc, &lr, fp)
819e50e2 AT	187
	188	mcount_exit
	189	ENDPROC(ftrace_graph_caller)
	190
	191	/*
	192	* void return_to_handler(void)
	193	*
	194	* Run ftrace_return_to_handler() before going back to parent.
5c176aff	195	* @fp is checked against the value passed by ftrace_graph_caller().
819e50e2 AT	196	*/
819e50e2 AT	197	ENTRY(return_to_handler)
49e258e0 MR	198	/* save return value regs */
	199	sub sp, sp, #64
	200	stp x0, x1, [sp]
	201	stp x2, x3, [sp, #16]
	202	stp x4, x5, [sp, #32]
	203	stp x6, x7, [sp, #48]
	204
819e50e2 AT	205	mov x0, x29 // parent's fp
	206	bl ftrace_return_to_handler// addr = ftrace_return_to_hander(fp);
	207	mov x30, x0 // restore the original return address
49e258e0 MR	208
	209	/* restore return value regs */
	210	ldp x0, x1, [sp]
	211	ldp x2, x3, [sp, #16]
	212	ldp x4, x5, [sp, #32]
	213	ldp x6, x7, [sp, #48]
	214	add sp, sp, #64
	215
819e50e2 AT	216	ret
	217	END(return_to_handler)
	218	#endif /* CONFIG_FUNCTION_GRAPH_TRACER */