[linux-2.6-block.git] / arch / x86 / boot / compressed / head_64.S

/*
 *  linux/boot/head.S
 *
 *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
 */

/*
 *  head.S contains the 32-bit startup code.
 *
 * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
 * the page directory will exist. The startup code will be overwritten by
 * the page directory. [According to comments etc elsewhere on a compressed
 * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
 *
 * Page 0 is deliberately kept safe, since System Management Mode code in 
 * laptops may need to access the BIOS data stored there.  This is also
 * useful for future device drivers that either access the BIOS via VM86 
 * mode.
 */

/*
 * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
 */
.code32
.text

#include <linux/linkage.h>
#include <asm/segment.h>
#include <asm/pgtable.h>
#include <asm/page.h>
#include <asm/boot.h>
#include <asm/msr.h>
#include <asm/processor-flags.h>
#include <asm/asm-offsets.h>

.section ".text.head"
	.code32
	.globl startup_32

startup_32:
	cld
	/* test KEEP_SEGMENTS flag to see if the bootloader is asking
	 * us to not reload segments */
	testb $(1<<6), BP_loadflags(%esi)
	jnz 1f

	cli
	movl	$(__KERNEL_DS), %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
1:

/* Calculate the delta between where we were compiled to run
 * at and where we were actually loaded at.  This can only be done
 * with a short local call on x86.  Nothing  else will tell us what
 * address we are running at.  The reserved chunk of the real-mode
 * data at 0x1e4 (defined as a scratch field) are used as the stack
 * for this calculation. Only 4 bytes are needed.
 */
	leal	(0x1e4+4)(%esi), %esp
	call	1f
1:	popl	%ebp
	subl	$1b, %ebp

/* setup a stack and make sure cpu supports long mode. */
	movl	$boot_stack_end, %eax
	addl	%ebp, %eax
	movl	%eax, %esp

	call	verify_cpu
	testl	%eax, %eax
	jnz	no_longmode

/* Compute the delta between where we were compiled to run at
 * and where the code will actually run at.
 */
/* %ebp contains the address we are loaded at by the boot loader and %ebx
 * contains the address where we should move the kernel image temporarily
 * for safe in-place decompression.
 */

#ifdef CONFIG_RELOCATABLE
	movl	%ebp, %ebx
	addl	$(PMD_PAGE_SIZE -1), %ebx
	andl	$PMD_PAGE_MASK, %ebx
#else
	movl	$CONFIG_PHYSICAL_START, %ebx
#endif

	/* Replace the compressed data size with the uncompressed size */
	subl	input_len(%ebp), %ebx
	movl	output_len(%ebp), %eax
	addl	%eax, %ebx
	/* Add 8 bytes for every 32K input block */
	shrl	$12, %eax
	addl	%eax, %ebx
	/* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
	addl	$(32768 + 18 + 4095), %ebx
	andl	$~4095, %ebx

/*
 * Prepare for entering 64 bit mode
 */

	/* Load new GDT with the 64bit segments using 32bit descriptor */
	leal	gdt(%ebp), %eax
	movl	%eax, gdt+2(%ebp)
	lgdt	gdt(%ebp)

	/* Enable PAE mode */
	xorl	%eax, %eax
	orl	$(X86_CR4_PAE), %eax
	movl	%eax, %cr4

 /*
  * Build early 4G boot pagetable
  */
	/* Initialize Page tables to 0*/
	leal	pgtable(%ebx), %edi
	xorl	%eax, %eax
	movl	$((4096*6)/4), %ecx
	rep	stosl

	/* Build Level 4 */
	leal	pgtable + 0(%ebx), %edi
	leal	0x1007 (%edi), %eax
	movl	%eax, 0(%edi)

	/* Build Level 3 */
	leal	pgtable + 0x1000(%ebx), %edi
	leal	0x1007(%edi), %eax
	movl	$4, %ecx
1:	movl	%eax, 0x00(%edi)
	addl	$0x00001000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Build Level 2 */
	leal	pgtable + 0x2000(%ebx), %edi
	movl	$0x00000183, %eax
	movl	$2048, %ecx
1:	movl	%eax, 0(%edi)
	addl	$0x00200000, %eax
	addl	$8, %edi
	decl	%ecx
	jnz	1b

	/* Enable the boot page tables */
	leal	pgtable(%ebx), %eax
	movl	%eax, %cr3

	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr
	btsl	$_EFER_LME, %eax
	wrmsr

	/* Setup for the jump to 64bit mode
	 *
	 * When the jump is performend we will be in long mode but
	 * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	 * (and in turn EFER.LMA = 1).	To jump into 64bit mode we use
	 * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	 * We place all of the values on our mini stack so lret can
	 * used to perform that far jump.
	 */
	pushl	$__KERNEL_CS
	leal	startup_64(%ebp), %eax
	pushl	%eax

	/* Enter paged protected Mode, activating Long Mode */
	movl	$(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
	movl	%eax, %cr0

	/* Jump from 32bit compatibility mode into 64bit mode. */
	lret

no_longmode:
	/* This isn't an x86-64 CPU so hang */
1:
	hlt
	jmp     1b

#include "../../kernel/verify_cpu_64.S"

	/* Be careful here startup_64 needs to be at a predictable
	 * address so I can export it in an ELF header.  Bootloaders
	 * should look at the ELF header to find this address, as
	 * it may change in the future.
	 */
	.code64
	.org 0x200
ENTRY(startup_64)
	/* We come here either from startup_32 or directly from a
	 * 64bit bootloader.  If we come here from a bootloader we depend on
	 * an identity mapped page table being provied that maps our
	 * entire text+data+bss and hopefully all of memory.
	 */

	/* Setup data segments. */
	xorl	%eax, %eax
	movl	%eax, %ds
	movl	%eax, %es
	movl	%eax, %ss
	movl	%eax, %fs
	movl	%eax, %gs
	lldt	%ax
	movl    $0x20, %eax
	ltr	%ax

	/* Compute the decompressed kernel start address.  It is where
	 * we were loaded at aligned to a 2M boundary. %rbp contains the
	 * decompressed kernel start address.
	 *
	 * If it is a relocatable kernel then decompress and run the kernel
	 * from load address aligned to 2MB addr, otherwise decompress and
	 * run the kernel from CONFIG_PHYSICAL_START
	 */

	/* Start with the delta to where the kernel will run at. */
#ifdef CONFIG_RELOCATABLE
	leaq	startup_32(%rip) /* - $startup_32 */, %rbp
	addq	$(PMD_PAGE_SIZE - 1), %rbp
	andq	$PMD_PAGE_MASK, %rbp
	movq	%rbp, %rbx
#else
	movq	$CONFIG_PHYSICAL_START, %rbp
	movq	%rbp, %rbx
#endif

	/* Replace the compressed data size with the uncompressed size */
	movl	input_len(%rip), %eax
	subq	%rax, %rbx
	movl	output_len(%rip), %eax
	addq	%rax, %rbx
	/* Add 8 bytes for every 32K input block */
	shrq	$12, %rax
	addq	%rax, %rbx
	/* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
	addq	$(32768 + 18 + 4095), %rbx
	andq	$~4095, %rbx

/* Copy the compressed kernel to the end of our buffer
 * where decompression in place becomes safe.
 */
	leaq	_end_before_pgt(%rip), %r8
	leaq	_end_before_pgt(%rbx), %r9
	movq	$_end_before_pgt /* - $startup_32 */, %rcx
1:	subq	$8, %r8
	subq	$8, %r9
	movq	0(%r8), %rax
	movq	%rax, 0(%r9)
	subq	$8, %rcx
	jnz	1b

/*
 * Jump to the relocated address.
 */
	leaq	relocated(%rbx), %rax
	jmp	*%rax

.section ".text"
relocated:

/*
 * Clear BSS
 */
	xorq	%rax, %rax
	leaq    _edata(%rbx), %rdi
	leaq    _end_before_pgt(%rbx), %rcx
	subq	%rdi, %rcx
	cld
	rep
	stosb

	/* Setup the stack */
	leaq	boot_stack_end(%rip), %rsp

	/* zero EFLAGS after setting rsp */
	pushq	$0
	popfq

/*
 * Do the decompression, and jump to the new kernel..
 */
	pushq	%rsi			# Save the real mode argument
	movq	%rsi, %rdi		# real mode address
	leaq	boot_heap(%rip), %rsi	# malloc area for uncompression
	leaq	input_data(%rip), %rdx  # input_data
	movl	input_len(%rip), %eax
	movq	%rax, %rcx		# input_len
	movq	%rbp, %r8		# output
	call	decompress_kernel
	popq	%rsi


/*
 * Jump to the decompressed kernel.
 */
	jmp	*%rbp

	.data
gdt:
	.word	gdt_end - gdt
	.long	gdt
	.word	0
	.quad	0x0000000000000000	/* NULL descriptor */
	.quad	0x00af9a000000ffff	/* __KERNEL_CS */
	.quad	0x00cf92000000ffff	/* __KERNEL_DS */
	.quad	0x0080890000000000	/* TS descriptor */
	.quad   0x0000000000000000	/* TS continued */
gdt_end:

.bss
/* Stack and heap for uncompression */
.balign 4
boot_heap:
	.fill BOOT_HEAP_SIZE, 1, 0
boot_stack:
	.fill BOOT_STACK_SIZE, 1, 0
boot_stack_end:
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/boot/head.S
	3	*
	4	* Copyright (C) 1991, 1992, 1993 Linus Torvalds
1da177e4 LT	5	*/
	6
	7	/*
	8	* head.S contains the 32-bit startup code.
	9	*
	10	* NOTE!!! Startup happens at absolute address 0x00001000, which is also where
	11	* the page directory will exist. The startup code will be overwritten by
	12	* the page directory. [According to comments etc elsewhere on a compressed
	13	* kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
	14	*
	15	* Page 0 is deliberately kept safe, since System Management Mode code in
	16	* laptops may need to access the BIOS data stored there. This is also
	17	* useful for future device drivers that either access the BIOS via VM86
	18	* mode.
	19	*/
	20
	21	/*
f4549448	22	* High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
1da177e4 LT	23	*/
	24	.code32
	25	.text
	26
	27	#include <linux/linkage.h>
	28	#include <asm/segment.h>
1ab60e0f	29	#include <asm/pgtable.h>
d0537508	30	#include <asm/page.h>
7c539764	31	#include <asm/boot.h>
1ab60e0f	32	#include <asm/msr.h>
e83e31f4	33	#include <asm/processor-flags.h>
bd53147d	34	#include <asm/asm-offsets.h>
1da177e4	35
1ab60e0f	36	.section ".text.head"
1da177e4 LT	37	.code32
1da177e4 LT	38	.globl startup_32
1ab60e0f	39
1da177e4 LT	40	startup_32:
1da177e4 LT	41	cld
bd53147d EB	42	/* test KEEP_SEGMENTS flag to see if the bootloader is asking
	43	* us to not reload segments */
	44	testb $(1<<6), BP_loadflags(%esi)
	45	jnz 1f
	46
1da177e4	47	cli
1ab60e0f VG	48	movl $(__KERNEL_DS), %eax
	49	movl %eax, %ds
	50	movl %eax, %es
	51	movl %eax, %ss
bd53147d	52	1:
1ab60e0f VG	53
	54	/* Calculate the delta between where we were compiled to run
	55	* at and where we were actually loaded at. This can only be done
	56	* with a short local call on x86. Nothing else will tell us what
	57	* address we are running at. The reserved chunk of the real-mode
85414b69 PA	58	* data at 0x1e4 (defined as a scratch field) are used as the stack
85414b69 PA	59	* for this calculation. Only 4 bytes are needed.
1ab60e0f	60	*/
85414b69	61	leal (0x1e4+4)(%esi), %esp
1ab60e0f VG	62	call 1f
	63	1: popl %ebp
	64	subl $1b, %ebp
	65
a4831e08	66	/* setup a stack and make sure cpu supports long mode. */
7c539764	67	movl $boot_stack_end, %eax
a4831e08 VG	68	addl %ebp, %eax
	69	movl %eax, %esp
	70
	71	call verify_cpu
	72	testl %eax, %eax
	73	jnz no_longmode
	74
1ab60e0f VG	75	/* Compute the delta between where we were compiled to run at
	76	* and where the code will actually run at.
	77	*/
	78	/* %ebp contains the address we are loaded at by the boot loader and %ebx
	79	* contains the address where we should move the kernel image temporarily
	80	* for safe in-place decompression.
	81	*/
	82
	83	#ifdef CONFIG_RELOCATABLE
	84	movl %ebp, %ebx
31422c51 AK	85	addl $(PMD_PAGE_SIZE -1), %ebx
31422c51 AK	86	andl $PMD_PAGE_MASK, %ebx
1ab60e0f VG	87	#else
	88	movl $CONFIG_PHYSICAL_START, %ebx
	89	#endif
	90
	91	/* Replace the compressed data size with the uncompressed size */
	92	subl input_len(%ebp), %ebx
	93	movl output_len(%ebp), %eax
	94	addl %eax, %ebx
	95	/* Add 8 bytes for every 32K input block */
	96	shrl $12, %eax
	97	addl %eax, %ebx
	98	/* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
	99	addl $(32768 + 18 + 4095), %ebx
	100	andl $~4095, %ebx
1da177e4 LT	101
1da177e4 LT	102	/*
1ab60e0f	103	* Prepare for entering 64 bit mode
1da177e4	104	*/
1ab60e0f VG	105
	106	/* Load new GDT with the 64bit segments using 32bit descriptor */
	107	leal gdt(%ebp), %eax
	108	movl %eax, gdt+2(%ebp)
	109	lgdt gdt(%ebp)
	110
	111	/* Enable PAE mode */
	112	xorl %eax, %eax
e83e31f4	113	orl $(X86_CR4_PAE), %eax
1ab60e0f VG	114	movl %eax, %cr4
	115
	116	/*
	117	* Build early 4G boot pagetable
	118	*/
	119	/* Initialize Page tables to 0*/
	120	leal pgtable(%ebx), %edi
	121	xorl %eax, %eax
	122	movl $((4096*6)/4), %ecx
	123	rep stosl
	124
	125	/* Build Level 4 */
	126	leal pgtable + 0(%ebx), %edi
	127	leal 0x1007 (%edi), %eax
	128	movl %eax, 0(%edi)
	129
	130	/* Build Level 3 */
	131	leal pgtable + 0x1000(%ebx), %edi
	132	leal 0x1007(%edi), %eax
	133	movl $4, %ecx
	134	1: movl %eax, 0x00(%edi)
	135	addl $0x00001000, %eax
	136	addl $8, %edi
	137	decl %ecx
	138	jnz 1b
	139
	140	/* Build Level 2 */
	141	leal pgtable + 0x2000(%ebx), %edi
	142	movl $0x00000183, %eax
	143	movl $2048, %ecx
	144	1: movl %eax, 0(%edi)
	145	addl $0x00200000, %eax
	146	addl $8, %edi
	147	decl %ecx
	148	jnz 1b
	149
	150	/* Enable the boot page tables */
	151	leal pgtable(%ebx), %eax
	152	movl %eax, %cr3
	153
	154	/* Enable Long mode in EFER (Extended Feature Enable Register) */
	155	movl $MSR_EFER, %ecx
	156	rdmsr
	157	btsl $_EFER_LME, %eax
	158	wrmsr
	159
	160	/* Setup for the jump to 64bit mode
	161	*
	162	* When the jump is performend we will be in long mode but
	163	* in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
	164	* (and in turn EFER.LMA = 1). To jump into 64bit mode we use
	165	* the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	166	* We place all of the values on our mini stack so lret can
	167	* used to perform that far jump.
	168	*/
	169	pushl $__KERNEL_CS
	170	leal startup_64(%ebp), %eax
	171	pushl %eax
	172
	173	/* Enter paged protected Mode, activating Long Mode */
e83e31f4	174	movl $(X86_CR0_PG \| X86_CR0_PE), %eax /* Enable Paging and Protected mode */
1ab60e0f VG	175	movl %eax, %cr0
	176
	177	/* Jump from 32bit compatibility mode into 64bit mode. */
	178	lret
	179
a4831e08 VG	180	no_longmode:
	181	/* This isn't an x86-64 CPU so hang */
	182	1:
	183	hlt
	184	jmp 1b
	185
250c2277	186	#include "../../kernel/verify_cpu_64.S"
a4831e08	187
1ab60e0f VG	188	/* Be careful here startup_64 needs to be at a predictable
	189	* address so I can export it in an ELF header. Bootloaders
	190	* should look at the ELF header to find this address, as
	191	* it may change in the future.
	192	*/
	193	.code64
a4831e08	194	.org 0x200
1ab60e0f VG	195	ENTRY(startup_64)
	196	/* We come here either from startup_32 or directly from a
	197	* 64bit bootloader. If we come here from a bootloader we depend on
	198	* an identity mapped page table being provied that maps our
	199	* entire text+data+bss and hopefully all of memory.
	200	*/
	201
	202	/* Setup data segments. */
	203	xorl %eax, %eax
	204	movl %eax, %ds
	205	movl %eax, %es
	206	movl %eax, %ss
08da5a2c ZA	207	movl %eax, %fs
	208	movl %eax, %gs
	209	lldt %ax
	210	movl $0x20, %eax
	211	ltr %ax
1ab60e0f VG	212
	213	/* Compute the decompressed kernel start address. It is where
	214	* we were loaded at aligned to a 2M boundary. %rbp contains the
	215	* decompressed kernel start address.
	216	*
	217	* If it is a relocatable kernel then decompress and run the kernel
	218	* from load address aligned to 2MB addr, otherwise decompress and
	219	* run the kernel from CONFIG_PHYSICAL_START
	220	*/
	221
	222	/* Start with the delta to where the kernel will run at. */
	223	#ifdef CONFIG_RELOCATABLE
	224	leaq startup_32(%rip) /* - $startup_32 */, %rbp
31422c51 AK	225	addq $(PMD_PAGE_SIZE - 1), %rbp
31422c51 AK	226	andq $PMD_PAGE_MASK, %rbp
1ab60e0f VG	227	movq %rbp, %rbx
	228	#else
	229	movq $CONFIG_PHYSICAL_START, %rbp
	230	movq %rbp, %rbx
	231	#endif
	232
	233	/* Replace the compressed data size with the uncompressed size */
	234	movl input_len(%rip), %eax
	235	subq %rax, %rbx
	236	movl output_len(%rip), %eax
	237	addq %rax, %rbx
	238	/* Add 8 bytes for every 32K input block */
	239	shrq $12, %rax
	240	addq %rax, %rbx
	241	/* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
	242	addq $(32768 + 18 + 4095), %rbx
	243	andq $~4095, %rbx
	244
	245	/* Copy the compressed kernel to the end of our buffer
	246	* where decompression in place becomes safe.
	247	*/
4a9f54cf YL	248	leaq _end_before_pgt(%rip), %r8
	249	leaq _end_before_pgt(%rbx), %r9
	250	movq $_end_before_pgt /* - $startup_32 */, %rcx
1ab60e0f VG	251	1: subq $8, %r8
	252	subq $8, %r9
	253	movq 0(%r8), %rax
	254	movq %rax, 0(%r9)
	255	subq $8, %rcx
	256	jnz 1b
	257
	258	/*
	259	* Jump to the relocated address.
	260	*/
	261	leaq relocated(%rbx), %rax
	262	jmp *%rax
	263
	264	.section ".text"
	265	relocated:
	266
1da177e4 LT	267	/*
	268	* Clear BSS
	269	*/
1ab60e0f VG	270	xorq %rax, %rax
1ab60e0f VG	271	leaq _edata(%rbx), %rdi
4a9f54cf	272	leaq _end_before_pgt(%rbx), %rcx
1ab60e0f	273	subq %rdi, %rcx
1da177e4 LT	274	cld
	275	rep
	276	stosb
1ab60e0f VG	277
1ab60e0f VG	278	/* Setup the stack */
7c539764	279	leaq boot_stack_end(%rip), %rsp
1ab60e0f VG	280
	281	/* zero EFLAGS after setting rsp */
	282	pushq $0
	283	popfq
	284
1da177e4 LT	285	/*
	286	* Do the decompression, and jump to the new kernel..
	287	*/
1ab60e0f VG	288	pushq %rsi # Save the real mode argument
1ab60e0f VG	289	movq %rsi, %rdi # real mode address
7c539764	290	leaq boot_heap(%rip), %rsi # malloc area for uncompression
1ab60e0f VG	291	leaq input_data(%rip), %rdx # input_data
	292	movl input_len(%rip), %eax
	293	movq %rax, %rcx # input_len
	294	movq %rbp, %r8 # output
	295	call decompress_kernel
	296	popq %rsi
1da177e4	297
1da177e4 LT	298
1da177e4 LT	299	/*
1ab60e0f	300	* Jump to the decompressed kernel.
1da177e4	301	*/
1ab60e0f	302	jmp *%rbp
1da177e4	303
1ab60e0f VG	304	.data
	305	gdt:
	306	.word gdt_end - gdt
	307	.long gdt
	308	.word 0
	309	.quad 0x0000000000000000 /* NULL descriptor */
	310	.quad 0x00af9a000000ffff /* __KERNEL_CS */
	311	.quad 0x00cf92000000ffff /* __KERNEL_DS */
08da5a2c ZA	312	.quad 0x0080890000000000 /* TS descriptor */
08da5a2c ZA	313	.quad 0x0000000000000000 /* TS continued */
1ab60e0f	314	gdt_end:
7c539764 AH	315
	316	.bss
	317	/* Stack and heap for uncompression */
	318	.balign 4
	319	boot_heap:
	320	.fill BOOT_HEAP_SIZE, 1, 0
	321	boot_stack:
	322	.fill BOOT_STACK_SIZE, 1, 0
	323	boot_stack_end: