arch/s390/kernel/swsusp_asm64.S

   1 /*
   2  * S390 64-bit swsusp implementation
   3  *
   4  * Copyright IBM Corp. 2009
   5  *
   6  * Author(s): Hans-Joachim Picht <hans@linux.vnet.ibm.com>
   7  *            Michael Holzheu <holzheu@linux.vnet.ibm.com>
   8  */
   9
  10 #include <asm/page.h>
  11 #include <asm/ptrace.h>
  12 #include <asm/asm-offsets.h>
  13
  14 /*
  15  * Save register context in absolute 0 lowcore and call swsusp_save() to
  16  * create in-memory kernel image. The context is saved in the designated
  17  * "store status" memory locations (see POP).
  18  * We return from this function twice. The first time during the suspend to
  19  * disk process. The second time via the swsusp_arch_resume() function
  20  * (see below) in the resume process.
  21  * This function runs with disabled interrupts.
  22  */
  23         .section .text
  24         .align  4
  25         .globl swsusp_arch_suspend
  26 swsusp_arch_suspend:
  27         stmg    %r6,%r15,__SF_GPRS(%r15)
  28         lgr     %r1,%r15
  29         aghi    %r15,-STACK_FRAME_OVERHEAD
  30         stg     %r1,__SF_BACKCHAIN(%r15)
  31
  32         /* Deactivate DAT */
  33         stnsm   __SF_EMPTY(%r15),0xfb
  34
  35         /* Store prefix register on stack */
  36         stpx    __SF_EMPTY(%r15)
  37
  38         /* Save prefix register contents for lowcore */
  39         llgf    %r4,__SF_EMPTY(%r15)
  40
  41         /* Get pointer to save area */
  42         lghi    %r1,0x1000
  43
  44         /* Store registers */
  45         mvc     0x318(4,%r1),__SF_EMPTY(%r15)   /* move prefix to lowcore */
  46         stfpc   0x31c(%r1)                      /* store fpu control */
  47         std     0,0x200(%r1)                    /* store f0 */
  48         std     1,0x208(%r1)                    /* store f1 */
  49         std     2,0x210(%r1)                    /* store f2 */
  50         std     3,0x218(%r1)                    /* store f3 */
  51         std     4,0x220(%r1)                    /* store f4 */
  52         std     5,0x228(%r1)                    /* store f5 */
  53         std     6,0x230(%r1)                    /* store f6 */
  54         std     7,0x238(%r1)                    /* store f7 */
  55         std     8,0x240(%r1)                    /* store f8 */
  56         std     9,0x248(%r1)                    /* store f9 */
  57         std     10,0x250(%r1)                   /* store f10 */
  58         std     11,0x258(%r1)                   /* store f11 */
  59         std     12,0x260(%r1)                   /* store f12 */
  60         std     13,0x268(%r1)                   /* store f13 */
  61         std     14,0x270(%r1)                   /* store f14 */
  62         std     15,0x278(%r1)                   /* store f15 */
  63         stam    %a0,%a15,0x340(%r1)             /* store access registers */
  64         stctg   %c0,%c15,0x380(%r1)             /* store control registers */
  65         stmg    %r0,%r15,0x280(%r1)             /* store general registers */
  66
  67         stpt    0x328(%r1)                      /* store timer */
  68         stckc   0x330(%r1)                      /* store clock comparator */
  69
  70         /* Activate DAT */
  71         stosm   __SF_EMPTY(%r15),0x04
  72
  73         /* Set prefix page to zero */
  74         xc      __SF_EMPTY(4,%r15),__SF_EMPTY(%r15)
  75         spx     __SF_EMPTY(%r15)
  76
  77         lghi    %r2,0
  78         lghi    %r3,2*PAGE_SIZE
  79         lghi    %r5,2*PAGE_SIZE
  80 1:      mvcle   %r2,%r4,0
  81         jo      1b
  82
  83         /* Save image */
  84         brasl   %r14,swsusp_save
  85
  86         /* Restore prefix register and return */
  87         lghi    %r1,0x1000
  88         spx     0x318(%r1)
  89         lmg     %r6,%r15,STACK_FRAME_OVERHEAD + __SF_GPRS(%r15)
  90         lghi    %r2,0
  91         br      %r14
  92
  93 /*
  94  * Restore saved memory image to correct place and restore register context.
  95  * Then we return to the function that called swsusp_arch_suspend().
  96  * swsusp_arch_resume() runs with disabled interrupts.
  97  */
  98         .globl swsusp_arch_resume
  99 swsusp_arch_resume:
 100         stmg    %r6,%r15,__SF_GPRS(%r15)
 101         lgr     %r1,%r15
 102         aghi    %r15,-STACK_FRAME_OVERHEAD
 103         stg     %r1,__SF_BACKCHAIN(%r15)
 104
 105         /* Make all free pages stable */
 106         lghi    %r2,1
 107         brasl   %r14,arch_set_page_states
 108 #ifdef CONFIG_SMP
 109         /* Save boot cpu number */
 110         brasl   %r14,smp_get_phys_cpu_id
 111         lgr     %r10,%r2
 112 #endif
 113         /* Deactivate DAT */
 114         stnsm   __SF_EMPTY(%r15),0xfb
 115
 116         /* Set prefix page to zero */
 117         xc      __SF_EMPTY(4,%r15),__SF_EMPTY(%r15)
 118         spx     __SF_EMPTY(%r15)
 119
 120         /* Restore saved image */
 121         larl    %r1,restore_pblist
 122         lg      %r1,0(%r1)
 123         ltgr    %r1,%r1
 124         jz      2f
 125 0:
 126         lg      %r2,8(%r1)
 127         lg      %r4,0(%r1)
 128         lghi    %r3,PAGE_SIZE
 129         lghi    %r5,PAGE_SIZE
 130 1:
 131         mvcle   %r2,%r4,0
 132         jo      1b
 133         lg      %r1,16(%r1)
 134         ltgr    %r1,%r1
 135         jnz     0b
 136 2:
 137         ptlb                            /* flush tlb */
 138
 139         /* Restore registers */
 140         lghi    %r13,0x1000             /* %r1 = pointer to save arae */
 141
 142         spt     0x328(%r13)             /* reprogram timer */
 143         //sckc  0x330(%r13)             /* set clock comparator */
 144
 145         lctlg   %c0,%c15,0x380(%r13)    /* load control registers */
 146         lam     %a0,%a15,0x340(%r13)    /* load access registers */
 147
 148         lfpc    0x31c(%r13)             /* load fpu control */
 149         ld      0,0x200(%r13)           /* load f0 */
 150         ld      1,0x208(%r13)           /* load f1 */
 151         ld      2,0x210(%r13)           /* load f2 */
 152         ld      3,0x218(%r13)           /* load f3 */
 153         ld      4,0x220(%r13)           /* load f4 */
 154         ld      5,0x228(%r13)           /* load f5 */
 155         ld      6,0x230(%r13)           /* load f6 */
 156         ld      7,0x238(%r13)           /* load f7 */
 157         ld      8,0x240(%r13)           /* load f8 */
 158         ld      9,0x248(%r13)           /* load f9 */
 159         ld      10,0x250(%r13)          /* load f10 */
 160         ld      11,0x258(%r13)          /* load f11 */
 161         ld      12,0x260(%r13)          /* load f12 */
 162         ld      13,0x268(%r13)          /* load f13 */
 163         ld      14,0x270(%r13)          /* load f14 */
 164         ld      15,0x278(%r13)          /* load f15 */
 165
 166         /* Load old stack */
 167         lg      %r15,0x2f8(%r13)
 168
 169         /* Pointer to save area */
 170         lghi    %r13,0x1000
 171
 172 #ifdef CONFIG_SMP
 173         /* Switch CPUs */
 174         lgr     %r2,%r10                /* get cpu id */
 175         llgf    %r3,0x318(%r13)
 176         brasl   %r14,smp_switch_boot_cpu_in_resume
 177 #endif
 178         /* Restore prefix register */
 179         spx     0x318(%r13)
 180
 181         /* Activate DAT */
 182         stosm   __SF_EMPTY(%r15),0x04
 183
 184         /* Make all free pages unstable */
 185         lghi    %r2,0
 186         brasl   %r14,arch_set_page_states
 187
 188         /* Return 0 */
 189         lmg     %r6,%r15,STACK_FRAME_OVERHEAD + __SF_GPRS(%r15)
 190         lghi    %r2,0
 191         br      %r14