[linux-2.6-block.git] / arch / arm64 / kernel / efi-entry.S

/*
 * EFI entry point.
 *
 * Copyright (C) 2013, 2014 Red Hat, Inc.
 * Author: Mark Salter <msalter@redhat.com>
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 *
 */
#include <linux/linkage.h>
#include <linux/init.h>

#include <asm/assembler.h>

#define EFI_LOAD_ERROR 0x8000000000000001

	__INIT

	/*
	 * We arrive here from the EFI boot manager with:
	 *
	 *    * CPU in little-endian mode
	 *    * MMU on with identity-mapped RAM
	 *    * Icache and Dcache on
	 *
	 * We will most likely be running from some place other than where
	 * we want to be. The kernel image wants to be placed at TEXT_OFFSET
	 * from start of RAM.
	 */
ENTRY(entry)
	/*
	 * Create a stack frame to save FP/LR with extra space
	 * for image_addr variable passed to efi_entry().
	 */
	stp	x29, x30, [sp, #-32]!
	mov	x29, sp

	/*
	 * Call efi_entry to do the real work.
	 * x0 and x1 are already set up by firmware. Current runtime
	 * address of image is calculated and passed via *image_addr.
	 *
	 * unsigned long efi_entry(void *handle,
	 *                         efi_system_table_t *sys_table,
	 *                         unsigned long *image_addr) ;
	 */
	adr_l	x8, _text
	add	x2, sp, 16
	str	x8, [x2]
	bl	efi_entry
	cmn	x0, #1
	b.eq	efi_load_fail

	/*
	 * efi_entry() will have copied the kernel image if necessary and we
	 * return here with device tree address in x0 and the kernel entry
	 * point stored at *image_addr. Save those values in registers which
	 * are callee preserved.
	 */
	mov	x20, x0		// DTB address
	ldr	x0, [sp, #16]	// relocated _text address
	ldr	w21, =stext_offset
	add	x21, x0, x21

	/*
	 * Calculate size of the kernel Image (same for original and copy).
	 */
	adr_l	x1, _text
	adr_l	x2, _edata
	sub	x1, x2, x1

	/*
	 * Flush the copied Image to the PoC, and ensure it is not shadowed by
	 * stale icache entries from before relocation.
	 */
	bl	__flush_dcache_area
	ic	ialluis

	/*
	 * Ensure that the rest of this function (in the original Image) is
	 * visible when the caches are disabled. The I-cache can't have stale
	 * entries for the VA range of the current image, so no maintenance is
	 * necessary.
	 */
	adr	x0, entry
	adr	x1, entry_end
	sub	x1, x1, x0
	bl	__flush_dcache_area

	/* Turn off Dcache and MMU */
	mrs	x0, CurrentEL
	cmp	x0, #CurrentEL_EL2
	b.ne	1f
	mrs	x0, sctlr_el2
	bic	x0, x0, #1 << 0	// clear SCTLR.M
	bic	x0, x0, #1 << 2	// clear SCTLR.C
	pre_disable_mmu_workaround
	msr	sctlr_el2, x0
	isb
	b	2f
1:
	mrs	x0, sctlr_el1
	bic	x0, x0, #1 << 0	// clear SCTLR.M
	bic	x0, x0, #1 << 2	// clear SCTLR.C
	pre_disable_mmu_workaround
	msr	sctlr_el1, x0
	isb
2:
	/* Jump to kernel entry point */
	mov	x0, x20
	mov	x1, xzr
	mov	x2, xzr
	mov	x3, xzr
	br	x21

efi_load_fail:
	mov	x0, #EFI_LOAD_ERROR
	ldp	x29, x30, [sp], #32
	ret

entry_end:
ENDPROC(entry)
Commit	Line	Data
3c7f2550 MS	1	/*
	2	* EFI entry point.
	3	*
	4	* Copyright (C) 2013, 2014 Red Hat, Inc.
	5	* Author: Mark Salter <msalter@redhat.com>
	6	*
	7	* This program is free software; you can redistribute it and/or modify
	8	* it under the terms of the GNU General Public License version 2 as
	9	* published by the Free Software Foundation.
	10	*
	11	*/
	12	#include <linux/linkage.h>
	13	#include <linux/init.h>
	14
	15	#include <asm/assembler.h>
	16
	17	#define EFI_LOAD_ERROR 0x8000000000000001
	18
	19	__INIT
	20
	21	/*
	22	* We arrive here from the EFI boot manager with:
	23	*
	24	* * CPU in little-endian mode
	25	* * MMU on with identity-mapped RAM
	26	* * Icache and Dcache on
	27	*
	28	* We will most likely be running from some place other than where
	29	* we want to be. The kernel image wants to be placed at TEXT_OFFSET
	30	* from start of RAM.
	31	*/
e8f3010f	32	ENTRY(entry)
3c7f2550 MS	33	/*
	34	* Create a stack frame to save FP/LR with extra space
	35	* for image_addr variable passed to efi_entry().
	36	*/
	37	stp x29, x30, [sp, #-32]!
cd1b76bb	38	mov x29, sp
3c7f2550 MS	39
	40	/*
	41	* Call efi_entry to do the real work.
	42	* x0 and x1 are already set up by firmware. Current runtime
	43	* address of image is calculated and passed via *image_addr.
	44	*
	45	* unsigned long efi_entry(void *handle,
	46	* efi_system_table_t *sys_table,
	47	* unsigned long *image_addr) ;
	48	*/
526d10ae	49	adr_l x8, _text
3c7f2550 MS	50	add x2, sp, 16
	51	str x8, [x2]
	52	bl efi_entry
	53	cmn x0, #1
	54	b.eq efi_load_fail
	55
	56	/*
9b0b2658 MR	57	* efi_entry() will have copied the kernel image if necessary and we
	58	* return here with device tree address in x0 and the kernel entry
	59	* point stored at *image_addr. Save those values in registers which
	60	* are callee preserved.
3c7f2550 MS	61	*/
	62	mov x20, x0 // DTB address
	63	ldr x0, [sp, #16] // relocated _text address
546c8c44	64	ldr w21, =stext_offset
95b39596	65	add x21, x0, x21
3c7f2550 MS	66
3c7f2550 MS	67	/*
9b0b2658	68	* Calculate size of the kernel Image (same for original and copy).
3c7f2550	69	*/
526d10ae MR	70	adr_l x1, _text
526d10ae MR	71	adr_l x2, _edata
3c7f2550 MS	72	sub x1, x2, x1
3c7f2550 MS	73
9b0b2658 MR	74	/*
	75	* Flush the copied Image to the PoC, and ensure it is not shadowed by
	76	* stale icache entries from before relocation.
	77	*/
3c7f2550 MS	78	bl __flush_dcache_area
	79	ic ialluis
	80
9b0b2658 MR	81	/*
	82	* Ensure that the rest of this function (in the original Image) is
	83	* visible when the caches are disabled. The I-cache can't have stale
	84	* entries for the VA range of the current image, so no maintenance is
	85	* necessary.
	86	*/
e8f3010f AB	87	adr x0, entry
e8f3010f AB	88	adr x1, entry_end
9b0b2658 MR	89	sub x1, x1, x0
	90	bl __flush_dcache_area
	91
3c7f2550 MS	92	/* Turn off Dcache and MMU */
3c7f2550 MS	93	mrs x0, CurrentEL
974c8e45	94	cmp x0, #CurrentEL_EL2
3c7f2550 MS	95	b.ne 1f
	96	mrs x0, sctlr_el2
	97	bic x0, x0, #1 << 0 // clear SCTLR.M
	98	bic x0, x0, #1 << 2 // clear SCTLR.C
932b50c7	99	pre_disable_mmu_workaround
3c7f2550 MS	100	msr sctlr_el2, x0
	101	isb
	102	b 2f
	103	1:
	104	mrs x0, sctlr_el1
	105	bic x0, x0, #1 << 0 // clear SCTLR.M
	106	bic x0, x0, #1 << 2 // clear SCTLR.C
932b50c7	107	pre_disable_mmu_workaround
3c7f2550 MS	108	msr sctlr_el1, x0
	109	isb
	110	2:
	111	/* Jump to kernel entry point */
	112	mov x0, x20
	113	mov x1, xzr
	114	mov x2, xzr
	115	mov x3, xzr
	116	br x21
	117
	118	efi_load_fail:
	119	mov x0, #EFI_LOAD_ERROR
	120	ldp x29, x30, [sp], #32
	121	ret
	122
e8f3010f AB	123	entry_end:
e8f3010f AB	124	ENDPROC(entry)