[linux-block.git] / arch / arm / kernel / entry-common.S

/*
 *  linux/arch/arm/kernel/entry-common.S
 *
 *  Copyright (C) 2000 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */

#include <asm/unistd.h>
#include <asm/ftrace.h>
#include <mach/entry-macro.S>

#include "entry-header.S"


	.align	5
/*
 * This is the fast syscall return path.  We do as little as
 * possible here, and this includes saving r0 back into the SVC
 * stack.
 */
ret_fast_syscall:
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	fast_work_pending

	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	@ fast_restore_user_regs
	ldr	r1, [sp, #S_OFF + S_PSR]	@ get calling cpsr
	ldr	lr, [sp, #S_OFF + S_PC]!	@ get pc
	msr	spsr_cxsf, r1			@ save in spsr_svc
	ldmdb	sp, {r1 - lr}^			@ get calling r1 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE - S_PC
	movs	pc, lr				@ return & move spsr_svc into cpsr

/*
 * Ok, we need to do extra processing, enter the slow path.
 */
fast_work_pending:
	str	r0, [sp, #S_R0+S_OFF]!		@ returned r0
work_pending:
	tst	r1, #_TIF_NEED_RESCHED
	bne	work_resched
	tst	r1, #_TIF_SIGPENDING
	beq	no_work_pending
	mov	r0, sp				@ 'regs'
	mov	r2, why				@ 'syscall'
	bl	do_notify_resume
	b	ret_slow_syscall		@ Check work again

work_resched:
	bl	schedule
/*
 * "slow" syscall return path.  "why" tells us if this was a real syscall.
 */
ENTRY(ret_to_user)
ret_slow_syscall:
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	work_pending
no_work_pending:
	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	@ slow_restore_user_regs
	ldr	r1, [sp, #S_PSR]		@ get calling cpsr
	ldr	lr, [sp, #S_PC]!		@ get pc
	msr	spsr_cxsf, r1			@ save in spsr_svc
	ldmdb	sp, {r0 - lr}^			@ get calling r0 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE - S_PC
	movs	pc, lr				@ return & move spsr_svc into cpsr
ENDPROC(ret_to_user)

/*
 * This is how we return from a fork.
 */
ENTRY(ret_from_fork)
	bl	schedule_tail
	get_thread_info tsk
	ldr	r1, [tsk, #TI_FLAGS]		@ check for syscall tracing
	mov	why, #1
	tst	r1, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	beq	ret_slow_syscall
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall
ENDPROC(ret_from_fork)

	.equ NR_syscalls,0
#define CALL(x) .equ NR_syscalls,NR_syscalls+1
#include "calls.S"
#undef CALL
#define CALL(x) .long x

#ifdef CONFIG_FUNCTION_TRACER
#ifdef CONFIG_DYNAMIC_FTRACE
ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl mcount_call
mcount_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

ENTRY(ftrace_caller)
	stmdb sp!, {r0-r3, lr}
	ldr r1, [fp, #-4]
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl ftrace_call
ftrace_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

#else

ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	ldr r0, =ftrace_trace_function
	ldr r2, [r0]
	adr r0, ftrace_stub
	cmp r0, r2
	bne trace
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

trace:
	ldr r1, [fp, #-4]			@ lr of instrumented routine
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE
	mov lr, pc
	mov pc, r2
	mov lr, r1				@ restore lr
	ldmia sp!, {r0-r3, pc}

#endif /* CONFIG_DYNAMIC_FTRACE */

	.globl ftrace_stub
ftrace_stub:
	mov pc, lr

#endif /* CONFIG_FUNCTION_TRACER */

/*=============================================================================
 * SWI handler
 *-----------------------------------------------------------------------------
 */

	/* If we're optimising for StrongARM the resulting code won't 
	   run on an ARM7 and we can save a couple of instructions.  
								--pb */
#ifdef CONFIG_CPU_ARM710
#define A710(code...) code
.Larm710bug:
	ldmia	sp, {r0 - lr}^			@ Get calling r0 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE
	subs	pc, lr, #4
#else
#define A710(code...)
#endif

	.align	5
ENTRY(vector_swi)
	sub	sp, sp, #S_FRAME_SIZE
	stmia	sp, {r0 - r12}			@ Calling r0 - r12
	add	r8, sp, #S_PC
	stmdb	r8, {sp, lr}^			@ Calling sp, lr
	mrs	r8, spsr			@ called from non-FIQ mode, so ok.
	str	lr, [sp, #S_PC]			@ Save calling PC
	str	r8, [sp, #S_PSR]		@ Save CPSR
	str	r0, [sp, #S_OLD_R0]		@ Save OLD_R0
	zero_fp

	/*
	 * Get the system call number.
	 */

#if defined(CONFIG_OABI_COMPAT)

	/*
	 * If we have CONFIG_OABI_COMPAT then we need to look at the swi
	 * value to determine if it is an EABI or an old ABI call.
	 */
#ifdef CONFIG_ARM_THUMB
	tst	r8, #PSR_T_BIT
	movne	r10, #0				@ no thumb OABI emulation
	ldreq	r10, [lr, #-4]			@ get SWI instruction
#else
	ldr	r10, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, r10, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)
#endif

#elif defined(CONFIG_AEABI)

	/*
	 * Pure EABI user space always put syscall number into scno (r7).
	 */
  A710(	ldr	ip, [lr, #-4]			@ get SWI instruction	)
  A710(	and	ip, ip, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#elif defined(CONFIG_ARM_THUMB)

	/* Legacy ABI only, possibly thumb mode. */
	tst	r8, #PSR_T_BIT			@ this is SPSR from save_user_regs
	addne	scno, r7, #__NR_SYSCALL_BASE	@ put OS number in
	ldreq	scno, [lr, #-4]

#else

	/* Legacy ABI only. */
	ldr	scno, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, scno, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#endif

#ifdef CONFIG_ALIGNMENT_TRAP
	ldr	ip, __cr_alignment
	ldr	ip, [ip]
	mcr	p15, 0, ip, c1, c0		@ update control register
#endif
	enable_irq

	get_thread_info tsk
	adr	tbl, sys_call_table		@ load syscall table pointer
	ldr	ip, [tsk, #TI_FLAGS]		@ check for syscall tracing

#if defined(CONFIG_OABI_COMPAT)
	/*
	 * If the swi argument is zero, this is an EABI call and we do nothing.
	 *
	 * If this is an old ABI call, get the syscall number into scno and
	 * get the old ABI syscall table address.
	 */
	bics	r10, r10, #0xff000000
	eorne	scno, r10, #__NR_OABI_SYSCALL_BASE
	ldrne	tbl, =sys_oabi_call_table
#elif !defined(CONFIG_AEABI)
	bic	scno, scno, #0xff000000		@ mask off SWI op-code
	eor	scno, scno, #__NR_SYSCALL_BASE	@ check OS number
#endif

	stmdb	sp!, {r4, r5}			@ push fifth and sixth args
	tst	ip, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	bne	__sys_trace

	cmp	scno, #NR_syscalls		@ check upper syscall limit
	adr	lr, ret_fast_syscall		@ return address
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine

	add	r1, sp, #S_OFF
2:	mov	why, #0				@ no longer a real syscall
	cmp	scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
	eor	r0, scno, #__NR_SYSCALL_BASE	@ put OS number back
	bcs	arm_syscall	
	b	sys_ni_syscall			@ not private func
ENDPROC(vector_swi)

	/*
	 * This is the really slow path.  We're going to be doing
	 * context switches, and waiting for our parent to respond.
	 */
__sys_trace:
	mov	r2, scno
	add	r1, sp, #S_OFF
	mov	r0, #0				@ trace entry [IP = 0]
	bl	syscall_trace

	adr	lr, __sys_trace_return		@ return address
	mov	scno, r0			@ syscall number (possibly new)
	add	r1, sp, #S_R0 + S_OFF		@ pointer to regs
	cmp	scno, #NR_syscalls		@ check upper syscall limit
	ldmccia	r1, {r0 - r3}			@ have to reload r0 - r3
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine
	b	2b

__sys_trace_return:
	str	r0, [sp, #S_R0 + S_OFF]!	@ save returned r0
	mov	r2, scno
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall

	.align	5
#ifdef CONFIG_ALIGNMENT_TRAP
	.type	__cr_alignment, #object
__cr_alignment:
	.word	cr_alignment
#endif
	.ltorg

/*
 * This is the syscall table declaration for native ABI syscalls.
 * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 */
#define ABI(native, compat) native
#ifdef CONFIG_AEABI
#define OBSOLETE(syscall) sys_ni_syscall
#else
#define OBSOLETE(syscall) syscall
#endif

	.type	sys_call_table, #object
ENTRY(sys_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

/*============================================================================
 * Special system call wrappers
 */
@ r0 = syscall number
@ r8 = syscall table
sys_syscall:
		bic	scno, r0, #__NR_OABI_SYSCALL_BASE
		cmp	scno, #__NR_syscall - __NR_SYSCALL_BASE
		cmpne	scno, #NR_syscalls	@ check range
		stmloia	sp, {r5, r6}		@ shuffle args
		movlo	r0, r1
		movlo	r1, r2
		movlo	r2, r3
		movlo	r3, r4
		ldrlo	pc, [tbl, scno, lsl #2]
		b	sys_ni_syscall
ENDPROC(sys_syscall)

sys_fork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_fork
ENDPROC(sys_fork_wrapper)

sys_vfork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_vfork
ENDPROC(sys_vfork_wrapper)

sys_execve_wrapper:
		add	r3, sp, #S_OFF
		b	sys_execve
ENDPROC(sys_execve_wrapper)

sys_clone_wrapper:
		add	ip, sp, #S_OFF
		str	ip, [sp, #4]
		b	sys_clone
ENDPROC(sys_clone_wrapper)

sys_sigsuspend_wrapper:
		add	r3, sp, #S_OFF
		b	sys_sigsuspend
ENDPROC(sys_sigsuspend_wrapper)

sys_rt_sigsuspend_wrapper:
		add	r2, sp, #S_OFF
		b	sys_rt_sigsuspend
ENDPROC(sys_rt_sigsuspend_wrapper)

sys_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_sigreturn
ENDPROC(sys_sigreturn_wrapper)

sys_rt_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_rt_sigreturn
ENDPROC(sys_rt_sigreturn_wrapper)

sys_sigaltstack_wrapper:
		ldr	r2, [sp, #S_OFF + S_SP]
		b	do_sigaltstack
ENDPROC(sys_sigaltstack_wrapper)

sys_statfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_statfs64
ENDPROC(sys_statfs64_wrapper)

sys_fstatfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_fstatfs64
ENDPROC(sys_fstatfs64_wrapper)

/*
 * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 * offset, we return EINVAL.
 */
sys_mmap2:
#if PAGE_SHIFT > 12
		tst	r5, #PGOFF_MASK
		moveq	r5, r5, lsr #PAGE_SHIFT - 12
		streq	r5, [sp, #4]
		beq	do_mmap2
		mov	r0, #-EINVAL
		mov	pc, lr
#else
		str	r5, [sp, #4]
		b	do_mmap2
#endif
ENDPROC(sys_mmap2)

ENTRY(pabort_ifar)
		mrc	p15, 0, r0, cr6, cr0, 2
ENTRY(pabort_noifar)
		mov	pc, lr
ENDPROC(pabort_ifar)
ENDPROC(pabort_noifar)

#ifdef CONFIG_OABI_COMPAT

/*
 * These are syscalls with argument register differences
 */

sys_oabi_pread64:
		stmia	sp, {r3, r4}
		b	sys_pread64
ENDPROC(sys_oabi_pread64)

sys_oabi_pwrite64:
		stmia	sp, {r3, r4}
		b	sys_pwrite64
ENDPROC(sys_oabi_pwrite64)

sys_oabi_truncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_truncate64
ENDPROC(sys_oabi_truncate64)

sys_oabi_ftruncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_ftruncate64
ENDPROC(sys_oabi_ftruncate64)

sys_oabi_readahead:
		str	r3, [sp]
		mov	r3, r2
		mov	r2, r1
		b	sys_readahead
ENDPROC(sys_oabi_readahead)

/*
 * Let's declare a second syscall table for old ABI binaries
 * using the compatibility syscall entries.
 */
#define ABI(native, compat) compat
#define OBSOLETE(syscall) syscall

	.type	sys_oabi_call_table, #object
ENTRY(sys_oabi_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

#endif
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/kernel/entry-common.S
	3	*
	4	* Copyright (C) 2000 Russell King
	5	*
	6	* This program is free software; you can redistribute it and/or modify
	7	* it under the terms of the GNU General Public License version 2 as
	8	* published by the Free Software Foundation.
	9	*/
1da177e4	10
1da177e4	11	#include <asm/unistd.h>
395a59d0	12	#include <asm/ftrace.h>
a09e64fb	13	#include <mach/entry-macro.S>
1da177e4 LT	14
	15	#include "entry-header.S"
	16
1da177e4 LT	17
	18	.align 5
	19	/*
	20	* This is the fast syscall return path. We do as little as
	21	* possible here, and this includes saving r0 back into the SVC
	22	* stack.
	23	*/
	24	ret_fast_syscall:
1ec42c0c	25	disable_irq @ disable interrupts
1da177e4 LT	26	ldr r1, [tsk, #TI_FLAGS]
	27	tst r1, #_TIF_WORK_MASK
	28	bne fast_work_pending
f4dc9a4c	29
f80dff9d DW	30	/* perform architecture specific actions before user return */
	31	arch_ret_to_user r1, lr
	32
f4dc9a4c RK	33	@ fast_restore_user_regs
	34	ldr r1, [sp, #S_OFF + S_PSR] @ get calling cpsr
	35	ldr lr, [sp, #S_OFF + S_PC]! @ get pc
	36	msr spsr_cxsf, r1 @ save in spsr_svc
	37	ldmdb sp, {r1 - lr}^ @ get calling r1 - lr
	38	mov r0, r0
	39	add sp, sp, #S_FRAME_SIZE - S_PC
	40	movs pc, lr @ return & move spsr_svc into cpsr
1da177e4 LT	41
	42	/*
	43	* Ok, we need to do extra processing, enter the slow path.
	44	*/
	45	fast_work_pending:
	46	str r0, [sp, #S_R0+S_OFF]! @ returned r0
	47	work_pending:
	48	tst r1, #_TIF_NEED_RESCHED
	49	bne work_resched
a583f1b5	50	tst r1, #_TIF_SIGPENDING
1da177e4 LT	51	beq no_work_pending
	52	mov r0, sp @ 'regs'
	53	mov r2, why @ 'syscall'
	54	bl do_notify_resume
a6c61e9d	55	b ret_slow_syscall @ Check work again
1da177e4 LT	56
	57	work_resched:
	58	bl schedule
	59	/*
	60	* "slow" syscall return path. "why" tells us if this was a real syscall.
	61	*/
	62	ENTRY(ret_to_user)
	63	ret_slow_syscall:
1ec42c0c	64	disable_irq @ disable interrupts
1da177e4 LT	65	ldr r1, [tsk, #TI_FLAGS]
	66	tst r1, #_TIF_WORK_MASK
	67	bne work_pending
	68	no_work_pending:
f80dff9d DW	69	/* perform architecture specific actions before user return */
	70	arch_ret_to_user r1, lr
	71
f4dc9a4c RK	72	@ slow_restore_user_regs
	73	ldr r1, [sp, #S_PSR] @ get calling cpsr
	74	ldr lr, [sp, #S_PC]! @ get pc
	75	msr spsr_cxsf, r1 @ save in spsr_svc
7b544c99	76	ldmdb sp, {r0 - lr}^ @ get calling r0 - lr
f4dc9a4c RK	77	mov r0, r0
	78	add sp, sp, #S_FRAME_SIZE - S_PC
	79	movs pc, lr @ return & move spsr_svc into cpsr
93ed3970	80	ENDPROC(ret_to_user)
1da177e4 LT	81
	82	/*
	83	* This is how we return from a fork.
	84	*/
	85	ENTRY(ret_from_fork)
	86	bl schedule_tail
	87	get_thread_info tsk
	88	ldr r1, [tsk, #TI_FLAGS] @ check for syscall tracing
	89	mov why, #1
	90	tst r1, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	91	beq ret_slow_syscall
	92	mov r1, sp
	93	mov r0, #1 @ trace exit [IP = 1]
	94	bl syscall_trace
	95	b ret_slow_syscall
93ed3970	96	ENDPROC(ret_from_fork)
1da177e4	97
fa1b4f91 AV	98	.equ NR_syscalls,0
fa1b4f91 AV	99	#define CALL(x) .equ NR_syscalls,NR_syscalls+1
1da177e4	100	#include "calls.S"
fa1b4f91 AV	101	#undef CALL
fa1b4f91 AV	102	#define CALL(x) .long x
1da177e4	103
606576ce	104	#ifdef CONFIG_FUNCTION_TRACER
014c257c AS	105	#ifdef CONFIG_DYNAMIC_FTRACE
	106	ENTRY(mcount)
	107	stmdb sp!, {r0-r3, lr}
	108	mov r0, lr
395a59d0	109	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	110
	111	.globl mcount_call
	112	mcount_call:
	113	bl ftrace_stub
d4cc510c	114	ldr lr, [fp, #-4] @ restore lr
014c257c AS	115	ldmia sp!, {r0-r3, pc}
	116
	117	ENTRY(ftrace_caller)
	118	stmdb sp!, {r0-r3, lr}
	119	ldr r1, [fp, #-4]
	120	mov r0, lr
395a59d0	121	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	122
	123	.globl ftrace_call
	124	ftrace_call:
	125	bl ftrace_stub
d4cc510c	126	ldr lr, [fp, #-4] @ restore lr
014c257c AS	127	ldmia sp!, {r0-r3, pc}
	128
	129	#else
	130
	131	ENTRY(mcount)
	132	stmdb sp!, {r0-r3, lr}
	133	ldr r0, =ftrace_trace_function
	134	ldr r2, [r0]
	135	adr r0, ftrace_stub
	136	cmp r0, r2
	137	bne trace
d4cc510c	138	ldr lr, [fp, #-4] @ restore lr
014c257c AS	139	ldmia sp!, {r0-r3, pc}
	140
	141	trace:
b3c960b2	142	ldr r1, [fp, #-4] @ lr of instrumented routine
014c257c	143	mov r0, lr
395a59d0	144	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	145	mov lr, pc
014c257c AS	146	mov pc, r2
d4cc510c	147	mov lr, r1 @ restore lr
014c257c AS	148	ldmia sp!, {r0-r3, pc}
	149
	150	#endif /* CONFIG_DYNAMIC_FTRACE */
	151
	152	.globl ftrace_stub
	153	ftrace_stub:
	154	mov pc, lr
	155
606576ce	156	#endif /* CONFIG_FUNCTION_TRACER */
014c257c	157
1da177e4 LT	158	/*=============================================================================
	159	* SWI handler
	160	*-----------------------------------------------------------------------------
	161	*/
	162
	163	/* If we're optimising for StrongARM the resulting code won't
	164	run on an ARM7 and we can save a couple of instructions.
	165	--pb */
	166	#ifdef CONFIG_CPU_ARM710
3f2829a3 NP	167	#define A710(code...) code
3f2829a3 NP	168	.Larm710bug:
1da177e4 LT	169	ldmia sp, {r0 - lr}^ @ Get calling r0 - lr
1da177e4 LT	170	mov r0, r0
1da177e4	171	add sp, sp, #S_FRAME_SIZE
60ac133a	172	subs pc, lr, #4
1da177e4	173	#else
3f2829a3	174	#define A710(code...)
1da177e4 LT	175	#endif
	176
	177	.align 5
	178	ENTRY(vector_swi)
f4dc9a4c RK	179	sub sp, sp, #S_FRAME_SIZE
	180	stmia sp, {r0 - r12} @ Calling r0 - r12
	181	add r8, sp, #S_PC
	182	stmdb r8, {sp, lr}^ @ Calling sp, lr
	183	mrs r8, spsr @ called from non-FIQ mode, so ok.
	184	str lr, [sp, #S_PC] @ Save calling PC
	185	str r8, [sp, #S_PSR] @ Save CPSR
	186	str r0, [sp, #S_OLD_R0] @ Save OLD_R0
1da177e4	187	zero_fp
e0f9f4a6 RK	188
	189	/*
	190	* Get the system call number.
	191	*/
3f2829a3	192
dd35afc2	193	#if defined(CONFIG_OABI_COMPAT)
3f2829a3	194
dd35afc2 NP	195	/*
	196	* If we have CONFIG_OABI_COMPAT then we need to look at the swi
	197	* value to determine if it is an EABI or an old ABI call.
	198	*/
	199	#ifdef CONFIG_ARM_THUMB
	200	tst r8, #PSR_T_BIT
	201	movne r10, #0 @ no thumb OABI emulation
	202	ldreq r10, [lr, #-4] @ get SWI instruction
	203	#else
	204	ldr r10, [lr, #-4] @ get SWI instruction
	205	A710( and ip, r10, #0x0f000000 @ check for SWI )
	206	A710( teq ip, #0x0f000000 )
	207	A710( bne .Larm710bug )
	208	#endif
	209
	210	#elif defined(CONFIG_AEABI)
	211
	212	/*
	213	* Pure EABI user space always put syscall number into scno (r7).
	214	*/
3f2829a3 NP	215	A710( ldr ip, [lr, #-4] @ get SWI instruction )
	216	A710( and ip, ip, #0x0f000000 @ check for SWI )
	217	A710( teq ip, #0x0f000000 )
	218	A710( bne .Larm710bug )
dd35afc2	219
3f2829a3	220	#elif defined(CONFIG_ARM_THUMB)
dd35afc2 NP	221
dd35afc2 NP	222	/* Legacy ABI only, possibly thumb mode. */
e0f9f4a6 RK	223	tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs
	224	addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in
	225	ldreq scno, [lr, #-4]
dd35afc2	226
e0f9f4a6	227	#else
dd35afc2 NP	228
dd35afc2 NP	229	/* Legacy ABI only. */
e0f9f4a6	230	ldr scno, [lr, #-4] @ get SWI instruction
3f2829a3 NP	231	A710( and ip, scno, #0x0f000000 @ check for SWI )
	232	A710( teq ip, #0x0f000000 )
	233	A710( bne .Larm710bug )
dd35afc2	234
e0f9f4a6	235	#endif
1da177e4 LT	236
	237	#ifdef CONFIG_ALIGNMENT_TRAP
	238	ldr ip, __cr_alignment
	239	ldr ip, [ip]
	240	mcr p15, 0, ip, c1, c0 @ update control register
	241	#endif
1ec42c0c	242	enable_irq
1da177e4	243
1da177e4	244	get_thread_info tsk
dd35afc2	245	adr tbl, sys_call_table @ load syscall table pointer
1da177e4	246	ldr ip, [tsk, #TI_FLAGS] @ check for syscall tracing
dd35afc2 NP	247
	248	#if defined(CONFIG_OABI_COMPAT)
	249	/*
	250	* If the swi argument is zero, this is an EABI call and we do nothing.
	251	*
	252	* If this is an old ABI call, get the syscall number into scno and
	253	* get the old ABI syscall table address.
	254	*/
	255	bics r10, r10, #0xff000000
	256	eorne scno, r10, #__NR_OABI_SYSCALL_BASE
	257	ldrne tbl, =sys_oabi_call_table
	258	#elif !defined(CONFIG_AEABI)
1da177e4	259	bic scno, scno, #0xff000000 @ mask off SWI op-code
e0f9f4a6	260	eor scno, scno, #__NR_SYSCALL_BASE @ check OS number
3f2829a3	261	#endif
dd35afc2	262
3f2829a3	263	stmdb sp!, {r4, r5} @ push fifth and sixth args
1da177e4 LT	264	tst ip, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	265	bne __sys_trace
	266
1da177e4	267	cmp scno, #NR_syscalls @ check upper syscall limit
3f2829a3	268	adr lr, ret_fast_syscall @ return address
1da177e4 LT	269	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	270
	271	add r1, sp, #S_OFF
	272	2: mov why, #0 @ no longer a real syscall
e0f9f4a6 RK	273	cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
e0f9f4a6 RK	274	eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back
1da177e4 LT	275	bcs arm_syscall
1da177e4 LT	276	b sys_ni_syscall @ not private func
93ed3970	277	ENDPROC(vector_swi)
1da177e4 LT	278
	279	/*
	280	* This is the really slow path. We're going to be doing
	281	* context switches, and waiting for our parent to respond.
	282	*/
	283	__sys_trace:
3f471126	284	mov r2, scno
1da177e4 LT	285	add r1, sp, #S_OFF
	286	mov r0, #0 @ trace entry [IP = 0]
	287	bl syscall_trace
	288
	289	adr lr, __sys_trace_return @ return address
3f471126	290	mov scno, r0 @ syscall number (possibly new)
1da177e4 LT	291	add r1, sp, #S_R0 + S_OFF @ pointer to regs
	292	cmp scno, #NR_syscalls @ check upper syscall limit
	293	ldmccia r1, {r0 - r3} @ have to reload r0 - r3
	294	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	295	b 2b
	296
	297	__sys_trace_return:
	298	str r0, [sp, #S_R0 + S_OFF]! @ save returned r0
3f471126	299	mov r2, scno
1da177e4 LT	300	mov r1, sp
	301	mov r0, #1 @ trace exit [IP = 1]
	302	bl syscall_trace
	303	b ret_slow_syscall
	304
	305	.align 5
	306	#ifdef CONFIG_ALIGNMENT_TRAP
	307	.type __cr_alignment, #object
	308	__cr_alignment:
	309	.word cr_alignment
dd35afc2 NP	310	#endif
	311	.ltorg
	312
	313	/*
	314	* This is the syscall table declaration for native ABI syscalls.
	315	* With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
	316	*/
	317	#define ABI(native, compat) native
	318	#ifdef CONFIG_AEABI
	319	#define OBSOLETE(syscall) sys_ni_syscall
	320	#else
	321	#define OBSOLETE(syscall) syscall
1da177e4 LT	322	#endif
	323
	324	.type sys_call_table, #object
	325	ENTRY(sys_call_table)
	326	#include "calls.S"
dd35afc2 NP	327	#undef ABI
dd35afc2 NP	328	#undef OBSOLETE
1da177e4 LT	329
	330	/*============================================================================
	331	* Special system call wrappers
	332	*/
	333	@ r0 = syscall number
567bd980	334	@ r8 = syscall table
1da177e4	335	sys_syscall:
5247593c	336	bic scno, r0, #__NR_OABI_SYSCALL_BASE
1da177e4 LT	337	cmp scno, #__NR_syscall - __NR_SYSCALL_BASE
	338	cmpne scno, #NR_syscalls @ check range
	339	stmloia sp, {r5, r6} @ shuffle args
	340	movlo r0, r1
	341	movlo r1, r2
	342	movlo r2, r3
	343	movlo r3, r4
	344	ldrlo pc, [tbl, scno, lsl #2]
	345	b sys_ni_syscall
93ed3970	346	ENDPROC(sys_syscall)
1da177e4 LT	347
	348	sys_fork_wrapper:
	349	add r0, sp, #S_OFF
	350	b sys_fork
93ed3970	351	ENDPROC(sys_fork_wrapper)
1da177e4 LT	352
	353	sys_vfork_wrapper:
	354	add r0, sp, #S_OFF
	355	b sys_vfork
93ed3970	356	ENDPROC(sys_vfork_wrapper)
1da177e4 LT	357
	358	sys_execve_wrapper:
	359	add r3, sp, #S_OFF
	360	b sys_execve
93ed3970	361	ENDPROC(sys_execve_wrapper)
1da177e4 LT	362
	363	sys_clone_wrapper:
	364	add ip, sp, #S_OFF
	365	str ip, [sp, #4]
	366	b sys_clone
93ed3970	367	ENDPROC(sys_clone_wrapper)
1da177e4 LT	368
	369	sys_sigsuspend_wrapper:
	370	add r3, sp, #S_OFF
	371	b sys_sigsuspend
93ed3970	372	ENDPROC(sys_sigsuspend_wrapper)
1da177e4 LT	373
	374	sys_rt_sigsuspend_wrapper:
	375	add r2, sp, #S_OFF
	376	b sys_rt_sigsuspend
93ed3970	377	ENDPROC(sys_rt_sigsuspend_wrapper)
1da177e4 LT	378
	379	sys_sigreturn_wrapper:
	380	add r0, sp, #S_OFF
	381	b sys_sigreturn
93ed3970	382	ENDPROC(sys_sigreturn_wrapper)
1da177e4 LT	383
	384	sys_rt_sigreturn_wrapper:
	385	add r0, sp, #S_OFF
	386	b sys_rt_sigreturn
93ed3970	387	ENDPROC(sys_rt_sigreturn_wrapper)
1da177e4 LT	388
	389	sys_sigaltstack_wrapper:
	390	ldr r2, [sp, #S_OFF + S_SP]
	391	b do_sigaltstack
93ed3970	392	ENDPROC(sys_sigaltstack_wrapper)
1da177e4	393
713c4815 NP	394	sys_statfs64_wrapper:
	395	teq r1, #88
	396	moveq r1, #84
	397	b sys_statfs64
93ed3970	398	ENDPROC(sys_statfs64_wrapper)
713c4815 NP	399
	400	sys_fstatfs64_wrapper:
	401	teq r1, #88
	402	moveq r1, #84
	403	b sys_fstatfs64
93ed3970	404	ENDPROC(sys_fstatfs64_wrapper)
713c4815	405
1da177e4 LT	406	/*
	407	* Note: off_4k (r5) is always units of 4K. If we can't do the requested
	408	* offset, we return EINVAL.
	409	*/
	410	sys_mmap2:
	411	#if PAGE_SHIFT > 12
	412	tst r5, #PGOFF_MASK
	413	moveq r5, r5, lsr #PAGE_SHIFT - 12
	414	streq r5, [sp, #4]
	415	beq do_mmap2
	416	mov r0, #-EINVAL
7999d8d7	417	mov pc, lr
1da177e4 LT	418	#else
	419	str r5, [sp, #4]
	420	b do_mmap2
	421	#endif
93ed3970	422	ENDPROC(sys_mmap2)
687ad019	423
48d7927b PB	424	ENTRY(pabort_ifar)
	425	mrc p15, 0, r0, cr6, cr0, 2
	426	ENTRY(pabort_noifar)
	427	mov pc, lr
93ed3970 CM	428	ENDPROC(pabort_ifar)
93ed3970 CM	429	ENDPROC(pabort_noifar)
48d7927b	430
687ad019	431	#ifdef CONFIG_OABI_COMPAT
dd35afc2	432
687ad019 NP	433	/*
	434	* These are syscalls with argument register differences
	435	*/
	436
	437	sys_oabi_pread64:
	438	stmia sp, {r3, r4}
	439	b sys_pread64
93ed3970	440	ENDPROC(sys_oabi_pread64)
687ad019 NP	441
	442	sys_oabi_pwrite64:
	443	stmia sp, {r3, r4}
	444	b sys_pwrite64
93ed3970	445	ENDPROC(sys_oabi_pwrite64)
687ad019 NP	446
	447	sys_oabi_truncate64:
	448	mov r3, r2
	449	mov r2, r1
	450	b sys_truncate64
93ed3970	451	ENDPROC(sys_oabi_truncate64)
687ad019 NP	452
	453	sys_oabi_ftruncate64:
	454	mov r3, r2
	455	mov r2, r1
	456	b sys_ftruncate64
93ed3970	457	ENDPROC(sys_oabi_ftruncate64)
687ad019 NP	458
	459	sys_oabi_readahead:
	460	str r3, [sp]
	461	mov r3, r2
	462	mov r2, r1
	463	b sys_readahead
93ed3970	464	ENDPROC(sys_oabi_readahead)
687ad019	465
dd35afc2 NP	466	/*
	467	* Let's declare a second syscall table for old ABI binaries
	468	* using the compatibility syscall entries.
	469	*/
	470	#define ABI(native, compat) compat
	471	#define OBSOLETE(syscall) syscall
	472
	473	.type sys_oabi_call_table, #object
	474	ENTRY(sys_oabi_call_table)
	475	#include "calls.S"
	476	#undef ABI
	477	#undef OBSOLETE
	478
687ad019 NP	479	#endif
687ad019 NP	480