[linux-2.6-block.git] / arch / arm / kernel / entry-common.S

/*
 *  linux/arch/arm/kernel/entry-common.S
 *
 *  Copyright (C) 2000 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */

#include <asm/unistd.h>
#include <asm/ftrace.h>
#include <mach/entry-macro.S>
#include <asm/unwind.h>

#include "entry-header.S"


	.align	5
/*
 * This is the fast syscall return path.  We do as little as
 * possible here, and this includes saving r0 back into the SVC
 * stack.
 */
ret_fast_syscall:
 UNWIND(.fnstart	)
 UNWIND(.cantunwind	)
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	fast_work_pending

	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	restore_user_regs fast = 1, offset = S_OFF
 UNWIND(.fnend		)

/*
 * Ok, we need to do extra processing, enter the slow path.
 */
fast_work_pending:
	str	r0, [sp, #S_R0+S_OFF]!		@ returned r0
work_pending:
	tst	r1, #_TIF_NEED_RESCHED
	bne	work_resched
	tst	r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
	beq	no_work_pending
	mov	r0, sp				@ 'regs'
	mov	r2, why				@ 'syscall'
	bl	do_notify_resume
	b	ret_slow_syscall		@ Check work again

work_resched:
	bl	schedule
/*
 * "slow" syscall return path.  "why" tells us if this was a real syscall.
 */
ENTRY(ret_to_user)
ret_slow_syscall:
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	work_pending
no_work_pending:
	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	restore_user_regs fast = 0, offset = 0
ENDPROC(ret_to_user)

/*
 * This is how we return from a fork.
 */
ENTRY(ret_from_fork)
	bl	schedule_tail
	get_thread_info tsk
	ldr	r1, [tsk, #TI_FLAGS]		@ check for syscall tracing
	mov	why, #1
	tst	r1, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	beq	ret_slow_syscall
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall
ENDPROC(ret_from_fork)

	.equ NR_syscalls,0
#define CALL(x) .equ NR_syscalls,NR_syscalls+1
#include "calls.S"
#undef CALL
#define CALL(x) .long x

#ifdef CONFIG_FUNCTION_TRACER
#ifdef CONFIG_DYNAMIC_FTRACE
ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl mcount_call
mcount_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

ENTRY(ftrace_caller)
	stmdb sp!, {r0-r3, lr}
	ldr r1, [fp, #-4]
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl ftrace_call
ftrace_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

#else

ENTRY(__gnu_mcount_nc)
	stmdb sp!, {r0-r3, lr}
	ldr r0, =ftrace_trace_function
	ldr r2, [r0]
	adr r0, ftrace_stub
	cmp r0, r2
	bne gnu_trace
	ldmia sp!, {r0-r3, ip, lr}
	mov pc, ip

gnu_trace:
	ldr r1, [sp, #20]			@ lr of instrumented routine
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE
	mov lr, pc
	mov pc, r2
	ldmia sp!, {r0-r3, ip, lr}
	mov pc, ip

ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	ldr r0, =ftrace_trace_function
	ldr r2, [r0]
	adr r0, ftrace_stub
	cmp r0, r2
	bne trace
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

trace:
	ldr r1, [fp, #-4]			@ lr of instrumented routine
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE
	mov lr, pc
	mov pc, r2
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

#endif /* CONFIG_DYNAMIC_FTRACE */

	.globl ftrace_stub
ftrace_stub:
	mov pc, lr

#endif /* CONFIG_FUNCTION_TRACER */

/*=============================================================================
 * SWI handler
 *-----------------------------------------------------------------------------
 */

	/* If we're optimising for StrongARM the resulting code won't 
	   run on an ARM7 and we can save a couple of instructions.  
								--pb */
#ifdef CONFIG_CPU_ARM710
#define A710(code...) code
.Larm710bug:
	ldmia	sp, {r0 - lr}^			@ Get calling r0 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE
	subs	pc, lr, #4
#else
#define A710(code...)
#endif

	.align	5
ENTRY(vector_swi)
	sub	sp, sp, #S_FRAME_SIZE
	stmia	sp, {r0 - r12}			@ Calling r0 - r12
 ARM(	add	r8, sp, #S_PC		)
 ARM(	stmdb	r8, {sp, lr}^		)	@ Calling sp, lr
 THUMB(	mov	r8, sp			)
 THUMB(	store_user_sp_lr r8, r10, S_SP	)	@ calling sp, lr
	mrs	r8, spsr			@ called from non-FIQ mode, so ok.
	str	lr, [sp, #S_PC]			@ Save calling PC
	str	r8, [sp, #S_PSR]		@ Save CPSR
	str	r0, [sp, #S_OLD_R0]		@ Save OLD_R0
	zero_fp

	/*
	 * Get the system call number.
	 */

#if defined(CONFIG_OABI_COMPAT)

	/*
	 * If we have CONFIG_OABI_COMPAT then we need to look at the swi
	 * value to determine if it is an EABI or an old ABI call.
	 */
#ifdef CONFIG_ARM_THUMB
	tst	r8, #PSR_T_BIT
	movne	r10, #0				@ no thumb OABI emulation
	ldreq	r10, [lr, #-4]			@ get SWI instruction
#else
	ldr	r10, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, r10, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)
#endif
#ifdef CONFIG_CPU_ENDIAN_BE8
	rev	r10, r10			@ little endian instruction
#endif

#elif defined(CONFIG_AEABI)

	/*
	 * Pure EABI user space always put syscall number into scno (r7).
	 */
  A710(	ldr	ip, [lr, #-4]			@ get SWI instruction	)
  A710(	and	ip, ip, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#elif defined(CONFIG_ARM_THUMB)

	/* Legacy ABI only, possibly thumb mode. */
	tst	r8, #PSR_T_BIT			@ this is SPSR from save_user_regs
	addne	scno, r7, #__NR_SYSCALL_BASE	@ put OS number in
	ldreq	scno, [lr, #-4]

#else

	/* Legacy ABI only. */
	ldr	scno, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, scno, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#endif

#ifdef CONFIG_ALIGNMENT_TRAP
	ldr	ip, __cr_alignment
	ldr	ip, [ip]
	mcr	p15, 0, ip, c1, c0		@ update control register
#endif
	enable_irq

	get_thread_info tsk
	adr	tbl, sys_call_table		@ load syscall table pointer
	ldr	ip, [tsk, #TI_FLAGS]		@ check for syscall tracing

#if defined(CONFIG_OABI_COMPAT)
	/*
	 * If the swi argument is zero, this is an EABI call and we do nothing.
	 *
	 * If this is an old ABI call, get the syscall number into scno and
	 * get the old ABI syscall table address.
	 */
	bics	r10, r10, #0xff000000
	eorne	scno, r10, #__NR_OABI_SYSCALL_BASE
	ldrne	tbl, =sys_oabi_call_table
#elif !defined(CONFIG_AEABI)
	bic	scno, scno, #0xff000000		@ mask off SWI op-code
	eor	scno, scno, #__NR_SYSCALL_BASE	@ check OS number
#endif

	stmdb	sp!, {r4, r5}			@ push fifth and sixth args
	tst	ip, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	bne	__sys_trace

	cmp	scno, #NR_syscalls		@ check upper syscall limit
	adr	lr, BSYM(ret_fast_syscall)	@ return address
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine

	add	r1, sp, #S_OFF
2:	mov	why, #0				@ no longer a real syscall
	cmp	scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
	eor	r0, scno, #__NR_SYSCALL_BASE	@ put OS number back
	bcs	arm_syscall	
	b	sys_ni_syscall			@ not private func
ENDPROC(vector_swi)

	/*
	 * This is the really slow path.  We're going to be doing
	 * context switches, and waiting for our parent to respond.
	 */
__sys_trace:
	mov	r2, scno
	add	r1, sp, #S_OFF
	mov	r0, #0				@ trace entry [IP = 0]
	bl	syscall_trace

	adr	lr, BSYM(__sys_trace_return)	@ return address
	mov	scno, r0			@ syscall number (possibly new)
	add	r1, sp, #S_R0 + S_OFF		@ pointer to regs
	cmp	scno, #NR_syscalls		@ check upper syscall limit
	ldmccia	r1, {r0 - r3}			@ have to reload r0 - r3
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine
	b	2b

__sys_trace_return:
	str	r0, [sp, #S_R0 + S_OFF]!	@ save returned r0
	mov	r2, scno
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall

	.align	5
#ifdef CONFIG_ALIGNMENT_TRAP
	.type	__cr_alignment, #object
__cr_alignment:
	.word	cr_alignment
#endif
	.ltorg

/*
 * This is the syscall table declaration for native ABI syscalls.
 * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 */
#define ABI(native, compat) native
#ifdef CONFIG_AEABI
#define OBSOLETE(syscall) sys_ni_syscall
#else
#define OBSOLETE(syscall) syscall
#endif

	.type	sys_call_table, #object
ENTRY(sys_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

/*============================================================================
 * Special system call wrappers
 */
@ r0 = syscall number
@ r8 = syscall table
sys_syscall:
		bic	scno, r0, #__NR_OABI_SYSCALL_BASE
		cmp	scno, #__NR_syscall - __NR_SYSCALL_BASE
		cmpne	scno, #NR_syscalls	@ check range
		stmloia	sp, {r5, r6}		@ shuffle args
		movlo	r0, r1
		movlo	r1, r2
		movlo	r2, r3
		movlo	r3, r4
		ldrlo	pc, [tbl, scno, lsl #2]
		b	sys_ni_syscall
ENDPROC(sys_syscall)

sys_fork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_fork
ENDPROC(sys_fork_wrapper)

sys_vfork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_vfork
ENDPROC(sys_vfork_wrapper)

sys_execve_wrapper:
		add	r3, sp, #S_OFF
		b	sys_execve
ENDPROC(sys_execve_wrapper)

sys_clone_wrapper:
		add	ip, sp, #S_OFF
		str	ip, [sp, #4]
		b	sys_clone
ENDPROC(sys_clone_wrapper)

sys_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_sigreturn
ENDPROC(sys_sigreturn_wrapper)

sys_rt_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_rt_sigreturn
ENDPROC(sys_rt_sigreturn_wrapper)

sys_sigaltstack_wrapper:
		ldr	r2, [sp, #S_OFF + S_SP]
		b	do_sigaltstack
ENDPROC(sys_sigaltstack_wrapper)

sys_statfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_statfs64
ENDPROC(sys_statfs64_wrapper)

sys_fstatfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_fstatfs64
ENDPROC(sys_fstatfs64_wrapper)

/*
 * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 * offset, we return EINVAL.
 */
sys_mmap2:
#if PAGE_SHIFT > 12
		tst	r5, #PGOFF_MASK
		moveq	r5, r5, lsr #PAGE_SHIFT - 12
		streq	r5, [sp, #4]
		beq	sys_mmap_pgoff
		mov	r0, #-EINVAL
		mov	pc, lr
#else
		str	r5, [sp, #4]
		b	sys_mmap_pgoff
#endif
ENDPROC(sys_mmap2)

#ifdef CONFIG_OABI_COMPAT

/*
 * These are syscalls with argument register differences
 */

sys_oabi_pread64:
		stmia	sp, {r3, r4}
		b	sys_pread64
ENDPROC(sys_oabi_pread64)

sys_oabi_pwrite64:
		stmia	sp, {r3, r4}
		b	sys_pwrite64
ENDPROC(sys_oabi_pwrite64)

sys_oabi_truncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_truncate64
ENDPROC(sys_oabi_truncate64)

sys_oabi_ftruncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_ftruncate64
ENDPROC(sys_oabi_ftruncate64)

sys_oabi_readahead:
		str	r3, [sp]
		mov	r3, r2
		mov	r2, r1
		b	sys_readahead
ENDPROC(sys_oabi_readahead)

/*
 * Let's declare a second syscall table for old ABI binaries
 * using the compatibility syscall entries.
 */
#define ABI(native, compat) compat
#define OBSOLETE(syscall) syscall

	.type	sys_oabi_call_table, #object
ENTRY(sys_oabi_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

#endif
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/kernel/entry-common.S
	3	*
	4	* Copyright (C) 2000 Russell King
	5	*
	6	* This program is free software; you can redistribute it and/or modify
	7	* it under the terms of the GNU General Public License version 2 as
	8	* published by the Free Software Foundation.
	9	*/
1da177e4	10
1da177e4	11	#include <asm/unistd.h>
395a59d0	12	#include <asm/ftrace.h>
a09e64fb	13	#include <mach/entry-macro.S>
c4c5716e	14	#include <asm/unwind.h>
1da177e4 LT	15
	16	#include "entry-header.S"
	17
1da177e4 LT	18
	19	.align 5
	20	/*
	21	* This is the fast syscall return path. We do as little as
	22	* possible here, and this includes saving r0 back into the SVC
	23	* stack.
	24	*/
	25	ret_fast_syscall:
c4c5716e CM	26	UNWIND(.fnstart )
c4c5716e CM	27	UNWIND(.cantunwind )
1ec42c0c	28	disable_irq @ disable interrupts
1da177e4 LT	29	ldr r1, [tsk, #TI_FLAGS]
	30	tst r1, #_TIF_WORK_MASK
	31	bne fast_work_pending
f4dc9a4c	32
f80dff9d DW	33	/* perform architecture specific actions before user return */
	34	arch_ret_to_user r1, lr
	35
b86040a5	36	restore_user_regs fast = 1, offset = S_OFF
c4c5716e	37	UNWIND(.fnend )
1da177e4 LT	38
	39	/*
	40	* Ok, we need to do extra processing, enter the slow path.
	41	*/
	42	fast_work_pending:
	43	str r0, [sp, #S_R0+S_OFF]! @ returned r0
	44	work_pending:
	45	tst r1, #_TIF_NEED_RESCHED
	46	bne work_resched
d0420c83	47	tst r1, #_TIF_SIGPENDING\|_TIF_NOTIFY_RESUME
1da177e4 LT	48	beq no_work_pending
	49	mov r0, sp @ 'regs'
	50	mov r2, why @ 'syscall'
	51	bl do_notify_resume
a6c61e9d	52	b ret_slow_syscall @ Check work again
1da177e4 LT	53
	54	work_resched:
	55	bl schedule
	56	/*
	57	* "slow" syscall return path. "why" tells us if this was a real syscall.
	58	*/
	59	ENTRY(ret_to_user)
	60	ret_slow_syscall:
1ec42c0c	61	disable_irq @ disable interrupts
1da177e4 LT	62	ldr r1, [tsk, #TI_FLAGS]
	63	tst r1, #_TIF_WORK_MASK
	64	bne work_pending
	65	no_work_pending:
f80dff9d DW	66	/* perform architecture specific actions before user return */
	67	arch_ret_to_user r1, lr
	68
b86040a5	69	restore_user_regs fast = 0, offset = 0
93ed3970	70	ENDPROC(ret_to_user)
1da177e4 LT	71
	72	/*
	73	* This is how we return from a fork.
	74	*/
	75	ENTRY(ret_from_fork)
	76	bl schedule_tail
	77	get_thread_info tsk
	78	ldr r1, [tsk, #TI_FLAGS] @ check for syscall tracing
	79	mov why, #1
	80	tst r1, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	81	beq ret_slow_syscall
	82	mov r1, sp
	83	mov r0, #1 @ trace exit [IP = 1]
	84	bl syscall_trace
	85	b ret_slow_syscall
93ed3970	86	ENDPROC(ret_from_fork)
1da177e4	87
fa1b4f91 AV	88	.equ NR_syscalls,0
fa1b4f91 AV	89	#define CALL(x) .equ NR_syscalls,NR_syscalls+1
1da177e4	90	#include "calls.S"
fa1b4f91 AV	91	#undef CALL
fa1b4f91 AV	92	#define CALL(x) .long x
1da177e4	93
606576ce	94	#ifdef CONFIG_FUNCTION_TRACER
014c257c AS	95	#ifdef CONFIG_DYNAMIC_FTRACE
	96	ENTRY(mcount)
	97	stmdb sp!, {r0-r3, lr}
	98	mov r0, lr
395a59d0	99	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	100
	101	.globl mcount_call
	102	mcount_call:
	103	bl ftrace_stub
d4cc510c	104	ldr lr, [fp, #-4] @ restore lr
014c257c AS	105	ldmia sp!, {r0-r3, pc}
	106
	107	ENTRY(ftrace_caller)
	108	stmdb sp!, {r0-r3, lr}
	109	ldr r1, [fp, #-4]
	110	mov r0, lr
395a59d0	111	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	112
	113	.globl ftrace_call
	114	ftrace_call:
	115	bl ftrace_stub
d4cc510c	116	ldr lr, [fp, #-4] @ restore lr
014c257c AS	117	ldmia sp!, {r0-r3, pc}
	118
	119	#else
	120
181f817e UKK	121	ENTRY(__gnu_mcount_nc)
	122	stmdb sp!, {r0-r3, lr}
	123	ldr r0, =ftrace_trace_function
	124	ldr r2, [r0]
	125	adr r0, ftrace_stub
	126	cmp r0, r2
	127	bne gnu_trace
	128	ldmia sp!, {r0-r3, ip, lr}
6176d394	129	mov pc, ip
181f817e UKK	130
	131	gnu_trace:
	132	ldr r1, [sp, #20] @ lr of instrumented routine
	133	mov r0, lr
	134	sub r0, r0, #MCOUNT_INSN_SIZE
	135	mov lr, pc
	136	mov pc, r2
	137	ldmia sp!, {r0-r3, ip, lr}
6176d394	138	mov pc, ip
181f817e	139
014c257c AS	140	ENTRY(mcount)
	141	stmdb sp!, {r0-r3, lr}
	142	ldr r0, =ftrace_trace_function
	143	ldr r2, [r0]
	144	adr r0, ftrace_stub
	145	cmp r0, r2
	146	bne trace
d4cc510c	147	ldr lr, [fp, #-4] @ restore lr
014c257c AS	148	ldmia sp!, {r0-r3, pc}
	149
	150	trace:
b3c960b2	151	ldr r1, [fp, #-4] @ lr of instrumented routine
014c257c	152	mov r0, lr
395a59d0	153	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	154	mov lr, pc
014c257c AS	155	mov pc, r2
3ef7143d	156	ldr lr, [fp, #-4] @ restore lr
014c257c AS	157	ldmia sp!, {r0-r3, pc}
	158
	159	#endif /* CONFIG_DYNAMIC_FTRACE */
	160
	161	.globl ftrace_stub
	162	ftrace_stub:
	163	mov pc, lr
	164
606576ce	165	#endif /* CONFIG_FUNCTION_TRACER */
014c257c	166
1da177e4 LT	167	/*=============================================================================
	168	* SWI handler
	169	*-----------------------------------------------------------------------------
	170	*/
	171
	172	/* If we're optimising for StrongARM the resulting code won't
	173	run on an ARM7 and we can save a couple of instructions.
	174	--pb */
	175	#ifdef CONFIG_CPU_ARM710
3f2829a3 NP	176	#define A710(code...) code
3f2829a3 NP	177	.Larm710bug:
1da177e4 LT	178	ldmia sp, {r0 - lr}^ @ Get calling r0 - lr
1da177e4 LT	179	mov r0, r0
1da177e4	180	add sp, sp, #S_FRAME_SIZE
60ac133a	181	subs pc, lr, #4
1da177e4	182	#else
3f2829a3	183	#define A710(code...)
1da177e4 LT	184	#endif
	185
	186	.align 5
	187	ENTRY(vector_swi)
f4dc9a4c RK	188	sub sp, sp, #S_FRAME_SIZE
f4dc9a4c RK	189	stmia sp, {r0 - r12} @ Calling r0 - r12
b86040a5 CM	190	ARM( add r8, sp, #S_PC )
	191	ARM( stmdb r8, {sp, lr}^ ) @ Calling sp, lr
	192	THUMB( mov r8, sp )
	193	THUMB( store_user_sp_lr r8, r10, S_SP ) @ calling sp, lr
f4dc9a4c RK	194	mrs r8, spsr @ called from non-FIQ mode, so ok.
	195	str lr, [sp, #S_PC] @ Save calling PC
	196	str r8, [sp, #S_PSR] @ Save CPSR
	197	str r0, [sp, #S_OLD_R0] @ Save OLD_R0
1da177e4	198	zero_fp
e0f9f4a6 RK	199
	200	/*
	201	* Get the system call number.
	202	*/
3f2829a3	203
dd35afc2	204	#if defined(CONFIG_OABI_COMPAT)
3f2829a3	205
dd35afc2 NP	206	/*
	207	* If we have CONFIG_OABI_COMPAT then we need to look at the swi
	208	* value to determine if it is an EABI or an old ABI call.
	209	*/
	210	#ifdef CONFIG_ARM_THUMB
	211	tst r8, #PSR_T_BIT
	212	movne r10, #0 @ no thumb OABI emulation
	213	ldreq r10, [lr, #-4] @ get SWI instruction
	214	#else
	215	ldr r10, [lr, #-4] @ get SWI instruction
	216	A710( and ip, r10, #0x0f000000 @ check for SWI )
	217	A710( teq ip, #0x0f000000 )
	218	A710( bne .Larm710bug )
	219	#endif
26584853 CM	220	#ifdef CONFIG_CPU_ENDIAN_BE8
	221	rev r10, r10 @ little endian instruction
	222	#endif
dd35afc2 NP	223
	224	#elif defined(CONFIG_AEABI)
	225
	226	/*
	227	* Pure EABI user space always put syscall number into scno (r7).
	228	*/
3f2829a3 NP	229	A710( ldr ip, [lr, #-4] @ get SWI instruction )
	230	A710( and ip, ip, #0x0f000000 @ check for SWI )
	231	A710( teq ip, #0x0f000000 )
	232	A710( bne .Larm710bug )
dd35afc2	233
3f2829a3	234	#elif defined(CONFIG_ARM_THUMB)
dd35afc2 NP	235
dd35afc2 NP	236	/* Legacy ABI only, possibly thumb mode. */
e0f9f4a6 RK	237	tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs
	238	addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in
	239	ldreq scno, [lr, #-4]
dd35afc2	240
e0f9f4a6	241	#else
dd35afc2 NP	242
dd35afc2 NP	243	/* Legacy ABI only. */
e0f9f4a6	244	ldr scno, [lr, #-4] @ get SWI instruction
3f2829a3 NP	245	A710( and ip, scno, #0x0f000000 @ check for SWI )
	246	A710( teq ip, #0x0f000000 )
	247	A710( bne .Larm710bug )
dd35afc2	248
e0f9f4a6	249	#endif
1da177e4 LT	250
	251	#ifdef CONFIG_ALIGNMENT_TRAP
	252	ldr ip, __cr_alignment
	253	ldr ip, [ip]
	254	mcr p15, 0, ip, c1, c0 @ update control register
	255	#endif
1ec42c0c	256	enable_irq
1da177e4	257
1da177e4	258	get_thread_info tsk
dd35afc2	259	adr tbl, sys_call_table @ load syscall table pointer
1da177e4	260	ldr ip, [tsk, #TI_FLAGS] @ check for syscall tracing
dd35afc2 NP	261
	262	#if defined(CONFIG_OABI_COMPAT)
	263	/*
	264	* If the swi argument is zero, this is an EABI call and we do nothing.
	265	*
	266	* If this is an old ABI call, get the syscall number into scno and
	267	* get the old ABI syscall table address.
	268	*/
	269	bics r10, r10, #0xff000000
	270	eorne scno, r10, #__NR_OABI_SYSCALL_BASE
	271	ldrne tbl, =sys_oabi_call_table
	272	#elif !defined(CONFIG_AEABI)
1da177e4	273	bic scno, scno, #0xff000000 @ mask off SWI op-code
e0f9f4a6	274	eor scno, scno, #__NR_SYSCALL_BASE @ check OS number
3f2829a3	275	#endif
dd35afc2	276
3f2829a3	277	stmdb sp!, {r4, r5} @ push fifth and sixth args
1da177e4 LT	278	tst ip, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	279	bne __sys_trace
	280
1da177e4	281	cmp scno, #NR_syscalls @ check upper syscall limit
b86040a5	282	adr lr, BSYM(ret_fast_syscall) @ return address
1da177e4 LT	283	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	284
	285	add r1, sp, #S_OFF
	286	2: mov why, #0 @ no longer a real syscall
e0f9f4a6 RK	287	cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
e0f9f4a6 RK	288	eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back
1da177e4 LT	289	bcs arm_syscall
1da177e4 LT	290	b sys_ni_syscall @ not private func
93ed3970	291	ENDPROC(vector_swi)
1da177e4 LT	292
	293	/*
	294	* This is the really slow path. We're going to be doing
	295	* context switches, and waiting for our parent to respond.
	296	*/
	297	__sys_trace:
3f471126	298	mov r2, scno
1da177e4 LT	299	add r1, sp, #S_OFF
	300	mov r0, #0 @ trace entry [IP = 0]
	301	bl syscall_trace
	302
b86040a5	303	adr lr, BSYM(__sys_trace_return) @ return address
3f471126	304	mov scno, r0 @ syscall number (possibly new)
1da177e4 LT	305	add r1, sp, #S_R0 + S_OFF @ pointer to regs
	306	cmp scno, #NR_syscalls @ check upper syscall limit
	307	ldmccia r1, {r0 - r3} @ have to reload r0 - r3
	308	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	309	b 2b
	310
	311	__sys_trace_return:
	312	str r0, [sp, #S_R0 + S_OFF]! @ save returned r0
3f471126	313	mov r2, scno
1da177e4 LT	314	mov r1, sp
	315	mov r0, #1 @ trace exit [IP = 1]
	316	bl syscall_trace
	317	b ret_slow_syscall
	318
	319	.align 5
	320	#ifdef CONFIG_ALIGNMENT_TRAP
	321	.type __cr_alignment, #object
	322	__cr_alignment:
	323	.word cr_alignment
dd35afc2 NP	324	#endif
	325	.ltorg
	326
	327	/*
	328	* This is the syscall table declaration for native ABI syscalls.
	329	* With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
	330	*/
	331	#define ABI(native, compat) native
	332	#ifdef CONFIG_AEABI
	333	#define OBSOLETE(syscall) sys_ni_syscall
	334	#else
	335	#define OBSOLETE(syscall) syscall
1da177e4 LT	336	#endif
	337
	338	.type sys_call_table, #object
	339	ENTRY(sys_call_table)
	340	#include "calls.S"
dd35afc2 NP	341	#undef ABI
dd35afc2 NP	342	#undef OBSOLETE
1da177e4 LT	343
	344	/*============================================================================
	345	* Special system call wrappers
	346	*/
	347	@ r0 = syscall number
567bd980	348	@ r8 = syscall table
1da177e4	349	sys_syscall:
5247593c	350	bic scno, r0, #__NR_OABI_SYSCALL_BASE
1da177e4 LT	351	cmp scno, #__NR_syscall - __NR_SYSCALL_BASE
	352	cmpne scno, #NR_syscalls @ check range
	353	stmloia sp, {r5, r6} @ shuffle args
	354	movlo r0, r1
	355	movlo r1, r2
	356	movlo r2, r3
	357	movlo r3, r4
	358	ldrlo pc, [tbl, scno, lsl #2]
	359	b sys_ni_syscall
93ed3970	360	ENDPROC(sys_syscall)
1da177e4 LT	361
	362	sys_fork_wrapper:
	363	add r0, sp, #S_OFF
	364	b sys_fork
93ed3970	365	ENDPROC(sys_fork_wrapper)
1da177e4 LT	366
	367	sys_vfork_wrapper:
	368	add r0, sp, #S_OFF
	369	b sys_vfork
93ed3970	370	ENDPROC(sys_vfork_wrapper)
1da177e4 LT	371
	372	sys_execve_wrapper:
	373	add r3, sp, #S_OFF
	374	b sys_execve
93ed3970	375	ENDPROC(sys_execve_wrapper)
1da177e4 LT	376
	377	sys_clone_wrapper:
	378	add ip, sp, #S_OFF
	379	str ip, [sp, #4]
	380	b sys_clone
93ed3970	381	ENDPROC(sys_clone_wrapper)
1da177e4	382
1da177e4 LT	383	sys_sigreturn_wrapper:
	384	add r0, sp, #S_OFF
	385	b sys_sigreturn
93ed3970	386	ENDPROC(sys_sigreturn_wrapper)
1da177e4 LT	387
	388	sys_rt_sigreturn_wrapper:
	389	add r0, sp, #S_OFF
	390	b sys_rt_sigreturn
93ed3970	391	ENDPROC(sys_rt_sigreturn_wrapper)
1da177e4 LT	392
	393	sys_sigaltstack_wrapper:
	394	ldr r2, [sp, #S_OFF + S_SP]
	395	b do_sigaltstack
93ed3970	396	ENDPROC(sys_sigaltstack_wrapper)
1da177e4	397
713c4815 NP	398	sys_statfs64_wrapper:
	399	teq r1, #88
	400	moveq r1, #84
	401	b sys_statfs64
93ed3970	402	ENDPROC(sys_statfs64_wrapper)
713c4815 NP	403
	404	sys_fstatfs64_wrapper:
	405	teq r1, #88
	406	moveq r1, #84
	407	b sys_fstatfs64
93ed3970	408	ENDPROC(sys_fstatfs64_wrapper)
713c4815	409
1da177e4 LT	410	/*
	411	* Note: off_4k (r5) is always units of 4K. If we can't do the requested
	412	* offset, we return EINVAL.
	413	*/
	414	sys_mmap2:
	415	#if PAGE_SHIFT > 12
	416	tst r5, #PGOFF_MASK
	417	moveq r5, r5, lsr #PAGE_SHIFT - 12
	418	streq r5, [sp, #4]
f8b72560	419	beq sys_mmap_pgoff
1da177e4	420	mov r0, #-EINVAL
7999d8d7	421	mov pc, lr
1da177e4 LT	422	#else
1da177e4 LT	423	str r5, [sp, #4]
f8b72560	424	b sys_mmap_pgoff
1da177e4	425	#endif
93ed3970	426	ENDPROC(sys_mmap2)
687ad019 NP	427
687ad019 NP	428	#ifdef CONFIG_OABI_COMPAT
dd35afc2	429
687ad019 NP	430	/*
	431	* These are syscalls with argument register differences
	432	*/
	433
	434	sys_oabi_pread64:
	435	stmia sp, {r3, r4}
	436	b sys_pread64
93ed3970	437	ENDPROC(sys_oabi_pread64)
687ad019 NP	438
	439	sys_oabi_pwrite64:
	440	stmia sp, {r3, r4}
	441	b sys_pwrite64
93ed3970	442	ENDPROC(sys_oabi_pwrite64)
687ad019 NP	443
	444	sys_oabi_truncate64:
	445	mov r3, r2
	446	mov r2, r1
	447	b sys_truncate64
93ed3970	448	ENDPROC(sys_oabi_truncate64)
687ad019 NP	449
	450	sys_oabi_ftruncate64:
	451	mov r3, r2
	452	mov r2, r1
	453	b sys_ftruncate64
93ed3970	454	ENDPROC(sys_oabi_ftruncate64)
687ad019 NP	455
	456	sys_oabi_readahead:
	457	str r3, [sp]
	458	mov r3, r2
	459	mov r2, r1
	460	b sys_readahead
93ed3970	461	ENDPROC(sys_oabi_readahead)
687ad019	462
dd35afc2 NP	463	/*
	464	* Let's declare a second syscall table for old ABI binaries
	465	* using the compatibility syscall entries.
	466	*/
	467	#define ABI(native, compat) compat
	468	#define OBSOLETE(syscall) syscall
	469
	470	.type sys_oabi_call_table, #object
	471	ENTRY(sys_oabi_call_table)
	472	#include "calls.S"
	473	#undef ABI
	474	#undef OBSOLETE
	475
687ad019 NP	476	#endif
687ad019 NP	477