[linux-2.6-block.git] / arch / arm / kernel / vmlinux.lds.S

/* ld script to make ARM Linux kernel
 * taken from the i386 version by Russell King
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
 */

#include <asm-generic/vmlinux.lds.h>
#include <linux/config.h>
#include <asm/thread_info.h>
	
OUTPUT_ARCH(arm)
ENTRY(stext)
#ifndef __ARMEB__
jiffies = jiffies_64;
#else
jiffies = jiffies_64 + 4;
#endif
SECTIONS
{
	. = TEXTADDR;
	.init : {			/* Init code and data		*/
		_stext = .;
			_sinittext = .;
			*(.init.text)
			_einittext = .;
		__proc_info_begin = .;
			*(.proc.info.init)
		__proc_info_end = .;
		__arch_info_begin = .;
			*(.arch.info.init)
		__arch_info_end = .;
		__tagtable_begin = .;
			*(.taglist.init)
		__tagtable_end = .;
		. = ALIGN(16);
		__setup_start = .;
			*(.init.setup)
		__setup_end = .;
		__early_begin = .;
			*(.early_param.init)
		__early_end = .;
		__initcall_start = .;
			*(.initcall1.init)
			*(.initcall2.init)
			*(.initcall3.init)
			*(.initcall4.init)
			*(.initcall5.init)
			*(.initcall6.init)
			*(.initcall7.init)
		__initcall_end = .;
		__con_initcall_start = .;
			*(.con_initcall.init)
		__con_initcall_end = .;
		__security_initcall_start = .;
			*(.security_initcall.init)
		__security_initcall_end = .;
		. = ALIGN(32);
		__initramfs_start = .;
			usr/built-in.o(.init.ramfs)
		__initramfs_end = .;
		. = ALIGN(64);
		__per_cpu_start = .;
			*(.data.percpu)
		__per_cpu_end = .;
#ifndef CONFIG_XIP_KERNEL
		__init_begin = _stext;
		*(.init.data)
		. = ALIGN(4096);
		__init_end = .;
#endif
	}

	/DISCARD/ : {			/* Exit code and data		*/
		*(.exit.text)
		*(.exit.data)
		*(.exitcall.exit)
	}

	.text : {			/* Real text segment		*/
		_text = .;		/* Text and read-only data	*/
			*(.text)
			SCHED_TEXT
			LOCK_TEXT
			*(.fixup)
			*(.gnu.warning)
			*(.rodata)
			*(.rodata.*)
			*(.glue_7)
			*(.glue_7t)
		*(.got)			/* Global offset table		*/
	}

	. = ALIGN(16);
	__ex_table : {			/* Exception table		*/
		__start___ex_table = .;
			*(__ex_table)
		__stop___ex_table = .;
	}

	RODATA

	_etext = .;			/* End of text and rodata section */

#ifdef CONFIG_XIP_KERNEL
	__data_loc = ALIGN(4);		/* location in binary */
	. = DATAADDR;
#else
	. = ALIGN(THREAD_SIZE);
	__data_loc = .;
#endif

	.data : AT(__data_loc) {
		__data_start = .;	/* address in memory */

		/*
		 * first, the init task union, aligned
		 * to an 8192 byte boundary.
		 */
		*(.init.task)

#ifdef CONFIG_XIP_KERNEL
		. = ALIGN(4096);
		__init_begin = .;
		*(.init.data)
		. = ALIGN(4096);
		__init_end = .;
#endif

		. = ALIGN(4096);
		__nosave_begin = .;
		*(.data.nosave)
		. = ALIGN(4096);
		__nosave_end = .;

		/*
		 * then the cacheline aligned data
		 */
		. = ALIGN(32);
		*(.data.cacheline_aligned)

		/*
		 * and the usual data section
		 */
		*(.data)
		CONSTRUCTORS

		_edata = .;
	}

	.bss : {
		__bss_start = .;	/* BSS				*/
		*(.bss)
		*(COMMON)
		_end = .;
	}
					/* Stabs debugging sections.	*/
	.stab 0 : { *(.stab) }
	.stabstr 0 : { *(.stabstr) }
	.stab.excl 0 : { *(.stab.excl) }
	.stab.exclstr 0 : { *(.stab.exclstr) }
	.stab.index 0 : { *(.stab.index) }
	.stab.indexstr 0 : { *(.stab.indexstr) }
	.comment 0 : { *(.comment) }
}

/* those must never be empty */
ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
Commit	Line	Data
1da177e4 LT	1	/* ld script to make ARM Linux kernel
	2	* taken from the i386 version by Russell King
	3	* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
	4	*/
	5
	6	#include <asm-generic/vmlinux.lds.h>
	7	#include <linux/config.h>
4f7a1812	8	#include <asm/thread_info.h>
1da177e4 LT	9
	10	OUTPUT_ARCH(arm)
	11	ENTRY(stext)
	12	#ifndef __ARMEB__
	13	jiffies = jiffies_64;
	14	#else
	15	jiffies = jiffies_64 + 4;
	16	#endif
	17	SECTIONS
	18	{
	19	. = TEXTADDR;
	20	.init : { /* Init code and data */
	21	_stext = .;
	22	_sinittext = .;
	23	*(.init.text)
	24	_einittext = .;
	25	__proc_info_begin = .;
02b7dd12	26	*(.proc.info.init)
1da177e4 LT	27	__proc_info_end = .;
1da177e4 LT	28	__arch_info_begin = .;
9d0fd1eb	29	*(.arch.info.init)
1da177e4 LT	30	__arch_info_end = .;
1da177e4 LT	31	__tagtable_begin = .;
9506057f	32	*(.taglist.init)
1da177e4 LT	33	__tagtable_end = .;
	34	. = ALIGN(16);
	35	__setup_start = .;
	36	*(.init.setup)
	37	__setup_end = .;
	38	__early_begin = .;
bfe6815e	39	*(.early_param.init)
1da177e4 LT	40	__early_end = .;
	41	__initcall_start = .;
	42	*(.initcall1.init)
	43	*(.initcall2.init)
	44	*(.initcall3.init)
	45	*(.initcall4.init)
	46	*(.initcall5.init)
	47	*(.initcall6.init)
	48	*(.initcall7.init)
	49	__initcall_end = .;
	50	__con_initcall_start = .;
	51	*(.con_initcall.init)
	52	__con_initcall_end = .;
	53	__security_initcall_start = .;
	54	*(.security_initcall.init)
	55	__security_initcall_end = .;
	56	. = ALIGN(32);
	57	__initramfs_start = .;
	58	usr/built-in.o(.init.ramfs)
	59	__initramfs_end = .;
	60	. = ALIGN(64);
	61	__per_cpu_start = .;
	62	*(.data.percpu)
	63	__per_cpu_end = .;
	64	#ifndef CONFIG_XIP_KERNEL
	65	__init_begin = _stext;
	66	*(.init.data)
	67	. = ALIGN(4096);
	68	__init_end = .;
	69	#endif
	70	}
	71
	72	/DISCARD/ : { /* Exit code and data */
	73	*(.exit.text)
	74	*(.exit.data)
	75	*(.exitcall.exit)
	76	}
	77
	78	.text : { /* Real text segment */
	79	_text = .; /* Text and read-only data */
	80	*(.text)
	81	SCHED_TEXT
	82	LOCK_TEXT
	83	*(.fixup)
	84	*(.gnu.warning)
	85	*(.rodata)
	86	(.rodata.)
	87	*(.glue_7)
	88	*(.glue_7t)
	89	(.got) / Global offset table */
	90	}
	91
	92	. = ALIGN(16);
	93	__ex_table : { /* Exception table */
	94	__start___ex_table = .;
	95	*(__ex_table)
	96	__stop___ex_table = .;
	97	}
	98
	99	RODATA
	100
	101	_etext = .; /* End of text and rodata section */
	102
	103	#ifdef CONFIG_XIP_KERNEL
104	__data_loc = ALIGN(4); /* location in binary */
105	. = DATAADDR;
106	#else
4f7a1812	107	. = ALIGN(THREAD_SIZE);
1da177e4 LT	108	__data_loc = .;
	109	#endif
	110
	111	.data : AT(__data_loc) {
	112	__data_start = .; /* address in memory */
	113
	114	/*
	115	* first, the init task union, aligned
	116	* to an 8192 byte boundary.
	117	*/
	118	*(.init.task)
	119
	120	#ifdef CONFIG_XIP_KERNEL
	121	. = ALIGN(4096);
	122	__init_begin = .;
	123	*(.init.data)
	124	. = ALIGN(4096);
	125	__init_end = .;
	126	#endif
	127
	128	. = ALIGN(4096);
	129	__nosave_begin = .;
	130	*(.data.nosave)
	131	. = ALIGN(4096);
	132	__nosave_end = .;
	133
	134	/*
	135	* then the cacheline aligned data
	136	*/
	137	. = ALIGN(32);
	138	*(.data.cacheline_aligned)
	139
	140	/*
	141	* and the usual data section
	142	*/
	143	*(.data)
	144	CONSTRUCTORS
	145
	146	_edata = .;
	147	}
	148
	149	.bss : {
	150	__bss_start = .; /* BSS */
	151	*(.bss)
	152	*(COMMON)
	153	_end = .;
	154	}
	155	/* Stabs debugging sections. */
	156	.stab 0 : { *(.stab) }
	157	.stabstr 0 : { *(.stabstr) }
	158	.stab.excl 0 : { *(.stab.excl) }
	159	.stab.exclstr 0 : { *(.stab.exclstr) }
	160	.stab.index 0 : { *(.stab.index) }
	161	.stab.indexstr 0 : { *(.stab.indexstr) }
	162	.comment 0 : { *(.comment) }
	163	}
	164
	165	/* those must never be empty */
	166	ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
	167	ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")