[linux-2.6-block.git] / scripts / recordmcount.pl

#!/usr/bin/perl -w
# (c) 2008, Steven Rostedt <srostedt@redhat.com>
# Licensed under the terms of the GNU GPL License version 2
#
# recordmcount.pl - makes a section called __mcount_loc that holds
#                   all the offsets to the calls to mcount.
#
#
# What we want to end up with this is that each object file will have a
# section called __mcount_loc that will hold the list of pointers to mcount
# callers. After final linking, the vmlinux will have within .init.data the
# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
# Later on boot up, the kernel will read this list, save the locations and turn
# them into nops. When tracing or profiling is later enabled, these locations
# will then be converted back to pointers to some function.
#
# This is no easy feat. This script is called just after the original
# object is compiled and before it is linked.
#
# When parse this object file using 'objdump', the references to the call
# sites are offsets from the section that the call site is in. Hence, all
# functions in a section that has a call site to mcount, will have the
# offset from the beginning of the section and not the beginning of the
# function.
#
# But where this section will reside finally in vmlinx is undetermined at
# this point. So we can't use this kind of offsets to record the final
# address of this call site.
#
# The trick is to change the call offset referring the start of a section to
# referring a function symbol in this section. During the link step, 'ld' will
# compute the final address according to the information we record.
#
# e.g.
#
#  .section ".sched.text", "ax"
#        [...]
#  func1:
#        [...]
#        call mcount  (offset: 0x10)
#        [...]
#        ret
#  .globl fun2
#  func2:             (offset: 0x20)
#        [...]
#        [...]
#        ret
#  func3:
#        [...]
#        call mcount (offset: 0x30)
#        [...]
#
# Both relocation offsets for the mcounts in the above example will be
# offset from .sched.text. If we choose global symbol func2 as a reference and
# make another file called tmp.s with the new offsets:
#
#  .section __mcount_loc
#  .quad  func2 - 0x10
#  .quad  func2 + 0x10
#
# We can then compile this tmp.s into tmp.o, and link it back to the original
# object.
#
# In our algorithm, we will choose the first global function we meet in this
# section as the reference. But this gets hard if there is no global functions
# in this section. In such a case we have to select a local one. E.g. func1:
#
#  .section ".sched.text", "ax"
#  func1:
#        [...]
#        call mcount  (offset: 0x10)
#        [...]
#        ret
#  func2:
#        [...]
#        call mcount (offset: 0x20)
#        [...]
#  .section "other.section"
#
# If we make the tmp.s the same as above, when we link together with
# the original object, we will end up with two symbols for func1:
# one local, one global.  After final compile, we will end up with
# an undefined reference to func1 or a wrong reference to another global
# func1 in other files.
#
# Since local objects can reference local variables, we need to find
# a way to make tmp.o reference the local objects of the original object
# file after it is linked together. To do this, we convert func1
# into a global symbol before linking tmp.o. Then after we link tmp.o
# we will only have a single symbol for func1 that is global.
# We can convert func1 back into a local symbol and we are done.
#
# Here are the steps we take:
#
# 1) Record all the local and weak symbols by using 'nm'
# 2) Use objdump to find all the call site offsets and sections for
#    mcount.
# 3) Compile the list into its own object.
# 4) Do we have to deal with local functions? If not, go to step 8.
# 5) Make an object that converts these local functions to global symbols
#    with objcopy.
# 6) Link together this new object with the list object.
# 7) Convert the local functions back to local symbols and rename
#    the result as the original object.
# 8) Link the object with the list object.
# 9) Move the result back to the original object.
#

use strict;

my $P = $0;
$P =~ s@.*/@@g;

my $V = '0.1';

if ($#ARGV != 10) {
	print "usage: $P arch bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
	print "version: $V\n";
	exit(1);
}

my ($arch, $bits, $objdump, $objcopy, $cc,
    $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;

# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
    exit(0);
}

# Acceptable sections to record.
my %text_sections = (
     ".text" => 1,
     ".sched.text" => 1,
     ".spinlock.text" => 1,
     ".irqentry.text" => 1,
     ".text.unlikely" => 1,
);

$objdump = "objdump" if ((length $objdump) == 0);
$objcopy = "objcopy" if ((length $objcopy) == 0);
$cc = "gcc" if ((length $cc) == 0);
$ld = "ld" if ((length $ld) == 0);
$nm = "nm" if ((length $nm) == 0);
$rm = "rm" if ((length $rm) == 0);
$mv = "mv" if ((length $mv) == 0);

#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
#    "'$nm' '$rm' '$mv' '$inputfile'\n";

my %locals;		# List of local (static) functions
my %weak;		# List of weak functions
my %convert;		# List of local functions used that needs conversion

my $type;
my $local_regex;	# Match a local function (return function)
my $weak_regex; 	# Match a weak function (return function)
my $section_regex;	# Find the start of a section
my $function_regex;	# Find the name of a function
			#    (return offset and func name)
my $mcount_regex;	# Find the call site to mcount (return offset)
my $alignment;		# The .align value to use for $mcount_section
my $section_type;	# Section header plus possible alignment command
my $can_use_local = 0; 	# If we can use local function references

##
# check_objcopy - whether objcopy supports --globalize-symbols
#
#  --globalize-symbols came out in 2.17, we must test the version
#  of objcopy, and if it is less than 2.17, then we can not
#  record local functions.
sub check_objcopy
{
    open (IN, "$objcopy --version |") or die "error running $objcopy";
    while (<IN>) {
	if (/objcopy.*\s(\d+)\.(\d+)/) {
	    $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
	    last;
	}
    }
    close (IN);

    if (!$can_use_local) {
	print STDERR "WARNING: could not find objcopy version or version " .
	    "is less than 2.17.\n" .
	    "\tLocal function references is disabled.\n";
    }
}

if ($arch eq "x86") {
    if ($bits == 64) {
	$arch = "x86_64";
    } else {
	$arch = "i386";
    }
}

#
# We base the defaults off of i386, the other archs may
# feel free to change them in the below if statements.
#
$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
$section_regex = "Disassembly of section\\s+(\\S+):";
$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
$section_type = '@progbits';
$type = ".long";

if ($arch eq "x86_64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
    $type = ".quad";
    $alignment = 8;

    # force flags for this arch
    $ld .= " -m elf_x86_64";
    $objdump .= " -M x86-64";
    $objcopy .= " -O elf64-x86-64";
    $cc .= " -m64";

} elsif ($arch eq "i386") {
    $alignment = 4;

    # force flags for this arch
    $ld .= " -m elf_i386";
    $objdump .= " -M i386";
    $objcopy .= " -O elf32-i386";
    $cc .= " -m32";

} elsif ($arch eq "s390" && $bits == 32) {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
    $alignment = 4;
    $ld .= " -m elf_s390";
    $cc .= " -m31";

} elsif ($arch eq "s390" && $bits == 64) {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
    $alignment = 8;
    $type = ".quad";
    $ld .= " -m elf64_s390";
    $cc .= " -m64";

} elsif ($arch eq "sh") {
    $alignment = 2;

    # force flags for this arch
    $ld .= " -m shlelf_linux";
    $objcopy .= " -O elf32-sh-linux";
    $cc .= " -m32";

} elsif ($arch eq "powerpc") {
    $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";

    if ($bits == 64) {
	$type = ".quad";
    }

} elsif ($arch eq "arm") {
    $alignment = 2;
    $section_type = '%progbits';

} elsif ($arch eq "ia64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
    $type = "data8";

    if ($is_module eq "0") {
        $cc .= " -mconstant-gp";
    }
} elsif ($arch eq "sparc64") {
    # In the objdump output there are giblets like:
    # 0000000000000000 <igmp_net_exit-0x18>:
    # As there's some data blobs that get emitted into the
    # text section before the first instructions and the first
    # real symbols.  We don't want to match that, so to combat
    # this we use '\w' so we'll match just plain symbol names,
    # and not those that also include hex offsets inside of the
    # '<>' brackets.  Actually the generic function_regex setting
    # could safely use this too.
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";

    # Sparc64 calls '_mcount' instead of plain 'mcount'.
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";

    $alignment = 8;
    $type = ".xword";
    $ld .= " -m elf64_sparc";
    $cc .= " -m64";
    $objcopy .= " -O elf64-sparc";
} else {
    die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
}

my $text_found = 0;
my $read_function = 0;
my $opened = 0;
my $mcount_section = "__mcount_loc";

my $dirname;
my $filename;
my $prefix;
my $ext;

if ($inputfile =~ m,^(.*)/([^/]*)$,) {
    $dirname = $1;
    $filename = $2;
} else {
    $dirname = ".";
    $filename = $inputfile;
}

if ($filename =~ m,^(.*)(\.\S),) {
    $prefix = $1;
    $ext = $2;
} else {
    $prefix = $filename;
    $ext = "";
}

my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";

check_objcopy();

#
# Step 1: find all the local (static functions) and weak symbols.
#         't' is local, 'w/W' is weak
#
open (IN, "$nm $inputfile|") || die "error running $nm";
while (<IN>) {
    if (/$local_regex/) {
	$locals{$1} = 1;
    } elsif (/$weak_regex/) {
	$weak{$2} = $1;
    }
}
close(IN);

my @offsets;		# Array of offsets of mcount callers
my $ref_func;		# reference function to use for offsets
my $offset = 0;		# offset of ref_func to section beginning

##
# update_funcs - print out the current mcount callers
#
#  Go through the list of offsets to callers and write them to
#  the output file in a format that can be read by an assembler.
#
sub update_funcs
{
    return unless ($ref_func and @offsets);

    # A section only had a weak function, to represent it.
    # Unfortunately, a weak function may be overwritten by another
    # function of the same name, making all these offsets incorrect.
    # To be safe, we simply print a warning and bail.
    if (defined $weak{$ref_func}) {
	print STDERR
	    "$inputfile: WARNING: referencing weak function" .
	    " $ref_func for mcount\n";
	return;
    }

    # is this function static? If so, note this fact.
    if (defined $locals{$ref_func}) {

	# only use locals if objcopy supports globalize-symbols
	if (!$can_use_local) {
	    return;
	}
	$convert{$ref_func} = 1;
    }

    # Loop through all the mcount caller offsets and print a reference
    # to the caller based from the ref_func.
    for (my $i=0; $i <= $#offsets; $i++) {
	if (!$opened) {
	    open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
	    $opened = 1;
	    print FILE "\t.section $mcount_section,\"a\",$section_type\n";
	    print FILE "\t.align $alignment\n" if (defined($alignment));
	}
	printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
    }
}

#
# Step 2: find the sections and mcount call sites
#
open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";

my $text;


# read headers first
my $read_headers = 1;

while (<IN>) {

    if ($read_headers && /$mcount_section/) {
	#
	# Somehow the make process can execute this script on an
	# object twice. If it does, we would duplicate the mcount
	# section and it will cause the function tracer self test
	# to fail. Check if the mcount section exists, and if it does,
	# warn and exit.
	#
	print STDERR "ERROR: $mcount_section already in $inputfile\n" .
	    "\tThis may be an indication that your build is corrupted.\n" .
	    "\tDelete $inputfile and try again. If the same object file\n" .
	    "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
	exit(-1);
    }

    # is it a section?
    if (/$section_regex/) {
	$read_headers = 0;

	# Only record text sections that we know are safe
	if (defined($text_sections{$1})) {
	    $read_function = 1;
	} else {
	    $read_function = 0;
	}
	# print out any recorded offsets
	update_funcs();

	# reset all markers and arrays
	$text_found = 0;
	undef($ref_func);
	undef(@offsets);

    # section found, now is this a start of a function?
    } elsif ($read_function && /$function_regex/) {
	$text_found = 1;
	$text = $2;

	# if this is either a local function or a weak function
	# keep looking for functions that are global that
	# we can use safely.
	if (!defined($locals{$text}) && !defined($weak{$text})) {
	    $ref_func = $text;
	    $read_function = 0;
	    $offset = hex $1;
	} else {
	    # if we already have a function, and this is weak, skip it
	    if (!defined($ref_func) && !defined($weak{$text}) &&
		 # PPC64 can have symbols that start with .L and
		 # gcc considers these special. Don't use them!
		 $text !~ /^\.L/) {
		$ref_func = $text;
		$offset = hex $1;
	    }
	}
    }
    # is this a call site to mcount? If so, record it to print later
    if ($text_found && /$mcount_regex/) {
	$offsets[$#offsets + 1] = hex $1;
    }
}

# dump out anymore offsets that may have been found
update_funcs();

# If we did not find any mcount callers, we are done (do nothing).
if (!$opened) {
    exit(0);
}

close(FILE);

#
# Step 3: Compile the file that holds the list of call sites to mcount.
#
`$cc -o $mcount_o -c $mcount_s`;

my @converts = keys %convert;

#
# Step 4: Do we have sections that started with local functions?
#
if ($#converts >= 0) {
    my $globallist = "";
    my $locallist = "";

    foreach my $con (@converts) {
	$globallist .= " --globalize-symbol $con";
	$locallist .= " --localize-symbol $con";
    }

    my $globalobj = $dirname . "/.tmp_gl_" . $filename;
    my $globalmix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 5: set up each local function as a global
    #
    `$objcopy $globallist $inputfile $globalobj`;

    #
    # Step 6: Link the global version to our list.
    #
    `$ld -r $globalobj $mcount_o -o $globalmix`;

    #
    # Step 7: Convert the local functions back into local symbols
    #
    `$objcopy $locallist $globalmix $inputfile`;

    # Remove the temp files
    `$rm $globalobj $globalmix`;

} else {

    my $mix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 8: Link the object with our list of call sites object.
    #
    `$ld -r $inputfile $mcount_o -o $mix`;

    #
    # Step 9: Move the result back to the original object.
    #
    `$mv $mix $inputfile`;
}

# Clean up the temp files
`$rm $mcount_o $mcount_s`;

exit(0);
Commit	Line	Data
8da3821b SR	1	#!/usr/bin/perl -w
	2	# (c) 2008, Steven Rostedt <srostedt@redhat.com>
	3	# Licensed under the terms of the GNU GPL License version 2
	4	#
	5	# recordmcount.pl - makes a section called __mcount_loc that holds
	6	# all the offsets to the calls to mcount.
	7	#
	8	#
d49f6aa7 LH	9	# What we want to end up with this is that each object file will have a
	10	# section called __mcount_loc that will hold the list of pointers to mcount
	11	# callers. After final linking, the vmlinux will have within .init.data the
	12	# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
	13	# Later on boot up, the kernel will read this list, save the locations and turn
	14	# them into nops. When tracing or profiling is later enabled, these locations
	15	# will then be converted back to pointers to some function.
8da3821b SR	16	#
	17	# This is no easy feat. This script is called just after the original
	18	# object is compiled and before it is linked.
	19	#
d49f6aa7 LH	20	# When parse this object file using 'objdump', the references to the call
	21	# sites are offsets from the section that the call site is in. Hence, all
	22	# functions in a section that has a call site to mcount, will have the
	23	# offset from the beginning of the section and not the beginning of the
	24	# function.
	25	#
	26	# But where this section will reside finally in vmlinx is undetermined at
	27	# this point. So we can't use this kind of offsets to record the final
	28	# address of this call site.
	29	#
	30	# The trick is to change the call offset referring the start of a section to
	31	# referring a function symbol in this section. During the link step, 'ld' will
	32	# compute the final address according to the information we record.
8da3821b	33	#
8da3821b SR	34	# e.g.
8da3821b SR	35	#
31b6e76e	36	# .section ".sched.text", "ax"
8da3821b	37	# [...]
d49f6aa7 LH	38	# func1:
	39	# [...]
	40	# call mcount (offset: 0x10)
	41	# [...]
	42	# ret
	43	# .globl fun2
	44	# func2: (offset: 0x20)
	45	# [...]
8da3821b SR	46	# [...]
8da3821b SR	47	# ret
d49f6aa7	48	# func3:
8da3821b	49	# [...]
d49f6aa7	50	# call mcount (offset: 0x30)
8da3821b SR	51	# [...]
	52	#
	53	# Both relocation offsets for the mcounts in the above example will be
d49f6aa7 LH	54	# offset from .sched.text. If we choose global symbol func2 as a reference and
d49f6aa7 LH	55	# make another file called tmp.s with the new offsets:
8da3821b SR	56	#
8da3821b SR	57	# .section __mcount_loc
d49f6aa7 LH	58	# .quad func2 - 0x10
d49f6aa7 LH	59	# .quad func2 + 0x10
8da3821b	60	#
d49f6aa7	61	# We can then compile this tmp.s into tmp.o, and link it back to the original
8da3821b SR	62	# object.
8da3821b SR	63	#
d49f6aa7 LH	64	# In our algorithm, we will choose the first global function we meet in this
	65	# section as the reference. But this gets hard if there is no global functions
	66	# in this section. In such a case we have to select a local one. E.g. func1:
8da3821b	67	#
31b6e76e	68	# .section ".sched.text", "ax"
d49f6aa7	69	# func1:
8da3821b	70	# [...]
d49f6aa7	71	# call mcount (offset: 0x10)
8da3821b SR	72	# [...]
8da3821b SR	73	# ret
d49f6aa7	74	# func2:
8da3821b	75	# [...]
d49f6aa7	76	# call mcount (offset: 0x20)
8da3821b	77	# [...]
d49f6aa7	78	# .section "other.section"
8da3821b SR	79	#
8da3821b SR	80	# If we make the tmp.s the same as above, when we link together with
d49f6aa7	81	# the original object, we will end up with two symbols for func1:
8da3821b	82	# one local, one global. After final compile, we will end up with
d49f6aa7 LH	83	# an undefined reference to func1 or a wrong reference to another global
d49f6aa7 LH	84	# func1 in other files.
8da3821b SR	85	#
	86	# Since local objects can reference local variables, we need to find
	87	# a way to make tmp.o reference the local objects of the original object
d49f6aa7	88	# file after it is linked together. To do this, we convert func1
8da3821b	89	# into a global symbol before linking tmp.o. Then after we link tmp.o
d49f6aa7 LH	90	# we will only have a single symbol for func1 that is global.
d49f6aa7 LH	91	# We can convert func1 back into a local symbol and we are done.
8da3821b SR	92	#
	93	# Here are the steps we take:
	94	#
306dcf47	95	# 1) Record all the local and weak symbols by using 'nm'
8da3821b SR	96	# 2) Use objdump to find all the call site offsets and sections for
	97	# mcount.
	98	# 3) Compile the list into its own object.
	99	# 4) Do we have to deal with local functions? If not, go to step 8.
	100	# 5) Make an object that converts these local functions to global symbols
	101	# with objcopy.
	102	# 6) Link together this new object with the list object.
	103	# 7) Convert the local functions back to local symbols and rename
	104	# the result as the original object.
8da3821b SR	105	# 8) Link the object with the list object.
8da3821b SR	106	# 9) Move the result back to the original object.
8da3821b SR	107	#
	108
	109	use strict;
	110
	111	my $P = $0;
	112	$P =~ s@.*/@@g;
	113
	114	my $V = '0.1';
	115
e2d753fa	116	if ($#ARGV != 10) {
b43f7093	117	print "usage: $P arch bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
8da3821b SR	118	print "version: $V\n";
	119	exit(1);
	120	}
	121
dce9d18a	122	my ($arch, $bits, $objdump, $objcopy, $cc,
18c167fd	123	$ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
8da3821b	124
25aac9dc	125	# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
bdd3b052	126	if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
25aac9dc SL	127	exit(0);
	128	}
	129
34698bcb SR	130	# Acceptable sections to record.
	131	my %text_sections = (
	132	".text" => 1,
d144d5ee LW	133	".sched.text" => 1,
d144d5ee LW	134	".spinlock.text" => 1,
a0343e82	135	".irqentry.text" => 1,
4d828949	136	".text.unlikely" => 1,
34698bcb SR	137	);
34698bcb SR	138
8da3821b SR	139	$objdump = "objdump" if ((length $objdump) == 0);
	140	$objcopy = "objcopy" if ((length $objcopy) == 0);
	141	$cc = "gcc" if ((length $cc) == 0);
	142	$ld = "ld" if ((length $ld) == 0);
	143	$nm = "nm" if ((length $nm) == 0);
	144	$rm = "rm" if ((length $rm) == 0);
	145	$mv = "mv" if ((length $mv) == 0);
	146
	147	#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
	148	# "'$nm' '$rm' '$mv' '$inputfile'\n";
	149
8feff1ca SR	150	my %locals; # List of local (static) functions
	151	my %weak; # List of weak functions
	152	my %convert; # List of local functions used that needs conversion
8da3821b SR	153
8da3821b SR	154	my $type;
306dcf47 LH	155	my $local_regex; # Match a local function (return function)
306dcf47 LH	156	my $weak_regex; # Match a weak function (return function)
8da3821b	157	my $section_regex; # Find the start of a section
8feff1ca SR	158	my $function_regex; # Find the name of a function
8feff1ca SR	159	# (return offset and func name)
8da3821b	160	my $mcount_regex; # Find the call site to mcount (return offset)
3a3d04ae	161	my $alignment; # The .align value to use for $mcount_section
e58918ab	162	my $section_type; # Section header plus possible alignment command
7b7edc27 LH	163	my $can_use_local = 0; # If we can use local function references
	164
	165	##
	166	# check_objcopy - whether objcopy supports --globalize-symbols
	167	#
	168	# --globalize-symbols came out in 2.17, we must test the version
	169	# of objcopy, and if it is less than 2.17, then we can not
	170	# record local functions.
	171	sub check_objcopy
	172	{
	173	open (IN, "$objcopy --version \|") or die "error running $objcopy";
	174	while (<IN>) {
	175	if (/objcopy.*\s(\d+)\.(\d+)/) {
	176	$can_use_local = 1 if ($1 > 2 \|\| ($1 == 2 && $2 >= 17));
	177	last;
	178	}
	179	}
	180	close (IN);
	181
	182	if (!$can_use_local) {
	183	print STDERR "WARNING: could not find objcopy version or version " .
	184	"is less than 2.17.\n" .
	185	"\tLocal function references is disabled.\n";
	186	}
	187	}
8da3821b	188
dce9d18a SR	189	if ($arch eq "x86") {
	190	if ($bits == 64) {
	191	$arch = "x86_64";
	192	} else {
	193	$arch = "i386";
	194	}
	195	}
	196
c204f726 SR	197	#
	198	# We base the defaults off of i386, the other archs may
	199	# feel free to change them in the below if statements.
	200	#
306dcf47 LH	201	$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
306dcf47 LH	202	$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
c204f726 SR	203	$section_regex = "Disassembly of section\\s+(\\S+):";
	204	$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
	205	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount\$";
e58918ab	206	$section_type = '@progbits';
c204f726 SR	207	$type = ".long";
c204f726 SR	208
8da3821b	209	if ($arch eq "x86_64") {
8da3821b SR	210	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
8da3821b SR	211	$type = ".quad";
7d5222a6	212	$alignment = 8;
d74fcd1e SR	213
	214	# force flags for this arch
	215	$ld .= " -m elf_x86_64";
	216	$objdump .= " -M x86-64";
	217	$objcopy .= " -O elf64-x86-64";
	218	$cc .= " -m64";
	219
8da3821b	220	} elsif ($arch eq "i386") {
7d5222a6	221	$alignment = 4;
d74fcd1e SR	222
	223	# force flags for this arch
	224	$ld .= " -m elf_i386";
	225	$objdump .= " -M i386";
	226	$objcopy .= " -O elf32-i386";
	227	$cc .= " -m32";
	228
dfd9f7ab HC	229	} elsif ($arch eq "s390" && $bits == 32) {
	230	$mcount_regex = "^\\s([0-9a-fA-F]+):\\sR_390_32\\s+_mcount\$";
	231	$alignment = 4;
	232	$ld .= " -m elf_s390";
	233	$cc .= " -m31";
	234
	235	} elsif ($arch eq "s390" && $bits == 64) {
	236	$mcount_regex = "^\\s([0-9a-fA-F]+):\\sR_390_(PC\|PLT)32DBL\\s+_mcount\\+0x2\$";
	237	$alignment = 8;
	238	$type = ".quad";
	239	$ld .= " -m elf64_s390";
	240	$cc .= " -m64";
	241
0da85c09	242	} elsif ($arch eq "sh") {
3a3d04ae	243	$alignment = 2;
0da85c09 MF	244
	245	# force flags for this arch
	246	$ld .= " -m shlelf_linux";
	247	$objcopy .= " -O elf32-sh-linux";
	248	$cc .= " -m32";
	249
42e007d0	250	} elsif ($arch eq "powerpc") {
306dcf47	251	$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
42e007d0 SR	252	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
42e007d0 SR	253	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s\\.?_mcount\$";
c204f726	254
42e007d0 SR	255	if ($bits == 64) {
42e007d0 SR	256	$type = ".quad";
42e007d0 SR	257	}
42e007d0 SR	258
e58918ab JR	259	} elsif ($arch eq "arm") {
	260	$alignment = 2;
	261	$section_type = '%progbits';
	262
418071eb SL	263	} elsif ($arch eq "ia64") {
	264	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	265	$type = "data8";
	266
	267	if ($is_module eq "0") {
	268	$cc .= " -mconstant-gp";
	269	}
9be12f9b DM	270	} elsif ($arch eq "sparc64") {
	271	# In the objdump output there are giblets like:
	272	# 0000000000000000 <igmp_net_exit-0x18>:
	273	# As there's some data blobs that get emitted into the
	274	# text section before the first instructions and the first
	275	# real symbols. We don't want to match that, so to combat
	276	# this we use '\w' so we'll match just plain symbol names,
	277	# and not those that also include hex offsets inside of the
	278	# '<>' brackets. Actually the generic function_regex setting
	279	# could safely use this too.
	280	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
	281
	282	# Sparc64 calls '_mcount' instead of plain 'mcount'.
	283	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	284
	285	$alignment = 8;
	286	$type = ".xword";
	287	$ld .= " -m elf64_sparc";
	288	$cc .= " -m64";
	289	$objcopy .= " -O elf64-sparc";
8da3821b SR	290	} else {
	291	die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
	292	}
	293
	294	my $text_found = 0;
	295	my $read_function = 0;
	296	my $opened = 0;
8da3821b SR	297	my $mcount_section = "__mcount_loc";
	298
	299	my $dirname;
	300	my $filename;
	301	my $prefix;
	302	my $ext;
	303
	304	if ($inputfile =~ m,^(.)/([^/])$,) {
	305	$dirname = $1;
	306	$filename = $2;
	307	} else {
	308	$dirname = ".";
	309	$filename = $inputfile;
	310	}
	311
	312	if ($filename =~ m,^(.*)(\.\S),) {
	313	$prefix = $1;
	314	$ext = $2;
	315	} else {
	316	$prefix = $filename;
	317	$ext = "";
	318	}
	319
	320	my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
	321	my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
	322
7b7edc27	323	check_objcopy();
f2f8458e	324
8da3821b	325	#
8feff1ca	326	# Step 1: find all the local (static functions) and weak symbols.
306dcf47	327	# 't' is local, 'w/W' is weak
8da3821b SR	328	#
	329	open (IN, "$nm $inputfile\|") \|\| die "error running $nm";
	330	while (<IN>) {
306dcf47	331	if (/$local_regex/) {
8da3821b	332	$locals{$1} = 1;
306dcf47	333	} elsif (/$weak_regex/) {
8feff1ca	334	$weak{$2} = $1;
8da3821b SR	335	}
	336	}
	337	close(IN);
	338
8feff1ca SR	339	my @offsets; # Array of offsets of mcount callers
	340	my $ref_func; # reference function to use for offsets
	341	my $offset = 0; # offset of ref_func to section beginning
	342
	343	##
	344	# update_funcs - print out the current mcount callers
	345	#
	346	# Go through the list of offsets to callers and write them to
	347	# the output file in a format that can be read by an assembler.
	348	#
	349	sub update_funcs
	350	{
6092858c	351	return unless ($ref_func and @offsets);
8feff1ca SR	352
	353	# A section only had a weak function, to represent it.
	354	# Unfortunately, a weak function may be overwritten by another
	355	# function of the same name, making all these offsets incorrect.
	356	# To be safe, we simply print a warning and bail.
	357	if (defined $weak{$ref_func}) {
	358	print STDERR
	359	"$inputfile: WARNING: referencing weak function" .
	360	" $ref_func for mcount\n";
	361	return;
	362	}
	363
	364	# is this function static? If so, note this fact.
	365	if (defined $locals{$ref_func}) {
f2f8458e SR	366
f2f8458e SR	367	# only use locals if objcopy supports globalize-symbols
7b7edc27	368	if (!$can_use_local) {
f2f8458e SR	369	return;
f2f8458e SR	370	}
8feff1ca SR	371	$convert{$ref_func} = 1;
	372	}
	373
	374	# Loop through all the mcount caller offsets and print a reference
	375	# to the caller based from the ref_func.
	376	for (my $i=0; $i <= $#offsets; $i++) {
	377	if (!$opened) {
	378	open(FILE, ">$mcount_s") \|\| die "can't create $mcount_s\n";
	379	$opened = 1;
e58918ab	380	print FILE "\t.section $mcount_section,\"a\",$section_type\n";
42e007d0	381	print FILE "\t.align $alignment\n" if (defined($alignment));
8feff1ca SR	382	}
	383	printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
	384	}
	385	}
	386
8da3821b SR	387	#
	388	# Step 2: find the sections and mcount call sites
	389	#
b43f7093	390	open(IN, "$objdump -hdr $inputfile\|") \|\| die "error running $objdump";
8da3821b	391
8feff1ca SR	392	my $text;
8feff1ca SR	393
db24c7dc LH	394
db24c7dc LH	395	# read headers first
b43f7093 SR	396	my $read_headers = 1;
b43f7093 SR	397
8da3821b	398	while (<IN>) {
db24c7dc LH	399
	400	if ($read_headers && /$mcount_section/) {
	401	#
	402	# Somehow the make process can execute this script on an
	403	# object twice. If it does, we would duplicate the mcount
	404	# section and it will cause the function tracer self test
	405	# to fail. Check if the mcount section exists, and if it does,
	406	# warn and exit.
	407	#
	408	print STDERR "ERROR: $mcount_section already in $inputfile\n" .
	409	"\tThis may be an indication that your build is corrupted.\n" .
	410	"\tDelete $inputfile and try again. If the same object file\n" .
	411	"\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
	412	exit(-1);
	413	}
	414
8da3821b SR	415	# is it a section?
8da3821b SR	416	if (/$section_regex/) {
b43f7093	417	$read_headers = 0;
34698bcb SR	418
	419	# Only record text sections that we know are safe
	420	if (defined($text_sections{$1})) {
	421	$read_function = 1;
	422	} else {
	423	$read_function = 0;
	424	}
8feff1ca	425	# print out any recorded offsets
6092858c	426	update_funcs();
8feff1ca SR	427
8feff1ca SR	428	# reset all markers and arrays
8da3821b	429	$text_found = 0;
8feff1ca SR	430	undef($ref_func);
	431	undef(@offsets);
	432
8da3821b SR	433	# section found, now is this a start of a function?
8da3821b SR	434	} elsif ($read_function && /$function_regex/) {
8da3821b	435	$text_found = 1;
8feff1ca SR	436	$text = $2;
	437
	438	# if this is either a local function or a weak function
	439	# keep looking for functions that are global that
	440	# we can use safely.
	441	if (!defined($locals{$text}) && !defined($weak{$text})) {
	442	$ref_func = $text;
	443	$read_function = 0;
bd171d5f	444	$offset = hex $1;
8feff1ca SR	445	} else {
8feff1ca SR	446	# if we already have a function, and this is weak, skip it
3f6e968e SR	447	if (!defined($ref_func) && !defined($weak{$text}) &&
	448	# PPC64 can have symbols that start with .L and
	449	# gcc considers these special. Don't use them!
	450	$text !~ /^\.L/) {
8feff1ca	451	$ref_func = $text;
bd171d5f	452	$offset = hex $1;
8feff1ca	453	}
8da3821b	454	}
8feff1ca	455	}
8feff1ca SR	456	# is this a call site to mcount? If so, record it to print later
	457	if ($text_found && /$mcount_regex/) {
	458	$offsets[$#offsets + 1] = hex $1;
8da3821b SR	459	}
	460	}
	461
8feff1ca	462	# dump out anymore offsets that may have been found
6092858c	463	update_funcs();
8feff1ca	464
8da3821b SR	465	# If we did not find any mcount callers, we are done (do nothing).
	466	if (!$opened) {
	467	exit(0);
	468	}
	469
	470	close(FILE);
	471
	472	#
	473	# Step 3: Compile the file that holds the list of call sites to mcount.
	474	#
	475	`$cc -o $mcount_o -c $mcount_s`;
	476
	477	my @converts = keys %convert;
	478
	479	#
	480	# Step 4: Do we have sections that started with local functions?
	481	#
	482	if ($#converts >= 0) {
	483	my $globallist = "";
	484	my $locallist = "";
	485
	486	foreach my $con (@converts) {
	487	$globallist .= " --globalize-symbol $con";
	488	$locallist .= " --localize-symbol $con";
	489	}
	490
	491	my $globalobj = $dirname . "/.tmp_gl_" . $filename;
	492	my $globalmix = $dirname . "/.tmp_mx_" . $filename;
	493
	494	#
	495	# Step 5: set up each local function as a global
	496	#
	497	`$objcopy $globallist $inputfile $globalobj`;
	498
	499	#
	500	# Step 6: Link the global version to our list.
	501	#
	502	`$ld -r $globalobj $mcount_o -o $globalmix`;
	503
	504	#
	505	# Step 7: Convert the local functions back into local symbols
	506	#
	507	`$objcopy $locallist $globalmix $inputfile`;
	508
	509	# Remove the temp files
	510	`$rm $globalobj $globalmix`;
	511
	512	} else {
	513
	514	my $mix = $dirname . "/.tmp_mx_" . $filename;
	515
	516	#
	517	# Step 8: Link the object with our list of call sites object.
	518	#
	519	`$ld -r $inputfile $mcount_o -o $mix`;
	520
	521	#
	522	# Step 9: Move the result back to the original object.
	523	#
	524	`$mv $mix $inputfile`;
	525	}
	526
	527	# Clean up the temp files
	528	`$rm $mcount_o $mcount_s`;
529
530	exit(0);