arch/x86/entry/entry_64_compat.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Compatibility mode system call entry point for x86-64.
   4  *
   5  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   6  */
   7 #include <asm/asm-offsets.h>
   8 #include <asm/current.h>
   9 #include <asm/errno.h>
  10 #include <asm/thread_info.h>
  11 #include <asm/segment.h>
  12 #include <asm/irqflags.h>
  13 #include <asm/asm.h>
  14 #include <asm/smap.h>
  15 #include <asm/nospec-branch.h>
  16 #include <linux/linkage.h>
  17 #include <linux/err.h>
  18
  19 #include "calling.h"
  20
  21         .section .entry.text, "ax"
  22
  23 /*
  24  * 32-bit SYSENTER entry.
  25  *
  26  * 32-bit system calls through the vDSO's __kernel_vsyscall enter here
  27  * on 64-bit kernels running on Intel CPUs.
  28  *
  29  * The SYSENTER instruction, in principle, should *only* occur in the
  30  * vDSO.  In practice, a small number of Android devices were shipped
  31  * with a copy of Bionic that inlined a SYSENTER instruction.  This
  32  * never happened in any of Google's Bionic versions -- it only happened
  33  * in a narrow range of Intel-provided versions.
  34  *
  35  * SYSENTER loads SS, RSP, CS, and RIP from previously programmed MSRs.
  36  * IF and VM in RFLAGS are cleared (IOW: interrupts are off).
  37  * SYSENTER does not save anything on the stack,
  38  * and does not save old RIP (!!!), RSP, or RFLAGS.
  39  *
  40  * Arguments:
  41  * eax  system call number
  42  * ebx  arg1
  43  * ecx  arg2
  44  * edx  arg3
  45  * esi  arg4
  46  * edi  arg5
  47  * ebp  user stack
  48  * 0(%ebp) arg6
  49  */
  50 SYM_CODE_START(entry_SYSENTER_compat)
  51         UNWIND_HINT_ENTRY
  52         ENDBR
  53         /* Interrupts are off on entry. */
  54         swapgs
  55
  56         pushq   %rax
  57         SWITCH_TO_KERNEL_CR3 scratch_reg=%rax
  58         popq    %rax
  59
  60         movq    PER_CPU_VAR(pcpu_hot + X86_top_of_stack), %rsp
  61
  62         /* Construct struct pt_regs on stack */
  63         pushq   $__USER_DS              /* pt_regs->ss */
  64         pushq   $0                      /* pt_regs->sp = 0 (placeholder) */
  65
  66         /*
  67          * Push flags.  This is nasty.  First, interrupts are currently
  68          * off, but we need pt_regs->flags to have IF set.  Second, if TS
  69          * was set in usermode, it's still set, and we're singlestepping
  70          * through this code.  do_SYSENTER_32() will fix up IF.
  71          */
  72         pushfq                          /* pt_regs->flags (except IF = 0) */
  73         pushq   $__USER32_CS            /* pt_regs->cs */
  74         pushq   $0                      /* pt_regs->ip = 0 (placeholder) */
  75 SYM_INNER_LABEL(entry_SYSENTER_compat_after_hwframe, SYM_L_GLOBAL)
  76
  77         /*
  78          * User tracing code (ptrace or signal handlers) might assume that
  79          * the saved RAX contains a 32-bit number when we're invoking a 32-bit
  80          * syscall.  Just in case the high bits are nonzero, zero-extend
  81          * the syscall number.  (This could almost certainly be deleted
  82          * with no ill effects.)
  83          */
  84         movl    %eax, %eax
  85
  86         pushq   %rax                    /* pt_regs->orig_ax */
  87         PUSH_AND_CLEAR_REGS rax=$-ENOSYS
  88         UNWIND_HINT_REGS
  89
  90         cld
  91
  92         IBRS_ENTER
  93         UNTRAIN_RET
  94         CLEAR_BRANCH_HISTORY
  95
  96         /*
  97          * SYSENTER doesn't filter flags, so we need to clear NT and AC
  98          * ourselves.  To save a few cycles, we can check whether
  99          * either was set instead of doing an unconditional popfq.
 100          * This needs to happen before enabling interrupts so that
 101          * we don't get preempted with NT set.
 102          *
 103          * If TF is set, we will single-step all the way to here -- do_debug
 104          * will ignore all the traps.  (Yes, this is slow, but so is
 105          * single-stepping in general.  This allows us to avoid having
 106          * a more complicated code to handle the case where a user program
 107          * forces us to single-step through the SYSENTER entry code.)
 108          *
 109          * NB.: .Lsysenter_fix_flags is a label with the code under it moved
 110          * out-of-line as an optimization: NT is unlikely to be set in the
 111          * majority of the cases and instead of polluting the I$ unnecessarily,
 112          * we're keeping that code behind a branch which will predict as
 113          * not-taken and therefore its instructions won't be fetched.
 114          */
 115         testl   $X86_EFLAGS_NT|X86_EFLAGS_AC|X86_EFLAGS_TF, EFLAGS(%rsp)
 116         jnz     .Lsysenter_fix_flags
 117 .Lsysenter_flags_fixed:
 118
 119         movq    %rsp, %rdi
 120         call    do_SYSENTER_32
 121         jmp     sysret32_from_system_call
 122
 123 .Lsysenter_fix_flags:
 124         pushq   $X86_EFLAGS_FIXED
 125         popfq
 126         jmp     .Lsysenter_flags_fixed
 127 SYM_INNER_LABEL(__end_entry_SYSENTER_compat, SYM_L_GLOBAL)
 128 SYM_CODE_END(entry_SYSENTER_compat)
 129
 130 /*
 131  * 32-bit SYSCALL entry.
 132  *
 133  * 32-bit system calls through the vDSO's __kernel_vsyscall enter here
 134  * on 64-bit kernels running on AMD CPUs.
 135  *
 136  * The SYSCALL instruction, in principle, should *only* occur in the
 137  * vDSO.  In practice, it appears that this really is the case.
 138  * As evidence:
 139  *
 140  *  - The calling convention for SYSCALL has changed several times without
 141  *    anyone noticing.
 142  *
 143  *  - Prior to the in-kernel X86_BUG_SYSRET_SS_ATTRS fixup, anything
 144  *    user task that did SYSCALL without immediately reloading SS
 145  *    would randomly crash.
 146  *
 147  *  - Most programmers do not directly target AMD CPUs, and the 32-bit
 148  *    SYSCALL instruction does not exist on Intel CPUs.  Even on AMD
 149  *    CPUs, Linux disables the SYSCALL instruction on 32-bit kernels
 150  *    because the SYSCALL instruction in legacy/native 32-bit mode (as
 151  *    opposed to compat mode) is sufficiently poorly designed as to be
 152  *    essentially unusable.
 153  *
 154  * 32-bit SYSCALL saves RIP to RCX, clears RFLAGS.RF, then saves
 155  * RFLAGS to R11, then loads new SS, CS, and RIP from previously
 156  * programmed MSRs.  RFLAGS gets masked by a value from another MSR
 157  * (so CLD and CLAC are not needed).  SYSCALL does not save anything on
 158  * the stack and does not change RSP.
 159  *
 160  * Note: RFLAGS saving+masking-with-MSR happens only in Long mode
 161  * (in legacy 32-bit mode, IF, RF and VM bits are cleared and that's it).
 162  * Don't get confused: RFLAGS saving+masking depends on Long Mode Active bit
 163  * (EFER.LMA=1), NOT on bitness of userspace where SYSCALL executes
 164  * or target CS descriptor's L bit (SYSCALL does not read segment descriptors).
 165  *
 166  * Arguments:
 167  * eax  system call number
 168  * ecx  return address
 169  * ebx  arg1
 170  * ebp  arg2    (note: not saved in the stack frame, should not be touched)
 171  * edx  arg3
 172  * esi  arg4
 173  * edi  arg5
 174  * esp  user stack
 175  * 0(%esp) arg6
 176  */
 177 SYM_CODE_START(entry_SYSCALL_compat)
 178         UNWIND_HINT_ENTRY
 179         ENDBR
 180         /* Interrupts are off on entry. */
 181         swapgs
 182
 183         /* Stash user ESP */
 184         movl    %esp, %r8d
 185
 186         /* Use %rsp as scratch reg. User ESP is stashed in r8 */
 187         SWITCH_TO_KERNEL_CR3 scratch_reg=%rsp
 188
 189         /* Switch to the kernel stack */
 190         movq    PER_CPU_VAR(pcpu_hot + X86_top_of_stack), %rsp
 191
 192 SYM_INNER_LABEL(entry_SYSCALL_compat_safe_stack, SYM_L_GLOBAL)
 193         ANNOTATE_NOENDBR
 194
 195         /* Construct struct pt_regs on stack */
 196         pushq   $__USER_DS              /* pt_regs->ss */
 197         pushq   %r8                     /* pt_regs->sp */
 198         pushq   %r11                    /* pt_regs->flags */
 199         pushq   $__USER32_CS            /* pt_regs->cs */
 200         pushq   %rcx                    /* pt_regs->ip */
 201 SYM_INNER_LABEL(entry_SYSCALL_compat_after_hwframe, SYM_L_GLOBAL)
 202         movl    %eax, %eax              /* discard orig_ax high bits */
 203         pushq   %rax                    /* pt_regs->orig_ax */
 204         PUSH_AND_CLEAR_REGS rcx=%rbp rax=$-ENOSYS
 205         UNWIND_HINT_REGS
 206
 207         IBRS_ENTER
 208         UNTRAIN_RET
 209         CLEAR_BRANCH_HISTORY
 210
 211         movq    %rsp, %rdi
 212         call    do_fast_syscall_32
 213
 214 sysret32_from_system_call:
 215         /* XEN PV guests always use IRET path */
 216         ALTERNATIVE "testb %al, %al; jz swapgs_restore_regs_and_return_to_usermode", \
 217                     "jmp swapgs_restore_regs_and_return_to_usermode", X86_FEATURE_XENPV
 218
 219         /*
 220          * Opportunistic SYSRET
 221          *
 222          * We are not going to return to userspace from the trampoline
 223          * stack. So let's erase the thread stack right now.
 224          */
 225         STACKLEAK_ERASE
 226
 227         IBRS_EXIT
 228
 229         movq    RBX(%rsp), %rbx         /* pt_regs->rbx */
 230         movq    RBP(%rsp), %rbp         /* pt_regs->rbp */
 231         movq    EFLAGS(%rsp), %r11      /* pt_regs->flags (in r11) */
 232         movq    RIP(%rsp), %rcx         /* pt_regs->ip (in rcx) */
 233         addq    $RAX, %rsp              /* Skip r8-r15 */
 234         popq    %rax                    /* pt_regs->rax */
 235         popq    %rdx                    /* Skip pt_regs->cx */
 236         popq    %rdx                    /* pt_regs->dx */
 237         popq    %rsi                    /* pt_regs->si */
 238         popq    %rdi                    /* pt_regs->di */
 239
 240         /*
 241          * USERGS_SYSRET32 does:
 242          *  GSBASE = user's GS base
 243          *  EIP = ECX
 244          *  RFLAGS = R11
 245          *  CS = __USER32_CS
 246          *  SS = __USER_DS
 247          *
 248          * ECX will not match pt_regs->cx, but we're returning to a vDSO
 249          * trampoline that will fix up RCX, so this is okay.
 250          *
 251          * R12-R15 are callee-saved, so they contain whatever was in them
 252          * when the system call started, which is already known to user
 253          * code.  We zero R8-R10 to avoid info leaks.
 254          */
 255         movq    RSP-ORIG_RAX(%rsp), %rsp
 256 SYM_INNER_LABEL(entry_SYSRETL_compat_unsafe_stack, SYM_L_GLOBAL)
 257         ANNOTATE_NOENDBR
 258
 259         /*
 260          * The original userspace %rsp (RSP-ORIG_RAX(%rsp)) is stored
 261          * on the process stack which is not mapped to userspace and
 262          * not readable after we SWITCH_TO_USER_CR3.  Delay the CR3
 263          * switch until after after the last reference to the process
 264          * stack.
 265          *
 266          * %r8/%r9 are zeroed before the sysret, thus safe to clobber.
 267          */
 268         SWITCH_TO_USER_CR3_NOSTACK scratch_reg=%r8 scratch_reg2=%r9
 269
 270         xorl    %r8d, %r8d
 271         xorl    %r9d, %r9d
 272         xorl    %r10d, %r10d
 273         swapgs
 274         CLEAR_CPU_BUFFERS
 275         sysretl
 276 SYM_INNER_LABEL(entry_SYSRETL_compat_end, SYM_L_GLOBAL)
 277         ANNOTATE_NOENDBR
 278         int3
 279 SYM_CODE_END(entry_SYSCALL_compat)
 280
 281 /*
 282  * int 0x80 is used by 32 bit mode as a system call entry. Normally idt entries
 283  * point to C routines, however since this is a system call interface the branch
 284  * history needs to be scrubbed to protect against BHI attacks, and that
 285  * scrubbing needs to take place in assembly code prior to entering any C
 286  * routines.
 287  */
 288 SYM_CODE_START(int80_emulation)
 289         ANNOTATE_NOENDBR
 290         UNWIND_HINT_FUNC
 291         CLEAR_BRANCH_HISTORY
 292         jmp do_int80_emulation
 293 SYM_CODE_END(int80_emulation)