[linux-2.6-block.git] / arch / x86 / entry / vdso / vdso-layout.lds.S

#include <asm/vdso.h>

/*
 * Linker script for vDSO.  This is an ELF shared object prelinked to
 * its virtual address, and with only one read-only segment.
 * This script controls its layout.
 */

#if defined(BUILD_VDSO64)
# define SHDR_SIZE 64
#elif defined(BUILD_VDSO32) || defined(BUILD_VDSOX32)
# define SHDR_SIZE 40
#else
# error unknown VDSO target
#endif

#define NUM_FAKE_SHDRS 13

SECTIONS
{
	/*
	 * User/kernel shared data is before the vDSO.  This may be a little
	 * uglier than putting it after the vDSO, but it avoids issues with
	 * non-allocatable things that dangle past the end of the PT_LOAD
	 * segment.
	 */

	vvar_start = . - 2 * PAGE_SIZE;
	vvar_page = vvar_start;

	/* Place all vvars at the offsets in asm/vvar.h. */
#define EMIT_VVAR(name, offset) vvar_ ## name = vvar_page + offset;
#define __VVAR_KERNEL_LDS
#include <asm/vvar.h>
#undef __VVAR_KERNEL_LDS
#undef EMIT_VVAR

	pvclock_page = vvar_start + PAGE_SIZE;

	. = SIZEOF_HEADERS;

	.hash		: { *(.hash) }			:text
	.gnu.hash	: { *(.gnu.hash) }
	.dynsym		: { *(.dynsym) }
	.dynstr		: { *(.dynstr) }
	.gnu.version	: { *(.gnu.version) }
	.gnu.version_d	: { *(.gnu.version_d) }
	.gnu.version_r	: { *(.gnu.version_r) }

	.dynamic	: { *(.dynamic) }		:text	:dynamic

	.rodata		: {
		*(.rodata*)
		*(.data*)
		*(.sdata*)
		*(.got.plt) *(.got)
		*(.gnu.linkonce.d.*)
		*(.bss*)
		*(.dynbss*)
		*(.gnu.linkonce.b.*)

		/*
		 * Ideally this would live in a C file, but that won't
		 * work cleanly for x32 until we start building the x32
		 * C code using an x32 toolchain.
		 */
		VDSO_FAKE_SECTION_TABLE_START = .;
		. = . + NUM_FAKE_SHDRS * SHDR_SIZE;
		VDSO_FAKE_SECTION_TABLE_END = .;
	}						:text

	.fake_shstrtab	: { *(.fake_shstrtab) }		:text


	.note		: { *(.note.*) }		:text	:note

	.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
	.eh_frame	: { KEEP (*(.eh_frame)) }	:text


	/*
	 * Text is well-separated from actual data: there's plenty of
	 * stuff that isn't used at runtime in between.
	 */

	.text		: { *(.text*) }			:text	=0x90909090,

	/*
	 * At the end so that eu-elflint stays happy when vdso2c strips
	 * these.  A better implementation would avoid allocating space
	 * for these.
	 */
	.altinstructions	: { *(.altinstructions) }	:text
	.altinstr_replacement	: { *(.altinstr_replacement) }	:text

	/DISCARD/ : {
		*(.discard)
		*(.discard.*)
		*(__bug_table)
	}
}

/*
 * Very old versions of ld do not recognize this name token; use the constant.
 */
#define PT_GNU_EH_FRAME	0x6474e550

/*
 * We must supply the ELF program headers explicitly to get just one
 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 */
PHDRS
{
	text		PT_LOAD		FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
	dynamic		PT_DYNAMIC	FLAGS(4);		/* PF_R */
	note		PT_NOTE		FLAGS(4);		/* PF_R */
	eh_frame_hdr	PT_GNU_EH_FRAME;
}
Commit	Line	Data
18d0a6fd AL	1	#include <asm/vdso.h>
18d0a6fd AL	2
f6b46ebf RM	3	/*
	4	* Linker script for vDSO. This is an ELF shared object prelinked to
	5	* its virtual address, and with only one read-only segment.
	6	* This script controls its layout.
	7	*/
	8
bfad381c AL	9	#if defined(BUILD_VDSO64)
	10	# define SHDR_SIZE 64
	11	#elif defined(BUILD_VDSO32) \|\| defined(BUILD_VDSOX32)
	12	# define SHDR_SIZE 40
	13	#else
	14	# error unknown VDSO target
	15	#endif
	16
0e3727a8	17	#define NUM_FAKE_SHDRS 13
bfad381c	18
f6b46ebf RM	19	SECTIONS
f6b46ebf RM	20	{
e6577a7c AL	21	/*
	22	* User/kernel shared data is before the vDSO. This may be a little
	23	* uglier than putting it after the vDSO, but it avoids issues with
	24	* non-allocatable things that dangle past the end of the PT_LOAD
	25	* segment.
	26	*/
	27
1ed95e52	28	vvar_start = . - 2 * PAGE_SIZE;
e6577a7c AL	29	vvar_page = vvar_start;
	30
	31	/* Place all vvars at the offsets in asm/vvar.h. */
	32	#define EMIT_VVAR(name, offset) vvar_ ## name = vvar_page + offset;
	33	#define __VVAR_KERNEL_LDS
	34	#include <asm/vvar.h>
	35	#undef __VVAR_KERNEL_LDS
	36	#undef EMIT_VVAR
	37
1ed95e52	38	pvclock_page = vvar_start + PAGE_SIZE;
e6577a7c	39
b0b49f26	40	. = SIZEOF_HEADERS;
f6b46ebf RM	41
	42	.hash : { *(.hash) } :text
	43	.gnu.hash : { *(.gnu.hash) }
	44	.dynsym : { *(.dynsym) }
	45	.dynstr : { *(.dynstr) }
	46	.gnu.version : { *(.gnu.version) }
	47	.gnu.version_d : { *(.gnu.version_d) }
	48	.gnu.version_r : { *(.gnu.version_r) }
	49
f6b46ebf RM	50	.dynamic : { *(.dynamic) } :text :dynamic
f6b46ebf RM	51
bfad381c AL	52	.rodata : {
bfad381c AL	53	(.rodata)
0e3727a8 AL	54	(.data)
	55	(.sdata)
	56	(.got.plt) (.got)
	57	(.gnu.linkonce.d.)
	58	(.bss)
	59	(.dynbss)
	60	(.gnu.linkonce.b.)
bfad381c AL	61
	62	/*
	63	* Ideally this would live in a C file, but that won't
	64	* work cleanly for x32 until we start building the x32
	65	* C code using an x32 toolchain.
	66	*/
	67	VDSO_FAKE_SECTION_TABLE_START = .;
	68	. = . + NUM_FAKE_SHDRS * SHDR_SIZE;
	69	VDSO_FAKE_SECTION_TABLE_END = .;
	70	} :text
	71
	72	.fake_shstrtab : { *(.fake_shstrtab) } :text
	73
f6b46ebf	74
0e3727a8 AL	75	.note : { (.note.) } :text :note
	76
	77	.eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
	78	.eh_frame : { KEEP (*(.eh_frame)) } :text
	79
f6b46ebf RM	80
f6b46ebf RM	81	/*
0e3727a8 AL	82	* Text is well-separated from actual data: there's plenty of
0e3727a8 AL	83	* stuff that isn't used at runtime in between.
f6b46ebf	84	*/
f6b46ebf	85
378ed3cc AL	86	.text : { (.text) } :text =0x90909090,
378ed3cc AL	87
0e3727a8 AL	88	/*
	89	* At the end so that eu-elflint stays happy when vdso2c strips
	90	* these. A better implementation would avoid allocating space
	91	* for these.
	92	*/
	93	.altinstructions : { *(.altinstructions) } :text
	94	.altinstr_replacement : { *(.altinstr_replacement) } :text
	95
26f5ef2e PA	96	/DISCARD/ : {
	97	*(.discard)
	98	(.discard.)
5f56e716	99	*(__bug_table)
26f5ef2e	100	}
f6b46ebf RM	101	}
	102
	103	/*
	104	* Very old versions of ld do not recognize this name token; use the constant.
	105	*/
	106	#define PT_GNU_EH_FRAME 0x6474e550
	107
	108	/*
	109	* We must supply the ELF program headers explicitly to get just one
	110	* PT_LOAD segment, and set the flags explicitly to make segments read-only.
	111	*/
	112	PHDRS
	113	{
	114	text PT_LOAD FLAGS(5) FILEHDR PHDRS; /* PF_R\|PF_X */
	115	dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
	116	note PT_NOTE FLAGS(4); /* PF_R */
	117	eh_frame_hdr PT_GNU_EH_FRAME;
	118	}